X-Git-Url: https://git.proxmox.com/?p=mirror_edk2.git;a=blobdiff_plain;f=OldMdePkg%2FLibrary%2FBaseLib%2FIa32%2FEnablePaging64.S;fp=OldMdePkg%2FLibrary%2FBaseLib%2FIa32%2FEnablePaging64.S;h=ffa9beb0a1544b6b28b701605fc9b716217d57f3;hp=0000000000000000000000000000000000000000;hb=586cd1f1f4129ab7ec24543d4968801e17cc870b;hpb=144d783d40c8a02113350feabd1b9a55b692313f

diff --git a/OldMdePkg/Library/BaseLib/Ia32/EnablePaging64.S b/OldMdePkg/Library/BaseLib/Ia32/EnablePaging64.S
new file mode 100644
index 0000000000..ffa9beb0a1
--- /dev/null
+++ b/OldMdePkg/Library/BaseLib/Ia32/EnablePaging64.S
@@ -0,0 +1,63 @@
+#------------------------------------------------------------------------------
+#
+# Copyright (c) 2006, Intel Corporation
+# All rights reserved. This program and the accompanying materials
+# are licensed and made available under the terms and conditions of the BSD License
+# which accompanies this distribution.  The full text of the license may be found at
+# http://opensource.org/licenses/bsd-license.php
+#
+# THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,
+# WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.
+#
+# Module Name:
+#
+#   EnablePaging64.Asm
+#
+# Abstract:
+#
+#   InternalX86EnablePaging64 function
+#
+# Notes:
+#
+#------------------------------------------------------------------------------
+
+.globl ASM_PFX(InternalX86EnablePaging64)
+
+#------------------------------------------------------------------------------
+# VOID
+# EFIAPI
+# InternalX86EnablePaging64 (
+#   IN      UINT16                    CodeSelector,
+#   IN      UINT64                    EntryPoint,
+#   IN      UINT64                    Context1,    OPTIONAL
+#   IN      UINT64                    Context2,    OPTIONAL
+#   IN      UINT64                    NewStack
+#   );
+#------------------------------------------------------------------------------
+ASM_PFX(InternalX86EnablePaging64):
+    cli
+    movl    $LongStart, (%esp)
+    movl    %cr4, %eax
+    orb     $0x20, %al
+    movl    %eax, %cr4                  # enable PAE
+    movl    $0xc0000080, %ecx
+    rdmsr
+    orb     $1, %ah                     # set LME
+    wrmsr
+    movl    %cr0, %eax
+    btsl    $31, %eax
+    movl    %eax, %cr0                  # enable paging
+    lret
+LongStart:                              # long mode starts here
+    .byte   0x67, 0x48
+    movl    (%esp), %ebx                # mov rbx, [esp]
+    .byte   0x67, 0x48
+    movl    8(%esp), %ecx               # mov rcx, [esp + 8]
+    .byte   0x67, 0x48
+    movl    0x10(%esp), %edx            # mov rdx, [esp + 10h]
+    .byte   0x67, 0x48
+    movl    0x18(%esp), %esp            # mov rsp, [esp + 18h]
+    .byte   0x48
+    addl    $0x-20, %esp                # add rsp, -20h
+    call    *%ebx                       # call rbx
+    jmp     .