new plugin architecture for Auth modules
[pve-access-control.git] / PVE / AccessControl.pm
1 package PVE::AccessControl;
2
3 use strict;
4 use Encode;
5 use Crypt::OpenSSL::Random;
6 use Crypt::OpenSSL::RSA;
7 use MIME::Base64;
8 use Digest::SHA;
9 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
10 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
11 use PVE::JSONSchema;
12
13 use PVE::Auth::Plugin;
14 use PVE::Auth::AD;
15 use PVE::Auth::LDAP;
16 use PVE::Auth::PVE;
17 use PVE::Auth::PAM;
18
19 use Data::Dumper; # fixme: remove
20
21 # load and initialize all plugins
22
23 PVE::Auth::AD->register();
24 PVE::Auth::LDAP->register();
25 PVE::Auth::PVE->register();
26 PVE::Auth::PAM->register();
27 PVE::Auth::Plugin->init();
28
29 # $authdir must be writable by root only!
30 my $confdir = "/etc/pve";
31 my $authdir = "$confdir/priv";
32 my $authprivkeyfn = "$authdir/authkey.key";
33 my $authpubkeyfn = "$confdir/authkey.pub";
34 my $pve_www_key_fn = "$confdir/pve-www.key";
35
36 my $ticket_lifetime = 3600*2; # 2 hours
37
38 Crypt::OpenSSL::RSA->import_random_seed();
39
40 cfs_register_file('user.cfg', 
41                   \&parse_user_config,  
42                   \&write_user_config);
43
44
45 sub verify_username {
46     PVE::Auth::Plugin::verify_username(@_);
47 }
48
49 sub pve_verify_realm {
50     PVE::Auth::Plugin::pve_verify_realm(@_);
51 }
52
53 sub lock_user_config {
54     my ($code, $errmsg) = @_;
55
56     cfs_lock_file("user.cfg", undef, $code);
57     if (my $err = $@) {
58         $errmsg ? die "$errmsg: $err" : die $err;
59     }
60 }
61
62 my $pve_auth_pub_key;
63 sub get_pubkey {    
64
65     return $pve_auth_pub_key if $pve_auth_pub_key;
66
67     my $input = PVE::Tools::file_get_contents($authpubkeyfn); 
68
69     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
70
71     return $pve_auth_pub_key;
72 }
73
74 my $csrf_prevention_secret;
75 my $get_csrfr_secret = sub {
76     if (!$csrf_prevention_secret) {
77         my $input = PVE::Tools::file_get_contents($pve_www_key_fn); 
78         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
79     }
80     return $csrf_prevention_secret;
81 };
82
83 sub assemble_csrf_prevention_token {
84     my ($username) = @_;
85
86     my $timestamp = sprintf("%08X", time());
87
88     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
89
90     return "$timestamp:$digest"; 
91 }
92
93 sub verify_csrf_prevention_token {
94     my ($username, $token, $noerr) = @_;
95
96     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
97         my $sig = $2;
98         my $timestamp = $1;
99         my $ttime = hex($timestamp);
100
101         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
102
103         my $age = time() - $ttime;
104         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
105     }
106
107     die "Permission denied - invalid csrf token\n" if !$noerr;
108
109     return undef;
110 }
111
112 my $pve_auth_priv_key;
113 sub get_privkey {
114
115     return $pve_auth_priv_key if $pve_auth_priv_key;
116
117     my $input = PVE::Tools::file_get_contents($authprivkeyfn); 
118
119     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
120
121     return $pve_auth_priv_key;
122 }
123
124 sub assemble_ticket {
125     my ($username) = @_;
126
127     my $rsa_priv = get_privkey();
128
129     my $timestamp = sprintf("%08X", time());
130
131     my $plain = "PVE:$username:$timestamp";
132
133     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
134
135     return $ticket;
136 }
137
138 sub verify_ticket {
139     my ($ticket, $noerr) = @_;
140
141     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
142         my $plain = $1;
143         my $sig = $2;
144
145         my $rsa_pub = get_pubkey();
146         if ($rsa_pub->verify($plain, decode_base64($sig))) {
147             if ($plain =~ m/^PVE:(\S+):([A-Z0-9]{8})$/) {
148                 my $username = $1;
149                 my $timestamp = $2;
150                 my $ttime = hex($timestamp);
151
152                 my $age = time() - $ttime;
153
154                 if (PVE::Auth::Plugin::verify_username($username, 1) &&
155                     ($age > -300) && ($age < $ticket_lifetime)) {
156                     return wantarray ? ($username, $age) : $username;
157                 }
158             }
159         }
160     }
161
162     die "permission denied - invalid ticket\n" if !$noerr;
163
164     return undef;
165 }
166
167 # VNC tickets
168 # - they do not contain the username in plain text
169 # - they are restricted to a specific resource path (example: '/vms/100')
170 sub assemble_vnc_ticket {
171     my ($username, $path) = @_;
172
173     my $rsa_priv = get_privkey();
174
175     my $timestamp = sprintf("%08X", time());
176
177     my $plain = "PVEVNC:$timestamp";
178
179     $path = normalize_path($path);
180
181     my $full = "$plain:$username:$path";
182
183     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
184
185     return $ticket;
186 }
187
188 sub verify_vnc_ticket {
189     my ($ticket, $username, $path, $noerr) = @_;
190
191     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
192         my $plain = $1;
193         my $sig = $2;
194         my $full = "$plain:$username:$path";
195
196         my $rsa_pub = get_pubkey();
197         # Note: sign only match if $username and  $path is correct
198         if ($rsa_pub->verify($full, decode_base64($sig))) {
199             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
200                 my $ttime = hex($1);
201
202                 my $age = time() - $ttime;
203
204                 if (($age > -20) && ($age < 40)) {
205                     return 1;
206                 }
207             }
208         }
209     }
210
211     die "permission denied - invalid vnc ticket\n" if !$noerr;
212
213     return undef;
214 }
215
216 sub check_user_exist {
217     my ($usercfg, $username, $noerr) = @_;
218
219     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
220     return undef if !$username;
221  
222     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
223
224     die "no such user ('$username')\n" if !$noerr;
225  
226     return undef;
227 }
228
229 sub check_user_enabled {
230     my ($usercfg, $username, $noerr) = @_;
231
232     my $data = check_user_exist($usercfg, $username, $noerr);
233     return undef if !$data;
234
235     return 1 if $data->{enable};
236
237     return 1 if $username eq 'root@pam'; # root is always enabled
238
239     die "user '$username' is disabled\n" if !$noerr;
240  
241     return undef;
242 }
243
244 # password should be utf8 encoded
245 sub authenticate_user {
246     my ($username, $password) = @_;
247
248     die "no username specified\n" if !$username;
249  
250     my ($ruid, $realm);
251
252     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
253
254     my $usercfg = cfs_read_file('user.cfg');
255
256     eval { check_user_enabled($usercfg, $username); };
257     if (my $err = $@) {
258         sleep(2);
259         die $err;
260     }
261
262     my $ctime = time();
263     my $expire = $usercfg->{users}->{$username}->{expire};
264
265     if ($expire && ($expire < $ctime)) {
266         sleep(2);
267         die "account expired\n"
268     }
269
270     my $domain_cfg = cfs_read_file('domains.cfg');
271
272     eval {
273         my $cfg = $domain_cfg->{ids}->{$realm};
274         die "auth domain '$realm' does not exists\n" if !$cfg;
275         my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
276         $plugin->authenticate_user($cfg, $realm, $ruid, $password);
277     };
278     if (my $err = $@) {
279         sleep(2); # timeout after failed auth
280         die $err;
281     }
282
283     return $username;
284 }
285
286 sub domain_set_password {
287     my ($realm, $username, $password) = @_;
288
289     die "no auth domain specified" if !$realm;
290
291     my $domain_cfg = cfs_read_file('domains.cfg');
292
293     my $cfg = $domain_cfg->{ids}->{$realm};
294     die "auth domain '$realm' does not exists\n" if !$cfg;
295     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
296     $plugin->store_password($cfg, $realm, $username, $password);
297 }
298
299 sub add_user_group {
300
301     my ($username, $usercfg, $group) = @_;
302     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
303     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
304 }
305
306 sub delete_user_group {
307
308     my ($username, $usercfg) = @_;
309     
310     foreach my $group (keys %{$usercfg->{groups}}) {
311
312         delete ($usercfg->{groups}->{$group}->{users}->{$username}) 
313             if $usercfg->{groups}->{$group}->{users}->{$username};
314     }
315 }
316
317 sub delete_user_acl {
318
319     my ($username, $usercfg) = @_;
320
321     foreach my $acl (keys %{$usercfg->{acl}}) {
322
323         delete ($usercfg->{acl}->{$acl}->{users}->{$username}) 
324             if $usercfg->{acl}->{$acl}->{users}->{$username};
325     }
326 }
327
328 sub delete_group_acl {
329
330     my ($group, $usercfg) = @_;
331
332     foreach my $acl (keys %{$usercfg->{acl}}) {
333
334         delete ($usercfg->{acl}->{$acl}->{groups}->{$group}) 
335             if $usercfg->{acl}->{$acl}->{groups}->{$group};
336     }
337 }
338
339 sub delete_pool_acl {
340
341     my ($pool, $usercfg) = @_;
342
343     my $path = "/pool/$pool";
344
345     foreach my $aclpath (keys %{$usercfg->{acl}}) {
346         delete ($usercfg->{acl}->{$aclpath})
347             if $usercfg->{acl}->{$aclpath} eq 'path';
348     }
349 }
350
351 # we automatically create some predefined roles by splitting privs
352 # into 3 groups (per category)
353 # root: only root is allowed to do that
354 # admin: an administrator can to that
355 # user: a normak user/customer can to that
356 my $privgroups = {
357     VM => {
358         root => [],
359         admin => [           
360             'VM.Config.Disk', 
361             'VM.Config.CPU', 
362             'VM.Config.Memory', 
363             'VM.Config.Network', 
364             'VM.Config.HWType',
365             'VM.Config.Options', # covers all other things 
366             'VM.Allocate', 
367             'VM.Migrate',
368             'VM.Monitor', 
369         ],
370         user => [
371             'VM.Config.CDROM', # change CDROM media
372             'VM.Console', 
373             'VM.Backup',
374             'VM.PowerMgmt',
375         ],
376         audit => [ 
377             'VM.Audit',
378         ],
379     },
380     Sys => {
381         root => [
382             'Sys.PowerMgmt',     
383             'Sys.Modify', # edit/change node settings
384         ],
385         admin => [
386             'Permissions.Modify',
387             'Sys.Console',    
388             'Sys.Syslog',
389         ],
390         user => [],
391         audit => [
392             'Sys.Audit',
393         ],
394     },
395     Datastore => {
396         root => [],
397         admin => [
398             'Datastore.Allocate',
399             'Datastore.AllocateTemplate',
400         ],
401         user => [
402             'Datastore.AllocateSpace',
403         ],
404         audit => [
405             'Datastore.Audit',
406         ],
407     },
408     User => {
409         root => [
410             'Realm.Allocate',
411         ],
412         admin => [
413             'User.Modify',
414             'Group.Allocate', # edit/change group settings
415             'Realm.AllocateUser', 
416         ],
417         user => [],
418         audit => [],
419     },
420     Pool => {
421         root => [],
422         admin => [
423             'Pool.Allocate', # create/delete pools
424         ],
425         user => [],
426         audit => [],
427     },
428 };
429
430 my $valid_privs = {};
431
432 my $special_roles = {
433     'NoAccess' => {}, # no priviledges
434     'Administrator' => $valid_privs, # all priviledges
435 };
436
437 sub create_roles {
438
439     foreach my $cat (keys %$privgroups) {
440         my $cd = $privgroups->{$cat};
441         foreach my $p (@{$cd->{root}}, @{$cd->{admin}}, 
442                        @{$cd->{user}}, @{$cd->{audit}}) {
443             $valid_privs->{$p} = 1;
444         }
445         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
446
447             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
448             $special_roles->{"PVEAdmin"}->{$p} = 1;
449         }
450         if (scalar(@{$cd->{user}})) {
451             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
452                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
453             }
454         }
455         foreach my $p (@{$cd->{audit}}) {
456             $special_roles->{"PVEAuditor"}->{$p} = 1;
457         }
458     }
459 };
460
461 create_roles();
462
463 sub add_role_privs {
464     my ($role, $usercfg, $privs) = @_;
465
466     return if !$privs;
467
468     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
469
470     foreach my $priv (split_list($privs)) {
471         if (defined ($valid_privs->{$priv})) {
472             $usercfg->{roles}->{$role}->{$priv} = 1;
473         } else {
474             die "invalid priviledge '$priv'\n";
475         } 
476     }   
477 }
478
479 sub normalize_path {
480     my $path = shift;
481
482     $path =~ s|/+|/|g;
483
484     $path =~ s|/$||;
485
486     $path = '/' if !$path;
487
488     $path = "/$path" if $path !~ m|^/|;
489
490     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
491
492     return $path;
493
494
495
496 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
497 sub verify_groupname {
498     my ($groupname, $noerr) = @_;
499
500     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
501
502         die "group name '$groupname' contains invalid characters\n" if !$noerr;
503
504         return undef;
505     }
506     
507     return $groupname;
508 }
509
510 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
511 sub verify_rolename {
512     my ($rolename, $noerr) = @_;
513
514     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
515
516         die "role name '$rolename' contains invalid characters\n" if !$noerr;
517
518         return undef;
519     }
520     
521     return $rolename;
522 }
523
524 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
525 sub verify_poolname {
526     my ($poolname, $noerr) = @_;
527
528     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
529
530         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
531
532         return undef;
533     }
534     
535     return $poolname;
536 }
537
538 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
539 sub verify_privname {
540     my ($priv, $noerr) = @_;
541
542     if (!$valid_privs->{$priv}) {
543         die "invalid priviledge '$priv'\n" if !$noerr;
544
545         return undef;
546     }
547     
548     return $priv;
549 }
550
551 sub userconfig_force_defaults {
552     my ($cfg) = @_;
553
554     foreach my $r (keys %$special_roles) {
555         $cfg->{roles}->{$r} = $special_roles->{$r};
556     }
557
558     # fixme: remove 'root' group (not required)?
559
560     # add root user 
561     $cfg->{users}->{'root@pam'}->{enable} = 1;
562 }
563
564 sub parse_user_config {
565     my ($filename, $raw) = @_;
566
567     my $cfg = {};
568
569     userconfig_force_defaults($cfg);
570
571     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
572         my $line = $1;
573
574         next if $line =~ m/^\s*$/; # skip empty lines
575
576         my @data;
577
578         foreach my $d (split (/:/, $line)) {
579             $d =~ s/^\s+//; 
580             $d =~ s/\s+$//;
581             push @data, $d
582         }
583
584         my $et = shift @data;
585
586         if ($et eq 'user') {
587             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
588
589             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
590             if (!$realm) {
591                 warn "user config - ignore user '$user' - invalid user name\n";
592                 next;
593             }
594
595             $enable = $enable ? 1 : 0;
596
597             $expire = 0 if !$expire;
598
599             if ($expire !~ m/^\d+$/) {
600                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
601                 next;
602             }
603             $expire = int($expire);
604
605             #if (!verify_groupname ($group, 1)) {
606             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
607             #    next;
608             #}
609
610             $cfg->{users}->{$user} = {
611                 enable => $enable,
612                 # group => $group,
613             };
614             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
615             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
616             $cfg->{users}->{$user}->{email} = $email;
617             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
618             $cfg->{users}->{$user}->{expire} = $expire;
619
620             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
621             #$cfg->{groups}->{$group}->{$user} = 1;
622
623         } elsif ($et eq 'group') {
624             my ($group, $userlist, $comment) = @data;
625
626             if (!verify_groupname($group, 1)) {
627                 warn "user config - ignore group '$group' - invalid characters in group name\n";
628                 next;
629             }
630
631             # make sure to add the group (even if there are no members)
632             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
633
634             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
635
636             foreach my $user (split_list($userlist)) {
637
638                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
639                     warn "user config - ignore invalid group member '$user'\n";
640                     next;
641                 }
642
643                 if ($cfg->{users}->{$user}) { # user exists 
644                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
645                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
646                 } else {
647                     warn "user config - ignore invalid group member '$user'\n";
648                 }
649             }
650
651         } elsif ($et eq 'role') {
652             my ($role, $privlist) = @data;
653                 
654             if (!verify_rolename($role, 1)) {
655                 warn "user config - ignore role '$role' - invalid characters in role name\n";
656                 next;
657             }
658
659             # make sure to add the role (even if there are no privileges)
660             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
661
662             foreach my $priv (split_list($privlist)) {
663                 if (defined ($valid_privs->{$priv})) {
664                     $cfg->{roles}->{$role}->{$priv} = 1;
665                 } else {
666                     warn "user config - ignore invalid priviledge '$priv'\n";
667                 } 
668             }
669             
670         } elsif ($et eq 'acl') {
671             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
672
673             if (my $path = normalize_path($pathtxt)) {
674                 foreach my $role (split_list($rolelist)) {
675                         
676                     if (!verify_rolename($role, 1)) {
677                         warn "user config - ignore invalid role name '$role' in acl\n";
678                         next;
679                     }
680
681                     foreach my $ug (split_list($uglist)) {
682                         if ($ug =~ m/^@(\S+)$/) {
683                             my $group = $1;
684                             if ($cfg->{groups}->{$group}) { # group exists 
685                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
686                             } else {
687                                 warn "user config - ignore invalid acl group '$group'\n";
688                             }
689                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
690                             if ($cfg->{users}->{$ug}) { # user exists 
691                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
692                             } else {
693                                 warn "user config - ignore invalid acl member '$ug'\n";
694                             }
695                         } else {
696                             warn "user config - invalid user/group '$ug' in acl\n";
697                         }
698                     }
699                 }
700             } else {
701                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
702             }
703         } elsif ($et eq 'pool') {
704             my ($pool, $comment, $vmlist, $storelist) = @data;
705
706             if (!verify_poolname($pool, 1)) {
707                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
708                 next;
709             }
710
711             # make sure to add the pool (even if there are no members)
712             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
713
714             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
715
716             foreach my $vmid (split_list($vmlist)) {
717                 if ($vmid !~ m/^\d+$/) {
718                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
719                     next;
720                 }
721                 $vmid = int($vmid);
722
723                 if ($cfg->{vms}->{$vmid}) {
724                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
725                     next;
726                 }
727
728                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
729                     
730                 # record vmid ==> pool relation
731                 $cfg->{vms}->{$vmid} = $pool;
732             }
733
734             foreach my $storeid (split_list($storelist)) {
735                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
736                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
737                     next;
738                 }
739                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
740             }
741         } else {
742             warn "user config - ignore config line: $line\n";
743         }
744     }
745
746     userconfig_force_defaults($cfg);
747
748     return $cfg;
749 }
750
751 sub write_user_config {
752     my ($filename, $cfg) = @_;
753
754     my $data = '';
755
756     foreach my $user (keys %{$cfg->{users}}) {
757         my $d = $cfg->{users}->{$user};
758         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
759         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
760         my $email = $d->{email} || '';
761         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
762         my $expire = int($d->{expire} || 0);
763         my $enable = $d->{enable} ? 1 : 0;
764         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
765     }
766
767     $data .= "\n";
768
769     foreach my $group (keys %{$cfg->{groups}}) {
770         my $d = $cfg->{groups}->{$group};
771         my $list = join (',', keys %{$d->{users}});
772         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
773         $data .= "group:$group:$list:$comment:\n";
774     }
775
776     $data .= "\n";
777
778     foreach my $pool (keys %{$cfg->{pools}}) {
779         my $d = $cfg->{pools}->{$pool};
780         my $vmlist = join (',', keys %{$d->{vms}});
781         my $storelist = join (',', keys %{$d->{storage}});
782         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
783         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
784     }
785
786     $data .= "\n";
787
788     foreach my $role (keys %{$cfg->{roles}}) {
789         next if $special_roles->{$role};
790
791         my $d = $cfg->{roles}->{$role};
792         my $list = join (',', keys %$d);
793         $data .= "role:$role:$list:\n";
794     }
795
796     $data .= "\n";
797
798     foreach my $path (sort keys %{$cfg->{acl}}) {
799         my $d = $cfg->{acl}->{$path};
800
801         my $ra = {};
802
803         foreach my $group (keys %{$d->{groups}}) {
804             my $l0 = '';
805             my $l1 = '';
806             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
807                 my $propagate = $d->{groups}->{$group}->{$role};
808                 if ($propagate) {
809                     $l1 .= ',' if $l1;
810                     $l1 .= $role;
811                 } else {
812                     $l0 .= ',' if $l0;
813                     $l0 .= $role;
814                 }
815             }
816             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
817             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
818         }
819
820         foreach my $user (keys %{$d->{users}}) {
821             # no need to save, because root is always 'Administartor'
822             next if $user eq 'root@pam'; 
823
824             my $l0 = '';
825             my $l1 = '';
826             foreach my $role (sort keys %{$d->{users}->{$user}}) {
827                 my $propagate = $d->{users}->{$user}->{$role};
828                 if ($propagate) {
829                     $l1 .= ',' if $l1;
830                     $l1 .= $role;
831                 } else {
832                     $l0 .= ',' if $l0;
833                     $l0 .= $role;
834                 }
835             }
836             $ra->{0}->{$l0}->{$user} = 1 if $l0;
837             $ra->{1}->{$l1}->{$user} = 1 if $l1;
838         }
839
840         foreach my $rolelist (sort keys %{$ra->{0}}) {
841             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
842             $data .= "acl:0:$path:$uglist:$rolelist:\n";
843         }
844         foreach my $rolelist (sort keys %{$ra->{1}}) {
845             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
846             $data .= "acl:1:$path:$uglist:$rolelist:\n";
847         }
848     }
849
850     return $data;
851 }
852
853 sub roles {
854     my ($cfg, $user, $path) = @_;
855
856     # NOTE: we do not consider pools here. 
857     # You need to use $rpcenv->roles() instead if you want that.
858
859     return 'Administrator' if $user eq 'root@pam'; # root can do anything
860
861     my $perm = {};
862
863     foreach my $p (sort keys %{$cfg->{acl}}) {
864         my $final = ($path eq $p);
865
866         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
867
868         my $acl = $cfg->{acl}->{$p};
869
870         #print "CHECKACL $path $p\n";
871         #print "ACL $path = " . Dumper ($acl);
872
873         if (my $ri = $acl->{users}->{$user}) {
874             my $new;
875             foreach my $role (keys %$ri) {
876                 my $propagate = $ri->{$role};
877                 if ($final || $propagate) {
878                     #print "APPLY ROLE $p $user $role\n";
879                     $new = {} if !$new;
880                     $new->{$role} = 1;
881                 }
882             }
883             if ($new) {
884                 $perm = $new; # overwrite previous settings
885                 next; # user privs always override group privs
886             }
887         }
888
889         my $new;
890         foreach my $g (keys %{$acl->{groups}}) {
891             next if !$cfg->{groups}->{$g}->{users}->{$user};
892             if (my $ri = $acl->{groups}->{$g}) {
893                 foreach my $role (keys %$ri) {
894                     my $propagate = $ri->{$role};
895                     if ($final || $propagate) {
896                         #print "APPLY ROLE $p \@$g $role\n";
897                         $new = {} if !$new;
898                         $new->{$role} = 1;
899                     }
900                 }
901             }
902         }
903         if ($new) {
904             $perm = $new; # overwrite previous settings
905             next;
906         }
907     }
908
909     return ('NoAccess') if defined ($perm->{NoAccess});
910     #return () if defined ($perm->{NoAccess});
911    
912     #print "permission $user $path = " . Dumper ($perm);
913
914     my @ra = keys %$perm;
915
916     #print "roles $user $path = " . join (',', @ra) . "\n";
917
918     return @ra;
919 }
920     
921 sub permission {
922     my ($cfg, $user, $path) = @_;
923
924     $user = PVE::Auth::Plugin::verify_username($user, 1);
925     return {} if !$user;
926
927     my @ra = roles($cfg, $user, $path);
928     
929     my $privs = {};
930
931     foreach my $role (@ra) {
932         if (my $privset = $cfg->{roles}->{$role}) {
933             foreach my $p (keys %$privset) {
934                 $privs->{$p} = 1;
935             }
936         }
937     }
938
939     #print "priviledges $user $path = " . Dumper ($privs);
940
941     return $privs;
942 }
943
944 sub check_permissions {
945     my ($username, $path, $privlist) = @_;
946
947     $path = normalize_path($path);
948     my $usercfg = cfs_read_file('user.cfg');
949     my $perm = permission($usercfg, $username, $path);
950
951     foreach my $priv (split_list($privlist)) {
952         return undef if !$perm->{$priv};
953     };
954
955     return 1;
956 }
957
958 1;