PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use Encode;
   5 use Crypt::OpenSSL::Random;
   6 use Crypt::OpenSSL::RSA;
   7 use MIME::Base64;
   8 use MIME::Base32 qw( RFC );
   9 use Digest::SHA;
  10 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  11 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  12 use PVE::JSONSchema;
  13
  14 use PVE::Auth::Plugin;
  15 use PVE::Auth::AD;
  16 use PVE::Auth::LDAP;
  17 use PVE::Auth::PVE;
  18 use PVE::Auth::PAM;
  19
  20 use Data::Dumper; # fixme: remove
  21
  22 # load and initialize all plugins
  23
  24 PVE::Auth::AD->register();
  25 PVE::Auth::LDAP->register();
  26 PVE::Auth::PVE->register();
  27 PVE::Auth::PAM->register();
  28 PVE::Auth::Plugin->init();
  29
  30 # $authdir must be writable by root only!
  31 my $confdir = "/etc/pve";
  32 my $authdir = "$confdir/priv";
  33 my $authprivkeyfn = "$authdir/authkey.key";
  34 my $authpubkeyfn = "$confdir/authkey.pub";
  35 my $pve_www_key_fn = "$confdir/pve-www.key";
  36
  37 my $ticket_lifetime = 3600*2; # 2 hours
  38
  39 Crypt::OpenSSL::RSA->import_random_seed();
  40
  41 cfs_register_file('user.cfg',
  42                   \&parse_user_config,
  43                   \&write_user_config);
  44
  45
  46 sub verify_username {
  47     PVE::Auth::Plugin::verify_username(@_);
  48 }
  49
  50 sub pve_verify_realm {
  51     PVE::Auth::Plugin::pve_verify_realm(@_);
  52 }
  53
  54 sub lock_user_config {
  55     my ($code, $errmsg) = @_;
  56
  57     cfs_lock_file("user.cfg", undef, $code);
  58     if (my $err = $@) {
  59         $errmsg ? die "$errmsg: $err" : die $err;
  60     }
  61 }
  62
  63 my $pve_auth_pub_key;
  64 sub get_pubkey {
  65
  66     return $pve_auth_pub_key if $pve_auth_pub_key;
  67
  68     my $input = PVE::Tools::file_get_contents($authpubkeyfn);
  69
  70     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
  71
  72     return $pve_auth_pub_key;
  73 }
  74
  75 my $csrf_prevention_secret;
  76 my $get_csrfr_secret = sub {
  77     if (!$csrf_prevention_secret) {
  78         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
  79         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
  80     }
  81     return $csrf_prevention_secret;
  82 };
  83
  84 sub assemble_csrf_prevention_token {
  85     my ($username) = @_;
  86
  87     my $timestamp = sprintf("%08X", time());
  88
  89     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
  90
  91     return "$timestamp:$digest";
  92 }
  93
  94 sub verify_csrf_prevention_token {
  95     my ($username, $token, $noerr) = @_;
  96
  97     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
  98         my $sig = $2;
  99         my $timestamp = $1;
 100         my $ttime = hex($timestamp);
 101
 102         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
 103
 104         my $age = time() - $ttime;
 105         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
 106     }
 107
 108     die "Permission denied - invalid csrf token\n" if !$noerr;
 109
 110     return undef;
 111 }
 112
 113 my $pve_auth_priv_key;
 114 sub get_privkey {
 115
 116     return $pve_auth_priv_key if $pve_auth_priv_key;
 117
 118     my $input = PVE::Tools::file_get_contents($authprivkeyfn);
 119
 120     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
 121
 122     return $pve_auth_priv_key;
 123 }
 124
 125 sub assemble_ticket {
 126     my ($username) = @_;
 127
 128     my $rsa_priv = get_privkey();
 129
 130     my $timestamp = sprintf("%08X", time());
 131
 132     my $plain = "PVE:$username:$timestamp";
 133
 134     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
 135
 136     return $ticket;
 137 }
 138
 139 sub verify_ticket {
 140     my ($ticket, $noerr) = @_;
 141
 142     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
 143         my $plain = $1;
 144         my $sig = $2;
 145
 146         my $rsa_pub = get_pubkey();
 147         if ($rsa_pub->verify($plain, decode_base64($sig))) {
 148             if ($plain =~ m/^PVE:(\S+):([A-Z0-9]{8})$/) {
 149                 my $username = $1;
 150                 my $timestamp = $2;
 151                 my $ttime = hex($timestamp);
 152
 153                 my $age = time() - $ttime;
 154
 155                 if (PVE::Auth::Plugin::verify_username($username, 1) &&
 156                     ($age > -300) && ($age < $ticket_lifetime)) {
 157                     return wantarray ? ($username, $age) : $username;
 158                 }
 159             }
 160         }
 161     }
 162
 163     die "permission denied - invalid ticket\n" if !$noerr;
 164
 165     return undef;
 166 }
 167
 168 # VNC tickets
 169 # - they do not contain the username in plain text
 170 # - they are restricted to a specific resource path (example: '/vms/100')
 171 sub assemble_vnc_ticket {
 172     my ($username, $path) = @_;
 173
 174     my $rsa_priv = get_privkey();
 175
 176     my $timestamp = sprintf("%08X", time());
 177
 178     my $plain = "PVEVNC:$timestamp";
 179
 180     $path = normalize_path($path);
 181
 182     my $full = "$plain:$username:$path";
 183
 184     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
 185
 186     return $ticket;
 187 }
 188
 189 sub verify_vnc_ticket {
 190     my ($ticket, $username, $path, $noerr) = @_;
 191
 192     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
 193         my $plain = $1;
 194         my $sig = $2;
 195         my $full = "$plain:$username:$path";
 196
 197         my $rsa_pub = get_pubkey();
 198         # Note: sign only match if $username and  $path is correct
 199         if ($rsa_pub->verify($full, decode_base64($sig))) {
 200             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
 201                 my $ttime = hex($1);
 202
 203                 my $age = time() - $ttime;
 204
 205                 if (($age > -20) && ($age < 40)) {
 206                     return 1;
 207                 }
 208             }
 209         }
 210     }
 211
 212     die "permission denied - invalid vnc ticket\n" if !$noerr;
 213
 214     return undef;
 215 }
 216
 217 sub assemble_spice_ticket {
 218     my ($username, $path) = @_;
 219
 220     my $rsa_priv = get_privkey();
 221
 222     my $timestamp = sprintf("%08X", time());
 223
 224     my $plain = "PVESPICE:$timestamp";
 225
 226     $path = normalize_path($path);
 227
 228     my $full = "$plain:$path";
 229
 230     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
 231     return MIME::Base32::encode($ticket."::".$full);
 232 }
 233
 234 sub check_user_exist {
 235     my ($usercfg, $username, $noerr) = @_;
 236
 237     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 238     return undef if !$username;
 239
 240     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 241
 242     die "no such user ('$username')\n" if !$noerr;
 243
 244     return undef;
 245 }
 246
 247 sub check_user_enabled {
 248     my ($usercfg, $username, $noerr) = @_;
 249
 250     my $data = check_user_exist($usercfg, $username, $noerr);
 251     return undef if !$data;
 252
 253     return 1 if $data->{enable};
 254
 255     return 1 if $username eq 'root@pam'; # root is always enabled
 256
 257     die "user '$username' is disabled\n" if !$noerr;
 258
 259     return undef;
 260 }
 261
 262 # password should be utf8 encoded
 263 sub authenticate_user {
 264     my ($username, $password) = @_;
 265
 266     die "no username specified\n" if !$username;
 267
 268     my ($ruid, $realm);
 269
 270     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 271
 272     my $usercfg = cfs_read_file('user.cfg');
 273
 274     eval { check_user_enabled($usercfg, $username); };
 275     if (my $err = $@) {
 276         sleep(2);
 277         die $err;
 278     }
 279
 280     my $ctime = time();
 281     my $expire = $usercfg->{users}->{$username}->{expire};
 282
 283     if ($expire && ($expire < $ctime)) {
 284         sleep(2);
 285         die "account expired\n"
 286     }
 287
 288     my $domain_cfg = cfs_read_file('domains.cfg');
 289
 290     eval {
 291         my $cfg = $domain_cfg->{ids}->{$realm};
 292         die "auth domain '$realm' does not exists\n" if !$cfg;
 293         my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 294         $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 295     };
 296     if (my $err = $@) {
 297         sleep(2); # timeout after failed auth
 298         die $err;
 299     }
 300
 301     return $username;
 302 }
 303
 304 sub domain_set_password {
 305     my ($realm, $username, $password) = @_;
 306
 307     die "no auth domain specified" if !$realm;
 308
 309     my $domain_cfg = cfs_read_file('domains.cfg');
 310
 311     my $cfg = $domain_cfg->{ids}->{$realm};
 312     die "auth domain '$realm' does not exists\n" if !$cfg;
 313     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 314     $plugin->store_password($cfg, $realm, $username, $password);
 315 }
 316
 317 sub add_user_group {
 318
 319     my ($username, $usercfg, $group) = @_;
 320     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 321     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 322 }
 323
 324 sub delete_user_group {
 325
 326     my ($username, $usercfg) = @_;
 327
 328     foreach my $group (keys %{$usercfg->{groups}}) {
 329
 330         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 331             if $usercfg->{groups}->{$group}->{users}->{$username};
 332     }
 333 }
 334
 335 sub delete_user_acl {
 336
 337     my ($username, $usercfg) = @_;
 338
 339     foreach my $acl (keys %{$usercfg->{acl}}) {
 340
 341         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 342             if $usercfg->{acl}->{$acl}->{users}->{$username};
 343     }
 344 }
 345
 346 sub delete_group_acl {
 347
 348     my ($group, $usercfg) = @_;
 349
 350     foreach my $acl (keys %{$usercfg->{acl}}) {
 351
 352         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 353             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 354     }
 355 }
 356
 357 sub delete_pool_acl {
 358
 359     my ($pool, $usercfg) = @_;
 360
 361     my $path = "/pool/$pool";
 362
 363     foreach my $aclpath (keys %{$usercfg->{acl}}) {
 364         delete ($usercfg->{acl}->{$aclpath})
 365             if $usercfg->{acl}->{$aclpath} eq 'path';
 366     }
 367 }
 368
 369 # we automatically create some predefined roles by splitting privs
 370 # into 3 groups (per category)
 371 # root: only root is allowed to do that
 372 # admin: an administrator can to that
 373 # user: a normak user/customer can to that
 374 my $privgroups = {
 375     VM => {
 376         root => [],
 377         admin => [
 378             'VM.Config.Disk',
 379             'VM.Config.CPU',
 380             'VM.Config.Memory',
 381             'VM.Config.Network',
 382             'VM.Config.HWType',
 383             'VM.Config.Options', # covers all other things
 384             'VM.Allocate',
 385             'VM.Clone',
 386             'VM.Migrate',
 387             'VM.Monitor',
 388             'VM.Snapshot',
 389         ],
 390         user => [
 391             'VM.Config.CDROM', # change CDROM media
 392             'VM.Console',
 393             'VM.Backup',
 394             'VM.PowerMgmt',
 395         ],
 396         audit => [
 397             'VM.Audit',
 398         ],
 399     },
 400     Sys => {
 401         root => [
 402             'Sys.PowerMgmt',
 403             'Sys.Modify', # edit/change node settings
 404         ],
 405         admin => [
 406             'Permissions.Modify',
 407             'Sys.Console',
 408             'Sys.Syslog',
 409         ],
 410         user => [],
 411         audit => [
 412             'Sys.Audit',
 413         ],
 414     },
 415     Datastore => {
 416         root => [],
 417         admin => [
 418             'Datastore.Allocate',
 419             'Datastore.AllocateTemplate',
 420         ],
 421         user => [
 422             'Datastore.AllocateSpace',
 423         ],
 424         audit => [
 425             'Datastore.Audit',
 426         ],
 427     },
 428     User => {
 429         root => [
 430             'Realm.Allocate',
 431         ],
 432         admin => [
 433             'User.Modify',
 434             'Group.Allocate', # edit/change group settings
 435             'Realm.AllocateUser',
 436         ],
 437         user => [],
 438         audit => [],
 439     },
 440     Pool => {
 441         root => [],
 442         admin => [
 443             'Pool.Allocate', # create/delete pools
 444         ],
 445         user => [],
 446         audit => [],
 447     },
 448 };
 449
 450 my $valid_privs = {};
 451
 452 my $special_roles = {
 453     'NoAccess' => {}, # no priviledges
 454     'Administrator' => $valid_privs, # all priviledges
 455 };
 456
 457 sub create_roles {
 458
 459     foreach my $cat (keys %$privgroups) {
 460         my $cd = $privgroups->{$cat};
 461         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 462                        @{$cd->{user}}, @{$cd->{audit}}) {
 463             $valid_privs->{$p} = 1;
 464         }
 465         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 466
 467             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 468             $special_roles->{"PVEAdmin"}->{$p} = 1;
 469         }
 470         if (scalar(@{$cd->{user}})) {
 471             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 472                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 473             }
 474         }
 475         foreach my $p (@{$cd->{audit}}) {
 476             $special_roles->{"PVEAuditor"}->{$p} = 1;
 477         }
 478     }
 479
 480     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
 481 };
 482
 483 create_roles();
 484
 485 sub add_role_privs {
 486     my ($role, $usercfg, $privs) = @_;
 487
 488     return if !$privs;
 489
 490     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 491
 492     foreach my $priv (split_list($privs)) {
 493         if (defined ($valid_privs->{$priv})) {
 494             $usercfg->{roles}->{$role}->{$priv} = 1;
 495         } else {
 496             die "invalid priviledge '$priv'\n";
 497         }
 498     }
 499 }
 500
 501 sub normalize_path {
 502     my $path = shift;
 503
 504     $path =~ s|/+|/|g;
 505
 506     $path =~ s|/$||;
 507
 508     $path = '/' if !$path;
 509
 510     $path = "/$path" if $path !~ m|^/|;
 511
 512     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
 513
 514     return $path;
 515 }
 516
 517
 518 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 519 sub verify_groupname {
 520     my ($groupname, $noerr) = @_;
 521
 522     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 523
 524         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 525
 526         return undef;
 527     }
 528
 529     return $groupname;
 530 }
 531
 532 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 533 sub verify_rolename {
 534     my ($rolename, $noerr) = @_;
 535
 536     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 537
 538         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 539
 540         return undef;
 541     }
 542
 543     return $rolename;
 544 }
 545
 546 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
 547 sub verify_poolname {
 548     my ($poolname, $noerr) = @_;
 549
 550     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 551
 552         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 553
 554         return undef;
 555     }
 556
 557     return $poolname;
 558 }
 559
 560 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 561 sub verify_privname {
 562     my ($priv, $noerr) = @_;
 563
 564     if (!$valid_privs->{$priv}) {
 565         die "invalid priviledge '$priv'\n" if !$noerr;
 566
 567         return undef;
 568     }
 569
 570     return $priv;
 571 }
 572
 573 sub userconfig_force_defaults {
 574     my ($cfg) = @_;
 575
 576     foreach my $r (keys %$special_roles) {
 577         $cfg->{roles}->{$r} = $special_roles->{$r};
 578     }
 579
 580     # fixme: remove 'root' group (not required)?
 581
 582     # add root user
 583     $cfg->{users}->{'root@pam'}->{enable} = 1;
 584 }
 585
 586 sub parse_user_config {
 587     my ($filename, $raw) = @_;
 588
 589     my $cfg = {};
 590
 591     userconfig_force_defaults($cfg);
 592
 593     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
 594         my $line = $1;
 595
 596         next if $line =~ m/^\s*$/; # skip empty lines
 597
 598         my @data;
 599
 600         foreach my $d (split (/:/, $line)) {
 601             $d =~ s/^\s+//;
 602             $d =~ s/\s+$//;
 603             push @data, $d
 604         }
 605
 606         my $et = shift @data;
 607
 608         if ($et eq 'user') {
 609             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
 610
 611             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 612             if (!$realm) {
 613                 warn "user config - ignore user '$user' - invalid user name\n";
 614                 next;
 615             }
 616
 617             $enable = $enable ? 1 : 0;
 618
 619             $expire = 0 if !$expire;
 620
 621             if ($expire !~ m/^\d+$/) {
 622                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 623                 next;
 624             }
 625             $expire = int($expire);
 626
 627             #if (!verify_groupname ($group, 1)) {
 628             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 629             #    next;
 630             #}
 631
 632             $cfg->{users}->{$user} = {
 633                 enable => $enable,
 634                 # group => $group,
 635             };
 636             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 637             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 638             $cfg->{users}->{$user}->{email} = $email;
 639             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 640             $cfg->{users}->{$user}->{expire} = $expire;
 641
 642             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 643             #$cfg->{groups}->{$group}->{$user} = 1;
 644
 645         } elsif ($et eq 'group') {
 646             my ($group, $userlist, $comment) = @data;
 647
 648             if (!verify_groupname($group, 1)) {
 649                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 650                 next;
 651             }
 652
 653             # make sure to add the group (even if there are no members)
 654             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 655
 656             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 657
 658             foreach my $user (split_list($userlist)) {
 659
 660                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
 661                     warn "user config - ignore invalid group member '$user'\n";
 662                     next;
 663                 }
 664
 665                 if ($cfg->{users}->{$user}) { # user exists
 666                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
 667                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
 668                 } else {
 669                     warn "user config - ignore invalid group member '$user'\n";
 670                 }
 671             }
 672
 673         } elsif ($et eq 'role') {
 674             my ($role, $privlist) = @data;
 675
 676             if (!verify_rolename($role, 1)) {
 677                 warn "user config - ignore role '$role' - invalid characters in role name\n";
 678                 next;
 679             }
 680
 681             # make sure to add the role (even if there are no privileges)
 682             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
 683
 684             foreach my $priv (split_list($privlist)) {
 685                 if (defined ($valid_privs->{$priv})) {
 686                     $cfg->{roles}->{$role}->{$priv} = 1;
 687                 } else {
 688                     warn "user config - ignore invalid priviledge '$priv'\n";
 689                 }
 690             }
 691
 692         } elsif ($et eq 'acl') {
 693             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
 694
 695             if (my $path = normalize_path($pathtxt)) {
 696                 foreach my $role (split_list($rolelist)) {
 697
 698                     if (!verify_rolename($role, 1)) {
 699                         warn "user config - ignore invalid role name '$role' in acl\n";
 700                         next;
 701                     }
 702
 703                     foreach my $ug (split_list($uglist)) {
 704                         if ($ug =~ m/^@(\S+)$/) {
 705                             my $group = $1;
 706                             if ($cfg->{groups}->{$group}) { # group exists
 707                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
 708                             } else {
 709                                 warn "user config - ignore invalid acl group '$group'\n";
 710                             }
 711                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
 712                             if ($cfg->{users}->{$ug}) { # user exists
 713                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
 714                             } else {
 715                                 warn "user config - ignore invalid acl member '$ug'\n";
 716                             }
 717                         } else {
 718                             warn "user config - invalid user/group '$ug' in acl\n";
 719                         }
 720                     }
 721                 }
 722             } else {
 723                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
 724             }
 725         } elsif ($et eq 'pool') {
 726             my ($pool, $comment, $vmlist, $storelist) = @data;
 727
 728             if (!verify_poolname($pool, 1)) {
 729                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
 730                 next;
 731             }
 732
 733             # make sure to add the pool (even if there are no members)
 734             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
 735
 736             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 737
 738             foreach my $vmid (split_list($vmlist)) {
 739                 if ($vmid !~ m/^\d+$/) {
 740                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
 741                     next;
 742                 }
 743                 $vmid = int($vmid);
 744
 745                 if ($cfg->{vms}->{$vmid}) {
 746                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
 747                     next;
 748                 }
 749
 750                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
 751
 752                 # record vmid ==> pool relation
 753                 $cfg->{vms}->{$vmid} = $pool;
 754             }
 755
 756             foreach my $storeid (split_list($storelist)) {
 757                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 758                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
 759                     next;
 760                 }
 761                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
 762             }
 763         } else {
 764             warn "user config - ignore config line: $line\n";
 765         }
 766     }
 767
 768     userconfig_force_defaults($cfg);
 769
 770     return $cfg;
 771 }
 772
 773 sub write_user_config {
 774     my ($filename, $cfg) = @_;
 775
 776     my $data = '';
 777
 778     foreach my $user (keys %{$cfg->{users}}) {
 779         my $d = $cfg->{users}->{$user};
 780         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
 781         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
 782         my $email = $d->{email} || '';
 783         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 784         my $expire = int($d->{expire} || 0);
 785         my $enable = $d->{enable} ? 1 : 0;
 786         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
 787     }
 788
 789     $data .= "\n";
 790
 791     foreach my $group (keys %{$cfg->{groups}}) {
 792         my $d = $cfg->{groups}->{$group};
 793         my $list = join (',', keys %{$d->{users}});
 794         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 795         $data .= "group:$group:$list:$comment:\n";
 796     }
 797
 798     $data .= "\n";
 799
 800     foreach my $pool (keys %{$cfg->{pools}}) {
 801         my $d = $cfg->{pools}->{$pool};
 802         my $vmlist = join (',', keys %{$d->{vms}});
 803         my $storelist = join (',', keys %{$d->{storage}});
 804         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 805         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
 806     }
 807
 808     $data .= "\n";
 809
 810     foreach my $role (keys %{$cfg->{roles}}) {
 811         next if $special_roles->{$role};
 812
 813         my $d = $cfg->{roles}->{$role};
 814         my $list = join (',', keys %$d);
 815         $data .= "role:$role:$list:\n";
 816     }
 817
 818     $data .= "\n";
 819
 820     foreach my $path (sort keys %{$cfg->{acl}}) {
 821         my $d = $cfg->{acl}->{$path};
 822
 823         my $ra = {};
 824
 825         foreach my $group (keys %{$d->{groups}}) {
 826             my $l0 = '';
 827             my $l1 = '';
 828             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
 829                 my $propagate = $d->{groups}->{$group}->{$role};
 830                 if ($propagate) {
 831                     $l1 .= ',' if $l1;
 832                     $l1 .= $role;
 833                 } else {
 834                     $l0 .= ',' if $l0;
 835                     $l0 .= $role;
 836                 }
 837             }
 838             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
 839             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
 840         }
 841
 842         foreach my $user (keys %{$d->{users}}) {
 843             # no need to save, because root is always 'Administartor'
 844             next if $user eq 'root@pam';
 845
 846             my $l0 = '';
 847             my $l1 = '';
 848             foreach my $role (sort keys %{$d->{users}->{$user}}) {
 849                 my $propagate = $d->{users}->{$user}->{$role};
 850                 if ($propagate) {
 851                     $l1 .= ',' if $l1;
 852                     $l1 .= $role;
 853                 } else {
 854                     $l0 .= ',' if $l0;
 855                     $l0 .= $role;
 856                 }
 857             }
 858             $ra->{0}->{$l0}->{$user} = 1 if $l0;
 859             $ra->{1}->{$l1}->{$user} = 1 if $l1;
 860         }
 861
 862         foreach my $rolelist (sort keys %{$ra->{0}}) {
 863             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
 864             $data .= "acl:0:$path:$uglist:$rolelist:\n";
 865         }
 866         foreach my $rolelist (sort keys %{$ra->{1}}) {
 867             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
 868             $data .= "acl:1:$path:$uglist:$rolelist:\n";
 869         }
 870     }
 871
 872     return $data;
 873 }
 874
 875 sub roles {
 876     my ($cfg, $user, $path) = @_;
 877
 878     # NOTE: we do not consider pools here.
 879     # You need to use $rpcenv->roles() instead if you want that.
 880
 881     return 'Administrator' if $user eq 'root@pam'; # root can do anything
 882
 883     my $perm = {};
 884
 885     foreach my $p (sort keys %{$cfg->{acl}}) {
 886         my $final = ($path eq $p);
 887
 888         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
 889
 890         my $acl = $cfg->{acl}->{$p};
 891
 892         #print "CHECKACL $path $p\n";
 893         #print "ACL $path = " . Dumper ($acl);
 894
 895         if (my $ri = $acl->{users}->{$user}) {
 896             my $new;
 897             foreach my $role (keys %$ri) {
 898                 my $propagate = $ri->{$role};
 899                 if ($final || $propagate) {
 900                     #print "APPLY ROLE $p $user $role\n";
 901                     $new = {} if !$new;
 902                     $new->{$role} = 1;
 903                 }
 904             }
 905             if ($new) {
 906                 $perm = $new; # overwrite previous settings
 907                 next; # user privs always override group privs
 908             }
 909         }
 910
 911         my $new;
 912         foreach my $g (keys %{$acl->{groups}}) {
 913             next if !$cfg->{groups}->{$g}->{users}->{$user};
 914             if (my $ri = $acl->{groups}->{$g}) {
 915                 foreach my $role (keys %$ri) {
 916                     my $propagate = $ri->{$role};
 917                     if ($final || $propagate) {
 918                         #print "APPLY ROLE $p \@$g $role\n";
 919                         $new = {} if !$new;
 920                         $new->{$role} = 1;
 921                     }
 922                 }
 923             }
 924         }
 925         if ($new) {
 926             $perm = $new; # overwrite previous settings
 927             next;
 928         }
 929     }
 930
 931     return ('NoAccess') if defined ($perm->{NoAccess});
 932     #return () if defined ($perm->{NoAccess});
 933
 934     #print "permission $user $path = " . Dumper ($perm);
 935
 936     my @ra = keys %$perm;
 937
 938     #print "roles $user $path = " . join (',', @ra) . "\n";
 939
 940     return @ra;
 941 }
 942
 943 sub permission {
 944     my ($cfg, $user, $path) = @_;
 945
 946     $user = PVE::Auth::Plugin::verify_username($user, 1);
 947     return {} if !$user;
 948
 949     my @ra = roles($cfg, $user, $path);
 950
 951     my $privs = {};
 952
 953     foreach my $role (@ra) {
 954         if (my $privset = $cfg->{roles}->{$role}) {
 955             foreach my $p (keys %$privset) {
 956                 $privs->{$p} = 1;
 957             }
 958         }
 959     }
 960
 961     #print "priviledges $user $path = " . Dumper ($privs);
 962
 963     return $privs;
 964 }
 965
 966 sub check_permissions {
 967     my ($username, $path, $privlist) = @_;
 968
 969     $path = normalize_path($path);
 970     my $usercfg = cfs_read_file('user.cfg');
 971     my $perm = permission($usercfg, $username, $path);
 972
 973     foreach my $priv (split_list($privlist)) {
 974         return undef if !$perm->{$priv};
 975     };
 976
 977     return 1;
 978 }
 979
 980 sub add_vm_to_pool {
 981     my ($vmid, $pool) = @_;
 982
 983     my $addVMtoPoolFn = sub {
 984         my $usercfg = cfs_read_file("user.cfg");
 985         if (my $data = $usercfg->{pools}->{$pool}) {
 986             $data->{vms}->{$vmid} = 1;
 987             $usercfg->{vms}->{$vmid} = $pool;
 988             cfs_write_file("user.cfg", $usercfg);
 989         }
 990     };
 991
 992     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
 993 }
 994
 995 sub remove_vm_from_pool {
 996     my ($vmid) = @_;
 997
 998     my $delVMfromPoolFn = sub {
 999         my $usercfg = cfs_read_file("user.cfg");
1000         if (my $pool = $usercfg->{vms}->{$vmid}) {
1001             if (my $data = $usercfg->{pools}->{$pool}) {
1002                 delete $data->{vms}->{$vmid};
1003                 delete $usercfg->{vms}->{$vmid};
1004                 cfs_write_file("user.cfg", $usercfg);
1005             }
1006         }
1007     };
1008
1009     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1010 }
1011
1012 1;