PVE/API2/AccessControl.pm

   1 package PVE::API2::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5
   6 use JSON;
   7 use MIME::Base64;
   8
   9 use PVE::Exception qw(raise raise_perm_exc raise_param_exc);
  10 use PVE::SafeSyslog;
  11 use PVE::RPCEnvironment;
  12 use PVE::Cluster qw(cfs_read_file);
  13 use PVE::DataCenterConfig;
  14 use PVE::RESTHandler;
  15 use PVE::AccessControl;
  16 use PVE::JSONSchema qw(get_standard_option);
  17 use PVE::API2::Domains;
  18 use PVE::API2::User;
  19 use PVE::API2::Group;
  20 use PVE::API2::Role;
  21 use PVE::API2::ACL;
  22 use PVE::Auth::Plugin;
  23 use PVE::OTP;
  24 use PVE::Tools;
  25
  26 my $u2f_available = 0;
  27 eval {
  28     require PVE::U2F;
  29     $u2f_available = 1;
  30 };
  31
  32 use base qw(PVE::RESTHandler);
  33
  34 __PACKAGE__->register_method ({
  35     subclass => "PVE::API2::User",
  36     path => 'users',
  37 });
  38
  39 __PACKAGE__->register_method ({
  40     subclass => "PVE::API2::Group",
  41     path => 'groups',
  42 });
  43
  44 __PACKAGE__->register_method ({
  45     subclass => "PVE::API2::Role",
  46     path => 'roles',
  47 });
  48
  49 __PACKAGE__->register_method ({
  50     subclass => "PVE::API2::ACL",
  51     path => 'acl',
  52 });
  53
  54 __PACKAGE__->register_method ({
  55     subclass => "PVE::API2::Domains",
  56     path => 'domains',
  57 });
  58
  59 __PACKAGE__->register_method ({
  60     name => 'index',
  61     path => '',
  62     method => 'GET',
  63     description => "Directory index.",
  64     permissions => {
  65         user => 'all',
  66     },
  67     parameters => {
  68         additionalProperties => 0,
  69         properties => {},
  70     },
  71     returns => {
  72         type => 'array',
  73         items => {
  74             type => "object",
  75             properties => {
  76                 subdir => { type => 'string' },
  77             },
  78         },
  79         links => [ { rel => 'child', href => "{subdir}" } ],
  80     },
  81     code => sub {
  82         my ($param) = @_;
  83
  84         my $res = [];
  85
  86         my $ma = __PACKAGE__->method_attributes();
  87
  88         foreach my $info (@$ma) {
  89             next if !$info->{subclass};
  90
  91             my $subpath = $info->{match_re}->[0];
  92
  93             push @$res, { subdir => $subpath };
  94         }
  95
  96         push @$res, { subdir => 'ticket' };
  97         push @$res, { subdir => 'password' };
  98
  99         return $res;
 100     }});
 101
 102
 103 my $verify_auth = sub {
 104     my ($rpcenv, $username, $pw_or_ticket, $otp, $path, $privs) = @_;
 105
 106     my $normpath = PVE::AccessControl::normalize_path($path);
 107
 108     my $ticketuser;
 109     if (($ticketuser = PVE::AccessControl::verify_ticket($pw_or_ticket, 1)) &&
 110         ($ticketuser eq $username)) {
 111         # valid ticket
 112     } elsif (PVE::AccessControl::verify_vnc_ticket($pw_or_ticket, $username, $normpath, 1)) {
 113         # valid vnc ticket
 114     } else {
 115         $username = PVE::AccessControl::authenticate_user($username, $pw_or_ticket, $otp);
 116     }
 117
 118     my $privlist = [ PVE::Tools::split_list($privs) ];
 119     if (!($normpath && scalar(@$privlist) && $rpcenv->check($username, $normpath, $privlist))) {
 120         die "no permission ($path, $privs)\n";
 121     }
 122
 123     return { username => $username };
 124 };
 125
 126 my $create_ticket = sub {
 127     my ($rpcenv, $username, $pw_or_ticket, $otp) = @_;
 128
 129     my ($ticketuser, undef, $tfa_info) = PVE::AccessControl::verify_ticket($pw_or_ticket, 1);
 130     if (defined($ticketuser) && ($ticketuser eq 'root@pam' || $ticketuser eq $username)) {
 131         if (defined($tfa_info)) {
 132             die "incomplete ticket\n";
 133         }
 134         # valid ticket. Note: root@pam can create tickets for other users
 135     } else {
 136         ($username, $tfa_info) = PVE::AccessControl::authenticate_user($username, $pw_or_ticket, $otp);
 137     }
 138
 139     my %extra;
 140     my $ticket_data = $username;
 141     if (defined($tfa_info)) {
 142         $extra{NeedTFA} = 1;
 143         if ($tfa_info->{type} eq 'u2f') {
 144             my $u2finfo = $tfa_info->{data};
 145             my $u2f = get_u2f_instance($rpcenv, $u2finfo->@{qw(publicKey keyHandle)});
 146             my $challenge = $u2f->auth_challenge()
 147                 or die "failed to get u2f challenge\n";
 148             $challenge = decode_json($challenge);
 149             $extra{U2FChallenge} = $challenge;
 150             $ticket_data = "u2f!$username!$challenge->{challenge}";
 151         } else {
 152             # General half-login / 'missing 2nd factor' ticket:
 153             $ticket_data = "tfa!$username";
 154         }
 155     }
 156
 157     my $ticket = PVE::AccessControl::assemble_ticket($ticket_data);
 158     my $csrftoken = PVE::AccessControl::assemble_csrf_prevention_token($username);
 159
 160     return {
 161         ticket => $ticket,
 162         username => $username,
 163         CSRFPreventionToken => $csrftoken,
 164         %extra,
 165     };
 166 };
 167
 168 my $compute_api_permission = sub {
 169     my ($rpcenv, $authuser) = @_;
 170
 171     my $usercfg = $rpcenv->{user_cfg};
 172
 173     my $res = {};
 174     my $priv_re_map = {
 175         vms => qr/VM\.|Permissions\.Modify/,
 176         access => qr/(User|Group)\.|Permissions\.Modify/,
 177         storage => qr/Datastore\.|Permissions\.Modify/,
 178         nodes => qr/Sys\.|Permissions\.Modify/,
 179         dc => qr/Sys\.Audit/,
 180     };
 181     map { $res->{$_} = {} } keys %$priv_re_map;
 182
 183     my $required_paths = ['/', '/nodes', '/access/groups', '/vms', '/storage'];
 184
 185     my $checked_paths = {};
 186     foreach my $path (@$required_paths, keys %{$usercfg->{acl}}) {
 187         next if $checked_paths->{$path};
 188         $checked_paths->{$path} = 1;
 189
 190         my $path_perm = $rpcenv->permissions($authuser, $path);
 191
 192         my $toplevel = ($path =~ /^\/(\w+)/) ? $1 : 'dc';
 193         if ($toplevel eq 'pool') {
 194             foreach my $priv (keys %$path_perm) {
 195                 if ($priv =~ m/^VM\./) {
 196                     $res->{vms}->{$priv} = 1;
 197                 } elsif ($priv =~ m/^Datastore\./) {
 198                     $res->{storage}->{$priv} = 1;
 199                 } elsif ($priv eq 'Permissions.Modify') {
 200                     $res->{storage}->{$priv} = 1;
 201                     $res->{vms}->{$priv} = 1;
 202                 }
 203             }
 204         } else {
 205             my $priv_regex = $priv_re_map->{$toplevel} // next;
 206             foreach my $priv (keys %$path_perm) {
 207                 next if $priv !~ m/^($priv_regex)/;
 208                 $res->{$toplevel}->{$priv} = 1;
 209             }
 210         }
 211     }
 212
 213     return $res;
 214 };
 215
 216 __PACKAGE__->register_method ({
 217     name => 'get_ticket',
 218     path => 'ticket',
 219     method => 'GET',
 220     permissions => { user => 'world' },
 221     description => "Dummy. Useful for formatters which want to provide a login page.",
 222     parameters => {
 223         additionalProperties => 0,
 224     },
 225     returns => { type => "null" },
 226     code => sub { return undef; }});
 227
 228 __PACKAGE__->register_method ({
 229     name => 'create_ticket',
 230     path => 'ticket',
 231     method => 'POST',
 232     permissions => {
 233         description => "You need to pass valid credientials.",
 234         user => 'world'
 235     },
 236     protected => 1, # else we can't access shadow files
 237     description => "Create or verify authentication ticket.",
 238     parameters => {
 239         additionalProperties => 0,
 240         properties => {
 241             username => {
 242                 description => "User name",
 243                 type => 'string',
 244                 maxLength => 64,
 245                 completion => \&PVE::AccessControl::complete_username,
 246             },
 247             realm =>  get_standard_option('realm', {
 248                 description => "You can optionally pass the realm using this parameter. Normally the realm is simply added to the username <username>\@<relam>.",
 249                 optional => 1,
 250                 completion => \&PVE::AccessControl::complete_realm,
 251             }),
 252             password => {
 253                 description => "The secret password. This can also be a valid ticket.",
 254                 type => 'string',
 255             },
 256             otp => {
 257                 description => "One-time password for Two-factor authentication.",
 258                 type => 'string',
 259                 optional => 1,
 260             },
 261             path => {
 262                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 263                 type => 'string',
 264                 requires => 'privs',
 265                 optional => 1,
 266                 maxLength => 64,
 267             },
 268             privs => {
 269                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 270                 type => 'string' , format => 'pve-priv-list',
 271                 requires => 'path',
 272                 optional => 1,
 273                 maxLength => 64,
 274             },
 275         }
 276     },
 277     returns => {
 278         type => "object",
 279         properties => {
 280             username => { type => 'string' },
 281             ticket => { type => 'string', optional => 1},
 282             CSRFPreventionToken => { type => 'string', optional => 1 },
 283             clustername => { type => 'string', optional => 1 },
 284             # cap => computed api permissions, unless there's a u2f challenge
 285         }
 286     },
 287     code => sub {
 288         my ($param) = @_;
 289
 290         my $username = $param->{username};
 291         $username .= "\@$param->{realm}" if $param->{realm};
 292
 293         my $rpcenv = PVE::RPCEnvironment::get();
 294
 295         my $res;
 296         eval {
 297             # test if user exists and is enabled
 298             $rpcenv->check_user_enabled($username);
 299
 300             if ($param->{path} && $param->{privs}) {
 301                 $res = &$verify_auth($rpcenv, $username, $param->{password}, $param->{otp},
 302                                      $param->{path}, $param->{privs});
 303             } else {
 304                 $res = &$create_ticket($rpcenv, $username, $param->{password}, $param->{otp});
 305             }
 306         };
 307         if (my $err = $@) {
 308             my $clientip = $rpcenv->get_client_ip() || '';
 309             syslog('err', "authentication failure; rhost=$clientip user=$username msg=$err");
 310             # do not return any info to prevent user enumeration attacks
 311             die PVE::Exception->new("authentication failure\n", code => 401);
 312         }
 313
 314         $res->{cap} = &$compute_api_permission($rpcenv, $username)
 315             if !defined($res->{NeedTFA});
 316
 317         my $clinfo = PVE::Cluster::get_clinfo();
 318         if ($clinfo->{cluster}->{name} && $rpcenv->check($username, '/', ['Sys.Audit'], 1)) {
 319             $res->{clustername} = $clinfo->{cluster}->{name};
 320         }
 321
 322         PVE::Cluster::log_msg('info', 'root@pam', "successful auth for user '$username'");
 323
 324         return $res;
 325     }});
 326
 327 __PACKAGE__->register_method ({
 328     name => 'change_password',
 329     path => 'password',
 330     method => 'PUT',
 331     permissions => {
 332         description => "Each user is allowed to change his own password. A user can change the password of another user if he has 'Realm.AllocateUser' (on the realm of user <userid>) and 'User.Modify' permission on /access/groups/<group> on a group where user <userid> is member of.",
 333         check => [ 'or',
 334                    ['userid-param', 'self'],
 335                    [ 'and',
 336                      [ 'userid-param', 'Realm.AllocateUser'],
 337                      [ 'userid-group', ['User.Modify']]
 338                    ]
 339             ],
 340     },
 341     protected => 1, # else we can't access shadow files
 342     description => "Change user password.",
 343     parameters => {
 344         additionalProperties => 0,
 345         properties => {
 346             userid => get_standard_option('userid-completed'),
 347             password => {
 348                 description => "The new password.",
 349                 type => 'string',
 350                 minLength => 5,
 351                 maxLength => 64,
 352             },
 353         }
 354     },
 355     returns => { type => "null" },
 356     code => sub {
 357         my ($param) = @_;
 358
 359         my $rpcenv = PVE::RPCEnvironment::get();
 360         my $authuser = $rpcenv->get_user();
 361
 362         my ($userid, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 363
 364         $rpcenv->check_user_exist($userid);
 365
 366         if ($authuser eq 'root@pam') {
 367             # OK - root can change anything
 368         } else {
 369             if ($authuser eq $userid) {
 370                 $rpcenv->check_user_enabled($userid);
 371                 # OK - each user can change its own password
 372             } else {
 373                 # only root may change root password
 374                 raise_perm_exc() if $userid eq 'root@pam';
 375                 # do not allow to change system user passwords
 376                 raise_perm_exc() if $realm eq 'pam';
 377             }
 378         }
 379
 380         PVE::AccessControl::domain_set_password($realm, $ruid, $param->{password});
 381
 382         PVE::Cluster::log_msg('info', 'root@pam', "changed password for user '$userid'");
 383
 384         return undef;
 385     }});
 386
 387 sub get_u2f_config() {
 388     die "u2f support not available\n" if !$u2f_available;
 389
 390     my $dc = cfs_read_file('datacenter.cfg');
 391     my $u2f = $dc->{u2f};
 392     die "u2f not configured in datacenter.cfg\n" if !$u2f;
 393     return $u2f;
 394 }
 395
 396 sub get_u2f_instance {
 397     my ($rpcenv, $publicKey, $keyHandle) = @_;
 398
 399     # We store the public key base64 encoded (as the api provides it in binary)
 400     $publicKey = decode_base64($publicKey) if defined($publicKey);
 401
 402     my $u2fconfig = get_u2f_config();
 403     my $u2f = PVE::U2F->new();
 404
 405     # via the 'Host' header (in case a node has multiple hosts available).
 406     my $origin = $u2fconfig->{origin};
 407     if (!defined($origin)) {
 408         $origin = $rpcenv->get_request_host(1);
 409         if ($origin) {
 410             $origin = "https://$origin";
 411         } else {
 412             die "failed to figure out u2f origin\n";
 413         }
 414     }
 415
 416     my $appid = $u2fconfig->{appid} // $origin;
 417     $u2f->set_appid($appid);
 418     $u2f->set_origin($origin);
 419     $u2f->set_publicKey($publicKey) if defined($publicKey);
 420     $u2f->set_keyHandle($keyHandle) if defined($keyHandle);
 421     return $u2f;
 422 }
 423
 424 sub verify_user_tfa_config {
 425     my ($type, $tfa_cfg, $value) = @_;
 426
 427     if (!defined($type)) {
 428         die "missing tfa 'type'\n";
 429     }
 430
 431     if ($type ne 'oath') {
 432         die "invalid type for custom tfa authentication\n";
 433     }
 434
 435     my $secret = $tfa_cfg->{keys}
 436         or die "missing TOTP secret\n";
 437     $tfa_cfg = $tfa_cfg->{config};
 438     # Copy the hash to verify that we have no unexpected keys without modifying the original hash.
 439     $tfa_cfg = {%$tfa_cfg};
 440
 441     # We can only verify 1 secret but oath_verify_otp allows multiple:
 442     if (scalar(PVE::Tools::split_list($secret)) != 1) {
 443         die "only exactly one secret key allowed\n";
 444     }
 445
 446     my $digits = delete($tfa_cfg->{digits}) // 6;
 447     my $step = delete($tfa_cfg->{step}) // 30;
 448     # Maybe also this?
 449     #     my $algorithm = delete($tfa_cfg->{algorithm}) // 'sha1';
 450
 451     if (length(my $more = join(', ', keys %$tfa_cfg))) {
 452         die "unexpected tfa config keys: $more\n";
 453     }
 454
 455     PVE::OTP::oath_verify_otp($value, $secret, $step, $digits);
 456 }
 457
 458 __PACKAGE__->register_method ({
 459     name => 'change_tfa',
 460     path => 'tfa',
 461     method => 'PUT',
 462     permissions => {
 463         description => 'A user can change their own u2f or totp token.',
 464         check => [ 'or',
 465                    ['userid-param', 'self'],
 466                    [ 'and',
 467                      [ 'userid-param', 'Realm.AllocateUser'],
 468                      [ 'userid-group', ['User.Modify']]
 469                    ]
 470             ],
 471     },
 472     protected => 1, # else we can't access shadow files
 473     description => "Change user u2f authentication.",
 474     parameters => {
 475         additionalProperties => 0,
 476         properties => {
 477             userid => get_standard_option('userid', {
 478                 completion => \&PVE::AccessControl::complete_username,
 479             }),
 480             password => {
 481                 optional => 1, # Only required if not root@pam
 482                 description => "The current password.",
 483                 type => 'string',
 484                 minLength => 5,
 485                 maxLength => 64,
 486             },
 487             action => {
 488                 description => 'The action to perform',
 489                 type => 'string',
 490                 enum => [qw(delete new confirm)],
 491             },
 492             response => {
 493                 optional => 1,
 494                 description =>
 495                     'Either the the response to the current u2f registration challenge,'
 496                     .' or, when adding TOTP, the currently valid TOTP value.',
 497                 type => 'string',
 498             },
 499             key => {
 500                 optional => 1,
 501                 description => 'When adding TOTP, the shared secret value.',
 502                 type => 'string',
 503                 format => 'pve-tfa-secret',
 504             },
 505             config => {
 506                 optional => 1,
 507                 description => 'A TFA configuration. This must currently be of type TOTP of not set at all.',
 508                 type => 'string',
 509                 format => 'pve-tfa-config',
 510                 maxLength => 128,
 511             },
 512         }
 513     },
 514     returns => { type => 'object' },
 515     code => sub {
 516         my ($param) = @_;
 517
 518         my $rpcenv = PVE::RPCEnvironment::get();
 519         my $authuser = $rpcenv->get_user();
 520
 521         my $action = delete $param->{action};
 522         my $response = delete $param->{response};
 523         my $password = delete($param->{password}) // '';
 524         my $key = delete($param->{key});
 525         my $config = delete($param->{config});
 526
 527         my ($userid, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 528         $rpcenv->check_user_exist($userid);
 529
 530         # Only root may modify root
 531         raise_perm_exc() if $userid eq 'root@pam' && $authuser ne 'root@pam';
 532
 533         # Regular users need to confirm their password to change u2f settings.
 534         if ($authuser ne 'root@pam') {
 535             raise_param_exc({ 'password' => 'password is required to modify u2f data' })
 536                 if !defined($password);
 537             my $domain_cfg = cfs_read_file('domains.cfg');
 538             my $cfg = $domain_cfg->{ids}->{$realm};
 539             die "auth domain '$realm' does not exists\n" if !$cfg;
 540             my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 541             $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 542         }
 543
 544         if ($action eq 'delete') {
 545             PVE::AccessControl::user_set_tfa($userid, $realm, undef, undef);
 546             PVE::Cluster::log_msg('info', $authuser, "deleted u2f data for user '$userid'");
 547         } elsif ($action eq 'new') {
 548             if (defined($config)) {
 549                 $config = PVE::Auth::Plugin::parse_tfa_config($config);
 550                 my $type = delete($config->{type});
 551                 my $tfa_cfg = {
 552                     keys => $key,
 553                     config => $config,
 554                 };
 555                 verify_user_tfa_config($type, $tfa_cfg, $response);
 556                 PVE::AccessControl::user_set_tfa($userid, $realm, $type, $tfa_cfg);
 557             } else {
 558                 # The default is U2F:
 559                 my $u2f = get_u2f_instance($rpcenv);
 560                 my $challenge = $u2f->registration_challenge()
 561                     or raise("failed to get u2f challenge");
 562                 $challenge = decode_json($challenge);
 563                 PVE::AccessControl::user_set_tfa($userid, $realm, 'u2f', $challenge);
 564                 return $challenge;
 565             }
 566         } elsif ($action eq 'confirm') {
 567             raise_param_exc({ 'response' => "confirm action requires the 'response' parameter to be set" })
 568                 if !defined($response);
 569
 570             my ($type, $u2fdata) = PVE::AccessControl::user_get_tfa($userid, $realm);
 571             raise("no u2f data available")
 572                 if (!defined($type) || $type ne 'u2f');
 573
 574             my $challenge = $u2fdata->{challenge}
 575                 or raise("no active challenge");
 576
 577             my $u2f = get_u2f_instance($rpcenv);
 578             $u2f->set_challenge($challenge);
 579             my ($keyHandle, $publicKey) = $u2f->registration_verify($response);
 580             PVE::AccessControl::user_set_tfa($userid, $realm, 'u2f', {
 581                 keyHandle => $keyHandle,
 582                 publicKey => $publicKey, # already base64 encoded
 583             });
 584         } else {
 585             die "invalid action: $action\n";
 586         }
 587
 588         return {};
 589     }});
 590
 591 __PACKAGE__->register_method({
 592     name => 'verify_tfa',
 593     path => 'tfa',
 594     method => 'POST',
 595     permissions => { user => 'all' },
 596     protected => 1, # else we can't access shadow files
 597     description => 'Finish a u2f challenge.',
 598     parameters => {
 599         additionalProperties => 0,
 600         properties => {
 601             response => {
 602                 type => 'string',
 603                 description => 'The response to the current authentication challenge.',
 604             },
 605         }
 606     },
 607     returns => {
 608         type => 'object',
 609         properties => {
 610             ticket => { type => 'string' },
 611             # cap
 612         }
 613     },
 614     code => sub {
 615         my ($param) = @_;
 616
 617         my $rpcenv = PVE::RPCEnvironment::get();
 618         my $authuser = $rpcenv->get_user();
 619         my ($username, undef, $realm) = PVE::AccessControl::verify_username($authuser);
 620
 621         my ($tfa_type, $tfa_data) = PVE::AccessControl::user_get_tfa($username, $realm);
 622         if (!defined($tfa_type)) {
 623             raise('no u2f data available');
 624         }
 625
 626         eval {
 627             if ($tfa_type eq 'u2f') {
 628                 my $challenge = $rpcenv->get_u2f_challenge()
 629                    or raise('no active challenge');
 630
 631                 my $keyHandle = $tfa_data->{keyHandle};
 632                 my $publicKey = $tfa_data->{publicKey};
 633                 raise("incomplete u2f setup")
 634                     if !defined($keyHandle) || !defined($publicKey);
 635
 636                 my $u2f = get_u2f_instance($rpcenv, $publicKey, $keyHandle);
 637                 $u2f->set_challenge($challenge);
 638
 639                 my ($counter, $present) = $u2f->auth_verify($param->{response});
 640                 # Do we want to do anything with these?
 641             } else {
 642                 # sanity check before handing off to the verification code:
 643                 my $keys = $tfa_data->{keys} or die "missing tfa keys\n";
 644                 my $config = $tfa_data->{config} or die "bad tfa entry\n";
 645                 PVE::AccessControl::verify_one_time_pw($tfa_type, $authuser, $keys, $config, $param->{response});
 646             }
 647         };
 648         if (my $err = $@) {
 649             my $clientip = $rpcenv->get_client_ip() || '';
 650             syslog('err', "authentication verification failure; rhost=$clientip user=$authuser msg=$err");
 651             die PVE::Exception->new("authentication failure\n", code => 401);
 652         }
 653
 654         return {
 655             ticket => PVE::AccessControl::assemble_ticket($authuser),
 656             cap => &$compute_api_permission($rpcenv, $authuser),
 657         }
 658     }});
 659
 660 1;