edksetup.bat

   1 @REM @file
   2 @REM   Windows batch file to setup a WORKSPACE environment
   3 @REM
   4 @REM Copyright (c) 2006 - 2013, Intel Corporation. All rights reserved.<BR>
   5 @REM This program and the accompanying materials
   6 @REM are licensed and made available under the terms and conditions of the BSD License
   7 @REM which accompanies this distribution.  The full text of the license may be found at
   8 @REM http://opensource.org/licenses/bsd-license.php
   9 @REM
  10 @REM THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
  11 @REM WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
  12 @REM
  13
  14 @REM set CYGWIN_HOME=C:\cygwin
  15
  16 @REM usage:
  17 @REM   edksetup.bat [--nt32] [AntBuild] [Rebuild] [ForceRebuild] [Reconfig]
  18 @REM if the argument, skip is present, only the paths and the
  19 @REM test and set of environment settings are performed.
  20
  21 @REM ##############################################################
  22 @REM # You should not have to modify anything below this line
  23 @REM #
  24
  25 @echo off
  26
  27 @REM
  28 @REM Set the WORKSPACE to the current working directory
  29 @REM
  30 pushd .
  31 cd %~dp0
  32
  33 if not defined WORKSPACE (
  34   goto SetWorkSpace
  35 )
  36
  37 if %WORKSPACE% == %CD% (
  38   @REM Workspace is not changed.
  39   goto ParseArgs
  40 )
  41
  42 :SetWorkSpace
  43 @REM set new workspace
  44 @REM clear EFI_SOURCE and EDK_SOURCE for the new workspace
  45 set WORKSPACE=%CD%
  46 set EFI_SOURCE=
  47 set EDK_SOURCE=
  48
  49 :ParseArgs
  50 if /I "%1"=="-h" goto Usage
  51 if /I "%1"=="-help" goto Usage
  52 if /I "%1"=="--help" goto Usage
  53 if /I "%1"=="/h" goto Usage
  54 if /I "%1"=="/?" goto Usage
  55 if /I "%1"=="/help" goto Usage
  56
  57 if /I not "%1"=="--nt32" goto no_nt32
  58
  59 @REM Flag, --nt32 is set
  60 @REM The Nt32 Emluation Platform requires Microsoft Libraries
  61 @REM and headers to interface with Windows.
  62
  63 if not defined VCINSTALLDIR (
  64   if defined VS110COMNTOOLS (
  65     call "%VS110COMNTOOLS%\vsvars32.bat"
  66   ) else (
  67     if defined VS100COMNTOOLS (
  68       call "%VS100COMNTOOLS%\vsvars32.bat"
  69     ) else (
  70       if defined VS90COMNTOOLS (
  71         call "%VS90COMNTOOLS%\vsvars32.bat"
  72       ) else (
  73         if defined VS80COMNTOOLS (
  74           call "%VS80COMNTOOLS%\vsvars32.bat"
  75         ) else (
  76           if defined VS71COMNTOOLS (
  77             call "%VS71COMNTOOLS%\vsvars32.bat"
  78           ) else (
  79             echo.
  80             echo !!! WARNING !!! Cannot find Visual Studio !!!
  81             echo.
  82           )
  83         )
  84       )
  85     )
  86   )
  87 )
  88 shift
  89
  90 :no_nt32
  91 if /I "%1"=="NewBuild" shift
  92 if not defined EDK_TOOLS_PATH set EDK_TOOLS_PATH=%WORKSPACE%\BaseTools
  93 IF NOT EXIST "%EDK_TOOLS_PATH%\toolsetup.bat" goto BadBaseTools
  94 call %EDK_TOOLS_PATH%\toolsetup.bat %*
  95 if /I "%1"=="Reconfig" shift
  96 goto check_cygwin
  97
  98 :BadBaseTools
  99   @REM
 100   REM Need the BaseTools Package in order to build
 101   @REM
 102   @echo.
 103   @echo !!! ERROR !!! The BaseTools Package was not found !!!
 104   @echo.
 105   @echo Set the system environment variable, EDK_TOOLS_PATH to the BaseTools,
 106   @echo For example,
 107   @echo   set EDK_TOOLS_PATH=C:\MyTools\BaseTools
 108   @echo The setup script, toolsetup.bat must reside in this folder.
 109   @echo.
 110   goto end
 111
 112 :check_cygwin
 113 if defined CYGWIN_HOME (
 114   if not exist "%CYGWIN_HOME%" (
 115     @echo.
 116     @echo !!! WARNING !!! CYGWIN_HOME not found, gcc build may not be used !!!
 117     @echo.
 118   )
 119 ) else (
 120   if exist c:\cygwin (
 121     set CYGWIN_HOME=c:\cygwin
 122   ) else (
 123     @echo.
 124     @echo !!! WARNING !!! No CYGWIN_HOME set, gcc build may not be used !!!
 125     @echo.
 126   )
 127 )
 128
 129 :cygwin_done
 130 if "%1"=="" goto end
 131
 132 :Usage
 133   @echo.
 134   @echo  Usage: "%0 [-h | -help | --help | /h | /help | /?] [--nt32] [Reconfig]"
 135   @echo         --nt32         Call vsvars32.bat for NT32 platform build.
 136   @echo.
 137   @echo         Reconfig       Reinstall target.txt, tools_def.txt and build_rule.txt.
 138   @echo.
 139   @echo  Note that target.template, tools_def.template and build_rules.template
 140   @echo  will only be copied to target.txt, tools_def.txt and build_rule.txt
 141   @echo  respectively if they do not exist. Use option [Reconfig] to force the copy.
 142   @echo.
 143   goto end
 144
 145 :end
 146   popd
 147