add more privileges, improve docs
[pve-access-control.git] / PVE / AccessControl.pm
1 package PVE::AccessControl;
2
3 use strict;
4 use Encode;
5 use Crypt::OpenSSL::Random;
6 use Crypt::OpenSSL::RSA;
7 use MIME::Base64;
8 use Digest::SHA;
9 use Authen::PAM qw(:constants);
10 use Net::LDAP;
11 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
12 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
13 use PVE::JSONSchema;
14 use Encode;
15
16 use Data::Dumper; # fixme: remove
17
18 # $authdir must be writable by root only!
19 my $confdir = "/etc/pve";
20 my $authdir = "$confdir/priv";
21 my $authprivkeyfn = "$authdir/authkey.key";
22 my $authpubkeyfn = "$confdir/authkey.pub";
23 my $shadowconfigfile = "priv/shadow.cfg";
24 my $domainconfigfile = "domains.cfg";
25 my $pve_www_key_fn = "$confdir/pve-www.key";
26
27 my $ticket_lifetime = 3600*2; # 2 hours
28
29 Crypt::OpenSSL::RSA->import_random_seed();
30
31 cfs_register_file('user.cfg', 
32                   \&parse_user_config,  
33                   \&write_user_config);
34
35 cfs_register_file($shadowconfigfile, 
36                   \&parse_shadow_passwd, 
37                   \&write_shadow_config);
38
39 cfs_register_file($domainconfigfile, 
40                   \&parse_domains,
41                   \&write_domains);
42
43
44 sub lock_user_config {
45     my ($code, $errmsg) = @_;
46
47     cfs_lock_file("user.cfg", undef, $code);
48     my $err = $@;
49     if ($err) {
50         $errmsg ? die "$errmsg: $err" : die $err;
51     }
52 }
53
54 sub lock_domain_config {
55     my ($code, $errmsg) = @_;
56
57     cfs_lock_file($domainconfigfile, undef, $code);
58     my $err = $@;
59     if ($err) {
60         $errmsg ? die "$errmsg: $err" : die $err;
61     }
62 }
63
64 sub lock_shadow_config {
65     my ($code, $errmsg) = @_;
66
67     cfs_lock_file($shadowconfigfile, undef, $code);
68     my $err = $@;
69     if ($err) {
70         $errmsg ? die "$errmsg: $err" : die $err;
71     }
72 }
73
74 my $pve_auth_pub_key;
75 sub get_pubkey {    
76
77     return $pve_auth_pub_key if $pve_auth_pub_key;
78
79     my $input = PVE::Tools::file_get_contents($authpubkeyfn); 
80
81     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
82
83     return $pve_auth_pub_key;
84 }
85
86 my $csrf_prevention_secret;
87 my $get_csrfr_secret = sub {
88     if (!$csrf_prevention_secret) {
89         my $input = PVE::Tools::file_get_contents($pve_www_key_fn); 
90         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
91     }
92     return $csrf_prevention_secret;
93 };
94
95 sub assemble_csrf_prevention_token {
96     my ($username) = @_;
97
98     my $timestamp = sprintf("%08X", time());
99
100     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
101
102     return "$timestamp:$digest"; 
103 }
104
105 sub verify_csrf_prevention_token {
106     my ($username, $token, $noerr) = @_;
107
108     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
109         my $sig = $2;
110         my $timestamp = $1;
111         my $ttime = hex($timestamp);
112
113         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
114
115         my $age = time() - $ttime;
116         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
117     }
118
119     die "Permission denied - invalid csrf token\n" if !$noerr;
120
121     return undef;
122 }
123
124 my $pve_auth_priv_key;
125 sub get_privkey {
126
127     return $pve_auth_priv_key if $pve_auth_priv_key;
128
129     my $input = PVE::Tools::file_get_contents($authprivkeyfn); 
130
131     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
132
133     return $pve_auth_priv_key;
134 }
135
136 sub assemble_ticket {
137     my ($username) = @_;
138
139     my $rsa_priv = get_privkey();
140
141     my $timestamp = sprintf("%08X", time());
142
143     my $plain = "PVE:$username:$timestamp";
144
145     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
146
147     return $ticket;
148 }
149
150 sub verify_ticket {
151     my ($ticket, $noerr) = @_;
152
153     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
154         my $plain = $1;
155         my $sig = $2;
156
157         my $rsa_pub = get_pubkey();
158         if ($rsa_pub->verify($plain, decode_base64($sig))) {
159             if ($plain =~ m/^PVE:(([A-Za-z0-9\.\-_]+)(\@([A-Za-z0-9\.\-_]+))?):([A-Z0-9]{8})$/) {
160                 my $username = $1;
161                 my $timestamp = $5;
162                 my $ttime = hex($timestamp);
163
164                 my $age = time() - $ttime;
165
166                 if (($age > -300) && ($age < $ticket_lifetime)) {
167                     return wantarray ? ($username, $age) : $username;
168                 }
169             }
170         }
171     }
172
173     die "permission denied - invalid ticket\n" if !$noerr;
174
175     return undef;
176 }
177
178 # VNC tickets
179 # - they do not contain the username in plain text
180 # - they are restricted to a specific resource path (example: '/vms/100')
181 sub assemble_vnc_ticket {
182     my ($username, $path) = @_;
183
184     my $rsa_priv = get_privkey();
185
186     my $timestamp = sprintf("%08X", time());
187
188     my $plain = "PVEVNC:$timestamp";
189
190     $path = normalize_path($path);
191
192     my $full = "$plain:$username:$path";
193
194     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
195
196     return $ticket;
197 }
198
199 sub verify_vnc_ticket {
200     my ($ticket, $username, $path, $noerr) = @_;
201
202     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
203         my $plain = $1;
204         my $sig = $2;
205         my $full = "$plain:$username:$path";
206
207         my $rsa_pub = get_pubkey();
208         # Note: sign only match if $username and  $path is correct
209         if ($rsa_pub->verify($full, decode_base64($sig))) {
210             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
211                 my $ttime = hex($1);
212
213                 my $age = time() - $ttime;
214
215                 if (($age > -20) && ($age < 40)) {
216                     return 1;
217                 }
218             }
219         }
220     }
221
222     die "permission denied - invalid vnc ticket\n" if !$noerr;
223
224     return undef;
225 }
226
227
228 sub authenticate_user_shadow {
229     my ($userid, $password) = @_;
230
231     die "no password\n" if !$password;
232
233     my $shadow_cfg = cfs_read_file($shadowconfigfile);
234     
235     if ($shadow_cfg->{users}->{$userid}) {
236         my $encpw = crypt($password, $shadow_cfg->{users}->{$userid}->{shadow});
237         die "invalid credentials\n" if ($encpw ne $shadow_cfg->{users}->{$userid}->{shadow});
238     } else {
239         die "no password set\n";
240     }
241 }
242
243 sub authenticate_user_pam {
244     my ($userid, $password) = @_;
245
246     # user (www-data) need to be able to read /etc/passwd /etc/shadow
247
248     die "no password\n" if !$password;
249
250     my $pamh = new Authen::PAM ('common-auth', $userid, sub {
251         my @res;
252         while(@_) {
253             my $msg_type = shift;
254             my $msg = shift;
255             push @res, (0, $password);
256         }
257         push @res, 0;
258         return @res;
259     });
260
261     if (!ref ($pamh)) {
262         my $err = $pamh->pam_strerror($pamh);
263         die "error during PAM init: $err";
264     }
265
266     my $res;
267
268     if (($res = $pamh->pam_authenticate(0)) != PAM_SUCCESS) {
269         my $err = $pamh->pam_strerror($res);
270         die "$err\n";
271     }
272
273     if (($res = $pamh->pam_acct_mgmt (0)) != PAM_SUCCESS) {
274         my $err = $pamh->pam_strerror($res);
275         die "$err\n";
276     }
277
278     $pamh = 0; # call destructor
279 }
280
281 sub authenticate_user_ad {
282
283     my ($entry, $server, $userid, $password) = @_;
284
285     my $default_port = $entry->{secure} ? 636: 389;
286     my $port = $entry->{port} ? $entry->{port} : $default_port;
287     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
288     my $conn_string = "$scheme://${server}:$port";
289     
290     my $ldap = Net::LDAP->new($server) || die "$@\n";
291
292     $userid = "$userid\@$entry->{domain}" 
293         if $userid !~ m/@/ && $entry->{domain};
294
295     my $res = $ldap->bind($userid, password => $password);
296
297     my $code = $res->code();
298     my $err = $res->error;
299
300     $ldap->unbind();
301
302     die "$err\n" if ($code);
303 }
304
305 sub authenticate_user_ldap {
306
307     my ($entry, $server, $userid, $password) = @_;
308
309     my $default_port = $entry->{secure} ? 636: 389;
310     my $port = $entry->{port} ? $entry->{port} : $default_port;
311     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
312     my $conn_string = "$scheme://${server}:$port";
313
314     my $ldap = Net::LDAP->new($conn_string, verify => 'none') || die "$@\n";
315     my $search = $entry->{user_attr} . "=" . $userid;
316     my $result = $ldap->search( base    => "$entry->{base_dn}",
317                                 scope   => "sub",
318                                 filter  => "$search",
319                                 attrs   => ['dn']
320                                 );
321     die "no entries returned\n" if !$result->entries;
322     my @entries = $result->entries;
323     my $res = $ldap->bind($entries[0]->dn, password => $password);
324
325     my $code = $res->code();
326     my $err = $res->error;
327
328     $ldap->unbind();
329
330     die "$err\n" if ($code);
331 }
332
333 sub authenticate_user_domain {
334     my ($realm, $userid, $password) = @_;
335  
336     my $domain_cfg = cfs_read_file($domainconfigfile);
337
338     die "no auth domain specified" if !$realm;
339
340     if ($realm eq 'pam') {
341         authenticate_user_pam($userid, $password);
342         return;
343     } 
344
345     eval {
346         if ($realm eq 'pve') {
347             authenticate_user_shadow($userid, $password);
348         } else { 
349
350             my $cfg = $domain_cfg->{$realm};
351             die "auth domain '$realm' does not exists\n" if !$cfg;
352     
353             if ($cfg->{type} eq 'ad') {
354                 eval { authenticate_user_ad($cfg, $cfg->{server1}, $userid, $password); };
355                 my $err = $@;
356                 return if !$err;
357                 die $err if !$cfg->{server2};
358                 authenticate_user_ad($cfg, $cfg->{server2}, $userid, $password); 
359             } elsif ($cfg->{type} eq 'ldap') {
360                 eval { authenticate_user_ldap($cfg, $cfg->{server1}, $userid, $password); };
361                 my $err = $@;
362                 return if !$err;
363                 die $err if !$cfg->{server2};
364                 authenticate_user_ldap($cfg, $cfg->{server2}, $userid, $password); 
365             } else {
366                 die "unknown auth type '$cfg->{type}'\n";
367             }
368         }
369     };
370     if (my $err = $@) {
371         sleep(2); # timeout after failed auth
372         die $err;
373     }
374 }
375
376 sub check_user_exist {
377     my ($usercfg, $username, $noerr) = @_;
378
379     $username = verify_username($username, $noerr);
380     return undef if !$username;
381  
382     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
383
384     die "no such user ('$username')\n" if !$noerr;
385  
386     return undef;
387 }
388
389 sub check_user_enabled {
390     my ($usercfg, $username, $noerr) = @_;
391
392     my $data = check_user_exist($usercfg, $username, $noerr);
393     return undef if !$data;
394
395     return 1 if $data->{enable};
396
397     return 1 if $username eq 'root@pam'; # root is always enabled
398
399     die "user '$username' is disabled\n" if !$noerr;
400  
401     return undef;
402 }
403
404 # password should be utf8 encoded
405 sub authenticate_user {
406     my ($username, $password) = @_;
407
408     die "no username specified\n" if !$username;
409  
410     my ($userid, $realm);
411
412     ($username, $userid, $realm) = verify_username($username);
413
414     my $usercfg = cfs_read_file('user.cfg');
415
416     eval { check_user_enabled($usercfg, $username); };
417     if (my $err = $@) {
418         sleep(2);
419         die $err;
420     }
421
422     my $ctime = time();
423     my $expire = $usercfg->{users}->{$username}->{expire};
424
425     if ($expire && ($expire < $ctime)) {
426         sleep(2);
427         die "account expired\n"
428     }
429
430     authenticate_user_domain($realm, $userid, $password);
431
432     return $username;
433 }
434
435 sub delete_shadow_password {
436     my ($userid) = @_;
437  
438     lock_shadow_config(sub {
439         my $shadow_cfg = cfs_read_file($shadowconfigfile);
440         delete ($shadow_cfg->{users}->{$userid})
441             if $shadow_cfg->{users}->{$userid};
442         cfs_write_file($shadowconfigfile, $shadow_cfg);
443     });
444 }
445
446 sub store_shadow_password {
447     my ($userid, $password) = @_;
448   
449     lock_shadow_config(sub {
450         my $shadow_cfg = cfs_read_file($shadowconfigfile);
451         $shadow_cfg->{users}->{$userid}->{shadow} = encrypt_pw($password);
452         cfs_write_file($shadowconfigfile, $shadow_cfg);
453     });
454 }
455
456 sub encrypt_pw {
457     my ($pw) = @_;
458
459     my $time = substr (Digest::SHA::sha1_base64 (time), 0, 8);
460     return crypt (encode("utf8", $pw), "\$5\$$time\$");
461 }
462
463 sub store_pam_password {
464     my ($userid, $password) = @_;
465
466     my $cmd = ['/usr/sbin/usermod'];
467
468     my $epw = encrypt_pw($password);
469     push @$cmd, '-p', $epw;
470
471     push @$cmd, $userid;
472
473     run_command($cmd);
474 }
475
476 sub domain_set_password {
477     my ($realm, $userid, $password) = @_;
478
479     die "no auth domain specified" if !$realm;
480
481     if ($realm eq 'pam') {
482         store_pam_password($userid, $password);
483     } elsif ($realm eq 'pve') {
484         store_shadow_password($userid, $password);
485     } else {
486         die "can't set password on auth domain '$realm'\n";
487     }
488 }
489
490 sub add_user_group {
491
492     my ($username, $usercfg, $group) = @_;
493     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
494     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
495 }
496
497 sub delete_user_group {
498
499     my ($username, $usercfg) = @_;
500     
501     foreach my $group (keys %{$usercfg->{groups}}) {
502
503         delete ($usercfg->{groups}->{$group}->{users}->{$username}) 
504             if $usercfg->{groups}->{$group}->{users}->{$username};
505     }
506 }
507
508 sub delete_user_acl {
509
510     my ($username, $usercfg) = @_;
511
512     foreach my $acl (keys %{$usercfg->{acl}}) {
513
514         delete ($usercfg->{acl}->{$acl}->{users}->{$username}) 
515             if $usercfg->{acl}->{$acl}->{users}->{$username};
516     }
517 }
518
519 sub delete_group_acl {
520
521     my ($group, $usercfg) = @_;
522
523     foreach my $acl (keys %{$usercfg->{acl}}) {
524
525         delete ($usercfg->{acl}->{$acl}->{groups}->{$group}) 
526             if $usercfg->{acl}->{$acl}->{groups}->{$group};
527     }
528 }
529
530 sub delete_pool_acl {
531
532     my ($pool, $usercfg) = @_;
533
534     my $path = "/pool/$pool";
535
536     foreach my $aclpath (keys %{$usercfg->{acl}}) {
537         delete ($usercfg->{acl}->{$aclpath})
538             if $usercfg->{acl}->{$aclpath} eq 'path';
539     }
540 }
541
542 # we automatically create some predefined roles by splitting privs
543 # into 3 groups (per category)
544 # root: only root is allowed to do that
545 # admin: an administrator can to that
546 # user: a normak user/customer can to that
547 my $privgroups = {
548     VM => {
549         root => [],
550         admin => [           
551             'VM.Config.Disk', 
552             'VM.Config.CDROM', 
553             'VM.Config.CPU', 
554             'VM.Config.Memory', 
555             'VM.Config.Network', 
556             'VM.Config.HWType',
557             'VM.Config.Options', # covers all other things 
558             'VM.Allocate', 
559             'VM.Migrate',
560             'VM.Monitor', 
561         ],
562         user => [
563             'VM.Console', 
564             'VM.PowerMgmt',
565         ],
566         audit => [ 
567             'VM.Audit',
568         ],
569     },
570     Sys => {
571         root => [
572             'Sys.PowerMgmt',     
573             'Sys.Modify', # edit/change node settings
574         ],
575         admin => [
576             'Permissions.Modify',
577             'Sys.Console',    
578             'Sys.Syslog',
579         ],
580         user => [],
581         audit => [
582             'Sys.Audit',
583         ],
584     },
585     Datastore => {
586         root => [],
587         admin => [
588             'Datastore.Allocate',
589         ],
590         user => [
591             'Datastore.AllocateSpace',
592         ],
593         audit => [
594             'Datastore.Audit',
595         ],
596     },
597     User => {
598         root => [
599             'Realm.Allocate',
600         ],
601         admin => [
602             'User.Modify',
603             'Group.Allocate', # edit/change group settings
604             'Realm.AllocateUser', 
605         ],
606         user => [],
607         audit => [],
608     },
609     Pool => {
610         root => [],
611         admin => [
612             'Pool.Allocate', # create/delete pools
613         ],
614         user => [],
615         audit => [],
616     },
617 };
618
619 my $valid_privs = {};
620
621 my $special_roles = {
622     'NoAccess' => {}, # no priviledges
623     'Administrator' => $valid_privs, # all priviledges
624 };
625
626 sub create_roles {
627
628     foreach my $cat (keys %$privgroups) {
629         my $cd = $privgroups->{$cat};
630         foreach my $p (@{$cd->{root}}, @{$cd->{admin}}, 
631                        @{$cd->{user}}, @{$cd->{audit}}) {
632             $valid_privs->{$p} = 1;
633         }
634         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
635
636             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
637             $special_roles->{"PVEAdmin"}->{$p} = 1;
638         }
639         if (scalar(@{$cd->{user}})) {
640             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
641                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
642             }
643         }
644         foreach my $p (@{$cd->{audit}}) {
645             $special_roles->{"PVEAuditor"}->{$p} = 1;
646         }
647     }
648 };
649
650 create_roles();
651
652 my $valid_attributes = {
653     ad => {
654         server1 => '[\w\d]+(.[\w\d]+)*',
655         server2 => '[\w\d]+(.[\w\d]+)*',
656         domain => '\S+',
657         port => '\d+',
658         secure => '',
659         comment => '.*',
660     },
661     ldap => {
662         server1 => '[\w\d]+(.[\w\d]+)*',
663         server2 => '[\w\d]+(.[\w\d]+)*',
664         base_dn => '\w+=[\w\s]+(,\s*\w+=[\w\s]+)*',
665         user_attr => '\S{2,}',
666         secure => '',
667         port => '\d+',
668         comment => '.*',
669     }
670 };
671
672 sub add_role_privs {
673     my ($role, $usercfg, $privs) = @_;
674
675     return if !$privs;
676
677     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
678
679     foreach my $priv (split_list($privs)) {
680         if (defined ($valid_privs->{$priv})) {
681             $usercfg->{roles}->{$role}->{$priv} = 1;
682         } else {
683             die "invalid priviledge '$priv'\n";
684         } 
685     }   
686 }
687
688 sub normalize_path {
689     my $path = shift;
690
691     $path =~ s|/+|/|g;
692
693     $path =~ s|/$||;
694
695     $path = '/' if !$path;
696
697     $path = "/$path" if $path !~ m|^/|;
698
699     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
700
701     return $path;
702
703
704 my $realm_regex = qr/[A-Za-z][A-Za-z0-9\.\-_]+/;
705
706 sub pve_verify_realm {
707     my ($realm, $noerr) = @_;
708  
709     if ($realm !~ m/^${realm_regex}$/) {
710         return undef if $noerr;
711         die "value does not look like a valid realm\n"; 
712     }
713     return $realm;
714 }
715
716 PVE::JSONSchema::register_format('pve-userid', \&verify_username);
717 sub verify_username {
718     my ($username, $noerr) = @_;
719
720     $username = '' if !$username;
721     my $len = length($username);
722     if ($len < 3) {
723         die "user name '$username' is too short\n" if !$noerr;
724         return undef;
725     }
726     if ($len > 64) {
727         die "user name '$username' is too long ($len > 64)\n" if !$noerr;
728         return undef;
729     }
730
731     # we only allow a limited set of characters (colon is not allowed,
732     # because we store usernames in colon separated lists)!
733     if ($username =~ m/^([^\s:]+)\@(${realm_regex})$/) {
734         return wantarray ? ($username, $1, $2) : $username;
735     }
736
737     die "value '$username' does not look like a valid user name\n" if !$noerr;
738
739     return undef;
740 }
741 PVE::JSONSchema::register_standard_option('userid', {
742     description => "User ID",
743     type => 'string', format => 'pve-userid',
744     maxLength => 64,
745 });
746
747 PVE::JSONSchema::register_standard_option('realm', {
748     description => "Authentication domain ID",
749     type => 'string', format => 'pve-configid',
750     maxLength => 32,
751 });
752
753 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
754 sub verify_groupname {
755     my ($groupname, $noerr) = @_;
756
757     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
758
759         die "group name '$groupname' contains invalid characters\n" if !$noerr;
760
761         return undef;
762     }
763     
764     return $groupname;
765 }
766
767 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
768 sub verify_rolename {
769     my ($rolename, $noerr) = @_;
770
771     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
772
773         die "role name '$rolename' contains invalid characters\n" if !$noerr;
774
775         return undef;
776     }
777     
778     return $rolename;
779 }
780
781 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
782 sub verify_poolname {
783     my ($poolname, $noerr) = @_;
784
785     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
786
787         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
788
789         return undef;
790     }
791     
792     return $poolname;
793 }
794
795 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
796 sub verify_privname {
797     my ($priv, $noerr) = @_;
798
799     if (!$valid_privs->{$priv}) {
800         die "invalid priviledge '$priv'\n" if !$noerr;
801
802         return undef;
803     }
804     
805     return $priv;
806 }
807
808 sub userconfig_force_defaults {
809     my ($cfg) = @_;
810
811     foreach my $r (keys %$special_roles) {
812         $cfg->{roles}->{$r} = $special_roles->{$r};
813     }
814
815     # fixme: remove 'root' group (not required)?
816
817     # add root user 
818     $cfg->{users}->{'root@pam'}->{enable} = 1;
819 }
820
821 sub parse_user_config {
822     my ($filename, $raw) = @_;
823
824     my $cfg = {};
825
826     userconfig_force_defaults($cfg);
827
828     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
829         my $line = $1;
830
831         next if $line =~ m/^\s*$/; # skip empty lines
832
833         my @data;
834
835         foreach my $d (split (/:/, $line)) {
836             $d =~ s/^\s+//; 
837             $d =~ s/\s+$//;
838             push @data, $d
839         }
840
841         my $et = shift @data;
842
843         if ($et eq 'user') {
844             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
845
846             my (undef, undef, $realm) = verify_username($user, 1);
847             if (!$realm) {
848                 warn "user config - ignore user '$user' - invalid user name\n";
849                 next;
850             }
851
852             $enable = $enable ? 1 : 0;
853
854             $expire = 0 if !$expire;
855
856             if ($expire !~ m/^\d+$/) {
857                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
858                 next;
859             }
860             $expire = int($expire);
861
862             #if (!verify_groupname ($group, 1)) {
863             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
864             #    next;
865             #}
866
867             $cfg->{users}->{$user} = {
868                 enable => $enable,
869                 # group => $group,
870             };
871             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
872             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
873             $cfg->{users}->{$user}->{email} = $email;
874             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
875             $cfg->{users}->{$user}->{expire} = $expire;
876
877             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
878             #$cfg->{groups}->{$group}->{$user} = 1;
879
880         } elsif ($et eq 'group') {
881             my ($group, $userlist, $comment) = @data;
882
883             if (!verify_groupname($group, 1)) {
884                 warn "user config - ignore group '$group' - invalid characters in group name\n";
885                 next;
886             }
887
888             # make sure to add the group (even if there are no members)
889             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
890
891             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
892
893             foreach my $user (split_list($userlist)) {
894
895                 if (!verify_username($user, 1)) {
896                     warn "user config - ignore invalid group member '$user'\n";
897                     next;
898                 }
899
900                 if ($cfg->{users}->{$user}) { # user exists 
901                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
902                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
903                 } else {
904                     warn "user config - ignore invalid group member '$user'\n";
905                 }
906             }
907
908         } elsif ($et eq 'role') {
909             my ($role, $privlist) = @data;
910                 
911             if (!verify_rolename($role, 1)) {
912                 warn "user config - ignore role '$role' - invalid characters in role name\n";
913                 next;
914             }
915
916             # make sure to add the role (even if there are no privileges)
917             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
918
919             foreach my $priv (split_list($privlist)) {
920                 if (defined ($valid_privs->{$priv})) {
921                     $cfg->{roles}->{$role}->{$priv} = 1;
922                 } else {
923                     warn "user config - ignore invalid priviledge '$priv'\n";
924                 } 
925             }
926             
927         } elsif ($et eq 'acl') {
928             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
929
930             if (my $path = normalize_path($pathtxt)) {
931                 foreach my $role (split_list($rolelist)) {
932                         
933                     if (!verify_rolename($role, 1)) {
934                         warn "user config - ignore invalid role name '$role' in acl\n";
935                         next;
936                     }
937
938                     foreach my $ug (split_list($uglist)) {
939                         if ($ug =~ m/^@(\w+)$/) {
940                             my $group = $1;
941                             if ($cfg->{groups}->{$group}) { # group exists 
942                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
943                             } else {
944                                 warn "user config - ignore invalid acl group '$group'\n";
945                             }
946                         } elsif (verify_username($ug, 1)) {
947                             if ($cfg->{users}->{$ug}) { # user exists 
948                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
949                             } else {
950                                 warn "user config - ignore invalid acl member '$ug'\n";
951                             }
952                         } else {
953                             warn "user config - invalid user/group '$ug' in acl\n";
954                         }
955                     }
956                 }
957             } else {
958                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
959             }
960         } elsif ($et eq 'pool') {
961             my ($pool, $comment, $vmlist, $storelist) = @data;
962
963             if (!verify_poolname($pool, 1)) {
964                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
965                 next;
966             }
967
968             # make sure to add the pool (even if there are no members)
969             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
970
971             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
972
973             foreach my $vmid (split_list($vmlist)) {
974                 if ($vmid !~ m/^\d+$/) {
975                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
976                     next;
977                 }
978                 $vmid = int($vmid);
979
980                 if ($cfg->{vms}->{$vmid}) {
981                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
982                     next;
983                 }
984
985                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
986                     
987                 # record vmid ==> pool relation
988                 $cfg->{vms}->{$vmid} = $pool;
989             }
990
991             foreach my $storeid (split_list($storelist)) {
992                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
993                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
994                     next;
995                 }
996                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
997             }
998         } else {
999             warn "user config - ignore config line: $line\n";
1000         }
1001     }
1002
1003     userconfig_force_defaults($cfg);
1004
1005     return $cfg;
1006 }
1007
1008 sub parse_shadow_passwd {
1009     my ($filename, $raw) = @_;
1010
1011     my $shadow = {};
1012
1013     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1014         my $line = $1;
1015
1016         next if $line =~ m/^\s*$/; # skip empty lines
1017
1018         if ($line !~ m/^\S+:\S+:$/) {
1019             warn "pve shadow password: ignore invalid line $.\n";
1020             next;
1021         }
1022
1023         my ($userid, $crypt_pass) = split (/:/, $line);
1024         $shadow->{users}->{$userid}->{shadow} = $crypt_pass;
1025     }
1026
1027     return $shadow;
1028 }
1029
1030 sub write_domains {
1031     my ($filename, $cfg) = @_;
1032
1033     my $data = '';
1034
1035     my $wrote_default;
1036
1037     foreach my $realm (sort keys %$cfg) {
1038         my $entry = $cfg->{$realm};
1039         my $type = lc($entry->{type});
1040
1041         next if !$type;
1042
1043         next if ($type eq 'pam') || ($type eq 'pve');
1044
1045         my $formats = $valid_attributes->{$type};
1046         next if !$formats;
1047
1048         $data .= "$type: $realm\n";
1049
1050         foreach my $k (sort keys %$entry) {
1051             next if $k eq 'type';
1052             my $v = $entry->{$k};
1053             if ($k eq 'default') {
1054                     $data .= "\t$k\n" if $v && !$wrote_default;
1055                     $wrote_default = 1;
1056             } elsif (defined($formats->{$k})) {
1057                 if (!$formats->{$k}) {
1058                     $data .= "\t$k\n" if $v;
1059                 } elsif ($v =~ m/^$formats->{$k}$/) {
1060                     $v = PVE::Tools::encode_text($v) if $k eq 'comment';
1061                     $data .= "\t$k $v\n";
1062                 } else {
1063                     die "invalid value '$v' for attribute '$k'\n";
1064                 }
1065             } else {
1066                 die "invalid attribute '$k' - not supported\n";
1067             }
1068         }
1069
1070         $data .= "\n";
1071     }
1072
1073     return $data;
1074 }
1075
1076 sub parse_domains {
1077     my ($filename, $raw) = @_;
1078
1079     my $cfg = {};
1080
1081     my $default;
1082
1083     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1084         my $line = $1;
1085  
1086         next if $line =~ m/^\#/; # skip comment lines
1087         next if $line =~ m/^\s*$/; # skip empty lines
1088
1089         if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
1090             my $realm = $2;
1091             my $type = lc($1);
1092
1093             my $ignore = 0;
1094             my $entry;
1095
1096             my $formats = $valid_attributes->{$type};
1097             if (!$formats) {
1098                 $ignore = 1;
1099                 warn "ignoring domain '$realm' - (unsupported authentication type '$type')\n";
1100             } elsif (!pve_verify_realm($realm, 1)) {
1101                 $ignore = 1;
1102                 warn "ignoring domain '$realm' - (illegal characters)\n";
1103             } else {
1104                 $entry = { type => $type };
1105             }
1106
1107             while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1108                 $line = $1;
1109
1110                 next if $line =~ m/^\#/; #skip comment lines
1111                 last if $line =~ m/^\s*$/;
1112                     
1113                 next if $ignore; # skip
1114
1115                 if ($line =~ m/^\s+(default)\s*$/) {
1116                     $default = $realm if !$default;
1117                 } elsif ($line =~ m/^\s+(\S+)(\s+(.*\S))?\s*$/) {
1118                     my ($k, $v) = (lc($1), $3);
1119                     if (defined($formats->{$k})) {
1120                         if (!$formats->{$k} && !defined($v)) {
1121                                 $entry->{$k} = 1;                           
1122                         } elsif ($formats->{$k} && $v =~ m/^$formats->{$k}$/) {
1123                             if (!defined($entry->{$k})) {
1124                                 $v = PVE::Tools::decode_text($v) if $k eq 'comment';
1125                                 $entry->{$k} = $v;
1126                             } else {
1127                                 warn "ignoring duplicate attribute '$k $v'\n";
1128                             }
1129                         } else {
1130                             warn "ignoring value '$v' for attribute '$k' - invalid format\n";
1131                         }
1132                     } else {
1133                         warn "ignoring attribute '$k' - not supported\n";
1134                     }
1135                 } else {
1136                     warn "ignore config line: $line\n";
1137                 }
1138             }
1139
1140             if ($entry->{server2} && !$entry->{server1}) {
1141                 $entry->{server1} = $entry->{server2};
1142                 delete $entry->{server2};
1143             }
1144
1145             if ($ignore) {
1146                 # do nothing
1147             } elsif (!$entry->{server1}) {
1148                 warn "ignoring domain '$realm' - missing server attribute\n";
1149             } elsif (($entry->{type} eq "ldap") && !$entry->{user_attr}) {
1150                 warn "ignoring domain '$realm' - missing user attribute\n";
1151             } elsif (($entry->{type} eq "ldap") && !$entry->{base_dn}) {
1152                 warn "ignoring domain '$realm' - missing base_dn attribute\n";
1153             } elsif (($entry->{type} eq "ad") && !$entry->{domain}) {
1154                 warn "ignoring domain '$realm' - missing domain attribute\n";
1155             } else {
1156                 $cfg->{$realm} = $entry;
1157             }
1158      
1159         } else {
1160             warn "ignore config line: $line\n";
1161         }
1162     }
1163
1164     $cfg->{$default}->{default} = 1 if $default;
1165
1166     # add default domains
1167
1168     $cfg->{pve} = {
1169         type => 'builtin',
1170         comment => "Proxmox VE authentication server", 
1171     };
1172
1173     $cfg->{pam} = {
1174         type => 'builtin',
1175         comment => "Linux PAM standard authentication", 
1176     };
1177         
1178     return $cfg;
1179 }
1180
1181 sub write_shadow_config {
1182     my ($filename, $cfg) = @_;
1183
1184     my $data = '';
1185     foreach my $userid (keys %{$cfg->{users}}) {
1186         my $crypt_pass = $cfg->{users}->{$userid}->{shadow};
1187         $data .= "$userid:$crypt_pass:\n";
1188     }
1189
1190     return $data
1191 }
1192
1193 sub write_user_config {
1194     my ($filename, $cfg) = @_;
1195
1196     my $data = '';
1197
1198     foreach my $user (keys %{$cfg->{users}}) {
1199         my $d = $cfg->{users}->{$user};
1200         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1201         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1202         my $email = $d->{email} || '';
1203         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1204         my $expire = int($d->{expire} || 0);
1205         my $enable = $d->{enable} ? 1 : 0;
1206         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
1207     }
1208
1209     $data .= "\n";
1210
1211     foreach my $group (keys %{$cfg->{groups}}) {
1212         my $d = $cfg->{groups}->{$group};
1213         my $list = join (',', keys %{$d->{users}});
1214         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
1215         $data .= "group:$group:$list:$comment:\n";
1216     }
1217
1218     $data .= "\n";
1219
1220     foreach my $pool (keys %{$cfg->{pools}}) {
1221         my $d = $cfg->{pools}->{$pool};
1222         my $vmlist = join (',', keys %{$d->{vms}});
1223         my $storelist = join (',', keys %{$d->{storage}});
1224         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
1225         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1226     }
1227
1228     $data .= "\n";
1229
1230     foreach my $role (keys %{$cfg->{roles}}) {
1231         next if $special_roles->{$role};
1232
1233         my $d = $cfg->{roles}->{$role};
1234         my $list = join (',', keys %$d);
1235         $data .= "role:$role:$list:\n";
1236     }
1237
1238     $data .= "\n";
1239
1240     foreach my $path (sort keys %{$cfg->{acl}}) {
1241         my $d = $cfg->{acl}->{$path};
1242
1243         my $ra = {};
1244
1245         foreach my $group (keys %{$d->{groups}}) {
1246             my $l0 = '';
1247             my $l1 = '';
1248             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
1249                 my $propagate = $d->{groups}->{$group}->{$role};
1250                 if ($propagate) {
1251                     $l1 .= ',' if $l1;
1252                     $l1 .= $role;
1253                 } else {
1254                     $l0 .= ',' if $l0;
1255                     $l0 .= $role;
1256                 }
1257             }
1258             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
1259             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
1260         }
1261
1262         foreach my $user (keys %{$d->{users}}) {
1263             # no need to save, because root is always 'Administartor'
1264             next if $user eq 'root@pam'; 
1265
1266             my $l0 = '';
1267             my $l1 = '';
1268             foreach my $role (sort keys %{$d->{users}->{$user}}) {
1269                 my $propagate = $d->{users}->{$user}->{$role};
1270                 if ($propagate) {
1271                     $l1 .= ',' if $l1;
1272                     $l1 .= $role;
1273                 } else {
1274                     $l0 .= ',' if $l0;
1275                     $l0 .= $role;
1276                 }
1277             }
1278             $ra->{0}->{$l0}->{$user} = 1 if $l0;
1279             $ra->{1}->{$l1}->{$user} = 1 if $l1;
1280         }
1281
1282         foreach my $rolelist (sort keys %{$ra->{0}}) {
1283             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
1284             $data .= "acl:0:$path:$uglist:$rolelist:\n";
1285         }
1286         foreach my $rolelist (sort keys %{$ra->{1}}) {
1287             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
1288             $data .= "acl:1:$path:$uglist:$rolelist:\n";
1289         }
1290     }
1291
1292     return $data;
1293 }
1294
1295 sub roles {
1296     my ($cfg, $user, $path) = @_;
1297
1298     # NOTE: we do not consider pools here. 
1299     # You need to use $rpcenv->roles() instead if you want that.
1300
1301     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1302
1303     my $perm = {};
1304
1305     foreach my $p (sort keys %{$cfg->{acl}}) {
1306         my $final = ($path eq $p);
1307
1308         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1309
1310         my $acl = $cfg->{acl}->{$p};
1311
1312         #print "CHECKACL $path $p\n";
1313         #print "ACL $path = " . Dumper ($acl);
1314
1315         if (my $ri = $acl->{users}->{$user}) {
1316             my $new;
1317             foreach my $role (keys %$ri) {
1318                 my $propagate = $ri->{$role};
1319                 if ($final || $propagate) {
1320                     #print "APPLY ROLE $p $user $role\n";
1321                     $new = {} if !$new;
1322                     $new->{$role} = 1;
1323                 }
1324             }
1325             if ($new) {
1326                 $perm = $new; # overwrite previous settings
1327                 next; # user privs always override group privs
1328             }
1329         }
1330
1331         my $new;
1332         foreach my $g (keys %{$acl->{groups}}) {
1333             next if !$cfg->{groups}->{$g}->{users}->{$user};
1334             if (my $ri = $acl->{groups}->{$g}) {
1335                 foreach my $role (keys %$ri) {
1336                     my $propagate = $ri->{$role};
1337                     if ($final || $propagate) {
1338                         #print "APPLY ROLE $p \@$g $role\n";
1339                         $new = {} if !$new;
1340                         $new->{$role} = 1;
1341                     }
1342                 }
1343             }
1344         }
1345         if ($new) {
1346             $perm = $new; # overwrite previous settings
1347             next;
1348         }
1349     }
1350
1351     return ('NoAccess') if defined ($perm->{NoAccess});
1352     #return () if defined ($perm->{NoAccess});
1353    
1354     #print "permission $user $path = " . Dumper ($perm);
1355
1356     my @ra = keys %$perm;
1357
1358     #print "roles $user $path = " . join (',', @ra) . "\n";
1359
1360     return @ra;
1361 }
1362     
1363 sub permission {
1364     my ($cfg, $user, $path) = @_;
1365
1366     $user = verify_username($user, 1);
1367     return {} if !$user;
1368
1369     my @ra = roles($cfg, $user, $path);
1370     
1371     my $privs = {};
1372
1373     foreach my $role (@ra) {
1374         if (my $privset = $cfg->{roles}->{$role}) {
1375             foreach my $p (keys %$privset) {
1376                 $privs->{$p} = 1;
1377             }
1378         }
1379     }
1380
1381     #print "priviledges $user $path = " . Dumper ($privs);
1382
1383     return $privs;
1384 }
1385
1386 sub check_permissions {
1387     my ($username, $path, $privlist) = @_;
1388
1389     $path = normalize_path($path);
1390     my $usercfg = cfs_read_file('user.cfg');
1391     my $perm = permission($usercfg, $username, $path);
1392
1393     foreach my $priv (split_list($privlist)) {
1394         return undef if !$perm->{$priv};
1395     };
1396
1397     return 1;
1398 }
1399
1400 1;