PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use IO::File;
  13 use File::stat;
  14 use JSON;
  15
  16 use PVE::OTP;
  17 use PVE::Ticket;
  18 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  19 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  20 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  21
  22 use PVE::Auth::Plugin;
  23 use PVE::Auth::AD;
  24 use PVE::Auth::LDAP;
  25 use PVE::Auth::PVE;
  26 use PVE::Auth::PAM;
  27
  28 # load and initialize all plugins
  29
  30 PVE::Auth::AD->register();
  31 PVE::Auth::LDAP->register();
  32 PVE::Auth::PVE->register();
  33 PVE::Auth::PAM->register();
  34 PVE::Auth::Plugin->init();
  35
  36 # $authdir must be writable by root only!
  37 my $confdir = "/etc/pve";
  38 my $authdir = "$confdir/priv";
  39
  40 my $pve_www_key_fn = "$confdir/pve-www.key";
  41
  42 my $pve_auth_key_files = {
  43     priv => "$authdir/authkey.key",
  44     pub =>  "$confdir/authkey.pub",
  45     pubold => "$confdir/authkey.pub.old",
  46 };
  47
  48 my $pve_auth_key_cache = {};
  49
  50 my $ticket_lifetime = 3600 * 2; # 2 hours
  51 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  52
  53 Crypt::OpenSSL::RSA->import_random_seed();
  54
  55 cfs_register_file('user.cfg',
  56                   \&parse_user_config,
  57                   \&write_user_config);
  58 cfs_register_file('priv/tfa.cfg',
  59                   \&parse_priv_tfa_config,
  60                   \&write_priv_tfa_config);
  61
  62 sub verify_username {
  63     PVE::Auth::Plugin::verify_username(@_);
  64 }
  65
  66 sub pve_verify_realm {
  67     PVE::Auth::Plugin::pve_verify_realm(@_);
  68 }
  69
  70 sub lock_user_config {
  71     my ($code, $errmsg) = @_;
  72
  73     cfs_lock_file("user.cfg", undef, $code);
  74     if (my $err = $@) {
  75         $errmsg ? die "$errmsg: $err" : die $err;
  76     }
  77 }
  78
  79 my $cache_read_key = sub {
  80     my ($type) = @_;
  81
  82     my $path = $pve_auth_key_files->{$type};
  83
  84     my $read_key_and_mtime = sub {
  85         my $fh = IO::File->new($path, "r");
  86
  87         return undef if !defined($fh);
  88
  89         my $st = stat($fh);
  90         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
  91
  92         close $fh;
  93
  94         my $key;
  95         if ($type eq 'pub' || $type eq 'pubold') {
  96             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
  97         } elsif ($type eq 'priv') {
  98             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
  99         } else {
 100             die "Invalid authkey type '$type'\n";
 101         }
 102
 103         return { key => $key, mtime => $st->mtime };
 104     };
 105
 106     if (!defined($pve_auth_key_cache->{$type})) {
 107         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 108     } else {
 109         my $st = stat($path);
 110         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 111             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 112         }
 113     }
 114
 115     return $pve_auth_key_cache->{$type};
 116 };
 117
 118 sub get_pubkey {
 119     my ($old) = @_;
 120
 121     my $type = $old ? 'pubold' : 'pub';
 122
 123     my $res = $cache_read_key->($type);
 124     return undef if !defined($res);
 125
 126     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 127 }
 128
 129 sub get_privkey {
 130     my $res = $cache_read_key->('priv');
 131
 132     if (!defined($res) || !check_authkey(1)) {
 133         rotate_authkey();
 134         $res = $cache_read_key->('priv');
 135     }
 136
 137     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 138 }
 139
 140 sub check_authkey {
 141     my ($quiet) = @_;
 142
 143     # skip check if non-quorate, as rotation is not possible anyway
 144     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 145
 146     my ($pub_key, $mtime) = get_pubkey();
 147     if (!$pub_key) {
 148         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 149         return 0;
 150     } else {
 151         if (time() - $mtime >= $authkey_lifetime) {
 152             warn "auth key pair too old, rotating..\n" if !$quiet;;
 153             return 0;
 154         } else {
 155             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 156             return 1;
 157         }
 158     }
 159 }
 160
 161 sub rotate_authkey {
 162     return if $authkey_lifetime == 0;
 163
 164     PVE::Cluster::cfs_lock_authkey(undef, sub {
 165         # re-check with lock to avoid double rotation in clusters
 166         return if check_authkey();
 167
 168         my $old = get_pubkey();
 169         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 170
 171         if ($old) {
 172             eval {
 173                 my $pem = $old->get_public_key_x509_string();
 174                 # mtime is used for caching and ticket age range calculation
 175                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 176             };
 177             die "Failed to store old auth key: $@\n" if $@;
 178         }
 179
 180         eval {
 181             my $pem = $new->get_public_key_x509_string();
 182             # mtime is used for caching and ticket age range calculation,
 183             # should be close to that of pubold above
 184             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 185         };
 186         if ($@) {
 187             if ($old) {
 188                 warn "Failed to store new auth key - $@\n";
 189                 warn "Reverting to previous auth key\n";
 190                 eval {
 191                     my $pem = $old->get_public_key_x509_string();
 192                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 193                 };
 194                 die "Failed to restore old auth key: $@\n" if $@;
 195             } else {
 196                 die "Failed to store new auth key - $@\n";
 197             }
 198         }
 199
 200         eval {
 201             my $pem = $new->get_private_key_string();
 202             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 203         };
 204         if ($@) {
 205             warn "Failed to store new auth key - $@\n";
 206             warn "Deleting auth key to force regeneration\n";
 207             unlink $pve_auth_key_files->{pub};
 208             unlink $pve_auth_key_files->{priv};
 209         }
 210     });
 211     die $@ if $@;
 212 }
 213
 214 PVE::JSONSchema::register_standard_option('tokenid', {
 215     description => "API token identifier.",
 216     type => "string",
 217     format => "pve-tokenid",
 218 });
 219
 220 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 221
 222 # username@realm username realm tokenid
 223 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 224
 225 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 226
 227 sub split_tokenid {
 228     my ($tokenid, $noerr) = @_;
 229
 230     if ($tokenid =~ /^${token_full_regex}$/) {
 231         return ($1, $4);
 232     }
 233
 234     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 235
 236     return undef;
 237 }
 238
 239 sub join_tokenid {
 240     my ($username, $tokensubid) = @_;
 241
 242     my $joined = "${username}!${tokensubid}";
 243
 244     return pve_verify_tokenid($joined);
 245 }
 246
 247 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 248 sub pve_verify_tokenid {
 249     my ($tokenid, $noerr) = @_;
 250
 251     if ($tokenid =~ /^${token_full_regex}$/) {
 252         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 253     }
 254
 255     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 256
 257     return undef;
 258 }
 259
 260
 261 my $csrf_prevention_secret;
 262 my $csrf_prevention_secret_legacy;
 263 my $get_csrfr_secret = sub {
 264     if (!$csrf_prevention_secret) {
 265         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 266         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 267         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 268     }
 269     return $csrf_prevention_secret;
 270 };
 271
 272 sub assemble_csrf_prevention_token {
 273     my ($username) = @_;
 274
 275     my $secret =  &$get_csrfr_secret();
 276
 277     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 278 }
 279
 280 sub verify_csrf_prevention_token {
 281     my ($username, $token, $noerr) = @_;
 282
 283     my $secret = $get_csrfr_secret->();
 284
 285     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 286     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 287         my $sig = $2;
 288         if (length($sig) == 27) {
 289             # the legacy secret got populated by above get_csrfr_secret call
 290             $secret = $csrf_prevention_secret_legacy;
 291         }
 292     }
 293
 294     return PVE::Ticket::verify_csrf_prevention_token(
 295         $secret, $username, $token, -300, $ticket_lifetime, $noerr);
 296 }
 297
 298 my $get_ticket_age_range = sub {
 299     my ($now, $mtime, $rotated) = @_;
 300
 301     my $key_age = $now - $mtime;
 302     $key_age = 0 if $key_age < 0;
 303
 304     my $min = -300;
 305     my $max = $ticket_lifetime;
 306
 307     if ($rotated) {
 308         # ticket creation after rotation is not allowed
 309         $min = $key_age - 300;
 310     } else {
 311         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 312             if (PVE::Cluster::check_cfs_quorum(1)) {
 313                 # key should have been rotated, clamp range accordingly
 314                 $min = $key_age - $authkey_lifetime;
 315             } else {
 316                 warn "Cluster not quorate - extending auth key lifetime!\n";
 317             }
 318         }
 319
 320         $max = $key_age + 300 if $key_age < $ticket_lifetime;
 321     }
 322
 323     return undef if $min > $ticket_lifetime;
 324     return ($min, $max);
 325 };
 326
 327 sub assemble_ticket {
 328     my ($data) = @_;
 329
 330     my $rsa_priv = get_privkey();
 331
 332     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data);
 333 }
 334
 335 sub verify_ticket {
 336     my ($ticket, $noerr) = @_;
 337
 338     my $now = time();
 339
 340     my $check = sub {
 341         my ($old) = @_;
 342
 343         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 344         return undef if !$rsa_pub;
 345
 346         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 347         return undef if !defined($min);
 348
 349         return PVE::Ticket::verify_rsa_ticket(
 350             $rsa_pub, 'PVE', $ticket, undef, $min, $max, 1);
 351     };
 352
 353     my ($data, $age) = $check->();
 354
 355     # check with old, rotated key if current key failed
 356     ($data, $age) = $check->(1) if !defined($data);
 357
 358     my $auth_failure = sub {
 359         if ($noerr) {
 360             return undef;
 361         } else {
 362             # raise error via undef ticket
 363             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 364         }
 365     };
 366
 367     if (!defined($data)) {
 368         return $auth_failure->();
 369     }
 370
 371     my ($username, $tfa_info);
 372     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 373         # Ticket for u2f-users:
 374         ($username, my $challenge) = ($1, $2);
 375         if ($challenge eq 'verified') {
 376             # u2f challenge was completed
 377             $challenge = undef;
 378         } elsif (!wantarray) {
 379             # The caller is not aware there could be an ongoing challenge,
 380             # so we treat this ticket as invalid:
 381             return $auth_failure->();
 382         }
 383         $tfa_info = {
 384             type => 'u2f',
 385             challenge => $challenge,
 386         };
 387     } elsif ($data =~ /^tfa!(.*)$/) {
 388         # TOTP and Yubico don't require a challenge so this is the generic
 389         # 'missing 2nd factor ticket'
 390         $username = $1;
 391         $tfa_info = { type => 'tfa' };
 392     } else {
 393         # Regular ticket (full access)
 394         $username = $data;
 395     }
 396
 397     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 398
 399     return wantarray ? ($username, $age, $tfa_info) : $username;
 400 }
 401
 402 sub verify_token {
 403     my ($api_token) = @_;
 404
 405     die "no API token specified\n" if !$api_token;
 406
 407     my ($tokenid, $value);
 408     if ($api_token =~ /^(.*)=(.*)$/) {
 409         $tokenid = $1;
 410         $value = $2;
 411     } else {
 412         die "no tokenid specified\n";
 413     }
 414
 415     my ($username, $token) = split_tokenid($tokenid);
 416
 417     my $usercfg = cfs_read_file('user.cfg');
 418     check_user_enabled($usercfg, $username);
 419     check_token_exist($usercfg, $username, $token);
 420
 421     my $ctime = time();
 422
 423     my $user = $usercfg->{users}->{$username};
 424     die "account expired\n" if $user->{expire} && ($user->{expire} < $ctime);
 425
 426     my $token_info = $user->{tokens}->{$token};
 427     die "token expired\n" if $token_info->{expire} && ($token_info->{expire} < $ctime);
 428
 429     die "invalid token value!\n" if !PVE::Cluster::verify_token($tokenid, $value);
 430
 431     return wantarray ? ($tokenid) : $tokenid;
 432 }
 433
 434
 435 # VNC tickets
 436 # - they do not contain the username in plain text
 437 # - they are restricted to a specific resource path (example: '/vms/100')
 438 sub assemble_vnc_ticket {
 439     my ($username, $path) = @_;
 440
 441     my $rsa_priv = get_privkey();
 442
 443     $path = normalize_path($path);
 444
 445     my $secret_data = "$username:$path";
 446
 447     return PVE::Ticket::assemble_rsa_ticket(
 448         $rsa_priv, 'PVEVNC', undef, $secret_data);
 449 }
 450
 451 sub verify_vnc_ticket {
 452     my ($ticket, $username, $path, $noerr) = @_;
 453
 454     my $secret_data = "$username:$path";
 455
 456     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 457     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 458         if ($noerr) {
 459             return undef;
 460         } else {
 461             # raise error via undef ticket
 462             PVE::Ticket::verify_rsa_ticket($rsa_pub, 'PVEVNC');
 463         }
 464     }
 465
 466     return PVE::Ticket::verify_rsa_ticket(
 467         $rsa_pub, 'PVEVNC', $ticket, $secret_data, -20, 40, $noerr);
 468 }
 469
 470 sub assemble_spice_ticket {
 471     my ($username, $vmid, $node) = @_;
 472
 473     my $secret = &$get_csrfr_secret();
 474
 475     return PVE::Ticket::assemble_spice_ticket(
 476         $secret, $username, $vmid, $node);
 477 }
 478
 479 sub verify_spice_connect_url {
 480     my ($connect_str) = @_;
 481
 482     my $secret = &$get_csrfr_secret();
 483
 484     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 485 }
 486
 487 sub read_x509_subject_spice {
 488     my ($filename) = @_;
 489
 490     # read x509 subject
 491     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 492     die "Could not open $filename using OpenSSL\n"
 493         if !$bio;
 494
 495     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 496     Net::SSLeay::BIO_free($bio);
 497
 498     die "Could not parse X509 certificate in $filename\n"
 499         if !$x509;
 500
 501     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 502     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 503     Net::SSLeay::X509_free($x509);
 504
 505     # remote-viewer wants comma as seperator (not '/')
 506     $subject =~ s!^/!!;
 507     $subject =~ s!/(\w+=)!,$1!g;
 508
 509     return $subject;
 510 }
 511
 512 # helper to generate SPICE remote-viewer configuration
 513 sub remote_viewer_config {
 514     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 515
 516     if (!$proxy) {
 517         my $host = `hostname -f` || PVE::INotify::nodename();
 518         chomp $host;
 519         $proxy = $host;
 520     }
 521
 522     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 523
 524     my $filename = "/etc/pve/local/pve-ssl.pem";
 525     my $subject = read_x509_subject_spice($filename);
 526
 527     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 528     $cacert =~ s/\n/\\n/g;
 529
 530     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 531     my $config = {
 532         'secure-attention' => "Ctrl+Alt+Ins",
 533         'toggle-fullscreen' => "Shift+F11",
 534         'release-cursor' => "Ctrl+Alt+R",
 535         type => 'spice',
 536         title => $title,
 537         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 538         proxy => "http://$proxy:3128",
 539         'tls-port' => $port,
 540         'host-subject' => $subject,
 541         ca => $cacert,
 542         password => $ticket,
 543         'delete-this-file' => 1,
 544     };
 545
 546     return ($ticket, $proxyticket, $config);
 547 }
 548
 549 sub check_user_exist {
 550     my ($usercfg, $username, $noerr) = @_;
 551
 552     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 553     return undef if !$username;
 554
 555     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 556
 557     die "no such user ('$username')\n" if !$noerr;
 558
 559     return undef;
 560 }
 561
 562 sub check_user_enabled {
 563     my ($usercfg, $username, $noerr) = @_;
 564
 565     my $data = check_user_exist($usercfg, $username, $noerr);
 566     return undef if !$data;
 567
 568     return 1 if $data->{enable};
 569
 570     die "user '$username' is disabled\n" if !$noerr;
 571
 572     return undef;
 573 }
 574
 575 sub check_token_exist {
 576     my ($usercfg, $username, $tokenid, $noerr) = @_;
 577
 578     my $user = check_user_exist($usercfg, $username, $noerr);
 579     return undef if !$user;
 580
 581     return $user->{tokens}->{$tokenid}
 582         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 583
 584     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 585
 586     return undef;
 587 }
 588
 589 sub verify_one_time_pw {
 590     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 591
 592     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 593
 594     # fixme: proxy support?
 595     my $proxy;
 596
 597     if ($type eq 'yubico') {
 598         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 599                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 600     } elsif ($type eq 'oath') {
 601         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 602     } else {
 603         die "unknown tfa type '$type'\n";
 604     }
 605 }
 606
 607 # password should be utf8 encoded
 608 # Note: some plugins delay/sleep if auth fails
 609 sub authenticate_user {
 610     my ($username, $password, $otp) = @_;
 611
 612     die "no username specified\n" if !$username;
 613
 614     my ($ruid, $realm);
 615
 616     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 617
 618     my $usercfg = cfs_read_file('user.cfg');
 619
 620     check_user_enabled($usercfg, $username);
 621
 622     my $ctime = time();
 623     my $expire = $usercfg->{users}->{$username}->{expire};
 624
 625     die "account expired\n" if $expire && ($expire < $ctime);
 626
 627     my $domain_cfg = cfs_read_file('domains.cfg');
 628
 629     my $cfg = $domain_cfg->{ids}->{$realm};
 630     die "auth domain '$realm' does not exist\n" if !$cfg;
 631     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 632     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 633
 634     my ($type, $tfa_data) = user_get_tfa($username, $realm);
 635     if ($type) {
 636         if ($type eq 'u2f') {
 637             # Note that if the user did not manage to complete the initial u2f registration
 638             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 639             $tfa_data = undef if exists $tfa_data->{challenge};
 640         } elsif (!defined($otp)) {
 641             # The user requires a 2nd factor but has not provided one. Return success but
 642             # don't clear $tfa_data.
 643         } else {
 644             my $keys = $tfa_data->{keys};
 645             my $tfa_cfg = $tfa_data->{config};
 646             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 647             $tfa_data = undef;
 648         }
 649
 650         # Return the type along with the rest:
 651         if ($tfa_data) {
 652             $tfa_data = {
 653                 type => $type,
 654                 data => $tfa_data,
 655             };
 656         }
 657     }
 658
 659     return wantarray ? ($username, $tfa_data) : $username;
 660 }
 661
 662 sub domain_set_password {
 663     my ($realm, $username, $password) = @_;
 664
 665     die "no auth domain specified" if !$realm;
 666
 667     my $domain_cfg = cfs_read_file('domains.cfg');
 668
 669     my $cfg = $domain_cfg->{ids}->{$realm};
 670     die "auth domain '$realm' does not exist\n" if !$cfg;
 671     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 672     $plugin->store_password($cfg, $realm, $username, $password);
 673 }
 674
 675 sub add_user_group {
 676     my ($username, $usercfg, $group) = @_;
 677
 678     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 679     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 680 }
 681
 682 sub delete_user_group {
 683     my ($username, $usercfg) = @_;
 684
 685     foreach my $group (keys %{$usercfg->{groups}}) {
 686
 687         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 688             if $usercfg->{groups}->{$group}->{users}->{$username};
 689     }
 690 }
 691
 692 sub delete_user_acl {
 693     my ($username, $usercfg) = @_;
 694
 695     foreach my $acl (keys %{$usercfg->{acl}}) {
 696
 697         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 698             if $usercfg->{acl}->{$acl}->{users}->{$username};
 699     }
 700 }
 701
 702 sub delete_group_acl {
 703     my ($group, $usercfg) = @_;
 704
 705     foreach my $acl (keys %{$usercfg->{acl}}) {
 706
 707         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 708             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 709     }
 710 }
 711
 712 sub delete_pool_acl {
 713     my ($pool, $usercfg) = @_;
 714
 715     my $path = "/pool/$pool";
 716
 717     delete ($usercfg->{acl}->{$path})
 718 }
 719
 720 # we automatically create some predefined roles by splitting privs
 721 # into 3 groups (per category)
 722 # root: only root is allowed to do that
 723 # admin: an administrator can to that
 724 # user: a normal user/customer can to that
 725 my $privgroups = {
 726     VM => {
 727         root => [],
 728         admin => [
 729             'VM.Config.Disk',
 730             'VM.Config.CPU',
 731             'VM.Config.Memory',
 732             'VM.Config.Network',
 733             'VM.Config.HWType',
 734             'VM.Config.Options', # covers all other things
 735             'VM.Allocate',
 736             'VM.Clone',
 737             'VM.Migrate',
 738             'VM.Monitor',
 739             'VM.Snapshot',
 740             'VM.Snapshot.Rollback',
 741         ],
 742         user => [
 743             'VM.Config.CDROM', # change CDROM media
 744             'VM.Console',
 745             'VM.Backup',
 746             'VM.PowerMgmt',
 747         ],
 748         audit => [
 749             'VM.Audit',
 750         ],
 751     },
 752     Sys => {
 753         root => [
 754             'Sys.PowerMgmt',
 755             'Sys.Modify', # edit/change node settings
 756         ],
 757         admin => [
 758             'Permissions.Modify',
 759             'Sys.Console',
 760             'Sys.Syslog',
 761         ],
 762         user => [],
 763         audit => [
 764             'Sys.Audit',
 765         ],
 766     },
 767     Datastore => {
 768         root => [],
 769         admin => [
 770             'Datastore.Allocate',
 771             'Datastore.AllocateTemplate',
 772         ],
 773         user => [
 774             'Datastore.AllocateSpace',
 775         ],
 776         audit => [
 777             'Datastore.Audit',
 778         ],
 779     },
 780     SDN => {
 781         root => [],
 782         admin => [
 783             'SDN.Allocate',
 784             'SDN.Audit',
 785         ],
 786         audit => [
 787             'SDN.Audit',
 788         ],
 789     },
 790     User => {
 791         root => [
 792             'Realm.Allocate',
 793         ],
 794         admin => [
 795             'User.Modify',
 796             'Group.Allocate', # edit/change group settings
 797             'Realm.AllocateUser',
 798         ],
 799         user => [],
 800         audit => [],
 801     },
 802     Pool => {
 803         root => [],
 804         admin => [
 805             'Pool.Allocate', # create/delete pools
 806         ],
 807         user => [],
 808         audit => [],
 809     },
 810 };
 811
 812 my $valid_privs = {};
 813
 814 my $special_roles = {
 815     'NoAccess' => {}, # no privileges
 816     'Administrator' => $valid_privs, # all privileges
 817 };
 818
 819 sub create_roles {
 820
 821     foreach my $cat (keys %$privgroups) {
 822         my $cd = $privgroups->{$cat};
 823         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 824                        @{$cd->{user}}, @{$cd->{audit}}) {
 825             $valid_privs->{$p} = 1;
 826         }
 827         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 828
 829             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 830             $special_roles->{"PVEAdmin"}->{$p} = 1;
 831         }
 832         if (scalar(@{$cd->{user}})) {
 833             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 834                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 835             }
 836         }
 837         foreach my $p (@{$cd->{audit}}) {
 838             $special_roles->{"PVEAuditor"}->{$p} = 1;
 839         }
 840     }
 841
 842     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
 843 };
 844
 845 create_roles();
 846
 847 sub create_priv_properties {
 848     my $properties = {};
 849     foreach my $priv (keys %$valid_privs) {
 850         $properties->{$priv} = {
 851             type => 'boolean',
 852             optional => 1,
 853         };
 854     }
 855     return $properties;
 856 }
 857
 858 sub role_is_special {
 859     my ($role) = @_;
 860     return (exists $special_roles->{$role}) ? 1 : 0;
 861 }
 862
 863 sub add_role_privs {
 864     my ($role, $usercfg, $privs) = @_;
 865
 866     return if !$privs;
 867
 868     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 869
 870     foreach my $priv (split_list($privs)) {
 871         if (defined ($valid_privs->{$priv})) {
 872             $usercfg->{roles}->{$role}->{$priv} = 1;
 873         } else {
 874             die "invalid privilege '$priv'\n";
 875         }
 876     }
 877 }
 878
 879 sub normalize_path {
 880     my $path = shift;
 881
 882     $path =~ s|/+|/|g;
 883
 884     $path =~ s|/$||;
 885
 886     $path = '/' if !$path;
 887
 888     $path = "/$path" if $path !~ m|^/|;
 889
 890     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
 891
 892     return $path;
 893 }
 894
 895 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 896 sub verify_groupname {
 897     my ($groupname, $noerr) = @_;
 898
 899     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 900
 901         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 902
 903         return undef;
 904     }
 905
 906     return $groupname;
 907 }
 908
 909 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 910 sub verify_rolename {
 911     my ($rolename, $noerr) = @_;
 912
 913     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 914
 915         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 916
 917         return undef;
 918     }
 919
 920     return $rolename;
 921 }
 922
 923 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
 924 sub verify_poolname {
 925     my ($poolname, $noerr) = @_;
 926
 927     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 928
 929         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 930
 931         return undef;
 932     }
 933
 934     return $poolname;
 935 }
 936
 937 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 938 sub verify_privname {
 939     my ($priv, $noerr) = @_;
 940
 941     if (!$valid_privs->{$priv}) {
 942         die "invalid privilege '$priv'\n" if !$noerr;
 943
 944         return undef;
 945     }
 946
 947     return $priv;
 948 }
 949
 950 sub userconfig_force_defaults {
 951     my ($cfg) = @_;
 952
 953     foreach my $r (keys %$special_roles) {
 954         $cfg->{roles}->{$r} = $special_roles->{$r};
 955     }
 956
 957     # add root user if not exists
 958     if (!$cfg->{users}->{'root@pam'}) {
 959         $cfg->{users}->{'root@pam'}->{enable} = 1;
 960     }
 961 }
 962
 963 sub parse_user_config {
 964     my ($filename, $raw) = @_;
 965
 966     my $cfg = {};
 967
 968     userconfig_force_defaults($cfg);
 969
 970     $raw = '' if !defined($raw);
 971     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 972         my $line = $1;
 973         my @data;
 974
 975         foreach my $d (split (/:/, $line)) {
 976             $d =~ s/^\s+//;
 977             $d =~ s/\s+$//;
 978             push @data, $d
 979         }
 980
 981         my $et = shift @data;
 982
 983         if ($et eq 'user') {
 984             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
 985
 986             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 987             if (!$realm) {
 988                 warn "user config - ignore user '$user' - invalid user name\n";
 989                 next;
 990             }
 991
 992             $enable = $enable ? 1 : 0;
 993
 994             $expire = 0 if !$expire;
 995
 996             if ($expire !~ m/^\d+$/) {
 997                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 998                 next;
 999             }
1000             $expire = int($expire);
1001
1002             #if (!verify_groupname ($group, 1)) {
1003             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
1004             #    next;
1005             #}
1006
1007             $cfg->{users}->{$user} = {
1008                 enable => $enable,
1009                 # group => $group,
1010             };
1011             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
1012             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
1013             $cfg->{users}->{$user}->{email} = $email;
1014             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1015             $cfg->{users}->{$user}->{expire} = $expire;
1016             # keys: allowed yubico key ids or oath secrets (base32 encoded)
1017             $cfg->{users}->{$user}->{keys} = $keys if $keys;
1018
1019             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
1020             #$cfg->{groups}->{$group}->{$user} = 1;
1021
1022         } elsif ($et eq 'group') {
1023             my ($group, $userlist, $comment) = @data;
1024
1025             if (!verify_groupname($group, 1)) {
1026                 warn "user config - ignore group '$group' - invalid characters in group name\n";
1027                 next;
1028             }
1029
1030             # make sure to add the group (even if there are no members)
1031             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
1032
1033             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1034
1035             foreach my $user (split_list($userlist)) {
1036
1037                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1038                     warn "user config - ignore invalid group member '$user'\n";
1039                     next;
1040                 }
1041
1042                 if ($cfg->{users}->{$user}) { # user exists
1043                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1044                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
1045                 } else {
1046                     warn "user config - ignore invalid group member '$user'\n";
1047                 }
1048             }
1049
1050         } elsif ($et eq 'role') {
1051             my ($role, $privlist) = @data;
1052
1053             if (!verify_rolename($role, 1)) {
1054                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1055                 next;
1056             }
1057
1058             # make sure to add the role (even if there are no privileges)
1059             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1060
1061             foreach my $priv (split_list($privlist)) {
1062                 if (defined ($valid_privs->{$priv})) {
1063                     $cfg->{roles}->{$role}->{$priv} = 1;
1064                 } else {
1065                     warn "user config - ignore invalid privilege '$priv'\n";
1066                 }
1067             }
1068
1069         } elsif ($et eq 'acl') {
1070             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1071
1072             $propagate = $propagate ? 1 : 0;
1073
1074             if (my $path = normalize_path($pathtxt)) {
1075                 foreach my $role (split_list($rolelist)) {
1076
1077                     if (!verify_rolename($role, 1)) {
1078                         warn "user config - ignore invalid role name '$role' in acl\n";
1079                         next;
1080                     }
1081
1082                     if (!$cfg->{roles}->{$role}) {
1083                         warn "user config - ignore invalid acl role '$role'\n";
1084                         next;
1085                     }
1086
1087                     foreach my $ug (split_list($uglist)) {
1088                         my ($group) = $ug =~ m/^@(\S+)$/;
1089
1090                         if ($group && verify_groupname($group, 1)) {
1091                             if ($cfg->{groups}->{$group}) { # group exists
1092                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1093                             } else {
1094                                 warn "user config - ignore invalid acl group '$group'\n";
1095                             }
1096                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1097                             if ($cfg->{users}->{$ug}) { # user exists
1098                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1099                             } else {
1100                                 warn "user config - ignore invalid acl member '$ug'\n";
1101                             }
1102                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1103                             if (check_token_exist($cfg, $user, $token, 1)) {
1104                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1105                             } else {
1106                                 warn "user config - ignore invalid acl token '$ug'\n";
1107                             }
1108                         } else {
1109                             warn "user config - invalid user/group '$ug' in acl\n";
1110                         }
1111                     }
1112                 }
1113             } else {
1114                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1115             }
1116         } elsif ($et eq 'pool') {
1117             my ($pool, $comment, $vmlist, $storelist) = @data;
1118
1119             if (!verify_poolname($pool, 1)) {
1120                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1121                 next;
1122             }
1123
1124             # make sure to add the pool (even if there are no members)
1125             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1126
1127             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1128
1129             foreach my $vmid (split_list($vmlist)) {
1130                 if ($vmid !~ m/^\d+$/) {
1131                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1132                     next;
1133                 }
1134                 $vmid = int($vmid);
1135
1136                 if ($cfg->{vms}->{$vmid}) {
1137                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1138                     next;
1139                 }
1140
1141                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1142
1143                 # record vmid ==> pool relation
1144                 $cfg->{vms}->{$vmid} = $pool;
1145             }
1146
1147             foreach my $storeid (split_list($storelist)) {
1148                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1149                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1150                     next;
1151                 }
1152                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1153             }
1154         } elsif ($et eq 'token') {
1155             my ($tokenid, $expire, $privsep, $comment) = @data;
1156
1157             my ($user, $token) = split_tokenid($tokenid, 1);
1158             if (!($user && $token)) {
1159                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1160                 next;
1161             }
1162
1163             $privsep = $privsep ? 1 : 0;
1164
1165             $expire = 0 if !$expire;
1166
1167             if ($expire !~ m/^\d+$/) {
1168                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1169                 next;
1170             }
1171             $expire = int($expire);
1172
1173             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1174                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1175                 my $token_cfg = $user_cfg->{tokens}->{$token};
1176                 $token_cfg->{privsep} = $privsep;
1177                 $token_cfg->{expire} = $expire;
1178                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1179             } else {
1180                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1181             }
1182         } else {
1183             warn "user config - ignore config line: $line\n";
1184         }
1185     }
1186
1187     userconfig_force_defaults($cfg);
1188
1189     return $cfg;
1190 }
1191
1192 sub write_user_config {
1193     my ($filename, $cfg) = @_;
1194
1195     my $data = '';
1196
1197     foreach my $user (sort keys %{$cfg->{users}}) {
1198         my $d = $cfg->{users}->{$user};
1199         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1200         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1201         my $email = $d->{email} || '';
1202         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1203         my $expire = int($d->{expire} || 0);
1204         my $enable = $d->{enable} ? 1 : 0;
1205         my $keys = $d->{keys} ? $d->{keys} : '';
1206         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1207
1208         my $user_tokens = $d->{tokens};
1209         foreach my $token (sort keys %$user_tokens) {
1210             my $td = $user_tokens->{$token};
1211             my $full_tokenid = join_tokenid($user, $token);
1212             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1213             my $expire = int($td->{expire} || 0);
1214             my $privsep = $td->{privsep} ? 1 : 0;
1215             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1216         }
1217     }
1218
1219     $data .= "\n";
1220
1221     foreach my $group (sort keys %{$cfg->{groups}}) {
1222         my $d = $cfg->{groups}->{$group};
1223         my $list = join (',', sort keys %{$d->{users}});
1224         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1225         $data .= "group:$group:$list:$comment:\n";
1226     }
1227
1228     $data .= "\n";
1229
1230     foreach my $pool (sort keys %{$cfg->{pools}}) {
1231         my $d = $cfg->{pools}->{$pool};
1232         my $vmlist = join (',', sort keys %{$d->{vms}});
1233         my $storelist = join (',', sort keys %{$d->{storage}});
1234         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1235         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1236     }
1237
1238     $data .= "\n";
1239
1240     foreach my $role (sort keys %{$cfg->{roles}}) {
1241         next if $special_roles->{$role};
1242
1243         my $d = $cfg->{roles}->{$role};
1244         my $list = join (',', sort keys %$d);
1245         $data .= "role:$role:$list:\n";
1246     }
1247
1248     $data .= "\n";
1249
1250     my $collect_rolelist_members = sub {
1251         my ($acl_members, $result, $prefix, $exclude) = @_;
1252
1253         foreach my $member (keys %$acl_members) {
1254             next if $exclude && $member eq $exclude;
1255
1256             my $l0 = '';
1257             my $l1 = '';
1258             foreach my $role (sort keys %{$acl_members->{$member}}) {
1259                 my $propagate = $acl_members->{$member}->{$role};
1260                 if ($propagate) {
1261                     $l1 .= ',' if $l1;
1262                     $l1 .= $role;
1263                 } else {
1264                     $l0 .= ',' if $l0;
1265                     $l0 .= $role;
1266                 }
1267             }
1268             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1269             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1270         }
1271     };
1272
1273     foreach my $path (sort keys %{$cfg->{acl}}) {
1274         my $d = $cfg->{acl}->{$path};
1275
1276         my $rolelist_members = {};
1277
1278         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1279
1280         # no need to save 'root@pam', it is always 'Administrator'
1281         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1282
1283         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1284
1285         foreach my $propagate (0,1) {
1286             my $filtered = $rolelist_members->{$propagate};
1287             foreach my $rolelist (sort keys %$filtered) {
1288                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1289                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1290             }
1291
1292         }
1293     }
1294
1295     return $data;
1296 }
1297
1298 # The TFA configuration in priv/tfa.cfg format contains one line per user of
1299 # the form:
1300 #     USER:TYPE:DATA
1301 # DATA is a base64 encoded json string and its format depends on the type.
1302 sub parse_priv_tfa_config {
1303     my ($filename, $raw) = @_;
1304
1305     my $users = {};
1306     my $cfg = { users => $users };
1307
1308     $raw = '' if !defined($raw);
1309     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1310         my $line = $1;
1311         my ($user, $type, $data) = split(/:/, $line, 3);
1312
1313         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1314         if (!$realm) {
1315             warn "user tfa config - ignore user '$user' - invalid user name\n";
1316             next;
1317         }
1318
1319         $data = decode_json(decode_base64($data));
1320
1321         $users->{$user} = {
1322             type => $type,
1323             data => $data,
1324         };
1325     }
1326
1327     return $cfg;
1328 }
1329
1330 sub write_priv_tfa_config {
1331     my ($filename, $cfg) = @_;
1332
1333     my $output = '';
1334
1335     my $users = $cfg->{users};
1336     foreach my $user (sort keys %$users) {
1337         my $info = $users->{$user};
1338         next if !%$info; # skip empty entries
1339
1340         $info = {%$info}; # copy to verify contents:
1341
1342         my $type = delete $info->{type};
1343         my $data = delete $info->{data};
1344
1345         if (my @keys = keys %$info) {
1346             die "invalid keys in TFA config for user $user: " . join(', ', @keys) . "\n";
1347         }
1348
1349         $data = encode_base64(encode_json($data), '');
1350         $output .= "${user}:${type}:${data}\n";
1351     }
1352
1353     return $output;
1354 }
1355
1356 sub roles {
1357     my ($cfg, $user, $path) = @_;
1358
1359     # NOTE: we do not consider pools here.
1360     # NOTE: for privsep tokens, this does not filter roles by those that the
1361     # corresponding user has.
1362     # Use $rpcenv->permission() for any actual permission checks!
1363
1364     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1365
1366     if (pve_verify_tokenid($user, 1)) {
1367         my $tokenid = $user;
1368         my ($username, $token) = split_tokenid($tokenid);
1369
1370         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
1371         return () if !$token_info;
1372
1373         my $user_roles = roles($cfg, $username, $path);
1374
1375         # return full user privileges
1376         return $user_roles if !$token_info->{privsep};
1377     }
1378
1379     my $roles = {};
1380
1381     foreach my $p (sort keys %{$cfg->{acl}}) {
1382         my $final = ($path eq $p);
1383
1384         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1385
1386         my $acl = $cfg->{acl}->{$p};
1387
1388         #print "CHECKACL $path $p\n";
1389         #print "ACL $path = " . Dumper ($acl);
1390         if (my $ri = $acl->{tokens}->{$user}) {
1391             my $new;
1392             foreach my $role (keys %$ri) {
1393                 my $propagate = $ri->{$role};
1394                 if ($final || $propagate) {
1395                     #print "APPLY ROLE $p $user $role\n";
1396                     $new = {} if !$new;
1397                     $new->{$role} = $propagate;
1398                 }
1399             }
1400             if ($new) {
1401                 $roles = $new; # overwrite previous settings
1402                 next;
1403             }
1404         }
1405
1406         if (my $ri = $acl->{users}->{$user}) {
1407             my $new;
1408             foreach my $role (keys %$ri) {
1409                 my $propagate = $ri->{$role};
1410                 if ($final || $propagate) {
1411                     #print "APPLY ROLE $p $user $role\n";
1412                     $new = {} if !$new;
1413                     $new->{$role} = $propagate;
1414                 }
1415             }
1416             if ($new) {
1417                 $roles = $new; # overwrite previous settings
1418                 next; # user privs always override group privs
1419             }
1420         }
1421
1422         my $new;
1423         foreach my $g (keys %{$acl->{groups}}) {
1424             next if !$cfg->{groups}->{$g}->{users}->{$user};
1425             if (my $ri = $acl->{groups}->{$g}) {
1426                 foreach my $role (keys %$ri) {
1427                     my $propagate = $ri->{$role};
1428                     if ($final || $propagate) {
1429                         #print "APPLY ROLE $p \@$g $role\n";
1430                         $new = {} if !$new;
1431                         $new->{$role} = $propagate;
1432                     }
1433                 }
1434             }
1435         }
1436         if ($new) {
1437             $roles = $new; # overwrite previous settings
1438             next;
1439         }
1440     }
1441
1442     return { 'NoAccess' => $roles->{NoAccess} } if defined ($roles->{NoAccess});
1443     #return () if defined ($roles->{NoAccess});
1444
1445     #print "permission $user $path = " . Dumper ($roles);
1446
1447     #print "roles $user $path = " . join (',', @ra) . "\n";
1448
1449     return $roles;
1450 }
1451
1452 sub remove_vm_access {
1453     my ($vmid) = @_;
1454     my $delVMaccessFn = sub {
1455         my $usercfg = cfs_read_file("user.cfg");
1456         my $modified;
1457
1458         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1459             delete $usercfg->{acl}->{"/vms/$vmid"};
1460             $modified = 1;
1461         }
1462         if (my $pool = $usercfg->{vms}->{$vmid}) {
1463             if (my $data = $usercfg->{pools}->{$pool}) {
1464                 delete $data->{vms}->{$vmid};
1465                 delete $usercfg->{vms}->{$vmid};
1466                 $modified = 1;
1467             }
1468         }
1469         cfs_write_file("user.cfg", $usercfg) if $modified;
1470     };
1471
1472     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1473 }
1474
1475 sub remove_storage_access {
1476     my ($storeid) = @_;
1477
1478     my $deleteStorageAccessFn = sub {
1479         my $usercfg = cfs_read_file("user.cfg");
1480         my $modified;
1481
1482         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1483             delete $usercfg->{acl}->{"/storage/$storeid"};
1484             $modified = 1;
1485         }
1486         foreach my $pool (keys %{$usercfg->{pools}}) {
1487             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1488             $modified = 1;
1489         }
1490         cfs_write_file("user.cfg", $usercfg) if $modified;
1491     };
1492
1493     lock_user_config($deleteStorageAccessFn,
1494                      "access permissions cleanup for storage $storeid failed");
1495 }
1496
1497 sub add_vm_to_pool {
1498     my ($vmid, $pool) = @_;
1499
1500     my $addVMtoPoolFn = sub {
1501         my $usercfg = cfs_read_file("user.cfg");
1502         if (my $data = $usercfg->{pools}->{$pool}) {
1503             $data->{vms}->{$vmid} = 1;
1504             $usercfg->{vms}->{$vmid} = $pool;
1505             cfs_write_file("user.cfg", $usercfg);
1506         }
1507     };
1508
1509     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1510 }
1511
1512 sub remove_vm_from_pool {
1513     my ($vmid) = @_;
1514
1515     my $delVMfromPoolFn = sub {
1516         my $usercfg = cfs_read_file("user.cfg");
1517         if (my $pool = $usercfg->{vms}->{$vmid}) {
1518             if (my $data = $usercfg->{pools}->{$pool}) {
1519                 delete $data->{vms}->{$vmid};
1520                 delete $usercfg->{vms}->{$vmid};
1521                 cfs_write_file("user.cfg", $usercfg);
1522             }
1523         }
1524     };
1525
1526     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1527 }
1528
1529 my $USER_CONTROLLED_TFA_TYPES = {
1530     u2f => 1,
1531     oath => 1,
1532 };
1533
1534 # Delete an entry by setting $data=undef in which case $type is ignored.
1535 # Otherwise both must be valid.
1536 sub user_set_tfa {
1537     my ($userid, $realm, $type, $data, $cached_usercfg, $cached_domaincfg) = @_;
1538
1539     if (defined($data) && !defined($type)) {
1540         # This is an internal usage error and should not happen
1541         die "cannot set tfa data without a type\n";
1542     }
1543
1544     my $user_cfg = $cached_usercfg || cfs_read_file('user.cfg');
1545     my $user = $user_cfg->{users}->{$userid}
1546         or die "user '$userid' not found\n";
1547
1548     my $domain_cfg = $cached_domaincfg || cfs_read_file('domains.cfg');
1549     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1550     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1551
1552     my $realm_tfa = $realm_cfg->{tfa};
1553     if (defined($realm_tfa)) {
1554         $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa);
1555         # If the realm has a TFA setting, we're only allowed to use that.
1556         if (defined($data)) {
1557             my $required_type = $realm_tfa->{type};
1558             if ($required_type ne $type) {
1559                 die "realm '$realm' only allows TFA of type '$required_type\n";
1560             }
1561
1562             if (defined($data->{config})) {
1563                 # XXX: Is it enough if the type matches? Or should the configuration also match?
1564             }
1565
1566             # realm-configured tfa always uses a simple key list, so use the user.cfg
1567             $user->{keys} = $data->{keys};
1568         } else {
1569             die "realm '$realm' does not allow removing the 2nd factor\n";
1570         }
1571     } else {
1572         # Without a realm-enforced TFA setting the user can add a u2f or totp entry by themselves.
1573         # The 'yubico' type requires yubico server settings, which have to be configured on the
1574         # realm, so this is not supported here:
1575         die "domain '$realm' does not support TFA type '$type'\n"
1576             if defined($data) && !$USER_CONTROLLED_TFA_TYPES->{$type};
1577     }
1578
1579     # Custom TFA entries are stored in priv/tfa.cfg as they can be more complet: u2f uses a
1580     # public key and a key handle, TOTP requires the usual totp settings...
1581
1582     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1583     my $tfa = ($tfa_cfg->{users}->{$userid} //= {});
1584
1585     if (defined($data)) {
1586         $tfa->{type} = $type;
1587         $tfa->{data} = $data;
1588         cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1589
1590         $user->{keys} = "x!$type";
1591     } else {
1592         delete $tfa_cfg->{users}->{$userid};
1593         cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1594
1595         delete $user->{keys};
1596     }
1597
1598     cfs_write_file('user.cfg', $user_cfg);
1599 }
1600
1601 sub user_get_tfa {
1602     my ($username, $realm) = @_;
1603
1604     my $user_cfg = cfs_read_file('user.cfg');
1605     my $user = $user_cfg->{users}->{$username}
1606         or die "user '$username' not found\n";
1607
1608     my $keys = $user->{keys};
1609
1610     my $domain_cfg = cfs_read_file('domains.cfg');
1611     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1612     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1613
1614     my $realm_tfa = $realm_cfg->{tfa};
1615     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1616         if $realm_tfa;
1617
1618     if (!$keys) {
1619         return if !$realm_tfa;
1620         die "missing required 2nd keys\n";
1621     }
1622
1623     # new style config starts with an 'x' and optionally contains a !<type> suffix
1624     if ($keys !~ /^x(?:!.*)?$/) {
1625         # old style config, find the type via the realm
1626         return if !$realm_tfa;
1627         return ($realm_tfa->{type}, {
1628             keys => $keys,
1629             config => $realm_tfa,
1630         });
1631     } else {
1632         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1633         my $tfa = $tfa_cfg->{users}->{$username};
1634         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1635
1636         if ($realm_tfa) {
1637             # if the realm has a tfa setting we need to verify the type:
1638             die "auth domain '$realm' and user have mismatching TFA settings\n"
1639                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1640         }
1641
1642         return ($tfa->{type}, $tfa->{data});
1643     }
1644 }
1645
1646 # bash completion helpers
1647
1648 register_standard_option('userid-completed',
1649     get_standard_option('userid', { completion => \&complete_username}),
1650 );
1651
1652 sub complete_username {
1653
1654     my $user_cfg = cfs_read_file('user.cfg');
1655
1656     return [ keys %{$user_cfg->{users}} ];
1657 }
1658
1659 sub complete_group {
1660
1661     my $user_cfg = cfs_read_file('user.cfg');
1662
1663     return [ keys %{$user_cfg->{groups}} ];
1664 }
1665
1666 sub complete_realm {
1667
1668     my $domain_cfg = cfs_read_file('domains.cfg');
1669
1670     return [ keys %{$domain_cfg->{ids}} ];
1671 }
1672
1673 1;