--- /dev/null
+;------------------------------------------------------------------------------\r
+;\r
+; Copyright (c) 2006, Intel Corporation. All rights reserved.<BR>\r
+; This program and the accompanying materials\r
+; are licensed and made available under the terms and conditions of the BSD License\r
+; which accompanies this distribution. The full text of the license may be found at\r
+; http://opensource.org/licenses/bsd-license.php.\r
+;\r
+; THE PROGRAM IS DISTRIBUTED UNDER THE BSD LICENSE ON AN "AS IS" BASIS,\r
+; WITHOUT WARRANTIES OR REPRESENTATIONS OF ANY KIND, EITHER EXPRESS OR IMPLIED.\r
+;\r
+; Module Name:\r
+;\r
+; SetMem.nasm\r
+;\r
+; Abstract:\r
+;\r
+; SetMem function\r
+;\r
+; Notes:\r
+;\r
+;------------------------------------------------------------------------------\r
+\r
+ SECTION .text\r
+\r
+;------------------------------------------------------------------------------\r
+; VOID *\r
+; EFIAPI\r
+; InternalMemSetMem (\r
+; IN VOID *Buffer,\r
+; IN UINTN Count,\r
+; IN UINT8 Value\r
+; );\r
+;------------------------------------------------------------------------------\r
+global ASM_PFX(InternalMemSetMem)\r
+ASM_PFX(InternalMemSetMem):\r
+ push edi\r
+ mov edx, [esp + 12] ; edx <- Count\r
+ mov edi, [esp + 8] ; edi <- Buffer\r
+ mov al, [esp + 16] ; al <- Value\r
+ xor ecx, ecx\r
+ sub ecx, edi\r
+ and ecx, 15 ; ecx + edi aligns on 16-byte boundary\r
+ jz .0\r
+ cmp ecx, edx\r
+ cmova ecx, edx\r
+ sub edx, ecx\r
+ rep stosb\r
+.0:\r
+ mov ecx, edx\r
+ and edx, 15\r
+ shr ecx, 4 ; ecx <- # of DQwords to set\r
+ jz @SetBytes\r
+ mov ah, al ; ax <- Value | (Value << 8)\r
+ add esp, -16\r
+ movdqu [esp], xmm0 ; save xmm0\r
+ movd xmm0, eax\r
+ pshuflw xmm0, xmm0, 0 ; xmm0[0..63] <- Value repeats 8 times\r
+ movlhps xmm0, xmm0 ; xmm0 <- Value repeats 16 times\r
+.1:\r
+ movntdq [edi], xmm0 ; edi should be 16-byte aligned\r
+ add edi, 16\r
+ loop .1\r
+ mfence\r
+ movdqu xmm0, [esp] ; restore xmm0\r
+ add esp, 16 ; stack cleanup\r
+@SetBytes:\r
+ mov ecx, edx\r
+ rep stosb\r
+ mov eax, [esp + 8] ; eax <- Buffer as return value\r
+ pop edi\r
+ ret\r
+\r