PVE/API2/AccessControl.pm

   1 package PVE::API2::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Exception qw(raise raise_perm_exc);
   7 use PVE::SafeSyslog;
   8 use PVE::RPCEnvironment;
   9 use PVE::Cluster qw(cfs_read_file);
  10 use PVE::RESTHandler;
  11 use PVE::AccessControl;
  12 use PVE::JSONSchema qw(get_standard_option);
  13 use PVE::API2::Domains;
  14 use PVE::API2::User;
  15 use PVE::API2::Group;
  16 use PVE::API2::Role;
  17 use PVE::API2::ACL;
  18
  19 use base qw(PVE::RESTHandler);
  20
  21 __PACKAGE__->register_method ({
  22     subclass => "PVE::API2::User",
  23     path => 'users',
  24 });
  25
  26 __PACKAGE__->register_method ({
  27     subclass => "PVE::API2::Group",
  28     path => 'groups',
  29 });
  30
  31 __PACKAGE__->register_method ({
  32     subclass => "PVE::API2::Role",
  33     path => 'roles',
  34 });
  35
  36 __PACKAGE__->register_method ({
  37     subclass => "PVE::API2::ACL",
  38     path => 'acl',
  39 });
  40
  41 __PACKAGE__->register_method ({
  42     subclass => "PVE::API2::Domains",
  43     path => 'domains',
  44 });
  45
  46 __PACKAGE__->register_method ({
  47     name => 'index',
  48     path => '',
  49     method => 'GET',
  50     description => "Directory index.",
  51     parameters => {
  52         additionalProperties => 0,
  53         properties => {},
  54     },
  55     returns => {
  56         type => 'array',
  57         items => {
  58             type => "object",
  59             properties => {
  60                 subdir => { type => 'string' },
  61             },
  62         },
  63         links => [ { rel => 'child', href => "{subdir}" } ],
  64     },
  65     code => sub {
  66         my ($param) = @_;
  67
  68         my $res = [];
  69
  70         my $ma = __PACKAGE__->method_attributes();
  71
  72         foreach my $info (@$ma) {
  73             next if !$info->{subclass};
  74
  75             my $subpath = $info->{match_re}->[0];
  76
  77             push @$res, { subdir => $subpath };
  78         }
  79
  80         push @$res, { subdir => 'ticket' };
  81         push @$res, { subdir => 'password' };
  82
  83         return $res;
  84     }});
  85
  86
  87 my $verify_auth = sub {
  88     my ($rpcenv, $username, $pw_or_ticket, $path, $privs) = @_;
  89
  90     my $normpath = PVE::AccessControl::normalize_path($path);
  91
  92     my $ticketuser;
  93     if (($ticketuser = PVE::AccessControl::verify_ticket($pw_or_ticket, 1)) &&
  94         ($ticketuser eq $username)) {
  95         # valid ticket
  96     } elsif (PVE::AccessControl::verify_vnc_ticket($pw_or_ticket, $username, $normpath, 1)) {
  97         # valid vnc ticket
  98     } else {
  99         $username = PVE::AccessControl::authenticate_user($username, $pw_or_ticket);
 100     }
 101
 102     my $privlist = [ PVE::Tools::split_list($privs) ];
 103     if (!($normpath && scalar(@$privlist) && $rpcenv->check($username, $normpath, $privlist))) {
 104         die "no permission ($path, $privs)\n";
 105     }
 106
 107     return { username => $username };
 108 };
 109
 110 my $create_ticket = sub {
 111     my ($rpcenv, $username, $pw_or_ticket) = @_;
 112
 113     my $ticketuser;
 114     if (($ticketuser = PVE::AccessControl::verify_ticket($pw_or_ticket, 1)) &&
 115         ($ticketuser eq 'root@pam' || $ticketuser eq $username)) {
 116         # valid ticket. Note: root@pam can create tickets for other users
 117     } else {
 118         $username = PVE::AccessControl::authenticate_user($username, $pw_or_ticket);
 119     }
 120
 121     my $ticket = PVE::AccessControl::assemble_ticket($username);
 122     my $csrftoken = PVE::AccessControl::assemble_csrf_prevention_token($username);
 123
 124     return {
 125         ticket => $ticket,
 126         username => $username,
 127         CSRFPreventionToken => $csrftoken,
 128     };
 129 };
 130
 131 __PACKAGE__->register_method ({
 132     name => 'create_ticket',
 133     path => 'ticket',
 134     method => 'POST',
 135     permissions => { user => 'world' },
 136     protected => 1, # else we can't access shadow files
 137     description => "Create or verify authentication ticket.",
 138     parameters => {
 139         additionalProperties => 0,
 140         properties => {
 141             username => {
 142                 description => "User name",
 143                 type => 'string',
 144                 maxLength => 64,
 145             },
 146             realm =>  get_standard_option('realm', {
 147                 description => "You can optionally pass the realm using this parameter. Normally the realm is simply added to the username <username>\@<relam>.",
 148                 optional => 1}),
 149             password => {
 150                 description => "The secret password. This can also be a valid ticket.",
 151                 type => 'string',
 152             },
 153             path => {
 154                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 155                 type => 'string',
 156                 requires => 'privs',
 157                 optional => 1,
 158                 maxLength => 64,
 159             },
 160             privs => {
 161                 description => "Verify ticket, and check if user have access 'privs' on 'path'",
 162                 type => 'string' , format => 'pve-priv-list',
 163                 requires => 'path',
 164                 optional => 1,
 165                 maxLength => 64,
 166             },
 167         }
 168     },
 169     returns => {
 170         type => "object",
 171         properties => {
 172             username => { type => 'string' },
 173             ticket => { type => 'string', optional => 1},
 174             CSRFPreventionToken => { type => 'string', optional => 1 },
 175         }
 176     },
 177     code => sub {
 178         my ($param) = @_;
 179
 180         my $username = $param->{username};
 181         $username .= "\@$param->{realm}" if $param->{realm};
 182
 183         my $rpcenv = PVE::RPCEnvironment::get();
 184
 185         my $res;
 186
 187         eval {
 188             # test if user exists and is enabled
 189             $rpcenv->check_user_enabled($username);
 190
 191             if ($param->{path} && $param->{privs}) {
 192                 $res = &$verify_auth($rpcenv, $username, $param->{password},
 193                                      $param->{path}, $param->{privs});
 194             } else {
 195                 $res = &$create_ticket($rpcenv, $username, $param->{password});
 196             }
 197         };
 198         if (my $err = $@) {
 199             my $clientip = $rpcenv->get_client_ip() || '';
 200             syslog('err', "authentication failure; rhost=$clientip user=$username msg=$err");
 201             die $err;
 202         }
 203
 204         PVE::Cluster::log_msg('info', 'root@pam', "successful auth for user '$username'");
 205
 206         return $res;
 207     }});
 208
 209 __PACKAGE__->register_method ({
 210     name => 'change_passsword',
 211     path => 'password',
 212     method => 'PUT',
 213     permissions => {
 214         description => "Each user is allowed to change his own password. A user can change the password of another user if he has modify permission on /access/groups/<group> on a group where user <userid> is member of.",
 215         check => [ 'or',
 216                    ['userid-param', 'self'],
 217                    ['userid-group', ['User.Modify']],
 218             ],
 219     },
 220     protected => 1, # else we can't access shadow files
 221     description => "Change user password.",
 222     parameters => {
 223         additionalProperties => 0,
 224         properties => {
 225             userid => get_standard_option('userid'),
 226             password => {
 227                 description => "The new password.",
 228                 type => 'string',
 229                 minLength => 5,
 230                 maxLength => 64,
 231             },
 232         }
 233     },
 234     returns => { type => "null" },
 235     code => sub {
 236         my ($param) = @_;
 237
 238         my $rpcenv = PVE::RPCEnvironment::get();
 239         my $authuser = $rpcenv->get_user();
 240
 241         my ($userid, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 242
 243         $rpcenv->check_user_exist($userid);
 244
 245         if ($authuser eq 'root@pam') {
 246             # OK - root can change anything
 247         } else {
 248             if ($authuser eq $userid) {
 249                 $rpcenv->check_user_enabled($userid);
 250                 # OK - each user can change its own password
 251             } else {
 252                 # only root may change root password
 253                 raise_perm_exc() if $userid eq 'root@pam';
 254             }
 255         }
 256
 257         PVE::AccessControl::domain_set_password($realm, $ruid, $param->{password});
 258
 259         PVE::Cluster::log_msg('info', 'root@pam', "changed password for user '$userid'");
 260
 261         return undef;
 262     }});
 263
 264 1;