PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use Encode;
   5 use Crypt::OpenSSL::Random;
   6 use Crypt::OpenSSL::RSA;
   7 use MIME::Base64;
   8 use Digest::SHA;
   9 use Authen::PAM qw(:constants);
  10 use Net::LDAP;
  11 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  12 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  13 use PVE::JSONSchema;
  14 use Encode;
  15
  16 use Data::Dumper; # fixme: remove
  17
  18 # $authdir must be writable by root only!
  19 my $confdir = "/etc/pve";
  20 my $authdir = "$confdir/priv";
  21 my $authprivkeyfn = "$authdir/authkey.key";
  22 my $authpubkeyfn = "$confdir/authkey.pub";
  23 my $shadowconfigfile = "priv/shadow.cfg";
  24 my $domainconfigfile = "domains.cfg";
  25 my $pve_www_key_fn = "$confdir/pve-www.key";
  26
  27 my $ticket_lifetime = 3600*2; # 2 hours
  28
  29 Crypt::OpenSSL::RSA->import_random_seed();
  30
  31 cfs_register_file('user.cfg',
  32                   \&parse_user_config,
  33                   \&write_user_config);
  34
  35 cfs_register_file($shadowconfigfile,
  36                   \&parse_shadow_passwd,
  37                   \&write_shadow_config);
  38
  39 cfs_register_file($domainconfigfile,
  40                   \&parse_domains,
  41                   \&write_domains);
  42
  43
  44 sub lock_user_config {
  45     my ($code, $errmsg) = @_;
  46
  47     cfs_lock_file("user.cfg", undef, $code);
  48     my $err = $@;
  49     if ($err) {
  50         $errmsg ? die "$errmsg: $err" : die $err;
  51     }
  52 }
  53
  54 sub lock_domain_config {
  55     my ($code, $errmsg) = @_;
  56
  57     cfs_lock_file($domainconfigfile, undef, $code);
  58     my $err = $@;
  59     if ($err) {
  60         $errmsg ? die "$errmsg: $err" : die $err;
  61     }
  62 }
  63
  64 sub lock_shadow_config {
  65     my ($code, $errmsg) = @_;
  66
  67     cfs_lock_file($shadowconfigfile, undef, $code);
  68     my $err = $@;
  69     if ($err) {
  70         $errmsg ? die "$errmsg: $err" : die $err;
  71     }
  72 }
  73
  74 my $pve_auth_pub_key;
  75 sub get_pubkey {
  76
  77     return $pve_auth_pub_key if $pve_auth_pub_key;
  78
  79     my $input = PVE::Tools::file_get_contents($authpubkeyfn);
  80
  81     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
  82
  83     return $pve_auth_pub_key;
  84 }
  85
  86 my $csrf_prevention_secret;
  87 my $get_csrfr_secret = sub {
  88     if (!$csrf_prevention_secret) {
  89         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
  90         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
  91     }
  92     return $csrf_prevention_secret;
  93 };
  94
  95 sub assemble_csrf_prevention_token {
  96     my ($username) = @_;
  97
  98     my $timestamp = sprintf("%08X", time());
  99
 100     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
 101
 102     return "$timestamp:$digest";
 103 }
 104
 105 sub verify_csrf_prevention_token {
 106     my ($username, $token, $noerr) = @_;
 107
 108     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 109         my $sig = $2;
 110         my $timestamp = $1;
 111         my $ttime = hex($timestamp);
 112
 113         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
 114
 115         my $age = time() - $ttime;
 116         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
 117     }
 118
 119     die "Permission denied - invalid csrf token\n" if !$noerr;
 120
 121     return undef;
 122 }
 123
 124 my $pve_auth_priv_key;
 125 sub get_privkey {
 126
 127     return $pve_auth_priv_key if $pve_auth_priv_key;
 128
 129     my $input = PVE::Tools::file_get_contents($authprivkeyfn);
 130
 131     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
 132
 133     return $pve_auth_priv_key;
 134 }
 135
 136 sub assemble_ticket {
 137     my ($username) = @_;
 138
 139     my $rsa_priv = get_privkey();
 140
 141     my $timestamp = sprintf("%08X", time());
 142
 143     my $plain = "PVE:$username:$timestamp";
 144
 145     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
 146
 147     return $ticket;
 148 }
 149
 150 sub verify_ticket {
 151     my ($ticket, $noerr) = @_;
 152
 153     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
 154         my $plain = $1;
 155         my $sig = $2;
 156
 157         my $rsa_pub = get_pubkey();
 158         if ($rsa_pub->verify($plain, decode_base64($sig))) {
 159             if ($plain =~ m/^PVE:(([A-Za-z0-9\.\-_]+)(\@([A-Za-z0-9\.\-_]+))?):([A-Z0-9]{8})$/) {
 160                 my $username = $1;
 161                 my $timestamp = $5;
 162                 my $ttime = hex($timestamp);
 163
 164                 my $age = time() - $ttime;
 165
 166                 if (($age > -300) && ($age < $ticket_lifetime)) {
 167                     return wantarray ? ($username, $age) : $username;
 168                 }
 169             }
 170         }
 171     }
 172
 173     die "permission denied - invalid ticket\n" if !$noerr;
 174
 175     return undef;
 176 }
 177
 178 # VNC tickets
 179 # - they do not contain the username in plain text
 180 # - they are restricted to a specific resource path (example: '/vms/100')
 181 sub assemble_vnc_ticket {
 182     my ($username, $path) = @_;
 183
 184     my $rsa_priv = get_privkey();
 185
 186     my $timestamp = sprintf("%08X", time());
 187
 188     my $plain = "PVEVNC:$timestamp";
 189
 190     $path = normalize_path($path);
 191
 192     my $full = "$plain:$username:$path";
 193
 194     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
 195
 196     return $ticket;
 197 }
 198
 199 sub verify_vnc_ticket {
 200     my ($ticket, $username, $path, $noerr) = @_;
 201
 202     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
 203         my $plain = $1;
 204         my $sig = $2;
 205         my $full = "$plain:$username:$path";
 206
 207         my $rsa_pub = get_pubkey();
 208         # Note: sign only match if $username and  $path is correct
 209         if ($rsa_pub->verify($full, decode_base64($sig))) {
 210             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
 211                 my $ttime = hex($1);
 212
 213                 my $age = time() - $ttime;
 214
 215                 if (($age > -20) && ($age < 40)) {
 216                     return 1;
 217                 }
 218             }
 219         }
 220     }
 221
 222     die "permission denied - invalid vnc ticket\n" if !$noerr;
 223
 224     return undef;
 225 }
 226
 227
 228 sub authenticate_user_shadow {
 229     my ($userid, $password) = @_;
 230
 231     die "no password\n" if !$password;
 232
 233     my $shadow_cfg = cfs_read_file($shadowconfigfile);
 234
 235     if ($shadow_cfg->{users}->{$userid}) {
 236         my $encpw = crypt($password, $shadow_cfg->{users}->{$userid}->{shadow});
 237         die "invalid credentials\n" if ($encpw ne $shadow_cfg->{users}->{$userid}->{shadow});
 238     } else {
 239         die "no password set\n";
 240     }
 241 }
 242
 243 sub authenticate_user_pam {
 244     my ($userid, $password) = @_;
 245
 246     # user (www-data) need to be able to read /etc/passwd /etc/shadow
 247
 248     die "no password\n" if !$password;
 249
 250     my $pamh = new Authen::PAM ('common-auth', $userid, sub {
 251         my @res;
 252         while(@_) {
 253             my $msg_type = shift;
 254             my $msg = shift;
 255             push @res, (0, $password);
 256         }
 257         push @res, 0;
 258         return @res;
 259     });
 260
 261     if (!ref ($pamh)) {
 262         my $err = $pamh->pam_strerror($pamh);
 263         die "error during PAM init: $err";
 264     }
 265
 266     my $res;
 267
 268     if (($res = $pamh->pam_authenticate(0)) != PAM_SUCCESS) {
 269         my $err = $pamh->pam_strerror($res);
 270         die "$err\n";
 271     }
 272
 273     if (($res = $pamh->pam_acct_mgmt (0)) != PAM_SUCCESS) {
 274         my $err = $pamh->pam_strerror($res);
 275         die "$err\n";
 276     }
 277
 278     $pamh = 0; # call destructor
 279 }
 280
 281 sub authenticate_user_ad {
 282
 283     my ($entry, $server, $userid, $password) = @_;
 284
 285     my $default_port = $entry->{secure} ? 636: 389;
 286     my $port = $entry->{port} ? $entry->{port} : $default_port;
 287     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
 288     my $conn_string = "$scheme://${server}:$port";
 289
 290     my $ldap = Net::LDAP->new($server) || die "$@\n";
 291
 292     $userid = "$userid\@$entry->{domain}"
 293         if $userid !~ m/@/ && $entry->{domain};
 294
 295     my $res = $ldap->bind($userid, password => $password);
 296
 297     my $code = $res->code();
 298     my $err = $res->error;
 299
 300     $ldap->unbind();
 301
 302     die "$err\n" if ($code);
 303 }
 304
 305 sub authenticate_user_ldap {
 306
 307     my ($entry, $server, $userid, $password) = @_;
 308
 309     my $default_port = $entry->{secure} ? 636: 389;
 310     my $port = $entry->{port} ? $entry->{port} : $default_port;
 311     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
 312     my $conn_string = "$scheme://${server}:$port";
 313
 314     my $ldap = Net::LDAP->new($conn_string, verify => 'none') || die "$@\n";
 315     my $search = $entry->{user_attr} . "=" . $userid;
 316     my $result = $ldap->search( base    => "$entry->{base_dn}",
 317                                 scope   => "sub",
 318                                 filter  => "$search",
 319                                 attrs   => ['dn']
 320                                 );
 321     die "no entries returned\n" if !$result->entries;
 322     my @entries = $result->entries;
 323     my $res = $ldap->bind($entries[0]->dn, password => $password);
 324
 325     my $code = $res->code();
 326     my $err = $res->error;
 327
 328     $ldap->unbind();
 329
 330     die "$err\n" if ($code);
 331 }
 332
 333 sub authenticate_user_domain {
 334     my ($realm, $userid, $password) = @_;
 335
 336     my $domain_cfg = cfs_read_file($domainconfigfile);
 337
 338     die "no auth domain specified" if !$realm;
 339
 340     if ($realm eq 'pam') {
 341         authenticate_user_pam($userid, $password);
 342         return;
 343     }
 344
 345     eval {
 346         if ($realm eq 'pve') {
 347             authenticate_user_shadow($userid, $password);
 348         } else {
 349
 350             my $cfg = $domain_cfg->{$realm};
 351             die "auth domain '$realm' does not exists\n" if !$cfg;
 352
 353             if ($cfg->{type} eq 'ad') {
 354                 eval { authenticate_user_ad($cfg, $cfg->{server1}, $userid, $password); };
 355                 my $err = $@;
 356                 return if !$err;
 357                 die $err if !$cfg->{server2};
 358                 authenticate_user_ad($cfg, $cfg->{server2}, $userid, $password);
 359             } elsif ($cfg->{type} eq 'ldap') {
 360                 eval { authenticate_user_ldap($cfg, $cfg->{server1}, $userid, $password); };
 361                 my $err = $@;
 362                 return if !$err;
 363                 die $err if !$cfg->{server2};
 364                 authenticate_user_ldap($cfg, $cfg->{server2}, $userid, $password);
 365             } else {
 366                 die "unknown auth type '$cfg->{type}'\n";
 367             }
 368         }
 369     };
 370     if (my $err = $@) {
 371         sleep(2); # timeout after failed auth
 372         die $err;
 373     }
 374 }
 375
 376 sub check_user_exist {
 377     my ($usercfg, $username, $noerr) = @_;
 378
 379     $username = verify_username($username, $noerr);
 380     return undef if !$username;
 381
 382     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 383
 384     die "no such user ('$username')\n" if !$noerr;
 385
 386     return undef;
 387 }
 388
 389 sub check_user_enabled {
 390     my ($usercfg, $username, $noerr) = @_;
 391
 392     my $data = check_user_exist($usercfg, $username, $noerr);
 393     return undef if !$data;
 394
 395     return 1 if $data->{enable};
 396
 397     return 1 if $username eq 'root@pam'; # root is always enabled
 398
 399     die "user '$username' is disabled\n" if !$noerr;
 400
 401     return undef;
 402 }
 403
 404 # password should be utf8 encoded
 405 sub authenticate_user {
 406     my ($username, $password) = @_;
 407
 408     die "no username specified\n" if !$username;
 409
 410     my ($userid, $realm);
 411
 412     ($username, $userid, $realm) = verify_username($username);
 413
 414     my $usercfg = cfs_read_file('user.cfg');
 415
 416     eval { check_user_enabled($usercfg, $username); };
 417     if (my $err = $@) {
 418         sleep(2);
 419         die $err;
 420     }
 421
 422     my $ctime = time();
 423     my $expire = $usercfg->{users}->{$username}->{expire};
 424
 425     if ($expire && ($expire < $ctime)) {
 426         sleep(2);
 427         die "account expired\n"
 428     }
 429
 430     authenticate_user_domain($realm, $userid, $password);
 431
 432     return $username;
 433 }
 434
 435 sub delete_shadow_password {
 436     my ($userid) = @_;
 437
 438     lock_shadow_config(sub {
 439         my $shadow_cfg = cfs_read_file($shadowconfigfile);
 440         delete ($shadow_cfg->{users}->{$userid})
 441             if $shadow_cfg->{users}->{$userid};
 442         cfs_write_file($shadowconfigfile, $shadow_cfg);
 443     });
 444 }
 445
 446 sub store_shadow_password {
 447     my ($userid, $password) = @_;
 448
 449     lock_shadow_config(sub {
 450         my $shadow_cfg = cfs_read_file($shadowconfigfile);
 451         $shadow_cfg->{users}->{$userid}->{shadow} = encrypt_pw($password);
 452         cfs_write_file($shadowconfigfile, $shadow_cfg);
 453     });
 454 }
 455
 456 sub encrypt_pw {
 457     my ($pw) = @_;
 458
 459     my $time = substr (Digest::SHA::sha1_base64 (time), 0, 8);
 460     return crypt (encode("utf8", $pw), "\$5\$$time\$");
 461 }
 462
 463 sub store_pam_password {
 464     my ($userid, $password) = @_;
 465
 466     my $cmd = ['/usr/sbin/usermod'];
 467
 468     my $epw = encrypt_pw($password);
 469     push @$cmd, '-p', $epw;
 470
 471     push @$cmd, $userid;
 472
 473     run_command($cmd);
 474 }
 475
 476 sub domain_set_password {
 477     my ($realm, $userid, $password) = @_;
 478
 479     die "no auth domain specified" if !$realm;
 480
 481     if ($realm eq 'pam') {
 482         store_pam_password($userid, $password);
 483     } elsif ($realm eq 'pve') {
 484         store_shadow_password($userid, $password);
 485     } else {
 486         die "can't set password on auth domain '$realm'\n";
 487     }
 488 }
 489
 490 sub add_user_group {
 491
 492     my ($username, $usercfg, $group) = @_;
 493     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 494     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 495 }
 496
 497 sub delete_user_group {
 498
 499     my ($username, $usercfg) = @_;
 500
 501     foreach my $group (keys %{$usercfg->{groups}}) {
 502
 503         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 504             if $usercfg->{groups}->{$group}->{users}->{$username};
 505     }
 506 }
 507
 508 sub delete_user_acl {
 509
 510     my ($username, $usercfg) = @_;
 511
 512     foreach my $acl (keys %{$usercfg->{acl}}) {
 513
 514         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 515             if $usercfg->{acl}->{$acl}->{users}->{$username};
 516     }
 517 }
 518
 519 sub delete_group_acl {
 520
 521     my ($group, $usercfg) = @_;
 522
 523     foreach my $acl (keys %{$usercfg->{acl}}) {
 524
 525         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 526             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 527     }
 528 }
 529
 530 sub delete_pool_acl {
 531
 532     my ($pool, $usercfg) = @_;
 533
 534     my $path = "/pool/$pool";
 535
 536     foreach my $aclpath (keys %{$usercfg->{acl}}) {
 537         delete ($usercfg->{acl}->{$aclpath})
 538             if $usercfg->{acl}->{$aclpath} eq 'path';
 539     }
 540 }
 541
 542 # we automatically create some predefined roles by splitting privs
 543 # into 3 groups (per category)
 544 # root: only root is allowed to do that
 545 # admin: an administrator can to that
 546 # user: a normak user/customer can to that
 547 my $privgroups = {
 548     VM => {
 549         root => [],
 550         admin => [
 551             'VM.Modify',
 552             'VM.Allocate',
 553             'VM.Migrate',
 554         ],
 555         user => [
 556             'VM.Console',
 557             'VM.PowerMgmt',
 558         ],
 559         audit => [
 560             'VM.Audit'
 561         ],
 562     },
 563     Sys => {
 564         root => [
 565             'Sys.PowerMgmt',
 566             'Sys.Modify', # edit/change node settings
 567         ],
 568         admin => [
 569             'Permissions.Modify',
 570             'Sys.Console',
 571             'Sys.Syslog',
 572         ],
 573         user => [],
 574         audit => [
 575             'Sys.Audit',
 576         ],
 577     },
 578     Datastore => {
 579         root => [],
 580         admin => [
 581             'Datastore.Allocate',
 582         ],
 583         user => [
 584             'Datastore.AllocateSpace',
 585         ],
 586         audit => [
 587             'Datastore.Audit',
 588         ],
 589     },
 590     User => {
 591         root => [],
 592         admin => [
 593             'User.Modify',
 594             'User.Allocate',
 595         ],
 596         user => [],
 597         audit => [],
 598     },
 599 };
 600
 601 my $valid_privs = {};
 602
 603 my $special_roles = {
 604     'NoAccess' => {}, # no priviledges
 605     'Administrator' => $valid_privs, # all priviledges
 606 };
 607
 608 sub create_roles {
 609
 610     foreach my $cat (keys %$privgroups) {
 611         my $cd = $privgroups->{$cat};
 612         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 613                        @{$cd->{user}}, @{$cd->{audit}}) {
 614             $valid_privs->{$p} = 1;
 615         }
 616         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 617
 618             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 619             $special_roles->{"PVEAdmin"}->{$p} = 1;
 620         }
 621         if (scalar(@{$cd->{user}})) {
 622             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 623                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 624             }
 625         }
 626         foreach my $p (@{$cd->{audit}}) {
 627             $special_roles->{"PVEAuditor"}->{$p} = 1;
 628         }
 629     }
 630 };
 631
 632 create_roles();
 633
 634 my $valid_attributes = {
 635     ad => {
 636         server1 => '[\w\d]+(.[\w\d]+)*',
 637         server2 => '[\w\d]+(.[\w\d]+)*',
 638         domain => '\S+',
 639         port => '\d+',
 640         secure => '',
 641         comment => '.*',
 642     },
 643     ldap => {
 644         server1 => '[\w\d]+(.[\w\d]+)*',
 645         server2 => '[\w\d]+(.[\w\d]+)*',
 646         base_dn => '\w+=[\w\s]+(,\s*\w+=[\w\s]+)*',
 647         user_attr => '\S{2,}',
 648         secure => '',
 649         port => '\d+',
 650         comment => '.*',
 651     }
 652 };
 653
 654 sub add_role_privs {
 655     my ($role, $usercfg, $privs) = @_;
 656
 657     return if !$privs;
 658
 659     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 660
 661     foreach my $priv (split_list($privs)) {
 662         if (defined ($valid_privs->{$priv})) {
 663             $usercfg->{roles}->{$role}->{$priv} = 1;
 664         } else {
 665             die "invalid priviledge '$priv'\n";
 666         }
 667     }
 668 }
 669
 670 sub normalize_path {
 671     my $path = shift;
 672
 673     $path =~ s|/+|/|g;
 674
 675     $path =~ s|/$||;
 676
 677     $path = '/' if !$path;
 678
 679     $path = "/$path" if $path !~ m|^/|;
 680
 681     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
 682
 683     return $path;
 684 }
 685
 686 my $realm_regex = qr/[A-Za-z][A-Za-z0-9\.\-_]+/;
 687
 688 sub pve_verify_realm {
 689     my ($realm, $noerr) = @_;
 690
 691     if ($realm !~ m/^${realm_regex}$/) {
 692         return undef if $noerr;
 693         die "value does not look like a valid realm\n";
 694     }
 695     return $realm;
 696 }
 697
 698 PVE::JSONSchema::register_format('pve-userid', \&verify_username);
 699 sub verify_username {
 700     my ($username, $noerr) = @_;
 701
 702     $username = '' if !$username;
 703     my $len = length($username);
 704     if ($len < 3) {
 705         die "user name '$username' is too short\n" if !$noerr;
 706         return undef;
 707     }
 708     if ($len > 64) {
 709         die "user name '$username' is too long ($len > 64)\n" if !$noerr;
 710         return undef;
 711     }
 712
 713     # we only allow a limited set of characters (colon is not allowed,
 714     # because we store usernames in colon separated lists)!
 715     if ($username =~ m/^([^\s:]+)\@(${realm_regex})$/) {
 716         return wantarray ? ($username, $1, $2) : $username;
 717     }
 718
 719     die "value '$username' does not look like a valid user name\n" if !$noerr;
 720
 721     return undef;
 722 }
 723 PVE::JSONSchema::register_standard_option('userid', {
 724     description => "User ID",
 725     type => 'string', format => 'pve-userid',
 726     maxLength => 64,
 727 });
 728
 729 PVE::JSONSchema::register_standard_option('realm', {
 730     description => "Authentication domain ID",
 731     type => 'string', format => 'pve-configid',
 732     maxLength => 32,
 733 });
 734
 735 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 736 sub verify_groupname {
 737     my ($groupname, $noerr) = @_;
 738
 739     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 740
 741         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 742
 743         return undef;
 744     }
 745
 746     return $groupname;
 747 }
 748
 749 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 750 sub verify_rolename {
 751     my ($rolename, $noerr) = @_;
 752
 753     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 754
 755         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 756
 757         return undef;
 758     }
 759
 760     return $rolename;
 761 }
 762
 763 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
 764 sub verify_poolname {
 765     my ($poolname, $noerr) = @_;
 766
 767     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 768
 769         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 770
 771         return undef;
 772     }
 773
 774     return $poolname;
 775 }
 776
 777 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 778 sub verify_privname {
 779     my ($priv, $noerr) = @_;
 780
 781     if (!$valid_privs->{$priv}) {
 782         die "invalid priviledge '$priv'\n" if !$noerr;
 783
 784         return undef;
 785     }
 786
 787     return $priv;
 788 }
 789
 790 sub userconfig_force_defaults {
 791     my ($cfg) = @_;
 792
 793     foreach my $r (keys %$special_roles) {
 794         $cfg->{roles}->{$r} = $special_roles->{$r};
 795     }
 796
 797     # fixme: remove 'root' group (not required)?
 798
 799     # add root user
 800     $cfg->{users}->{'root@pam'}->{enable} = 1;
 801 }
 802
 803 sub parse_user_config {
 804     my ($filename, $raw) = @_;
 805
 806     my $cfg = {};
 807
 808     userconfig_force_defaults($cfg);
 809
 810     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
 811         my $line = $1;
 812
 813         next if $line =~ m/^\s*$/; # skip empty lines
 814
 815         my @data;
 816
 817         foreach my $d (split (/:/, $line)) {
 818             $d =~ s/^\s+//;
 819             $d =~ s/\s+$//;
 820             push @data, $d
 821         }
 822
 823         my $et = shift @data;
 824
 825         if ($et eq 'user') {
 826             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
 827
 828             my (undef, undef, $realm) = verify_username($user, 1);
 829             if (!$realm) {
 830                 warn "user config - ignore user '$user' - invalid user name\n";
 831                 next;
 832             }
 833
 834             $enable = $enable ? 1 : 0;
 835
 836             $expire = 0 if !$expire;
 837
 838             if ($expire !~ m/^\d+$/) {
 839                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 840                 next;
 841             }
 842             $expire = int($expire);
 843
 844             #if (!verify_groupname ($group, 1)) {
 845             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 846             #    next;
 847             #}
 848
 849             $cfg->{users}->{$user} = {
 850                 enable => $enable,
 851                 # group => $group,
 852             };
 853             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 854             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 855             $cfg->{users}->{$user}->{email} = $email;
 856             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 857             $cfg->{users}->{$user}->{expire} = $expire;
 858
 859             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 860             #$cfg->{groups}->{$group}->{$user} = 1;
 861
 862         } elsif ($et eq 'group') {
 863             my ($group, $userlist, $comment) = @data;
 864
 865             if (!verify_groupname($group, 1)) {
 866                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 867                 next;
 868             }
 869
 870             # make sure to add the group (even if there are no members)
 871             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 872
 873             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 874
 875             foreach my $user (split_list($userlist)) {
 876
 877                 if (!verify_username($user, 1)) {
 878                     warn "user config - ignore invalid group member '$user'\n";
 879                     next;
 880                 }
 881
 882                 if ($cfg->{users}->{$user}) { # user exists
 883                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
 884                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
 885                 } else {
 886                     warn "user config - ignore invalid group member '$user'\n";
 887                 }
 888             }
 889
 890         } elsif ($et eq 'role') {
 891             my ($role, $privlist) = @data;
 892
 893             if (!verify_rolename($role, 1)) {
 894                 warn "user config - ignore role '$role' - invalid characters in role name\n";
 895                 next;
 896             }
 897
 898             # make sure to add the role (even if there are no privileges)
 899             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
 900
 901             foreach my $priv (split_list($privlist)) {
 902                 if (defined ($valid_privs->{$priv})) {
 903                     $cfg->{roles}->{$role}->{$priv} = 1;
 904                 } else {
 905                     warn "user config - ignore invalid priviledge '$priv'\n";
 906                 }
 907             }
 908
 909         } elsif ($et eq 'acl') {
 910             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
 911
 912             if (my $path = normalize_path($pathtxt)) {
 913                 foreach my $role (split_list($rolelist)) {
 914
 915                     if (!verify_rolename($role, 1)) {
 916                         warn "user config - ignore invalid role name '$role' in acl\n";
 917                         next;
 918                     }
 919
 920                     foreach my $ug (split_list($uglist)) {
 921                         if ($ug =~ m/^@(\w+)$/) {
 922                             my $group = $1;
 923                             if ($cfg->{groups}->{$group}) { # group exists
 924                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
 925                             } else {
 926                                 warn "user config - ignore invalid acl group '$group'\n";
 927                             }
 928                         } elsif (verify_username($ug, 1)) {
 929                             if ($cfg->{users}->{$ug}) { # user exists
 930                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
 931                             } else {
 932                                 warn "user config - ignore invalid acl member '$ug'\n";
 933                             }
 934                         } else {
 935                             warn "user config - invalid user/group '$ug' in acl\n";
 936                         }
 937                     }
 938                 }
 939             } else {
 940                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
 941             }
 942         } elsif ($et eq 'pool') {
 943             my ($pool, $comment, $vmlist, $storelist) = @data;
 944
 945             if (!verify_poolname($pool, 1)) {
 946                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
 947                 next;
 948             }
 949
 950             # make sure to add the pool (even if there are no members)
 951             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
 952
 953             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 954
 955             foreach my $vmid (split_list($vmlist)) {
 956                 if ($vmid !~ m/^\d+$/) {
 957                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
 958                     next;
 959                 }
 960                 $vmid = int($vmid);
 961
 962                 if ($cfg->{vms}->{$vmid}) {
 963                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
 964                     next;
 965                 }
 966
 967                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
 968
 969                 # record vmid ==> pool relation
 970                 $cfg->{vms}->{$vmid} = $pool;
 971             }
 972
 973             foreach my $storeid (split_list($storelist)) {
 974                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 975                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
 976                     next;
 977                 }
 978                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
 979             }
 980         } else {
 981             warn "user config - ignore config line: $line\n";
 982         }
 983     }
 984
 985     userconfig_force_defaults($cfg);
 986
 987     return $cfg;
 988 }
 989
 990 sub parse_shadow_passwd {
 991     my ($filename, $raw) = @_;
 992
 993     my $shadow = {};
 994
 995     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
 996         my $line = $1;
 997
 998         next if $line =~ m/^\s*$/; # skip empty lines
 999
1000         if ($line !~ m/^\S+:\S+:$/) {
1001             warn "pve shadow password: ignore invalid line $.\n";
1002             next;
1003         }
1004
1005         my ($userid, $crypt_pass) = split (/:/, $line);
1006         $shadow->{users}->{$userid}->{shadow} = $crypt_pass;
1007     }
1008
1009     return $shadow;
1010 }
1011
1012 sub write_domains {
1013     my ($filename, $cfg) = @_;
1014
1015     my $data = '';
1016
1017     my $wrote_default;
1018
1019     foreach my $realm (sort keys %$cfg) {
1020         my $entry = $cfg->{$realm};
1021         my $type = lc($entry->{type});
1022
1023         next if !$type;
1024
1025         next if ($type eq 'pam') || ($type eq 'pve');
1026
1027         my $formats = $valid_attributes->{$type};
1028         next if !$formats;
1029
1030         $data .= "$type: $realm\n";
1031
1032         foreach my $k (sort keys %$entry) {
1033             next if $k eq 'type';
1034             my $v = $entry->{$k};
1035             if ($k eq 'default') {
1036                     $data .= "\t$k\n" if $v && !$wrote_default;
1037                     $wrote_default = 1;
1038             } elsif (defined($formats->{$k})) {
1039                 if (!$formats->{$k}) {
1040                     $data .= "\t$k\n" if $v;
1041                 } elsif ($v =~ m/^$formats->{$k}$/) {
1042                     $v = PVE::Tools::encode_text($v) if $k eq 'comment';
1043                     $data .= "\t$k $v\n";
1044                 } else {
1045                     die "invalid value '$v' for attribute '$k'\n";
1046                 }
1047             } else {
1048                 die "invalid attribute '$k' - not supported\n";
1049             }
1050         }
1051
1052         $data .= "\n";
1053     }
1054
1055     return $data;
1056 }
1057
1058 sub parse_domains {
1059     my ($filename, $raw) = @_;
1060
1061     my $cfg = {};
1062
1063     my $default;
1064
1065     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1066         my $line = $1;
1067
1068         next if $line =~ m/^\#/; # skip comment lines
1069         next if $line =~ m/^\s*$/; # skip empty lines
1070
1071         if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
1072             my $realm = $2;
1073             my $type = lc($1);
1074
1075             my $ignore = 0;
1076             my $entry;
1077
1078             my $formats = $valid_attributes->{$type};
1079             if (!$formats) {
1080                 $ignore = 1;
1081                 warn "ignoring domain '$realm' - (unsupported authentication type '$type')\n";
1082             } elsif (!pve_verify_realm($realm, 1)) {
1083                 $ignore = 1;
1084                 warn "ignoring domain '$realm' - (illegal characters)\n";
1085             } else {
1086                 $entry = { type => $type };
1087             }
1088
1089             while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1090                 $line = $1;
1091
1092                 next if $line =~ m/^\#/; #skip comment lines
1093                 last if $line =~ m/^\s*$/;
1094
1095                 next if $ignore; # skip
1096
1097                 if ($line =~ m/^\s+(default)\s*$/) {
1098                     $default = $realm if !$default;
1099                 } elsif ($line =~ m/^\s+(\S+)(\s+(.*\S))?\s*$/) {
1100                     my ($k, $v) = (lc($1), $3);
1101                     if (defined($formats->{$k})) {
1102                         if (!$formats->{$k} && !defined($v)) {
1103                                 $entry->{$k} = 1;
1104                         } elsif ($formats->{$k} && $v =~ m/^$formats->{$k}$/) {
1105                             if (!defined($entry->{$k})) {
1106                                 $v = PVE::Tools::decode_text($v) if $k eq 'comment';
1107                                 $entry->{$k} = $v;
1108                             } else {
1109                                 warn "ignoring duplicate attribute '$k $v'\n";
1110                             }
1111                         } else {
1112                             warn "ignoring value '$v' for attribute '$k' - invalid format\n";
1113                         }
1114                     } else {
1115                         warn "ignoring attribute '$k' - not supported\n";
1116                     }
1117                 } else {
1118                     warn "ignore config line: $line\n";
1119                 }
1120             }
1121
1122             if ($entry->{server2} && !$entry->{server1}) {
1123                 $entry->{server1} = $entry->{server2};
1124                 delete $entry->{server2};
1125             }
1126
1127             if ($ignore) {
1128                 # do nothing
1129             } elsif (!$entry->{server1}) {
1130                 warn "ignoring domain '$realm' - missing server attribute\n";
1131             } elsif (($entry->{type} eq "ldap") && !$entry->{user_attr}) {
1132                 warn "ignoring domain '$realm' - missing user attribute\n";
1133             } elsif (($entry->{type} eq "ldap") && !$entry->{base_dn}) {
1134                 warn "ignoring domain '$realm' - missing base_dn attribute\n";
1135             } elsif (($entry->{type} eq "ad") && !$entry->{domain}) {
1136                 warn "ignoring domain '$realm' - missing domain attribute\n";
1137             } else {
1138                 $cfg->{$realm} = $entry;
1139             }
1140
1141         } else {
1142             warn "ignore config line: $line\n";
1143         }
1144     }
1145
1146     $cfg->{$default}->{default} = 1 if $default;
1147
1148     # add default domains
1149
1150     $cfg->{pve} = {
1151         type => 'builtin',
1152         comment => "Proxmox VE authentication server",
1153     };
1154
1155     $cfg->{pam} = {
1156         type => 'builtin',
1157         comment => "Linux PAM standard authentication",
1158     };
1159
1160     return $cfg;
1161 }
1162
1163 sub write_shadow_config {
1164     my ($filename, $cfg) = @_;
1165
1166     my $data = '';
1167     foreach my $userid (keys %{$cfg->{users}}) {
1168         my $crypt_pass = $cfg->{users}->{$userid}->{shadow};
1169         $data .= "$userid:$crypt_pass:\n";
1170     }
1171
1172     return $data
1173 }
1174
1175 sub write_user_config {
1176     my ($filename, $cfg) = @_;
1177
1178     my $data = '';
1179
1180     foreach my $user (keys %{$cfg->{users}}) {
1181         my $d = $cfg->{users}->{$user};
1182         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1183         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1184         my $email = $d->{email} || '';
1185         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1186         my $expire = int($d->{expire} || 0);
1187         my $enable = $d->{enable} ? 1 : 0;
1188         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
1189     }
1190
1191     $data .= "\n";
1192
1193     foreach my $group (keys %{$cfg->{groups}}) {
1194         my $d = $cfg->{groups}->{$group};
1195         my $list = join (',', keys %{$d->{users}});
1196         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1197         $data .= "group:$group:$list:$comment:\n";
1198     }
1199
1200     $data .= "\n";
1201
1202     foreach my $pool (keys %{$cfg->{pools}}) {
1203         my $d = $cfg->{pools}->{$pool};
1204         my $vmlist = join (',', keys %{$d->{vms}});
1205         my $storelist = join (',', keys %{$d->{storage}});
1206         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1207         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1208     }
1209
1210     $data .= "\n";
1211
1212     foreach my $role (keys %{$cfg->{roles}}) {
1213         next if $special_roles->{$role};
1214
1215         my $d = $cfg->{roles}->{$role};
1216         my $list = join (',', keys %$d);
1217         $data .= "role:$role:$list:\n";
1218     }
1219
1220     $data .= "\n";
1221
1222     foreach my $path (sort keys %{$cfg->{acl}}) {
1223         my $d = $cfg->{acl}->{$path};
1224
1225         my $ra = {};
1226
1227         foreach my $group (keys %{$d->{groups}}) {
1228             my $l0 = '';
1229             my $l1 = '';
1230             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
1231                 my $propagate = $d->{groups}->{$group}->{$role};
1232                 if ($propagate) {
1233                     $l1 .= ',' if $l1;
1234                     $l1 .= $role;
1235                 } else {
1236                     $l0 .= ',' if $l0;
1237                     $l0 .= $role;
1238                 }
1239             }
1240             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
1241             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
1242         }
1243
1244         foreach my $user (keys %{$d->{users}}) {
1245             # no need to save, because root is always 'Administartor'
1246             next if $user eq 'root@pam';
1247
1248             my $l0 = '';
1249             my $l1 = '';
1250             foreach my $role (sort keys %{$d->{users}->{$user}}) {
1251                 my $propagate = $d->{users}->{$user}->{$role};
1252                 if ($propagate) {
1253                     $l1 .= ',' if $l1;
1254                     $l1 .= $role;
1255                 } else {
1256                     $l0 .= ',' if $l0;
1257                     $l0 .= $role;
1258                 }
1259             }
1260             $ra->{0}->{$l0}->{$user} = 1 if $l0;
1261             $ra->{1}->{$l1}->{$user} = 1 if $l1;
1262         }
1263
1264         foreach my $rolelist (sort keys %{$ra->{0}}) {
1265             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
1266             $data .= "acl:0:$path:$uglist:$rolelist:\n";
1267         }
1268         foreach my $rolelist (sort keys %{$ra->{1}}) {
1269             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
1270             $data .= "acl:1:$path:$uglist:$rolelist:\n";
1271         }
1272     }
1273
1274     return $data;
1275 }
1276
1277 sub roles {
1278     my ($cfg, $user, $path) = @_;
1279
1280     # NOTE: we do not consider pools here.
1281     # You need to use $rpcenv->roles() instead if you want that.
1282
1283     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1284
1285     my $perm = {};
1286
1287     foreach my $p (sort keys %{$cfg->{acl}}) {
1288         my $final = ($path eq $p);
1289
1290         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1291
1292         my $acl = $cfg->{acl}->{$p};
1293
1294         #print "CHECKACL $path $p\n";
1295         #print "ACL $path = " . Dumper ($acl);
1296
1297         if (my $ri = $acl->{users}->{$user}) {
1298             my $new;
1299             foreach my $role (keys %$ri) {
1300                 my $propagate = $ri->{$role};
1301                 if ($final || $propagate) {
1302                     #print "APPLY ROLE $p $user $role\n";
1303                     $new = {} if !$new;
1304                     $new->{$role} = 1;
1305                 }
1306             }
1307             if ($new) {
1308                 $perm = $new; # overwrite previous settings
1309                 next; # user privs always override group privs
1310             }
1311         }
1312
1313         my $new;
1314         foreach my $g (keys %{$acl->{groups}}) {
1315             next if !$cfg->{groups}->{$g}->{users}->{$user};
1316             if (my $ri = $acl->{groups}->{$g}) {
1317                 foreach my $role (keys %$ri) {
1318                     my $propagate = $ri->{$role};
1319                     if ($final || $propagate) {
1320                         #print "APPLY ROLE $p \@$g $role\n";
1321                         $new = {} if !$new;
1322                         $new->{$role} = 1;
1323                     }
1324                 }
1325             }
1326         }
1327         if ($new) {
1328             $perm = $new; # overwrite previous settings
1329             next;
1330         }
1331     }
1332
1333     return ('NoAccess') if defined ($perm->{NoAccess});
1334     #return () if defined ($perm->{NoAccess});
1335
1336     #print "permission $user $path = " . Dumper ($perm);
1337
1338     my @ra = keys %$perm;
1339
1340     #print "roles $user $path = " . join (',', @ra) . "\n";
1341
1342     return @ra;
1343 }
1344
1345 sub permission {
1346     my ($cfg, $user, $path) = @_;
1347
1348     $user = verify_username($user, 1);
1349     return {} if !$user;
1350
1351     my @ra = roles($cfg, $user, $path);
1352
1353     my $privs = {};
1354
1355     foreach my $role (@ra) {
1356         if (my $privset = $cfg->{roles}->{$role}) {
1357             foreach my $p (keys %$privset) {
1358                 $privs->{$p} = 1;
1359             }
1360         }
1361     }
1362
1363     #print "priviledges $user $path = " . Dumper ($privs);
1364
1365     return $privs;
1366 }
1367
1368 sub check_permissions {
1369     my ($username, $path, $privlist) = @_;
1370
1371     $path = normalize_path($path);
1372     my $usercfg = cfs_read_file('user.cfg');
1373     my $perm = permission($usercfg, $username, $path);
1374
1375     foreach my $priv (split_list($privlist)) {
1376         return undef if !$perm->{$priv};
1377     };
1378
1379     return 1;
1380 }
1381
1382 1;