configure.ac

   1 ##
   2 ## Configure template file for FRRouting.
   3 ## autoconf will generate a configure script.
   4 ##
   5 ##  Copyright (c) 1996, 97, 98, 99, 2000 Kunihiro Ishiguro <kunihiro@zebra.org>
   6 ##  Portions Copyright (c) 2003 Paul Jakma <paul@dishone.st>
   7 ##
   8 AC_PREREQ([2.60])
   9
  10 AC_INIT([frr], [6.1-dev], [https://github.com/frrouting/frr/issues])
  11 PACKAGE_URL="https://frrouting.org/"
  12 AC_SUBST([PACKAGE_URL])
  13 PACKAGE_FULLNAME="FRRouting"
  14 AC_SUBST([PACKAGE_FULLNAME])
  15
  16 CONFIG_ARGS="`echo $ac_configure_args | sed -e \"s% '[[A-Z]]*FLAGS=[[^']]\+'%%g\"`"
  17 AC_SUBST([CONFIG_ARGS])
  18
  19 AC_CONFIG_SRCDIR([lib/zebra.h])
  20 AC_CONFIG_MACRO_DIR([m4])
  21
  22 dnl -----------------------------------
  23 dnl Get hostname and other information.
  24 dnl -----------------------------------
  25 AC_CANONICAL_BUILD()
  26 AC_CANONICAL_HOST()
  27
  28 AS_IF([test "$host" != "$build"], [
  29   if test "$srcdir" = "."; then
  30     AC_MSG_ERROR([cross-compilation is only possible with builddir separate from srcdir.  create a separate directory and run as .../path-to-frr/configure.])
  31   fi
  32   test -d hosttools || mkdir hosttools
  33   abssrc="`cd \"${srcdir}\"; pwd`"
  34
  35   AC_MSG_NOTICE([...])
  36   AC_MSG_NOTICE([... cross-compilation: creating hosttools directory and self-configuring for build platform tools])
  37   AC_MSG_NOTICE([... use HOST_CPPFLAGS / HOST_CFLAGS / HOST_LDFLAGS if neccessary])
  38   AC_MSG_NOTICE([...])
  39
  40   ( CPPFLAGS="$HOST_CPPFLAGS"; \
  41     CFLAGS="$HOST_CFLAGS"; \
  42     LDFLAGS="$HOST_LDFLAGS"; \
  43     cd hosttools; "${abssrc}/configure" "--host=$build" "--build=$build" "--enable-clippy-only" "--disable-nhrpd" "--disable-vtysh"; )
  44
  45   AC_MSG_NOTICE([...])
  46   AC_MSG_NOTICE([... cross-compilation: finished self-configuring for build platform tools])
  47   AC_MSG_NOTICE([...])
  48
  49   build_clippy="false"
  50   HOSTTOOLS="hosttools/"
  51 ], [
  52   build_clippy="true"
  53   HOSTTOOLS=""
  54 ])
  55 AC_SUBST([HOSTTOOLS])
  56 AM_CONDITIONAL([BUILD_CLIPPY], [$build_clippy])
  57
  58 # Disable portability warnings -- our automake code (in particular
  59 # common.am) uses some constructs specific to gmake.
  60 AM_INIT_AUTOMAKE([1.12 -Wno-portability foreign])
  61 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  62 AM_SILENT_RULES([yes])
  63 AC_CONFIG_HEADERS([config.h])
  64
  65 AC_PATH_PROG([PERL], [perl])
  66 PKG_PROG_PKG_CONFIG
  67
  68 dnl default is to match previous behavior
  69 exampledir=${sysconfdir}
  70 AC_ARG_ENABLE([exampledir],
  71           AS_HELP_STRING([--enable-exampledir],
  72                          [specify alternate directory for examples]),
  73                          exampledir="$enableval",)
  74 dnl XXX add --exampledir to autoconf standard directory list somehow
  75 AC_SUBST([exampledir])
  76
  77 dnl default is to match previous behavior
  78 pkgsrcrcdir=""
  79 AC_ARG_ENABLE([pkgsrcrcdir],
  80           AS_HELP_STRING([--enable-pkgsrcrcdir],
  81                          [specify directory for rc.d scripts]),
  82                          pkgsrcrcdir="$enableval",)
  83 dnl XXX add --pkgsrcrcdir to autoconf standard directory list somehow
  84 AC_SUBST([pkgsrcrcdir])
  85 AM_CONDITIONAL([PKGSRC], [test "x$pkgsrcrcdir" != "x"])
  86
  87 AC_ARG_WITH([moduledir], [AS_HELP_STRING([--with-moduledir=DIR], [module directory (${libdir}/frr/modules)])], [
  88         moduledir="$withval"
  89 ], [
  90         moduledir="\${libdir}/frr/modules"
  91 ])
  92 AC_SUBST([moduledir], [$moduledir])
  93
  94
  95 AC_ARG_WITH([yangmodelsdir], [AS_HELP_STRING([--with-yangmodelsdir=DIR], [yang models directory (${datarootdir}/yang)])], [
  96         yangmodelsdir="$withval"
  97 ], [
  98         yangmodelsdir="\${datarootdir}/yang"
  99 ])
 100 AC_SUBST([yangmodelsdir])
 101
 102 AC_ARG_WITH([libyang_pluginsdir], [AS_HELP_STRING([--with-libyang-pluginsdir=DIR], [yangmodule plugins directory (${libdir}/frr/libyang_plugins)])], [
 103         libyang_pluginsdir="$withval"
 104 ], [
 105    libyang_pluginsdir="\${libdir}/frr/libyang_plugins"
 106 ])
 107 AC_SUBST([libyang_pluginsdir])
 108
 109 AC_ARG_ENABLE(tcmalloc,
 110         AS_HELP_STRING([--enable-tcmalloc], [Turn on tcmalloc]),
 111 [case "${enableval}" in
 112   yes) tcmalloc_enabled=true
 113 LIBS="$LIBS -ltcmalloc_minimal"
 114  ;;
 115   no)  tcmalloc_enabled=false ;;
 116   *) AC_MSG_ERROR([bad value ${enableval} for --enable-tcmalloc]) ;;
 117 esac],[tcmalloc_enabled=false])
 118
 119
 120 dnl Thanks autoconf, but we don't want a default -g -O2.  We have our own
 121 dnl flag determination logic.
 122 CFLAGS="${CFLAGS:-}"
 123
 124 dnl --------------------
 125 dnl Check CC and friends
 126 dnl --------------------
 127 dnl note orig_cflags is also used further down
 128 orig_cflags="$CFLAGS"
 129 AC_LANG([C])
 130 AC_PROG_CC
 131 AC_PROG_CPP
 132 AM_PROG_CC_C_O
 133 dnl remove autoconf default "-g -O2"
 134 CFLAGS="$orig_cflags"
 135 AC_PROG_CC_C99
 136 dnl NB: see C11 below
 137
 138 AC_PROG_EGREP
 139 PKG_PROG_PKG_CONFIG
 140
 141 dnl autoconf 2.59 appears not to support AC_PROG_SED
 142 dnl AC_PROG_SED
 143 AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
 144
 145 dnl try and enable CFLAGS that are useful for FRR
 146 dnl - specifically, options to control warnings
 147
 148 AC_USE_SYSTEM_EXTENSIONS
 149 AC_DEFUN([AC_C_FLAG], [{
 150     m4_pushdef([cachename],[m4_translit([frr_cv_$1],[ =-],[___])])
 151     AC_CACHE_CHECK([[whether $CC supports $1]], cachename, [
 152         AC_LANG_PUSH([C])
 153         ac_c_flag_save="$CFLAGS"
 154         CFLAGS="$CFLAGS $1"
 155         AC_COMPILE_IFELSE(
 156                 [AC_LANG_PROGRAM([[]])],
 157                 [
 158                         cachename=yes
 159                 ], [
 160                         cachename=no
 161                 ])
 162         CFLAGS="$ac_c_flag_save"
 163         AC_LANG_POP([C])
 164     ])
 165     if test "${cachename}" = yes; then
 166         m4_if([$3], [], [CFLAGS="$CFLAGS $1"], [$3])
 167     else
 168         :
 169         $2
 170     fi
 171     m4_popdef([cachename])
 172 }])
 173
 174 AC_DEFUN([AC_LINK_IFELSE_FLAGS], [{
 175         AC_LANG_PUSH([C])
 176         ac_cflags_save="$CFLAGS"
 177         ac_libs_save="$LIBS"
 178         CFLAGS="$CFLAGS $1"
 179         LIBS="$LIBS $2"
 180         AC_LINK_IFELSE(
 181                 [$3],
 182                 [
 183                         AC_MSG_RESULT([yes])
 184                         CFLAGS="$ac_cflags_save"
 185                         LIBS="$ac_libs_save"
 186                         $5
 187                 ], [
 188                         AC_MSG_RESULT([no])
 189                         CFLAGS="$ac_cflags_save"
 190                         LIBS="$ac_libs_save"
 191                         $4
 192                 ])
 193         AC_LANG_POP([C])
 194         }])
 195
 196 dnl ICC won't bail on unknown options without -diag-error 10006
 197 dnl need to do this first so we get useful results for the other options
 198 AC_C_FLAG([-diag-error 10006])
 199
 200 dnl AC_PROG_CC_C99 may change CC to include -std=gnu99 or something
 201 ac_cc="$CC"
 202 CC="${CC% -std=gnu99}"
 203 CC="${CC% -std=c99}"
 204
 205 AC_C_FLAG([-std=gnu11], [CC="$ac_cc"], [CC="$CC -std=gnu11"])
 206
 207 dnl if the user has specified any CFLAGS, override our settings
 208 if test "x${enable_gcov}" = "xyes"; then
 209    if test "z$orig_cflags" = "z"; then
 210       AC_C_FLAG([-coverage])
 211       AC_C_FLAG([-O0])
 212    fi
 213
 214    LDFLAGS="${LDFLAGS} -lgcov"
 215 elif test "x${enable_dev_build}" = "xyes"; then
 216    AC_DEFINE([DEV_BUILD], [1], [Build for development])
 217    if test "z$orig_cflags" = "z"; then
 218       AC_C_FLAG([-g3])
 219       AC_C_FLAG([-O0])
 220    fi
 221    if test "x${enable_lua}" = "xyes"; then
 222       AC_CHECK_LIB([lua], [lua_newstate],
 223       [LIBS="$LIBS -llua"])
 224       AC_DEFINE([HAVE_LUA], [1], [Lua enabled for development])
 225    fi
 226 else
 227    if test "x${enable_lua}" = "xyes"; then
 228       AC_MSG_ERROR([Lua is not meant to be built/used outside of development at this time])
 229    fi
 230    if test "z$orig_cflags" = "z"; then
 231       AC_C_FLAG([-g])
 232       AC_C_FLAG([-Os], [
 233         AC_C_FLAG([-O2])
 234       ])
 235    fi
 236 fi
 237 AM_CONDITIONAL([DEV_BUILD], [test "x$enable_dev_build" = "xyes"])
 238
 239 dnl always want these CFLAGS
 240 AC_C_FLAG([-fno-omit-frame-pointer])
 241 AC_C_FLAG([-funwind-tables])
 242 AC_C_FLAG([-Wall])
 243 AC_C_FLAG([-Wextra])
 244 AC_C_FLAG([-Wmissing-prototypes])
 245 AC_C_FLAG([-Wmissing-declarations])
 246 AC_C_FLAG([-Wpointer-arith])
 247 AC_C_FLAG([-Wbad-function-cast])
 248 AC_C_FLAG([-Wwrite-strings])
 249 if test x"${enable_gcc_ultra_verbose}" = x"yes" ; then
 250   AC_C_FLAG([-Wcast-qual])
 251   AC_C_FLAG([-Wstrict-prototypes])
 252   AC_C_FLAG([-Wmissing-noreturn])
 253   AC_C_FLAG([-Wmissing-format-attribute])
 254   AC_C_FLAG([-Wunreachable-code])
 255   AC_C_FLAG([-Wpacked])
 256   AC_C_FLAG([-Wpadded])
 257   AC_C_FLAG([-Wshadow])
 258 else
 259   AC_C_FLAG([-Wno-unused-result])
 260 fi
 261 AC_C_FLAG([-Wno-unused-parameter])
 262 AC_C_FLAG([-Wno-missing-field-initializers])
 263
 264 dnl ICC emits a broken warning for const char *x = a ? "b" : "c";
 265 dnl for some reason the string consts get 'promoted' to char *,
 266 dnl triggering a const to non-const conversion warning.
 267 AC_C_FLAG([-diag-disable 3179])
 268
 269 if test x"${enable_werror}" = x"yes" ; then
 270   WERROR="-Werror"
 271 fi
 272 AC_SUBST([WERROR])
 273
 274 SAN_FLAGS=""
 275 if test "$enable_address_sanitizer" = "yes"; then
 276   AC_C_FLAG([-fsanitize=address], [
 277     AC_MSG_ERROR([$CC does not support Address Sanitizer.])
 278   ], [
 279     SAN_FLAGS="$SAN_FLAGS -fsanitize=address"
 280   ])
 281 fi
 282 if test "$enable_thread_sanitizer" = "yes"; then
 283   AC_C_FLAG([-fsanitize=thread], [
 284     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 285   ], [
 286     SAN_FLAGS="$SAN_FLAGS -fsanitize=thread"
 287   ])
 288 fi
 289 if test "$enable_memory_sanitizer" = "yes"; then
 290   AC_C_FLAG([-fsanitize=thread -fPIE -pie], [
 291     AC_MSG_ERROR([$CC does not support Thread Sanitizer.])
 292   ], [
 293     SAN_FLAGS="-fsanitize=memory -fPIE -pie"
 294   ])
 295 fi
 296 AC_SUBST([SAN_FLAGS])
 297
 298 dnl ----------
 299 dnl Essentials
 300 dnl ----------
 301
 302 AX_PTHREAD([
 303   CC="$PTHREAD_CC"
 304   CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 305   LIBS="$PTHREAD_LIBS $LIBS"
 306 ], [
 307   AC_MSG_FAILURE([This FRR version needs pthreads])
 308 ])
 309
 310 AC_SEARCH_LIBS([pthread_condattr_setclock], [],
 311                 [frr_cv_pthread_condattr_setclock=yes],
 312                 [frr_cv_pthread_condattr_setclock=no])
 313 if test "$frr_cv_pthread_condattr_setclock" = yes; then
 314   AC_DEFINE([HAVE_PTHREAD_CONDATTR_SETCLOCK], [1], [Have pthread.h pthread_condattr_setclock])
 315 fi
 316
 317 dnl --------------
 318 dnl Check programs
 319 dnl --------------
 320 AC_PROG_INSTALL
 321 AC_PROG_LN_S
 322 AC_PROG_MAKE_SET
 323 AC_CHECK_TOOL([AR], [ar])
 324
 325 dnl -------
 326 dnl libtool
 327 dnl -------
 328 AC_ARG_ENABLE([static-bin],
 329   AS_HELP_STRING([--enable-static-bin], [link binaries statically]))
 330 LT_INIT
 331 _LT_CONFIG_LIBTOOL([
 332   patch -N -i "${srcdir}/m4/libtool-whole-archive.patch" libtool >&AS_MESSAGE_LOG_FD || \
 333     AC_MSG_WARN([Could not patch libtool for static linking support.  Loading modules into a statically linked daemon will fail.])
 334 ])
 335 if test "$enable_static_bin" = "yes"; then
 336   AC_LDFLAGS="-static"
 337   if test "$enable_static" != "yes"; then
 338     AC_MSG_ERROR([The --enable-static-bin option must be combined with --enable-static.])
 339   fi
 340 fi
 341 if test "$enable_shared" != "yes"; then
 342   AC_MSG_ERROR([FRR cannot be built with --disable-shared.  If you want statically linked daemons, use --enable-shared --enable-static --enable-static-bin])
 343 fi
 344 AC_SUBST([AC_LDFLAGS])
 345 AM_CONDITIONAL([STATIC_BIN], [test "x$enable_static_bin" = "xyes"])
 346
 347 dnl $AR and $RANLIB are set by LT_INIT above
 348 AC_MSG_CHECKING([whether $AR supports D option])
 349 if $AR crD conftest.a; then
 350   AC_MSG_RESULT([yes])
 351   dnl ARFLAGS is for automake, AR_FLAGS for libtool m-(
 352   ARFLAGS="crD"
 353   AR_FLAGS="crD"
 354 else
 355   AC_MSG_RESULT([no])
 356   ARFLAGS="cru"
 357   AR_FLAGS="cru"
 358 fi
 359 AC_SUBST([ARFLAGS])
 360 AC_SUBST([AR_FLAGS])
 361
 362 AC_MSG_CHECKING([whether $RANLIB supports D option])
 363 if $RANLIB -D conftest.a; then
 364   AC_MSG_RESULT([yes])
 365   RANLIB="$RANLIB -D"
 366 else
 367   AC_MSG_RESULT([no])
 368 fi
 369 AC_SUBST([RANLIB])
 370
 371 test -f conftest.a && rm conftest.a
 372
 373 dnl ----------------------
 374 dnl Packages configuration
 375 dnl ----------------------
 376 if test -f config.version; then
 377   . ./config.version
 378 elif test -f "${srcdir}/config.version"; then
 379   . "${srcdir}/config.version"
 380 fi
 381 AC_ARG_WITH([pkg-extra-version],
 382   AS_HELP_STRING([--with-pkg-extra-version=VER], [add extra version field, for packagers/distributions]), [
 383   if test "$withval" = "no"; then
 384     EXTRAVERSION=
 385   else
 386     EXTRAVERSION=$withval
 387   fi
 388 ], [])
 389 AC_ARG_WITH([pkg-git-version],
 390         AS_HELP_STRING([--with-pkg-git-version], [add git information to MOTD and build version string]),
 391         [ test "x$withval" != "xno" && with_pkg_git_version="yes" ])
 392 AC_ARG_WITH([vtysh_pager],
 393         AS_HELP_STRING([--with-vtysh-pager=PAGER], [control what pager is compiled in as default]),
 394         VTYSH_PAGER=$withval, VTYSH_PAGER="more")
 395 AC_ARG_ENABLE([vtysh],
 396   AS_HELP_STRING([--disable-vtysh], [do not build integrated vty shell for FRR]))
 397 AC_ARG_ENABLE([doc],
 398   AS_HELP_STRING([--disable-doc], [do not build docs]))
 399 AC_ARG_ENABLE([doc-html],
 400   AS_HELP_STRING([--enable-doc-html], [build HTML docs]))
 401 AC_ARG_ENABLE([zebra],
 402   AS_HELP_STRING([--disable-zebra], [do not build zebra daemon]))
 403 AC_ARG_ENABLE([bgpd],
 404   AS_HELP_STRING([--disable-bgpd], [do not build bgpd]))
 405 AC_ARG_ENABLE([ripd],
 406   AS_HELP_STRING([--disable-ripd], [do not build ripd]))
 407 AC_ARG_ENABLE([ripngd],
 408   AS_HELP_STRING([--disable-ripngd], [do not build ripngd]))
 409 AC_ARG_ENABLE([ospfd],
 410   AS_HELP_STRING([--disable-ospfd], [do not build ospfd]))
 411 AC_ARG_ENABLE([ospf6d],
 412   AS_HELP_STRING([--disable-ospf6d], [do not build ospf6d]))
 413 AC_ARG_ENABLE([ldpd],
 414   AS_HELP_STRING([--disable-ldpd], [do not build ldpd]))
 415 AC_ARG_ENABLE([nhrpd],
 416   AS_HELP_STRING([--disable-nhrpd], [do not build nhrpd]))
 417 AC_ARG_ENABLE([eigrpd],
 418   AS_HELP_STRING([--disable-eigrpd], [do not build eigrpd]))
 419 AC_ARG_ENABLE([babeld],
 420   AS_HELP_STRING([--disable-babeld], [do not build babeld]))
 421 AC_ARG_ENABLE([watchfrr],
 422   AS_HELP_STRING([--disable-watchfrr], [do not build watchfrr]))
 423 AC_ARG_ENABLE([isisd],
 424   AS_HELP_STRING([--disable-isisd], [do not build isisd]))
 425 AC_ARG_ENABLE([pimd],
 426   AS_HELP_STRING([--disable-pimd], [do not build pimd]))
 427 AC_ARG_ENABLE([pbrd],
 428   AS_HELP_STRING([--disable-pbrd], [do not build pbrd]))
 429 AC_ARG_ENABLE([sharpd],
 430   AS_HELP_STRING([--enable-sharpd], [build sharpd]))
 431 AC_ARG_ENABLE([staticd],
 432   AS_HELP_STRING([--disable-staticd], [do not build staticd]))
 433 AC_ARG_ENABLE([fabricd],
 434   AS_HELP_STRING([--disable-fabricd], [do not build fabricd]))
 435 AC_ARG_ENABLE([bgp-announce],
 436   AS_HELP_STRING([--disable-bgp-announce,], [turn off BGP route announcement]))
 437 AC_ARG_ENABLE([bgp-vnc],
 438   AS_HELP_STRING([--disable-bgp-vnc],[turn off BGP VNC support]))
 439 AC_ARG_ENABLE([snmp],
 440   AS_HELP_STRING([--enable-snmp], [enable SNMP support for agentx]))
 441 AC_ARG_ENABLE([config_rollbacks],
 442   AS_HELP_STRING([--enable-config-rollbacks], [enable configuration rollbacks (requires sqlite3)]))
 443 AC_ARG_ENABLE([confd],
 444   AS_HELP_STRING([--enable-confd=ARG], [enable confd integration]))
 445 AC_ARG_ENABLE([sysrepo],
 446   AS_HELP_STRING([--enable-sysrepo], [enable sysrepo integration]))
 447 AC_ARG_ENABLE([zeromq],
 448   AS_HELP_STRING([--enable-zeromq], [enable ZeroMQ handler (libfrrzmq)]))
 449 AC_ARG_WITH([libpam],
 450   AS_HELP_STRING([--with-libpam], [use libpam for PAM support in vtysh]))
 451 AC_ARG_ENABLE([ospfapi],
 452   AS_HELP_STRING([--disable-ospfapi], [do not build OSPFAPI to access the OSPF LSA Database]))
 453 AC_ARG_ENABLE([ospfclient],
 454   AS_HELP_STRING([--disable-ospfclient], [do not build OSPFAPI client for OSPFAPI,
 455                           (this is the default if --disable-ospfapi is set)]))
 456 AC_ARG_ENABLE([multipath],
 457   AS_HELP_STRING([--enable-multipath=ARG], [enable multipath function, ARG must be digit]))
 458 AC_ARG_ENABLE([user],
 459   AS_HELP_STRING([--enable-user=USER], [user to run FRR suite as (default frr)]))
 460 AC_ARG_ENABLE([group],
 461   AS_HELP_STRING([--enable-group=GROUP], [group to run FRR suite as (default frr)]))
 462 AC_ARG_ENABLE([vty_group],
 463   AS_HELP_STRING([--enable-vty-group=ARG], [set vty sockets to have specified group as owner]))
 464 AC_ARG_ENABLE([configfile_mask],
 465   AS_HELP_STRING([--enable-configfile-mask=ARG], [set mask for config files]))
 466 AC_ARG_ENABLE([logfile_mask],
 467   AS_HELP_STRING([--enable-logfile-mask=ARG], [set mask for log files]))
 468 AC_ARG_ENABLE([shell_access],
 469   AS_HELP_STRING([--enable-shell-access], [Allow users to access shell/telnet/ssh]))
 470 AC_ARG_ENABLE([realms],
 471   AS_HELP_STRING([--enable-realms], [enable REALMS support under Linux]))
 472 AC_ARG_ENABLE([rtadv],
 473   AS_HELP_STRING([--disable-rtadv], [disable IPV6 router advertisement feature]))
 474 AC_ARG_ENABLE([irdp],
 475   AS_HELP_STRING([--disable-irdp], [enable IRDP server support in zebra (default if supported)]))
 476 AC_ARG_ENABLE([capabilities],
 477   AS_HELP_STRING([--disable-capabilities], [disable using POSIX capabilities]))
 478 AC_ARG_ENABLE([rusage],
 479   AS_HELP_STRING([--disable-rusage], [disable using getrusage]))
 480 AC_ARG_ENABLE([gcc_ultra_verbose],
 481   AS_HELP_STRING([--enable-gcc-ultra-verbose], [enable ultra verbose GCC warnings]))
 482 AC_ARG_ENABLE([backtrace],
 483   AS_HELP_STRING([--disable-backtrace,], [disable crash backtraces (default autodetect)]))
 484 AC_ARG_ENABLE([time-check],
 485   AS_HELP_STRING([--disable-time-check], [disable slow thread warning messages]))
 486 AC_ARG_ENABLE([pcreposix],
 487   AS_HELP_STRING([--enable-pcreposix], [enable using PCRE Posix libs for regex functions]))
 488 AC_ARG_ENABLE([fpm],
 489   AS_HELP_STRING([--enable-fpm], [enable Forwarding Plane Manager support]))
 490 AC_ARG_ENABLE([systemd],
 491   AS_HELP_STRING([--enable-systemd], [enable Systemd support]))
 492 AC_ARG_ENABLE([werror],
 493   AS_HELP_STRING([--enable-werror], [enable -Werror (recommended for developers only)]))
 494 AC_ARG_ENABLE([cumulus],
 495   AS_HELP_STRING([--enable-cumulus], [enable Cumulus Switch Special Extensions]))
 496 AC_ARG_ENABLE([datacenter],
 497   AS_HELP_STRING([--enable-datacenter], [enable Compilation for Data Center Extensions]))
 498 AC_ARG_ENABLE([fuzzing],
 499   AS_HELP_STRING([--enable-fuzzing], [enable ability to fuzz various parts of FRR]))
 500 AC_ARG_ENABLE([netlink_fuzzing],
 501   AS_HELP_STRING([--enable-netlink-fuzzing], [enable ability to fuzz netlink listening socket in zebra]))
 502 AC_ARG_ENABLE([rr-semantics],
 503   AS_HELP_STRING([--disable-rr-semantics], [disable the v6 Route Replace semantics]))
 504 AC_ARG_ENABLE([protobuf],
 505   AS_HELP_STRING([--enable-protobuf], [Enable experimental protobuf support]))
 506 AC_ARG_ENABLE([oldvpn_commands],
 507   AS_HELP_STRING([--enable-oldvpn-commands], [Keep old vpn commands]))
 508 AC_ARG_ENABLE([rpki],
 509   AS_HELP_STRING([--enable-rpki], [enable RPKI prefix validation support]))
 510 AC_ARG_ENABLE([clippy-only],
 511   AS_HELP_STRING([--enable-clippy-only], [Only build clippy]))
 512 AC_ARG_ENABLE([numeric_version],
 513   AS_HELP_STRING([--enable-numeric-version], [Only numeric digits allowed in version (for Alpine)]))
 514 AC_ARG_ENABLE([gcov],
 515   AS_HELP_STRING([--enable-gcov], [Add code coverage information]))
 516 AC_ARG_ENABLE([bfdd],
 517   AS_HELP_STRING([--disable-bfdd], [do not build bfdd]))
 518 AC_ARG_ENABLE([address-sanitizer],
 519   AS_HELP_STRING([--enable-address-sanitizer], [enable AddressSanitizer support for detecting a wide variety of memory allocation and deallocation errors]))
 520 AC_ARG_ENABLE([thread-sanitizer],
 521   AS_HELP_STRING([--enable-thread-sanitizer], [enable ThreadSanitizer support for detecting data races]))
 522 AC_ARG_ENABLE([memory-sanitizer],
 523   AS_HELP_STRING([--enable-memory-sanitizer], [enable MemorySanitizer support for detecting uninitialized memory reads]))
 524
 525 AS_IF([test "${enable_clippy_only}" != "yes"], [
 526 AC_CHECK_HEADERS([json-c/json.h])
 527 AC_CHECK_LIB([json-c], [json_object_get], [LIBS="$LIBS -ljson-c"], [], [-lm])
 528 if test "$ac_cv_lib_json_c_json_object_get" = no; then
 529   AC_CHECK_LIB([json], [json_object_get], [LIBS="$LIBS -ljson"])
 530   if test "$ac_cv_lib_json_json_object_get" = no; then
 531       AC_MSG_ERROR([libjson is needed to compile])
 532   fi
 533 fi
 534 ])
 535
 536 AC_ARG_ENABLE([dev_build],
 537     AS_HELP_STRING([--enable-dev-build], [build for development]))
 538
 539 AC_ARG_ENABLE([lua],
 540     AS_HELP_STRING([--enable-lua], [Build Lua scripting]))
 541
 542 if test x"${enable_time_check}" != x"no" ; then
 543   if test x"${enable_time_check}" = x"yes" -o x"${enable_time_check}" = x ; then
 544     AC_DEFINE([CONSUMED_TIME_CHECK], [5000000], [Consumed Time Check])
 545   else
 546     AC_DEFINE_UNQUOTED([CONSUMED_TIME_CHECK], [$enable_time_check], [Consumed Time Check])
 547   fi
 548 fi
 549
 550 case "${enable_systemd}" in
 551   "no") ;;
 552   "yes")
 553   AC_CHECK_LIB([systemd], [sd_notify], [LIBS="$LIBS -lsystemd"])
 554   if test $ac_cv_lib_systemd_sd_notify = no; then
 555     AC_MSG_ERROR([enable systemd has been specified but systemd development env not found on your system])
 556   else
 557     AC_DEFINE([HAVE_SYSTEMD], [1], [Compile systemd support in])
 558   fi
 559   ;;
 560   "*") ;;
 561 esac
 562
 563 if test "${enable_rr_semantics}" != "no" ; then
 564   AC_DEFINE([HAVE_V6_RR_SEMANTICS], [1], [Compile in v6 Route Replacement Semantics])
 565 fi
 566
 567 if test "${enable_datacenter}" = "yes" ; then
 568   AC_DEFINE([HAVE_DATACENTER], [1], [Compile extensions for a DataCenter])
 569   DFLT_NAME="datacenter"
 570 else
 571   DFLT_NAME="traditional"
 572 fi
 573
 574 if test "${enable_fuzzing}" = "yes" ; then
 575   AC_DEFINE([HANDLE_ZAPI_FUZZING], [1], [Compile extensions to use with a fuzzer])
 576 fi
 577
 578 if test "${enable_netlink_fuzzing}" = "yes" ; then
 579   AC_DEFINE([HANDLE_NETLINK_FUZZING], [1], [Compile extensions to use with a fuzzer for netlink])
 580 fi
 581
 582 if test "${enable_cumulus}" = "yes" ; then
 583   AC_DEFINE([HAVE_CUMULUS], [1], [Compile Special Cumulus Code in])
 584 fi
 585
 586 AC_SUBST([DFLT_NAME])
 587 AC_DEFINE_UNQUOTED([DFLT_NAME], ["$DFLT_NAME"], [Name of the configuration default set])
 588
 589 if test "${enable_shell_access}" = "yes"; then
 590    AC_DEFINE([HAVE_SHELL_ACCESS], [1], [Allow user to use ssh/telnet/bash])
 591 fi
 592
 593 AM_CONDITIONAL([FPM], [test "x$enable_fpm" = "xyes"])
 594
 595 #
 596 # Python for clippy
 597 #
 598
 599 AC_DEFUN([FRR_PYTHON_CHECK_WORKING], [
 600   AC_MSG_CHECKING([whether we found a working Python version])
 601   AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 602 #include <Python.h>
 603 #if PY_VERSION_HEX < 0x02070000
 604 #error python too old
 605 #endif
 606 int main(void);
 607 ],
 608 [
 609 {
 610   Py_Initialize();
 611   return 0;
 612 }
 613 ])], [
 614     # some python installs are missing the zlib dependency...
 615     PYTHON_LIBS="${PYTHON_LIBS} -lz"
 616     AC_LINK_IFELSE_FLAGS([$PYTHON_CFLAGS], [$PYTHON_LIBS], [AC_LANG_PROGRAM([
 617 #include <Python.h>
 618 #if PY_VERSION_HEX < 0x02070000
 619 #error python too old
 620 #endif
 621 int main(void);
 622 ],
 623 [
 624 {
 625   Py_Initialize();
 626   return 0;
 627 }
 628 ])], [
 629       m4_if([$1], [], [
 630         PYTHONCONFIG=""
 631         unset PYTHON_LIBS
 632         unset PYTHON_CFLAGS
 633       ], [$1])
 634     ])
 635   ])
 636 ])
 637
 638 AS_IF([test "$host" = "$build"], [
 639   PYTHONCONFIG=""
 640
 641   # ordering:
 642   # 1.  try python3, but respect the user's preference on which minor ver
 643   # 2.  try python, which might be py3 or py2 again on the user's preference
 644   # 3.  try python2 (can really only be 2.7 but eh)
 645   # 4.  try 3.6 > 3.5 > 3.4 > 3.3 > 3.2 > 2.7 through pkg-config (no user pref)
 646   #
 647   # (AX_PYTHON_DEVEL has no clue about py3 vs py2)
 648   # (AX_PYTHON does not do what we need)
 649
 650   AC_CHECK_TOOLS([PYTHONCONFIG], [ \
 651         python3-config \
 652         python-config \
 653         python2-config \
 654         python3.6-config \
 655         python3.5-config \
 656         python3.4-config \
 657         python3.3-config \
 658         python3.2-config \
 659         python2.7-config ])
 660   if test -n "$PYTHONCONFIG"; then
 661     PYTHON_CFLAGS="`\"${PYTHONCONFIG}\" --includes`"
 662     PYTHON_LIBS="`\"${PYTHONCONFIG}\" --ldflags`"
 663
 664     FRR_PYTHON_CHECK_WORKING([])
 665   fi
 666
 667   if test -z "$PYTHONCONFIG"; then
 668     PKG_CHECK_MODULES([PYTHON], [python-3.6], [], [
 669       PKG_CHECK_MODULES([PYTHON], [python-3.5], [], [
 670         PKG_CHECK_MODULES([PYTHON], [python-3.4], [], [
 671           PKG_CHECK_MODULES([PYTHON], [python-3.3], [], [
 672             PKG_CHECK_MODULES([PYTHON], [python-3.2], [], [
 673               PKG_CHECK_MODULES([PYTHON], [python-2.7], [], [
 674                 AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 675                 ])])])])])])
 676
 677
 678     FRR_PYTHON_CHECK_WORKING([
 679       AC_MSG_FAILURE([could not find python-config or pkg-config python, please install Python development files from libpython-dev or similar])
 680     ])
 681   fi
 682 ])
 683 AC_SUBST([PYTHON_CFLAGS])
 684 AC_SUBST([PYTHON_LIBS])
 685
 686 #
 687 # Logic for protobuf support.
 688 #
 689 if test "$enable_protobuf" = "yes"; then
 690   # Check for protoc & protoc-c
 691
 692   # protoc is not required, it's only for a "be nice" helper target
 693   AC_CHECK_PROGS([PROTOC], [protoc], [/bin/false])
 694
 695   AC_CHECK_PROGS([PROTOC_C], [protoc-c], [/bin/false])
 696   if test "$PROTOC_C" = "/bin/false"; then
 697     AC_MSG_FAILURE([protobuf requested but protoc-c not found.  Install protobuf-c.])
 698   fi
 699
 700   PKG_CHECK_MODULES([PROTOBUF_C], [libprotobuf-c >= 0.14],, [
 701     AC_MSG_FAILURE([protobuf requested but libprotobuf-c not found.  Install protobuf-c.])
 702   ])
 703   AC_CHECK_HEADER([google/protobuf-c/protobuf-c.h], [], [
 704     AC_MSG_FAILURE([protobuf requested but protobuf-c.h not found.  Install protobuf-c.])
 705   ])
 706
 707   AC_DEFINE([HAVE_PROTOBUF], [1], [protobuf])
 708 fi
 709 AM_CONDITIONAL([HAVE_PROTOBUF], [test "x$enable_protobuf" = "xyes"])
 710
 711 #
 712 # Logic for old vpn commands support.
 713 #
 714 if test "$enable_oldvpn_commands" = "yes"; then
 715    AC_DEFINE([KEEP_OLD_VPN_COMMANDS], [1], [Define for compiling with old vpn commands])
 716 fi
 717
 718 #
 719 # End of logic for protobuf support.
 720 #
 721
 722 AC_MSG_CHECKING([if zebra should be configurable to send Route Advertisements])
 723 if test "${enable_rtadv}" != "no"; then
 724   AC_MSG_RESULT([yes])
 725   AC_DEFINE([HAVE_RTADV], [1], [Enable IPv6 Routing Advertisement support])
 726 else
 727   AC_MSG_RESULT([no])
 728 fi
 729
 730 if test x"${enable_user}" = x"no"; then
 731   enable_user=""
 732 else
 733   if test x"${enable_user}" = x"yes" || test x"${enable_user}" = x""; then
 734     enable_user="frr"
 735   fi
 736   AC_DEFINE_UNQUOTED([FRR_USER], ["${enable_user}"], [frr User])
 737 fi
 738
 739 if test x"${enable_group}" = x"no"; then
 740   enable_group=""
 741 else
 742   if test x"${enable_group}" = x"yes" || test x"${enable_group}" = x""; then
 743     enable_group="frr"
 744   fi
 745   AC_DEFINE_UNQUOTED([FRR_GROUP], ["${enable_group}"], [frr Group])
 746 fi
 747
 748 if test x"${enable_vty_group}" = x"yes" ; then
 749   AC_MSG_ERROR([--enable-vty-group requires a group as argument, not yes])
 750 elif test x"${enable_vty_group}" != x""; then
 751   if test x"${enable_vty_group}" != x"no"; then
 752     AC_DEFINE_UNQUOTED([VTY_GROUP], ["${enable_vty_group}"], [VTY Sockets Group])
 753   fi
 754 fi
 755 AC_SUBST([enable_user])
 756 AC_SUBST([enable_group])
 757 AC_SUBST([enable_vty_group])
 758
 759 enable_configfile_mask=${enable_configfile_mask:-0600}
 760 AC_DEFINE_UNQUOTED([CONFIGFILE_MASK], [${enable_configfile_mask}], [Mask for config files])
 761
 762 enable_logfile_mask=${enable_logfile_mask:-0600}
 763 AC_DEFINE_UNQUOTED([LOGFILE_MASK], [${enable_logfile_mask}], [Mask for log files])
 764
 765 MPATH_NUM=1
 766
 767 case "${enable_multipath}" in
 768   0)
 769     MPATH_NUM=64
 770     ;;
 771   [[1-9]|[1-9][0-9]|[1-9][0-9][0-9]])
 772     MPATH_NUM="${enable_multipath}"
 773     ;;
 774   "")
 775     ;;
 776   *)
 777     AC_MSG_FAILURE([Please specify digit to enable multipath ARG])
 778     ;;
 779 esac
 780
 781 AC_DEFINE_UNQUOTED([MULTIPATH_NUM], [$MPATH_NUM], [Maximum number of paths for a route])
 782
 783 AC_DEFINE_UNQUOTED([VTYSH_PAGER], ["$VTYSH_PAGER"], [What pager to use])
 784
 785 dnl --------------------
 786 dnl Enable code coverage
 787 dnl --------------------
 788 AM_CONDITIONAL([HAVE_GCOV], [test '!' "$enable_gcov" = no])
 789
 790 dnl ------------------------------------
 791 dnl Alpine only accepts numeric versions
 792 dnl ------------------------------------
 793 if test "x${enable_numeric_version}" != "x" ; then
 794   VERSION="`echo ${VERSION} | tr -c -d '[[.0-9]]'`"
 795   PACKAGE_VERSION="`echo ${PACKAGE_VERSION} | tr -c -d '[[.0-9]]'`"
 796 fi
 797
 798 dnl -----------------------------------
 799 dnl Add extra version string to package
 800 dnl name, string and version fields.
 801 dnl -----------------------------------
 802 if test "x${EXTRAVERSION}" != "x" ; then
 803   VERSION="${VERSION}${EXTRAVERSION}"
 804   PACKAGE_VERSION="${PACKAGE_VERSION}${EXTRAVERSION}"
 805   AC_SUBST(PACKAGE_EXTRAVERSION, ["${EXTRAVERSION}"])
 806   PACKAGE_STRING="${PACKAGE_STRING}${EXTRAVERSION}"
 807 fi
 808 AC_SUBST([EXTRAVERSION])
 809
 810 if test "x$with_pkg_git_version" = "xyes"; then
 811         if test -d "${srcdir}/.git"; then
 812                 AC_DEFINE([GIT_VERSION], [1], [include git version info])
 813         else    with_pkg_git_version="no"
 814                 AC_MSG_WARN([--with-pkg-git-version given, but this is not a git checkout])
 815         fi
 816 fi
 817 AM_CONDITIONAL([GIT_VERSION], [test "x$with_pkg_git_version" = "xyes"])
 818
 819 AC_CHECK_TOOL([OBJCOPY], [objcopy], [:])
 820 AC_CACHE_CHECK([for .interp value to use], [frr_cv_interp], [
 821   frr_cv_interp=""
 822   AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])], [
 823     if $OBJCOPY -j.interp -Obinary conftest conftest.interp; then
 824       frr_cv_interp="`xargs -0 echo < conftest.interp`"
 825     fi
 826     test -f conftest.interp && rm conftest.interp
 827   ])
 828 ])
 829 if test -n "$frr_cv_interp"; then
 830   AC_DEFINE_UNQUOTED([INTERP], ["$frr_cv_interp"], [.interp value])
 831 fi
 832
 833 dnl ------------------------------------
 834 dnl Check C keywords and standard  types
 835 dnl ------------------------------------
 836 AC_C_CONST
 837 AC_C_INLINE
 838 AC_C_VOLATILE
 839 AC_HEADER_STDC
 840 dnl AC_TYPE_PID_T
 841 AC_TYPE_UID_T
 842 AC_TYPE_MODE_T
 843 AC_TYPE_SIZE_T
 844 AC_STRUCT_TM
 845
 846 dnl -------------------------
 847 dnl Check other header files.
 848 dnl -------------------------
 849 AC_CHECK_HEADERS([stropts.h sys/ksym.h \
 850         linux/version.h asm/types.h \
 851         sys/cdefs.h])
 852
 853 ac_stdatomic_ok=false
 854 AC_DEFINE([FRR_AUTOCONF_ATOMIC], [1], [did autoconf checks for atomic funcs])
 855 AC_CHECK_HEADER([stdatomic.h],[
 856
 857   AC_MSG_CHECKING([whether _Atomic qualifier works])
 858   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 859 #include <stdatomic.h>
 860 int main(int argc, char **argv) {
 861   _Atomic int i = 0;
 862   return i;
 863 }
 864 ]])], [
 865     AC_DEFINE([HAVE_STDATOMIC_H], [1], [found stdatomic.h])
 866     AC_MSG_RESULT([yes])
 867     ac_stdatomic_ok=true
 868   ], [
 869     AC_MSG_RESULT([no])
 870   ])
 871 ])
 872
 873 AS_IF([$ac_stdatomic_ok], [true], [
 874   AC_MSG_CHECKING([for __atomic_* builtins])
 875   AC_LINK_IFELSE([AC_LANG_SOURCE([[
 876 int main(int argc, char **argv) {
 877   volatile int i = 1;
 878   __atomic_store_n (&i, 0, __ATOMIC_RELEASE);
 879   return __atomic_load_n (&i, __ATOMIC_ACQUIRE);
 880 }
 881 ]])], [
 882     AC_DEFINE([HAVE___ATOMIC], [1], [found __atomic builtins])
 883     AC_MSG_RESULT([yes])
 884   ], [
 885     AC_MSG_RESULT([no])
 886
 887     dnl FreeBSD 9 has a broken stdatomic.h where _Atomic doesn't work
 888     AC_MSG_CHECKING([for __sync_* builtins])
 889     AC_LINK_IFELSE([AC_LANG_SOURCE([[
 890 int main(int argc, char **argv) {
 891   volatile int i = 1;
 892   __sync_fetch_and_sub (&i, 1);
 893   return __sync_val_compare_and_swap (&i, 0, 1);
 894 }
 895 ]])], [
 896       AC_DEFINE([HAVE___SYNC], [1], [found __sync builtins])
 897       AC_MSG_RESULT([yes])
 898
 899       AC_MSG_CHECKING([for __sync_swap builtin])
 900       AC_LINK_IFELSE([AC_LANG_SOURCE([[
 901 int main(int argc, char **argv) {
 902   volatile int i = 1;
 903   return __sync_swap (&i, 2);
 904 }
 905 ]])], [
 906         AC_DEFINE([HAVE___SYNC_SWAP], 1, [found __sync_swap builtin])
 907         AC_MSG_RESULT([yes])
 908       ], [
 909         AC_MSG_RESULT([no])
 910       ])
 911
 912     ], [
 913       AC_MSG_RESULT([no])
 914       AC_MSG_FAILURE([stdatomic.h unavailable and $CC has neither __atomic nor __sync builtins])
 915     ])
 916   ])
 917 ])
 918
 919 AC_CHECK_HEADERS([pthread_np.h],,, [
 920 #include <pthread.h>
 921 ])
 922 AC_CHECK_FUNCS([pthread_setname_np pthread_set_name_np])
 923
 924 dnl Utility macro to avoid retyping includes all the time
 925 m4_define([FRR_INCLUDES],
 926 [#ifdef SUNOS_5
 927 #define _POSIX_C_SOURCE 200809L
 928 #define __EXTENSIONS__
 929 #endif
 930 #include <stdio.h>
 931 #include <stdlib.h>
 932 #include <stddef.h>
 933 #include <sys/types.h>
 934 /* sys/conf.h depends on param.h on FBSD at least */
 935 #include <sys/param.h>
 936 /* Required for MAXSIG */
 937 #include <signal.h>
 938 #include <sys/socket.h>
 939 #ifdef __APPLE__
 940 # define __APPLE_USE_RFC_3542
 941 #endif
 942 #include <netinet/in.h>
 943 #include <sys/time.h>
 944 #include <time.h>
 945 #include <net/if.h>
 946 ])dnl
 947
 948 dnl Same applies for HAVE_NET_IF_VAR_H, which HAVE_NETINET6_ND6_H and
 949 dnl HAVE_NETINET_IN_VAR_H depend upon. But if_var.h depends on if.h, hence
 950 dnl an additional round for it.
 951
 952 AC_CHECK_HEADERS([net/if_var.h], [], [], [FRR_INCLUDES])
 953
 954 m4_define([FRR_INCLUDES],
 955 FRR_INCLUDES
 956 [#if HAVE_NET_IF_VAR_H
 957 # include <net/if_var.h>
 958 #endif
 959 ])dnl
 960
 961 AC_CHECK_HEADERS([netinet/in_var.h \
 962         net/if_dl.h net/netopt.h \
 963         inet/nd.h netinet/ip_icmp.h \
 964         sys/sysctl.h sys/sockio.h kvm.h sys/conf.h],
 965         [], [], [FRR_INCLUDES])
 966
 967 AC_CHECK_HEADERS([ucontext.h], [], [],
 968 [#ifndef __USE_GNU
 969 #define __USE_GNU
 970 #endif /* __USE_GNU */
 971 FRR_INCLUDES
 972 ])
 973
 974 m4_define([UCONTEXT_INCLUDES],
 975 [#include <ucontext.h>])dnl
 976
 977 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.uc_regs],
 978   [], [], [UCONTEXT_INCLUDES])
 979 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs],
 980   [AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.regs.nip],
 981    [], [], [UCONTEXT_INCLUDES])],
 982   [], [UCONTEXT_INCLUDES])
 983 AC_CHECK_MEMBERS([ucontext_t.uc_mcontext.gregs],
 984   [], [], [UCONTEXT_INCLUDES])
 985
 986 m4_define([FRR_INCLUDES],
 987 FRR_INCLUDES
 988 [
 989 #include <sys/un.h>
 990 #include <netinet/in_systm.h>
 991 #if HAVE_NETINET_IN_VAR_H
 992 # include <netinet/in_var.h>
 993 #endif
 994 #if HAVE_NET_IF_DL_H
 995 # include <net/if_dl.h>
 996 #endif
 997 #if HAVE_NET_NETOPT_H
 998 # include <net/netopt.h>
 999 #endif
1000 #include <net/route.h>
1001 #if HAVE_INET_ND_H
1002 # include <inet/nd.h>
1003 #endif
1004 #include <arpa/inet.h>
1005 /* Required for IDRP */
1006 #if HAVE_NETINET_IP_ICMP_H
1007 # include <netinet/ip_icmp.h>
1008 #endif
1009 ])dnl
1010
1011 dnl V6 headers are checked below, after we check for v6
1012
1013 AC_MSG_CHECKING([which operating system interface to use])
1014 case "$host_os" in
1015   sunos* | solaris2*)
1016     AC_MSG_RESULT([Solaris])
1017
1018     AC_DEFINE([SUNOS_5], [1], [SunOS 5])
1019     AC_DEFINE([SOLARIS_IPV6], [1], Solaris IPv6)
1020     AC_DEFINE([_POSIX_C_SOURCE], [200809L], [enable POSIX.1-2008 and XPG7/SUSv4])
1021
1022     AC_CHECK_LIB([socket], [main])
1023     AC_CHECK_LIB([nsl], [main])
1024     AC_CHECK_LIB([umem], [main])
1025     SOLARIS="solaris"
1026     ;;
1027   linux*)
1028     AC_MSG_RESULT([Linux])
1029
1030     AC_DEFINE([GNU_LINUX], [1], [GNU Linux])
1031     AC_DEFINE([HAVE_NETLINK], [1], [netlink])
1032     AC_DEFINE([LINUX_IPV6], [1], [Linux IPv6 stack])
1033
1034     dnl Linux has a compilation problem with mixing
1035     dnl netinet/in.h and linux/in6.h they are not
1036     dnl compatible.  There has been discussion on
1037     dnl how to fix it but no real progress on implementation
1038     dnl when they fix it, remove this
1039     AC_DEFINE([IPV6_MINHOPCOUNT], [73], [Linux ipv6 Min Hop Count])
1040     ;;
1041   openbsd*)
1042     AC_MSG_RESULT([OpenBSD])
1043
1044     AC_DEFINE([OPEN_BSD], [1], [OpenBSD])
1045     AC_DEFINE([KAME], [1], [KAME IPv6])
1046     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1047
1048     if test "x${enable_pimd}" != "xno"; then
1049       case "$host_os" in
1050       openbsd6.0)
1051         ;;
1052       openbsd[6-9]*)
1053         AC_MSG_FAILURE([pimd cannot be enabled as PIM support has been removed from OpenBSD 6.1])
1054         ;;
1055       esac
1056     fi
1057     ;;
1058   *)
1059     AC_MSG_RESULT([BSD])
1060
1061     AC_DEFINE([HAVE_NET_RT_IFLIST], [1], [NET_RT_IFLIST])
1062     AC_DEFINE([KAME], [1], [KAME IPv6])
1063     AC_DEFINE([BSD_V6_SYSCTL], [1], [BSD v6 sysctl to turn on and off forwarding])
1064     ;;
1065 esac
1066 AM_CONDITIONAL([SOLARIS], [test "${SOLARIS}" = "solaris"])
1067
1068 AC_SYS_LARGEFILE
1069
1070 dnl ------------------------
1071 dnl Integrated REALMS option
1072 dnl ------------------------
1073 if test "${enable_realms}" = "yes"; then
1074     case "$host_os" in
1075       linux*)
1076        AC_DEFINE([SUPPORT_REALMS], [1], [Realms support])
1077        ;;
1078       *)
1079        echo "Sorry, only Linux has REALMS support"
1080        exit 1
1081        ;;
1082     esac
1083 fi
1084 AM_CONDITIONAL([SUPPORT_REALMS], [test "${enable_realms}" = "yes"])
1085
1086 dnl ---------------------
1087 dnl Integrated VTY option
1088 dnl ---------------------
1089 case "${enable_vtysh}" in
1090 "no")
1091   VTYSH="";;
1092 *)
1093   VTYSH="vtysh";
1094   AC_DEFINE([VTYSH], [1], [VTY shell])
1095
1096   prev_libs="$LIBS"
1097   AC_CHECK_LIB([readline], [main], [
1098     LIBREADLINE="-lreadline"
1099   ], [
1100     dnl readline failed - it might be incorrectly linked and missing its
1101     dnl termcap/tinfo/curses dependency.  see if we can fix that...
1102     AC_SEARCH_LIBS([tputs], [termcap tinfo curses ncurses], [
1103       LIBREADLINE="$ac_cv_search_tputs"
1104     ], [
1105       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1106     ])
1107
1108     dnl re-try with the lib we found above
1109     unset ac_cv_lib_readline_main
1110     AC_CHECK_LIB([readline], [main], [
1111       LIBREADLINE="-lreadline $LIBREADLINE"
1112     ], [
1113       AC_MSG_ERROR([libreadline (needed for vtysh) not found and/or missing dependencies])
1114     ], [$LIBREADLINE])
1115   ], [])
1116   LIBS="$prev_libs"
1117
1118   AC_CHECK_HEADER([readline/history.h])
1119   if test $ac_cv_header_readline_history_h = no;then
1120     AC_MSG_ERROR([readline is too old to have readline/history.h, please update to the latest readline library.])
1121   fi
1122   AC_CHECK_LIB([readline], [rl_completion_matches], [true], [], [$LIBREADLINE])
1123   if test $ac_cv_lib_readline_rl_completion_matches = no; then
1124     AC_DEFINE([rl_completion_matches], [completion_matches], [Old readline])
1125   fi
1126   AC_CHECK_LIB([readline], [append_history], [frr_cv_append_history=yes], [frr_cv_append_history=no], [$LIBREADLINE])
1127   if test "$frr_cv_append_history" = yes; then
1128     AC_DEFINE([HAVE_APPEND_HISTORY], [1], [Have history.h append_history])
1129   fi
1130   ;;
1131 esac
1132 AC_SUBST([LIBREADLINE])
1133 AM_CONDITIONAL([VTYSH], test "x$VTYSH" = "xvtysh")
1134
1135 dnl ----------
1136 dnl PAM module
1137 dnl
1138 dnl FRR detects the PAM library it is built against by checking for a
1139 dnl functional pam_misc.h (Linux-PAM) or openpam.h (OpenPAM) header. pam_misc.h
1140 dnl is known to #include pam_appl.h, the standard header of a PAM library, and
1141 dnl openpam.h doesn't do that, although depends on the header too. Hence a
1142 dnl little assistance to AC_CHECK_HEADER is necessary for the proper detection
1143 dnl of OpenPAM.
1144 dnl ----------
1145 if test "$with_libpam" = "yes"; then
1146   AC_CHECK_HEADER([security/pam_misc.h],
1147     [AC_DEFINE([HAVE_PAM_MISC_H], [1], [Have pam_misc.h])
1148      AC_DEFINE([PAM_CONV_FUNC], [misc_conv], [Have misc_conv])
1149      pam_conv_func="misc_conv"
1150     ],
1151     [], FRR_INCLUDES)
1152   AC_CHECK_HEADER([security/openpam.h],
1153     [AC_DEFINE([HAVE_OPENPAM_H], [1], [Have openpam.h])
1154      AC_DEFINE([PAM_CONV_FUNC], [openpam_ttyconv], [Have openpam_ttyconv])
1155      pam_conv_func="openpam_ttyconv"
1156     ],
1157     [], FRR_INCLUDES[#include <security/pam_appl.h>])
1158   if test -z "$ac_cv_header_security_pam_misc_h$ac_cv_header_security_openpam_h" ; then
1159     AC_MSG_WARN([*** pam support will not be built ***])
1160     with_libpam="no"
1161   fi
1162 fi
1163
1164 if test "$with_libpam" = "yes"; then
1165 dnl took this test from proftpds configure.in and suited to our needs
1166 dnl -------------------------------------------------------------------------
1167 dnl
1168 dnl This next check looks funky due to a linker problem with some versions
1169 dnl of the PAM library.  Prior to 0.72 release, the Linux PAM shared library
1170 dnl omitted requiring libdl linking information. PAM-0.72 or better ships
1171 dnl with RedHat 6.2 and Debian 2.2 or better.
1172 AC_CHECK_LIB([pam], [pam_start],
1173   [AC_CHECK_LIB([pam], [$pam_conv_func],
1174     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1175      LIBPAM="-lpam"],
1176     [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1177      LIBPAM="-lpam -lpam_misc"]
1178     )
1179   ],
1180
1181   [AC_CHECK_LIB([pam], [pam_end],
1182     [AC_CHECK_LIB([pam], [$pam_conv_func],
1183       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1184        LIBPAM="-lpam -ldl"],
1185       [AC_DEFINE([USE_PAM], [1], [Use PAM for authentication])
1186        LIBPAM="-lpam -ldl -lpam_misc"]
1187      )
1188   ],AC_MSG_WARN([*** pam support will not be built ***]),
1189   [-ldl])
1190   ]
1191 )
1192 fi
1193 AC_SUBST([LIBPAM])
1194
1195 dnl -------------------------------
1196 dnl Endian-ness check
1197 dnl -------------------------------
1198 AC_WORDS_BIGENDIAN
1199
1200 dnl -------------------------------
1201 dnl check the size in byte of the C
1202 dnl -------------------------------
1203 dnl AC_CHECK_SIZEOF(char)
1204 dnl AC_CHECK_SIZEOF(int)
1205 dnl AC_CHECK_SIZEOF(short)
1206 dnl AC_CHECK_SIZEOF(long)
1207
1208 dnl ----------------------------
1209 dnl check existance of functions
1210 dnl ----------------------------
1211 AC_FUNC_FNMATCH
1212 AC_FUNC_FORK
1213 AC_FUNC_MKTIME
1214 AC_FUNC_STAT
1215
1216 dnl -------------------------------
1217 dnl bgpd needs pow() and hence libm
1218 dnl -------------------------------
1219 TMPLIBS="$LIBS"
1220 AC_CHECK_HEADER([math.h],
1221   [AC_CHECK_LIB([m], [pow],
1222     [LIBM="-lm"
1223      LIBS="$LIBS $LIBM"
1224      AC_CHECK_FUNCS(pow,[],[LIBM=""])
1225     ])
1226 ])
1227 if test x"$LIBM" = x ; then
1228   AC_MSG_WARN([Unable to find working pow function - bgpd may not link])
1229 fi
1230 LIBS="$TMPLIBS"
1231
1232 AC_SUBST([LIBM])
1233
1234 AC_CHECK_FUNCS([ppoll], [
1235   AC_DEFINE([HAVE_PPOLL], [1], [have Linux/BSD ppoll()])
1236 ])
1237 AC_CHECK_FUNCS([pollts], [
1238   AC_DEFINE([HAVE_POLLTS], [1], [have NetBSD pollts()])
1239 ])
1240
1241 dnl ---------------
1242 dnl other functions
1243 dnl ---------------
1244 AC_CHECK_FUNCS([ \
1245         strlcat strlcpy \
1246         getgrouplist])
1247
1248 AC_CHECK_HEADER([asm-generic/unistd.h],
1249                 [AC_CHECK_DECL(__NR_setns,
1250                                AC_DEFINE([HAVE_NETNS], [1], [Have netns]),,
1251                                FRR_INCLUDES [#include <asm-generic/unistd.h>
1252                                ])
1253                  AC_CHECK_FUNCS([setns])]
1254                )
1255
1256 dnl --------------------------
1257 dnl Determine IS-IS I/O method
1258 dnl --------------------------
1259 AC_DEFINE([ISIS_METHOD_PFPACKET], [1], [constant value for isis method pfpacket])
1260 AC_DEFINE([ISIS_METHOD_DLPI], [2], [constant value for isis method dlpi])
1261 AC_DEFINE([ISIS_METHOD_BPF], [3], [constant value for isis method bpf])
1262 AC_CHECK_HEADER([net/bpf.h])
1263 AC_CHECK_HEADER([sys/dlpi.h])
1264 AC_MSG_CHECKING([zebra IS-IS I/O method])
1265
1266 case "$host_os" in
1267   linux*)
1268     AC_MSG_RESULT([pfpacket])
1269     ISIS_METHOD_MACRO="ISIS_METHOD_PFPACKET"
1270     ;;
1271   solaris* | sunos*)
1272     AC_MSG_RESULT([DLPI])
1273     ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1274     ;;
1275   *)
1276     if test $ac_cv_header_net_bpf_h = no; then
1277       if test $ac_cv_header_sys_dlpi_h = no; then
1278         AC_MSG_RESULT([none])
1279         if test "${enable_isisd}" = yes -o "${enable_fabricd}" = yes; then
1280           AC_MSG_FAILURE([IS-IS support requested but no packet backend found])
1281         fi
1282         AC_MSG_WARN([*** IS-IS support will not be built ***])
1283         enable_isisd="no"
1284         enable_fabricd="no"
1285       else
1286         AC_MSG_RESULT([DLPI])
1287       fi
1288       ISIS_METHOD_MACRO="ISIS_METHOD_DLPI"
1289     else
1290       AC_MSG_RESULT([BPF])
1291       ISIS_METHOD_MACRO="ISIS_METHOD_BPF"
1292     fi
1293     ;;
1294 esac
1295 AC_DEFINE_UNQUOTED([ISIS_METHOD], [$ISIS_METHOD_MACRO], [selected method for isis, == one of the constants])
1296
1297 dnl ---------------------------------------------------------------
1298 dnl figure out how to specify an interface in multicast sockets API
1299 dnl ---------------------------------------------------------------
1300 AC_CHECK_MEMBERS([struct ip_mreqn.imr_ifindex], [], [], FRR_INCLUDES)
1301
1302 AC_CHECK_HEADERS([linux/mroute.h], [], [],[
1303         #include <sys/socket.h>
1304         #include <netinet/in.h>
1305         #define _LINUX_IN_H             /* For Linux <= 2.6.25 */
1306         #include <linux/types.h>
1307 ])
1308
1309 m4_define([FRR_INCLUDES],
1310 FRR_INCLUDES
1311 [#if HAVE_LINUX_MROUTE_H
1312 # include <linux/mroute.h>
1313 #endif
1314 ])dnl
1315
1316 AC_CHECK_HEADERS([netinet/ip_mroute.h], [], [],[
1317         #include <sys/socket.h>
1318         #include <sys/types.h>
1319         #include <netinet/in.h>
1320         #include <net/route.h>
1321 ])
1322
1323 m4_define([FRR_INCLUDES],
1324 FRR_INCLUDES
1325 [#if HAVE_NETINET_IP_MROUTE_H
1326 # include <netinet/ip_mroute.h>
1327 #endif
1328 ])dnl
1329
1330 AC_MSG_CHECKING([for BSD struct ip_mreq hack])
1331 AC_TRY_COMPILE([#include <sys/param.h>],
1332 [#if (defined(__FreeBSD__) && ((__FreeBSD_version >= 500022 && __FreeBSD_version < 700000) || (__FreeBSD_version < 500000 && __FreeBSD_version >= 440000))) || (defined(__NetBSD__) && defined(__NetBSD_Version__) && __NetBSD_Version__ >= 106010000) || defined(__OpenBSD__) || defined(__APPLE__) || defined(__DragonFly__) || defined(__sun)
1333   return (0);
1334 #else
1335   #error No support for BSD struct ip_mreq hack detected
1336 #endif],[AC_MSG_RESULT([yes])
1337 AC_DEFINE([HAVE_BSD_STRUCT_IP_MREQ_HACK], [1], [Can pass ifindex in struct ip_mreq])],
1338 AC_MSG_RESULT([no]))
1339
1340 AC_MSG_CHECKING([for RFC3678 protocol-independed API])
1341 AC_TRY_COMPILE([
1342 #include <sys/types.h>
1343 #include <netinet/in.h>
1344 ], [struct group_req gr; int sock; setsockopt(sock, IPPROTO_IP, MCAST_JOIN_GROUP, (void*)&gr, sizeof(gr));
1345 ], [AC_MSG_RESULT([yes])
1346 AC_DEFINE([HAVE_RFC3678], [1], [Have RFC3678 protocol-independed API])],
1347 AC_MSG_RESULT([no]))
1348
1349 dnl ---------------------------------------------------------------
1350 dnl figure out how to check link-state
1351 dnl ---------------------------------------------------------------
1352 AC_CHECK_HEADER([net/if_media.h],
1353   [m4_define([LINK_DETECT_INCLUDES],
1354     FRR_INCLUDES
1355     [#include <net/if_media.h>
1356   ])
1357   AC_CHECK_MEMBERS([struct ifmediareq.ifm_status],
1358     AC_DEFINE([HAVE_BSD_LINK_DETECT], [1], [BSD link-detect]),
1359     [], LINK_DETECT_INCLUDES)],
1360   [],
1361   FRR_INCLUDES)
1362
1363 dnl ---------------------------------------------------------------
1364 dnl Additional, newer way to check link-state using ifi_link_state.
1365 dnl Not available in all BSD's when ifmediareq available
1366 dnl ---------------------------------------------------------------
1367 AC_CHECK_MEMBERS([struct if_data.ifi_link_state],
1368   AC_DEFINE([HAVE_BSD_IFI_LINK_STATE], [1], [BSD ifi_link_state available]),
1369   [], FRR_INCLUDES)
1370
1371 dnl ------------------------
1372 dnl TCP_MD5SIG socket option
1373 dnl ------------------------
1374
1375 AC_CHECK_HEADER([netinet/tcp.h],
1376    [m4_define([MD5_INCLUDES],
1377       FRR_INCLUDES
1378       [#include <netinet/tcp.h>
1379     ])
1380     AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)],
1381    [],
1382    FRR_INCLUDES)
1383 if test $ac_cv_have_decl_TCP_MD5SIG = no; then
1384   AC_CHECK_HEADER([linux/tcp.h],
1385        [m4_define([MD5_INCLUDES],
1386           FRR_INCLUDES
1387           [#include <linux/tcp.h>
1388         ])
1389        AC_CHECK_DECLS([TCP_MD5SIG], [], [], MD5_INCLUDES)])
1390 fi
1391
1392 dnl ----------------------------------------------------------------------------
1393 dnl figure out if domainname is available in the utsname struct (GNU extension).
1394 dnl ----------------------------------------------------------------------------
1395 AC_CHECK_MEMBERS([struct utsname.domainname], [], [], [#include <sys/utsname.h>])
1396
1397 dnl ------------------
1398 dnl IPv6 header checks
1399 dnl ------------------
1400 AC_CHECK_HEADERS([netinet6/in6.h netinet/in6_var.h \
1401         netinet6/in6_var.h netinet6/nd6.h], [], [],
1402         FRR_INCLUDES)
1403
1404 m4_define([FRR_INCLUDES],dnl
1405 FRR_INCLUDES
1406 [#if HAVE_NETINET6_IN6_H
1407 #include <netinet6/in6.h>
1408 #endif
1409 #if HAVE_NETINET_IN6_VAR_H
1410 #include <netinet/in6_var.h>
1411 #endif
1412 #include <netinet/icmp6.h>
1413 #if HAVE_NETINET6_IN6_VAR_H
1414 # include <netinet6/in6_var.h>
1415 #endif
1416 #if HAVE_NETINET6_ND6_H
1417 # include <netinet6/nd6.h>
1418 #endif
1419 ])dnl
1420
1421 dnl disable doc check
1422 AC_CHECK_PROGS([SPHINXBUILD], [sphinx-build sphinx-build3 sphinx-build2], [/bin/false])
1423 if test "$SPHINXBUILD" = "/bin/false"; then
1424   if test "${enable_doc}" = "yes"; then
1425     AC_MSG_ERROR([Documentation was explicitly requested with --enable-doc but sphinx-build is not available. Please disable docs or install sphinx.])
1426   fi
1427 fi
1428 AM_CONDITIONAL([DOC], [test "${enable_doc}" != "no" -a "$SPHINXBUILD" != "/bin/false"])
1429 AM_CONDITIONAL([DOC_HTML], [test "${enable_doc_html}" = "yes"])
1430
1431 dnl --------------------
1432 dnl Daemon disable check
1433 dnl --------------------
1434 AM_CONDITIONAL([ZEBRA], [test "${enable_zebra}" != "no"])
1435
1436 if test "${enable_bgpd}" = "no";then
1437   BGPD=""
1438 else
1439   BGPD="bgpd"
1440 fi
1441 AM_CONDITIONAL([BGPD], [test "x$BGPD" = "xbgpd"])
1442
1443 AM_CONDITIONAL([RIPD], [test "${enable_ripd}" != "no"])
1444 AM_CONDITIONAL([OSPFD], [test "${enable_ospfd}" != "no"])
1445 AM_CONDITIONAL([LDPD], [test "${enable_ldpd}" != "no"])
1446
1447 AS_IF([test "${enable_ldpd}" != "no"], [
1448   AC_DEFINE([HAVE_LDPD], [1], [ldpd])
1449 ])
1450
1451 if test "$enable_bfdd" = "no"; then
1452   AC_DEFINE([HAVE_BFDD], [0], [bfdd])
1453   BFDD=""
1454 else
1455   AC_DEFINE([HAVE_BFDD], [1], [bfdd])
1456   BFDD="bfdd"
1457
1458   case $host_os in
1459     linux*)
1460       AC_DEFINE([BFD_LINUX], [1], [bfdd])
1461       ;;
1462
1463     *)
1464       AC_DEFINE([BFD_BSD], [1], [bfdd])
1465       ;;
1466   esac
1467 fi
1468
1469 AM_CONDITIONAL([BFDD], [test "x$BFDD" = "xbfdd"])
1470
1471 if test "$ac_cv_lib_json_c_json_object_get" = no -a "x$BFDD" = "xbfdd"; then
1472   AC_MSG_ERROR(["you must use json-c library to use bfdd"])
1473 fi
1474
1475 NHRPD=""
1476 case "$host_os" in
1477   linux*)
1478     if test "${enable_nhrpd}" != "no"; then
1479       NHRPD="nhrpd"
1480     fi
1481     ;;
1482   *)
1483     if test "${enable_nhrpd}" = "yes"; then
1484       AC_MSG_ERROR([nhrpd requires kernel APIs that are only present on Linux.])
1485     fi
1486     ;;
1487 esac
1488 AM_CONDITIONAL([NHRPD], [test "x$NHRPD" = "xnhrpd"])
1489
1490 AM_CONDITIONAL([EIGRPD], [test "${enable_eigrpd}" != "no"])
1491
1492 if test "${enable_watchfrr}" = "no";then
1493   WATCHFRR=""
1494 else
1495   WATCHFRR="watchfrr"
1496 fi
1497 AM_CONDITIONAL([WATCHFRR], [test "x$WATCHFRR" = "xwatchfrr"])
1498
1499 OSPFCLIENT=""
1500 if test "${enable_ospfapi}" != "no";then
1501     AC_DEFINE([SUPPORT_OSPF_API], [1], [OSPFAPI])
1502
1503   if test "${enable_ospfclient}" != "no";then
1504       OSPFCLIENT="ospfclient"
1505   fi
1506 fi
1507
1508 AM_CONDITIONAL([OSPFCLIENT], [test "x$OSPFCLIENT" = "xospfclient"])
1509 AM_CONDITIONAL([RIPNGD], [test "${enable_ripngd}" != "no"])
1510 AM_CONDITIONAL([BABELD], [test "${enable_babeld}" != "no"])
1511 AM_CONDITIONAL([OSPF6D], [test "${enable_ospf6d}" != "no"])
1512 AM_CONDITIONAL([ISISD], [test "${enable_isisd}" != "no"])
1513 AM_CONDITIONAL([PIMD], [test "${enable_pimd}" != "no"])
1514 AM_CONDITIONAL([PBRD], [test "${enable_pbrd}" != "no"])
1515 AM_CONDITIONAL([SHARPD], [test "${enable_sharpd}" = "yes"])
1516 AM_CONDITIONAL([STATICD], [test "${enable_staticd}" != "no"])
1517 AM_CONDITIONAL([FABRICD], [test "${enable_fabricd}" != "no"])
1518
1519 if test "${enable_bgp_announce}" = "no";then
1520   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [1], [Disable BGP installation to zebra])
1521 else
1522   AC_DEFINE([DISABLE_BGP_ANNOUNCE], [0], [Disable BGP installation to zebra])
1523 fi
1524
1525 if test "${enable_bgp_vnc}" != "no";then
1526   AC_DEFINE([ENABLE_BGP_VNC], [1], [Enable BGP VNC support])
1527 fi
1528 AM_CONDITIONAL([ENABLE_BGP_VNC], [test x${enable_bgp_vnc} != xno])
1529
1530 AC_SUBST([SOLARIS])
1531 AC_CHECK_LIB([crypt], [crypt], [],
1532                     [AC_CHECK_LIB([crypto], [DES_crypt])])
1533 AC_CHECK_LIB([resolv], [res_init])
1534
1535 dnl ---------------------------
1536 dnl check system has PCRE regexp
1537 dnl ---------------------------
1538 if test "x$enable_pcreposix" = "xyes"; then
1539   AC_CHECK_LIB([pcreposix], [regexec], [], [
1540     AC_MSG_ERROR([--enable-pcreposix given but unable to find libpcreposix])
1541   ])
1542 fi
1543 AC_SUBST([HAVE_LIBPCREPOSIX])
1544
1545 dnl ------------------
1546 dnl check C-Ares library
1547 dnl ------------------
1548 if test "${NHRPD}" != ""; then
1549   PKG_CHECK_MODULES([CARES], [libcares], ,[
1550     AC_MSG_ERROR([trying to build nhrpd, but libcares not found. install c-ares and its -dev headers.])
1551   ])
1552 fi
1553
1554
1555 dnl ------------------
1556 dnl check Net-SNMP library
1557 dnl ------------------
1558 if test "${enable_snmp}" != "" -a "${enable_snmp}" != "no"; then
1559    AC_PATH_TOOL([NETSNMP_CONFIG], [net-snmp-config], [no])
1560    if test x"$NETSNMP_CONFIG" = x"no"; then
1561       AC_MSG_ERROR([--enable-snmp given but unable to find net-snmp-config])
1562    fi
1563    SNMP_LIBS="`${NETSNMP_CONFIG} --agent-libs`"
1564    SNMP_CFLAGS="`${NETSNMP_CONFIG} --base-cflags`"
1565    # net-snmp lists all of its own dependencies.  we absolutely do not want that
1566    # among other things we avoid a GPL vs. OpenSSL license conflict here
1567    for removelib in crypto ssl sensors pci wrap; do
1568      SNMP_LIBS="`echo $SNMP_LIBS | sed -e 's/\(^\|\s\)-l'$removelib'\b/ /g' -e 's/\(^\|\s\)\([^\s]*\/\)\?lib'$removelib'\.[^\s]\+\b/ /g'`"
1569    done
1570    AC_MSG_CHECKING([whether we can link to Net-SNMP])
1571    AC_LINK_IFELSE_FLAGS([$SNMP_CFLAGS], [$SNMP_LIBS], [AC_LANG_PROGRAM([
1572 int main(void);
1573 ],
1574 [
1575 {
1576   return 0;
1577 }
1578 ])], [
1579      AC_MSG_ERROR([--enable-snmp given but not usable])])
1580    case "${enable_snmp}" in
1581      yes)
1582       SNMP_METHOD=agentx
1583       ;;
1584      agentx)
1585       SNMP_METHOD="${enable_snmp}"
1586       ;;
1587      *)
1588       AC_MSG_ERROR([--enable-snmp given with an unknown method (${enable_snmp}). Use yes or agentx])
1589       ;;
1590    esac
1591    AH_TEMPLATE([SNMP_AGENTX], [Use SNMP AgentX to interface with snmpd])
1592    AC_DEFINE_UNQUOTED(AS_TR_CPP(SNMP_${SNMP_METHOD}),,[SNMP method to interface with snmpd])
1593 fi
1594 AM_CONDITIONAL([SNMP], [test "x${SNMP_METHOD}" != "x"])
1595 AC_SUBST([SNMP_LIBS])
1596 AC_SUBST([SNMP_CFLAGS])
1597
1598 dnl ---------------
1599 dnl libyang
1600 dnl ---------------
1601 PKG_CHECK_MODULES([libyang], [libyang >= 0.16.7], , [
1602   AC_MSG_ERROR([libyang (>= 0.16.7) was not found on your system.])
1603 ])
1604 AC_CHECK_MEMBER([struct lyd_node.priv], [], [
1605   AC_MSG_ERROR([m4_normalize([
1606     libyang needs to be compiled with ENABLE_LYD_PRIV=ON.
1607     See http://docs.frrouting.org/projects/dev-guide/en/latest/building-libyang.html for details.])
1608   ])
1609 ], [[#include <libyang/libyang.h>]])
1610
1611 dnl ---------------
1612 dnl configuration rollbacks
1613 dnl ---------------
1614 SQLITE3=false
1615 if test "$enable_config_rollbacks" = "yes"; then
1616   PKG_CHECK_MODULES([sqlite3], [sqlite3], [
1617     AC_DEFINE([HAVE_CONFIG_ROLLBACKS], [1], [Enable configuration rollbacks])
1618     AC_DEFINE([HAVE_SQLITE3], [1], [Enable sqlite3 database])
1619     SQLITE3=true
1620   ], [
1621     AC_MSG_ERROR([--enable-config-rollbacks given but sqlite3 was not found on your system.])
1622   ])
1623 fi
1624 AM_CONDITIONAL([SQLITE3], [$SQLITE3])
1625
1626 dnl ---------------
1627 dnl confd
1628 dnl ---------------
1629 if test "$enable_confd" != "" -a "$enable_confd" != "no"; then
1630    AC_CHECK_PROG([CONFD], [confd], [confd], [/bin/false], "${enable_confd}/bin")
1631    if test "x$CONFD" = "x/bin/false"; then
1632       AC_MSG_ERROR([confd was not found on your system.])]
1633    fi
1634    CONFD_CFLAGS="-I${enable_confd}/include -L${enable_confd}/lib"
1635    AC_SUBST([CONFD_CFLAGS])
1636    AC_DEFINE([HAVE_CONFD], [1], [Enable confd integration])
1637 fi
1638 AM_CONDITIONAL([CONFD], [test "x$enable_confd" != "x"])
1639
1640 dnl ---------------
1641 dnl sysrepo
1642 dnl ---------------
1643 if test "$enable_sysrepo" = "yes"; then
1644   PKG_CHECK_MODULES([sysrepo], [libsysrepo],
1645       [AC_DEFINE([HAVE_SYSREPO], [1], [Enable sysrepo integration])
1646       SYSREPO=true],
1647       [SYSREPO=false
1648       AC_MSG_ERROR([sysrepo was not found on your system.])]
1649   )
1650 fi
1651 AM_CONDITIONAL([SYSREPO], [test "x$enable_sysrepo" = "xyes"])
1652
1653 dnl ---------------
1654 dnl math
1655 dnl ---------------
1656 AC_SEARCH_LIBS([sqrt], [m])
1657
1658 dnl ---------------
1659 dnl dlopen & dlinfo
1660 dnl ---------------
1661 AC_SEARCH_LIBS([dlopen], [dl dld], [], [
1662   AC_MSG_ERROR([unable to find the dlopen()])
1663 ])
1664
1665 AC_CHECK_HEADERS([link.h])
1666
1667 AC_CACHE_CHECK([for dlinfo(RTLD_DI_ORIGIN)], [frr_cv_rtld_di_origin], [
1668   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1669 #include <stdlib.h>
1670 #ifdef HAVE_LINK_H
1671 #include <link.h>
1672 #endif
1673 #include <dlfcn.h>
1674 ]], [[
1675   char origin[1];
1676   dlinfo (NULL, RTLD_DI_ORIGIN, &origin);
1677 ]])], [
1678     frr_cv_rtld_di_origin=yes
1679   ], [
1680     frr_cv_rtld_di_origin=no
1681   ])
1682 ])
1683 if test "$frr_cv_rtld_di_origin" = yes; then
1684   AC_DEFINE([HAVE_DLINFO_ORIGIN], [1], [Have dlinfo RTLD_DI_ORIGIN])
1685 fi
1686
1687 AC_CACHE_CHECK([for dlinfo(RTLD_DI_LINKMAP)], [frr_cv_rtld_di_linkmap], [
1688   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
1689 #include <stdlib.h>
1690 #ifdef HAVE_LINK_H
1691 #include <link.h>
1692 #endif
1693 #include <dlfcn.h>
1694 ]], [[
1695   struct link_map *lm = NULL;
1696   dlinfo (NULL, RTLD_DI_LINKMAP, &lm);
1697 ]])], [
1698     frr_cv_rtld_di_linkmap=yes
1699   ], [
1700     frr_cv_rtld_di_linkmap=no
1701   ])
1702 ])
1703 if test "$frr_cv_rtld_di_linkmap" = yes; then
1704   AC_DEFINE([HAVE_DLINFO_LINKMAP], [1], [Have dlinfo RTLD_DI_LINKMAP])
1705 fi
1706
1707 AM_CONDITIONAL([SNMP], [test "x$SNMP_METHOD" = "xagentx"])
1708
1709 dnl ---------------------------
1710 dnl sockaddr and netinet checks
1711 dnl ---------------------------
1712 AC_CHECK_TYPES([
1713         struct sockaddr_dl,
1714         struct vifctl, struct mfcctl, struct sioc_sg_req,
1715         vifi_t, struct sioc_vif_req, struct igmpmsg,
1716         struct ifaliasreq, struct if6_aliasreq, struct in6_aliasreq,
1717         struct nd_opt_adv_interval, struct rt_addrinfo,
1718         struct nd_opt_homeagent_info, struct nd_opt_adv_interval],
1719         [], [], FRR_INCLUDES)
1720
1721 AC_CHECK_MEMBERS([struct sockaddr.sa_len,
1722         struct sockaddr_in.sin_len, struct sockaddr_un.sun_len,
1723         struct sockaddr_dl.sdl_len,
1724         struct if6_aliasreq.ifra_lifetime,
1725         struct nd_opt_adv_interval.nd_opt_ai_type],
1726         [], [], FRR_INCLUDES)
1727
1728 dnl ---------------------------
1729 dnl IRDP/pktinfo/icmphdr checks
1730 dnl ---------------------------
1731
1732 AC_CHECK_TYPES([struct in_pktinfo], [
1733   AC_CHECK_TYPES([struct icmphdr], [
1734     IRDP=true
1735   ], [
1736     IRDP=false
1737   ], [FRR_INCLUDES])
1738 ], [
1739   IRDP=false
1740 ], [FRR_INCLUDES])
1741
1742 case "${enable_irdp}" in
1743 yes)
1744   $IRDP || AC_MSG_ERROR(['IRDP requires in_pktinfo at the moment!'])
1745   ;;
1746 no)
1747   IRDP=false
1748   ;;
1749 esac
1750
1751 AM_CONDITIONAL([IRDP], [$IRDP])
1752
1753 dnl -----------------------
1754 dnl checking for IP_PKTINFO
1755 dnl -----------------------
1756 AC_MSG_CHECKING([for IP_PKTINFO])
1757 AC_TRY_COMPILE([#include <netdb.h>], [
1758   int opt = IP_PKTINFO;
1759 ], [
1760   AC_MSG_RESULT([yes])
1761   AC_DEFINE([HAVE_IP_PKTINFO], [1], [Have IP_PKTINFO])
1762 ], [
1763   AC_MSG_RESULT([no])
1764 ])
1765
1766 dnl ---------------------------
1767 dnl checking for IP_RECVDSTADDR
1768 dnl ---------------------------
1769 AC_MSG_CHECKING([for IP_RECVDSTADDR])
1770 AC_TRY_COMPILE([#include <netinet/in.h>], [
1771   int opt = IP_RECVDSTADDR;
1772 ], [
1773   AC_MSG_RESULT([yes])
1774   AC_DEFINE([HAVE_IP_RECVDSTADDR], [1], [Have IP_RECVDSTADDR])
1775 ], [
1776   AC_MSG_RESULT([no])
1777 ])
1778
1779 dnl ----------------------
1780 dnl checking for IP_RECVIF
1781 dnl ----------------------
1782 AC_MSG_CHECKING([for IP_RECVIF])
1783 AC_TRY_COMPILE([#include <netinet/in.h>], [
1784   int opt = IP_RECVIF;
1785 ], [
1786   AC_MSG_RESULT([yes])
1787   AC_DEFINE([HAVE_IP_RECVIF], [1], [Have IP_RECVIF])
1788 ], [
1789   AC_MSG_RESULT([no])
1790 ])
1791
1792 dnl ----------------------
1793 dnl checking for SO_BINDANY
1794 dnl ----------------------
1795 AC_MSG_CHECKING([for SO_BINDANY])
1796 AC_TRY_COMPILE([#include <sys/socket.h>], [
1797   int opt = SO_BINDANY;
1798 ], [
1799   AC_MSG_RESULT([yes])
1800   AC_DEFINE([HAVE_SO_BINDANY], [1], [Have SO_BINDANY])
1801 ], [
1802   AC_MSG_RESULT([no])
1803 ])
1804
1805 dnl ----------------------
1806 dnl checking for IP_FREEBIND
1807 dnl ----------------------
1808 AC_MSG_CHECKING([for IP_FREEBIND])
1809 AC_TRY_COMPILE([#include <netinet/in.h>], [
1810   int opt = IP_FREEBIND;
1811 ], [
1812   AC_MSG_RESULT([yes])
1813   AC_DEFINE([HAVE_IP_FREEBIND], [1], [Have IP_FREEBIND])
1814 ], [
1815   AC_MSG_RESULT([no])
1816 ])
1817
1818 dnl --------------------------------------
1819 dnl checking for be32dec existence or not
1820 dnl --------------------------------------
1821 AC_CHECK_DECLS([be32enc, be32dec], [], [],
1822                [#include <sys/endian.h>])
1823
1824 dnl --------------------------------------
1825 dnl checking for clock_time monotonic struct and call
1826 dnl --------------------------------------
1827 AC_CHECK_DECL([CLOCK_MONOTONIC],
1828         [AC_CHECK_LIB([rt], [clock_gettime], [LIBS="$LIBS -lrt"])
1829          AC_DEFINE([HAVE_CLOCK_MONOTONIC], [1], [Have monotonic clock])
1830 ], [AC_MSG_RESULT([no])], [FRR_INCLUDES])
1831
1832 dnl --------------------------------------
1833 dnl checking for flex and bison
1834 dnl --------------------------------------
1835
1836 AM_PROG_LEX
1837 AC_MSG_CHECKING([version of flex])
1838 frr_ac_flex_version="$(eval $LEX -V | grep flex | head -n 1)"
1839 frr_ac_flex_version="${frr_ac_flex_version##* }"
1840 AC_MSG_RESULT([$frr_ac_flex_version])
1841 AX_COMPARE_VERSION([$frr_ac_flex_version], [lt], [2.5.20], [
1842   LEX="$SHELL $missing_dir/missing flex"
1843   if test -f "${srcdir}/lib/command_lex.c" -a -f "${srcdir}/lib/command_lex.h"; then
1844     AC_MSG_WARN([using pregenerated flex output files])
1845   else
1846     AC_MSG_ERROR([flex failure and pregenerated files not included (probably a git build)])
1847   fi
1848   AC_SUBST([LEX_OUTPUT_ROOT], [lex.yy])
1849   AC_SUBST([LEXLIB], [''])
1850 ])
1851
1852 AC_PROG_YACC
1853 dnl thanks GNU bison for this b*llshit...
1854 AC_MSG_CHECKING([version of bison])
1855 frr_ac_bison_version="$(eval $YACC -V | grep bison | head -n 1)"
1856 frr_ac_bison_version="${frr_ac_bison_version##* }"
1857 frr_ac_bison_missing="false"
1858 case "x${frr_ac_bison_version}" in
1859   x2.7*)
1860     BISON_OPENBRACE='"'
1861     BISON_CLOSEBRACE='"'
1862     BISON_VERBOSE=''
1863     AC_MSG_RESULT([$frr_ac_bison_version - 2.7 or older])
1864     ;;
1865   x2.*|x1.*)
1866     AC_MSG_RESULT([$frr_ac_bison_version])
1867     AC_MSG_WARN([installed bison is too old.  Please install GNU bison 2.7.x or newer.])
1868     frr_ac_bison_missing="true"
1869     ;;
1870   x)
1871     AC_MSG_RESULT([none])
1872     AC_MSG_WARN([could not determine bison version.  Please install GNU bison 2.7.x or newer.])
1873     frr_ac_bison_missing="true"
1874     ;;
1875   *)
1876     BISON_OPENBRACE='{'
1877     BISON_CLOSEBRACE='}'
1878     BISON_VERBOSE='-Dparse.error=verbose'
1879     AC_MSG_RESULT([$frr_ac_bison_version - 3.0 or newer])
1880     ;;
1881 esac
1882 AC_SUBST([BISON_OPENBRACE])
1883 AC_SUBST([BISON_CLOSEBRACE])
1884 AC_SUBST([BISON_VERBOSE])
1885
1886 if $frr_ac_bison_missing; then
1887   YACC="$SHELL $missing_dir/missing bison -y"
1888   if test -f "${srcdir}/lib/command_parse.c" -a -f "${srcdir}/lib/command_parse.h"; then
1889     AC_MSG_WARN([using pregenerated bison output files])
1890   else
1891     AC_MSG_ERROR([bison failure and pregenerated files not included (probably a git build)])
1892   fi
1893 fi
1894
1895 dnl -------------------
1896 dnl capabilities checks
1897 dnl -------------------
1898 if test "${enable_capabilities}" != "no"; then
1899   AC_MSG_CHECKING([whether prctl PR_SET_KEEPCAPS is available])
1900   AC_TRY_COMPILE([#include <sys/prctl.h>], [prctl(PR_SET_KEEPCAPS, 1, 0, 0, 0);],
1901     [AC_MSG_RESULT([yes])
1902      AC_DEFINE([HAVE_PR_SET_KEEPCAPS], [1], [prctl])
1903      frr_ac_keepcaps="yes"],
1904      AC_MSG_RESULT([no])
1905   )
1906   if test x"${frr_ac_keepcaps}" = x"yes"; then
1907     AC_CHECK_HEADERS([sys/capability.h])
1908   fi
1909   if test x"${ac_cv_header_sys_capability_h}" = x"yes"; then
1910     AC_CHECK_LIB([cap], [cap_init],
1911       [AC_DEFINE([HAVE_LCAPS], [1], [Capabilities])
1912        LIBCAP="-lcap"
1913        frr_ac_lcaps="yes"]
1914     )
1915   else
1916     AC_CHECK_HEADERS([priv.h],
1917      [AC_MSG_CHECKING([Solaris style privileges are available])
1918       AC_TRY_COMPILE([#include <priv.h>], [getpflags(PRIV_AWARE);],
1919           [AC_MSG_RESULT([yes])
1920            AC_DEFINE([HAVE_SOLARIS_CAPABILITIES], [1], [getpflags])
1921            frr_ac_scaps="yes"],
1922            AC_MSG_RESULT(no)
1923       )
1924      ]
1925    )
1926   fi
1927   if test x"${frr_ac_scaps}" = x"yes" \
1928        -o x"${frr_ac_lcaps}" = x"yes"; then
1929     AC_DEFINE([HAVE_CAPABILITIES], [1], [capabilities])
1930   fi
1931 fi
1932 AC_SUBST([LIBCAP])
1933
1934 dnl ---------------------------
1935 dnl check for glibc 'backtrace'
1936 dnl ---------------------------
1937 if test x"${enable_backtrace}" != x"no" ; then
1938   backtrace_ok=no
1939   PKG_CHECK_MODULES([UNWIND], [libunwind], [
1940     AC_DEFINE([HAVE_LIBUNWIND], [1], [libunwind])
1941     backtrace_ok=yes
1942   ], [
1943     case "$host_os" in
1944     sunos* | solaris2*)
1945       AC_CHECK_FUNCS([printstack], [
1946         AC_DEFINE([HAVE_PRINTSTACK], [1], [Solaris printstack])
1947         backtrace_ok=yes
1948       ])
1949       ;;
1950     esac
1951     if test "$backtrace_ok" = no; then
1952       AC_CHECK_HEADER([execinfo.h], [
1953         AC_SEARCH_LIBS([backtrace], [execinfo], [
1954           AC_DEFINE([HAVE_GLIBC_BACKTRACE], [1], [Glibc backtrace])
1955           backtrace_ok=yes
1956         ],, [-lm])
1957       ])
1958     fi
1959   ])
1960
1961   if test x"${enable_backtrace}" = x"yes" -a x"${backtrace_ok}" = x"no"; then
1962     dnl user explicitly requested backtrace but we failed to find support
1963     AC_MSG_FAILURE([failed to find backtrace or libunwind support])
1964   fi
1965 fi
1966
1967 dnl -----------------------------------------
1968 dnl check for malloc mallinfo struct and call
1969 dnl this must try and link using LIBS, in
1970 dnl order to check no alternative allocator
1971 dnl has been specified, which might not provide
1972 dnl mallinfo, e.g. such as Umem on Solaris.
1973 dnl -----------------------------------------
1974 AC_CHECK_HEADERS([malloc.h malloc_np.h malloc/malloc.h],,, [FRR_INCLUDES])
1975
1976 AC_CACHE_CHECK([whether mallinfo is available], [frr_cv_mallinfo], [
1977   AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
1978 #ifdef HAVE_MALLOC_H
1979 #include <malloc.h>
1980 #endif
1981 #ifdef HAVE_MALLOC_NP_H
1982 #include <malloc_np.h>
1983 #endif
1984 #ifdef HAVE_MALLOC_MALLOC_H
1985 #include <malloc/malloc.h>
1986 #endif
1987 ]], [[
1988 struct mallinfo ac_x; ac_x = mallinfo ();
1989 ]])], [
1990     frr_cv_mallinfo=yes
1991   ], [
1992     frr_cv_mallinfo=no
1993   ])
1994 ])
1995 if test "$frr_cv_mallinfo" = yes; then
1996   AC_DEFINE([HAVE_MALLINFO], [1], [mallinfo])
1997 fi
1998
1999 AC_MSG_CHECKING([whether malloc_usable_size is available])
2000 AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES [
2001 #ifdef HAVE_MALLOC_H
2002 #include <malloc.h>
2003 #endif
2004 #ifdef HAVE_MALLOC_MALLOC_H
2005 #include <malloc/malloc.h>
2006 #endif
2007 ]], [[
2008 size_t ac_x; ac_x = malloc_usable_size(NULL);
2009 ]])], [
2010   AC_MSG_RESULT([yes])
2011   AC_DEFINE([HAVE_MALLOC_USABLE_SIZE], [1], [malloc_usable_size])
2012 ], [
2013   AC_MSG_RESULT([no])
2014
2015   AC_MSG_CHECKING([whether malloc_size is available])
2016   AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2017 #ifdef HAVE_MALLOC_H
2018 #include <malloc.h>
2019 #endif
2020 #ifdef HAVE_MALLOC_MALLOC_H
2021 #include <malloc/malloc.h>
2022 #endif
2023 ]], [[
2024 size_t ac_x; ac_x = malloc_size(NULL);
2025 ]])], [
2026     AC_MSG_RESULT([yes])
2027     AC_DEFINE([HAVE_MALLOC_SIZE], [1], [malloc_size])
2028   ], [
2029     AC_MSG_RESULT([no])
2030   ])
2031 ])
2032
2033 dnl ------
2034 dnl ZeroMQ
2035 dnl ------
2036 if test "x$enable_zeromq" != "xno"; then
2037   PKG_CHECK_MODULES([ZEROMQ], [libzmq >= 4.0.0], [
2038     AC_DEFINE([HAVE_ZEROMQ], [1], [Enable ZeroMQ support])
2039     ZEROMQ=true
2040   ], [
2041     if test "x$enable_zeromq" = "xyes"; then
2042       AC_MSG_ERROR([configuration specifies --enable-zeromq but libzmq was not found])
2043     fi
2044   ])
2045 fi
2046 AM_CONDITIONAL([ZEROMQ], [test "x$ZEROMQ" = "xtrue"])
2047
2048 dnl ----------
2049 dnl configure date
2050 dnl ----------
2051 dev_version=`echo $VERSION | grep dev`
2052 #don't expire deprecated code in non 'dev' branch
2053 if test "${dev_version}" = ""; then
2054    CONFDATE=0
2055 else
2056    CONFDATE=`date '+%Y%m%d'`
2057 fi
2058 AC_SUBST([CONFDATE])
2059
2060 dnl ------------------------------
2061 dnl set paths for state directory
2062 dnl ------------------------------
2063 AC_MSG_CHECKING([directory to use for state file])
2064 if test "${prefix}" = "NONE"; then
2065   frr_statedir_prefix="";
2066 else
2067   frr_statedir_prefix=${prefix}
2068 fi
2069 if test "${localstatedir}" = '${prefix}/var'; then
2070   for FRR_STATE_DIR in ${frr_statedir_prefix}/var/run dnl
2071                         ${frr_statedir_prefix}/var/adm dnl
2072                         ${frr_statedir_prefix}/etc dnl
2073                         /var/run        dnl
2074                         /var/adm        dnl
2075                         /etc            dnl
2076                         /dev/null;
2077   do
2078     test -d $FRR_STATE_DIR && break
2079   done
2080   frr_statedir=$FRR_STATE_DIR
2081 else
2082   frr_statedir=${localstatedir}
2083 fi
2084 if test $frr_statedir = "/dev/null"; then
2085     AC_MSG_ERROR([STATE DIRECTORY NOT FOUND! FIX OR SPECIFY --localstatedir!])
2086 fi
2087 AC_MSG_RESULT([${frr_statedir}])
2088 AC_SUBST([frr_statedir])
2089
2090 AC_DEFINE_UNQUOTED([LDPD_SOCKET], ["$frr_statedir/ldpd.sock"], [ldpd control socket])
2091 AC_DEFINE_UNQUOTED([ZEBRA_SERV_PATH], ["$frr_statedir/zserv.api"], [zebra api socket])
2092 AC_DEFINE_UNQUOTED([BFDD_CONTROL_SOCKET], ["$frr_statedir/bfdd.sock"], [bfdd control socket])
2093 AC_DEFINE_UNQUOTED([DAEMON_VTY_DIR], ["$frr_statedir"], [daemon vty directory])
2094 AC_DEFINE_UNQUOTED([DAEMON_DB_DIR], ["$frr_statedir"], [daemon database directory])
2095
2096 dnl autoconf does this, but it does it too late...
2097 test "x$prefix" = xNONE && prefix=$ac_default_prefix
2098 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
2099
2100 dnl get the full path, recursing through variables...
2101 vtysh_bin="$bindir/vtysh"
2102 for I in 1 2 3 4 5 6 7 8 9 10; do
2103         eval vtysh_bin="\"$vtysh_bin\""
2104 done
2105 AC_DEFINE_UNQUOTED([VTYSH_BIN_PATH], ["$vtysh_bin"], [path to vtysh binary])
2106 AC_SUBST([vtysh_bin])
2107
2108 CFG_SYSCONF="$sysconfdir"
2109 CFG_SBIN="$sbindir"
2110 CFG_STATE="$frr_statedir"
2111 CFG_MODULE="$moduledir"
2112 CFG_YANGMODELS="$yangmodelsdir"
2113 CFG_LIBYANG_PLUGINS="$libyang_pluginsdir"
2114 for I in 1 2 3 4 5 6 7 8 9 10; do
2115         eval CFG_SYSCONF="\"$CFG_SYSCONF\""
2116         eval CFG_SBIN="\"$CFG_SBIN\""
2117         eval CFG_STATE="\"$CFG_STATE\""
2118         eval CFG_MODULE="\"$CFG_MODULE\""
2119         eval CFG_YANGMODELS="\"$CFG_YANGMODELS\""
2120         eval CFG_LIBYANG_PLUGINS="\"$CFG_LIBYANG_PLUGINS\""
2121 done
2122 AC_SUBST([CFG_SYSCONF])
2123 AC_SUBST([CFG_SBIN])
2124 AC_SUBST([CFG_STATE])
2125 AC_SUBST([CFG_MODULE])
2126 AC_SUBST([CFG_YANGMODELS])
2127 AC_SUBST([CFG_LIBYANG_PLUGINS])
2128 AC_DEFINE_UNQUOTED([MODULE_PATH], ["$CFG_MODULE"], [path to modules])
2129 AC_DEFINE_UNQUOTED([YANG_MODELS_PATH], ["$CFG_YANGMODELS"], [path to YANG data models])
2130 AC_DEFINE_UNQUOTED([LIBYANG_PLUGINS_PATH], ["$CFG_LIBYANG_PLUGINS"], [path to libyang plugins])
2131
2132 dnl ------------------------------------
2133 dnl Enable RPKI and add librtr to libs
2134 dnl ------------------------------------
2135 if test "${enable_rpki}" = "yes"; then
2136   PKG_CHECK_MODULES([RTRLIB], [rtrlib >= 0.5.0],
2137       [RPKI=true],
2138       [RPKI=false
2139       AC_MSG_ERROR([rtrlib was not found on your system or is too old.])]
2140   )
2141 fi
2142 AM_CONDITIONAL([RPKI], [test "x$RPKI" = "xtrue"])
2143
2144 dnl ------------------------------------------
2145 dnl Check whether rtrlib was build with ssh support
2146 dnl ------------------------------------------
2147 AC_MSG_CHECKING([whether the RTR Library is compiled with SSH])
2148 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "rtrlib/rtrlib.h"]],
2149                         [[struct tr_ssh_config config;]])],
2150         [AC_MSG_RESULT([yes])
2151         AC_DEFINE([FOUND_SSH], [1], [found_ssh])],
2152         AC_MSG_RESULT([no])
2153 )
2154
2155 dnl ---------------------------
2156 dnl Check htonl works correctly
2157 dnl ---------------------------
2158 AC_MSG_CHECKING([for working htonl])
2159 AC_CACHE_VAL(ac_cv_htonl_works,
2160  [AC_LINK_IFELSE([AC_LANG_PROGRAM([FRR_INCLUDES],[htonl (0);])],
2161                 [ac_cv_htonl_works=yes], [ac_cv_htonl_works=no])
2162  ]
2163 )
2164 AC_MSG_RESULT([$ac_cv_htonl_works])
2165
2166 AC_CONFIG_FILES([Makefile],[sed -e 's/^#AUTODERP# //' -i Makefile])
2167
2168 AC_CONFIG_FILES([
2169           config.version
2170           redhat/frr.spec
2171           solaris/Makefile
2172           debianpkg/changelog
2173           alpine/APKBUILD
2174           snapcraft/snapcraft.yaml
2175           lib/version.h
2176           tests/lib/cli/test_cli.refout
2177           pkgsrc/bgpd.sh pkgsrc/ospf6d.sh pkgsrc/ospfd.sh
2178           pkgsrc/ripd.sh pkgsrc/ripngd.sh pkgsrc/zebra.sh
2179           pkgsrc/eigrpd.sh])
2180
2181 AC_CONFIG_FILES([vtysh/extract.pl], [chmod +x vtysh/extract.pl])
2182 AC_CONFIG_FILES([tools/frr], [chmod +x tools/frr])
2183 AC_CONFIG_FILES([tools/watchfrr.sh], [chmod +x tools/watchfrr.sh])
2184 AC_CONFIG_FILES([tools/frrinit.sh], [chmod +x tools/frrinit.sh])
2185 AC_CONFIG_FILES([tools/frrcommon.sh])
2186
2187 AC_CONFIG_COMMANDS([lib/route_types.h], [
2188         dst="${ac_abs_top_builddir}/lib/route_types.h"
2189         ${PERL} "${ac_abs_top_srcdir}/lib/route_types.pl" \
2190                 < "${ac_abs_top_srcdir}/lib/route_types.txt" \
2191                 > "${dst}.tmp"
2192         test -f "${dst}" \
2193                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2194                 && rm "${dst}.tmp" \
2195                 || mv "${dst}.tmp" "${dst}"
2196 ], [
2197         PERL="$PERL"
2198 ])
2199
2200 AS_IF([test "x$with_pkg_git_version" = "xyes"], [
2201     AC_CONFIG_COMMANDS([lib/gitversion.h], [
2202         dst="${ac_abs_top_builddir}/lib/gitversion.h"
2203         ${PERL} "${ac_abs_top_srcdir}/lib/gitversion.pl" \
2204                 "${ac_abs_top_srcdir}" \
2205                 > "${dst}.tmp"
2206         test -f "${dst}" \
2207                 && diff "${dst}.tmp" "${dst}" >/dev/null 2>/dev/null \
2208                 && rm "${dst}.tmp" \
2209                 || mv "${dst}.tmp" "${dst}"
2210     ], [
2211         PERL="$PERL"
2212     ])
2213 ])
2214
2215 ## Hack, but working solution to avoid rebuilding of frr.info.
2216 ## It's already in CVS until texinfo 4.7 is more common.
2217 AC_OUTPUT
2218
2219 echo "
2220 FRRouting configuration
2221 ------------------------------
2222 FRR version             : ${PACKAGE_VERSION}
2223 host operating system   : ${host_os}
2224 source code location    : ${srcdir}
2225 compiler                : ${CC}
2226 compiler flags          : ${CFLAGS} ${SAN_FLAGS}
2227 make                    : ${MAKE-make}
2228 linker flags            : ${LDFLAGS} ${SAN_FLAGS} ${LIBS} ${LIBCAP} ${LIBREADLINE} ${LIBM}
2229 state file directory    : ${frr_statedir}
2230 config file directory   : `eval echo \`echo ${sysconfdir}\``
2231 example directory       : `eval echo \`echo ${exampledir}\``
2232 module directory        : ${CFG_MODULE}
2233 user to run as          : ${enable_user}
2234 group to run as         : ${enable_group}
2235 group for vty sockets   : ${enable_vty_group}
2236 config file mask        : ${enable_configfile_mask}
2237 log file mask           : ${enable_logfile_mask}
2238 zebra protobuf enabled  : ${enable_protobuf:-no}
2239
2240 The above user and group must have read/write access to the state file
2241 directory and to the config files in the config file directory."
2242
2243 if test "${enable_doc}" != "no";then
2244   AS_IF([test "$SPHINXBUILD" = /bin/false],
2245      AC_MSG_WARN([sphinx-build is missing but required to build documentation]))
2246 fi