d3feb24da841baa4022d41939a97bf4273fb1947
[pve-access-control.git] / PVE / AccessControl.pm
1 package PVE::AccessControl;
2
3 use strict;
4 use Encode;
5 use Crypt::OpenSSL::Random;
6 use Crypt::OpenSSL::RSA;
7 use MIME::Base64;
8 use Digest::SHA;
9 use Authen::PAM qw(:constants);
10 use Net::LDAP;
11 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
12 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
13 use PVE::JSONSchema;
14 use Encode;
15
16 use Data::Dumper; # fixme: remove
17
18 # $authdir must be writable by root only!
19 my $confdir = "/etc/pve";
20 my $authdir = "$confdir/priv";
21 my $authprivkeyfn = "$authdir/authkey.key";
22 my $authpubkeyfn = "$confdir/authkey.pub";
23 my $shadowconfigfile = "priv/shadow.cfg";
24 my $domainconfigfile = "domains.cfg";
25 my $pve_www_key_fn = "$confdir/pve-www.key";
26
27 my $ticket_lifetime = 3600*2; # 2 hours
28
29 Crypt::OpenSSL::RSA->import_random_seed();
30
31 cfs_register_file('user.cfg', 
32                   \&parse_user_config,  
33                   \&write_user_config);
34
35 cfs_register_file($shadowconfigfile, 
36                   \&parse_shadow_passwd, 
37                   \&write_shadow_config);
38
39 cfs_register_file($domainconfigfile, 
40                   \&parse_domains,
41                   \&write_domains);
42
43
44 sub lock_user_config {
45     my ($code, $errmsg) = @_;
46
47     cfs_lock_file("user.cfg", undef, $code);
48     my $err = $@;
49     if ($err) {
50         $errmsg ? die "$errmsg: $err" : die $err;
51     }
52 }
53
54 sub lock_domain_config {
55     my ($code, $errmsg) = @_;
56
57     cfs_lock_file($domainconfigfile, undef, $code);
58     my $err = $@;
59     if ($err) {
60         $errmsg ? die "$errmsg: $err" : die $err;
61     }
62 }
63
64 sub lock_shadow_config {
65     my ($code, $errmsg) = @_;
66
67     cfs_lock_file($shadowconfigfile, undef, $code);
68     my $err = $@;
69     if ($err) {
70         $errmsg ? die "$errmsg: $err" : die $err;
71     }
72 }
73
74 my $pve_auth_pub_key;
75 sub get_pubkey {    
76
77     return $pve_auth_pub_key if $pve_auth_pub_key;
78
79     my $input = PVE::Tools::file_get_contents($authpubkeyfn); 
80
81     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
82
83     return $pve_auth_pub_key;
84 }
85
86 my $csrf_prevention_secret;
87 my $get_csrfr_secret = sub {
88     if (!$csrf_prevention_secret) {
89         my $input = PVE::Tools::file_get_contents($pve_www_key_fn); 
90         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
91     }
92     return $csrf_prevention_secret;
93 };
94
95 sub assemble_csrf_prevention_token {
96     my ($username) = @_;
97
98     my $timestamp = sprintf("%08X", time());
99
100     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
101
102     return "$timestamp:$digest"; 
103 }
104
105 sub verify_csrf_prevention_token {
106     my ($username, $token, $noerr) = @_;
107
108     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
109         my $sig = $2;
110         my $timestamp = $1;
111         my $ttime = hex($timestamp);
112
113         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
114
115         my $age = time() - $ttime;
116         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
117     }
118
119     die "Permission denied - invalid csrf token\n" if !$noerr;
120
121     return undef;
122 }
123
124 my $pve_auth_priv_key;
125 sub get_privkey {
126
127     return $pve_auth_priv_key if $pve_auth_priv_key;
128
129     my $input = PVE::Tools::file_get_contents($authprivkeyfn); 
130
131     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
132
133     return $pve_auth_priv_key;
134 }
135
136 sub assemble_ticket {
137     my ($username) = @_;
138
139     my $rsa_priv = get_privkey();
140
141     my $timestamp = sprintf("%08X", time());
142
143     my $plain = "PVE:$username:$timestamp";
144
145     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
146
147     return $ticket;
148 }
149
150 sub verify_ticket {
151     my ($ticket, $noerr) = @_;
152
153     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
154         my $plain = $1;
155         my $sig = $2;
156
157         my $rsa_pub = get_pubkey();
158         if ($rsa_pub->verify($plain, decode_base64($sig))) {
159             if ($plain =~ m/^PVE:(([A-Za-z0-9\.\-_]+)(\@([A-Za-z0-9\.\-_]+))?):([A-Z0-9]{8})$/) {
160                 my $username = $1;
161                 my $timestamp = $5;
162                 my $ttime = hex($timestamp);
163
164                 my $age = time() - $ttime;
165
166                 if (($age > -300) && ($age < $ticket_lifetime)) {
167                     return wantarray ? ($username, $age) : $username;
168                 }
169             }
170         }
171     }
172
173     die "permission denied - invalid ticket\n" if !$noerr;
174
175     return undef;
176 }
177
178 # VNC tickets
179 # - they do not contain the username in plain text
180 # - they are restricted to a specific resource path (example: '/vms/100')
181 sub assemble_vnc_ticket {
182     my ($username, $path) = @_;
183
184     my $rsa_priv = get_privkey();
185
186     my $timestamp = sprintf("%08X", time());
187
188     my $plain = "PVEVNC:$timestamp";
189
190     $path = normalize_path($path);
191
192     my $full = "$plain:$username:$path";
193
194     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
195
196     return $ticket;
197 }
198
199 sub verify_vnc_ticket {
200     my ($ticket, $username, $path, $noerr) = @_;
201
202     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
203         my $plain = $1;
204         my $sig = $2;
205         my $full = "$plain:$username:$path";
206
207         my $rsa_pub = get_pubkey();
208         # Note: sign only match if $username and  $path is correct
209         if ($rsa_pub->verify($full, decode_base64($sig))) {
210             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
211                 my $ttime = hex($1);
212
213                 my $age = time() - $ttime;
214
215                 if (($age > -20) && ($age < 40)) {
216                     return 1;
217                 }
218             }
219         }
220     }
221
222     die "permission denied - invalid vnc ticket\n" if !$noerr;
223
224     return undef;
225 }
226
227
228 sub authenticate_user_shadow {
229     my ($userid, $password) = @_;
230
231     die "no password\n" if !$password;
232
233     my $shadow_cfg = cfs_read_file($shadowconfigfile);
234     
235     if ($shadow_cfg->{users}->{$userid}) {
236         my $encpw = crypt($password, $shadow_cfg->{users}->{$userid}->{shadow});
237         die "invalid credentials\n" if ($encpw ne $shadow_cfg->{users}->{$userid}->{shadow});
238     } else {
239         die "no password set\n";
240     }
241 }
242
243 sub authenticate_user_pam {
244     my ($userid, $password) = @_;
245
246     # user (www-data) need to be able to read /etc/passwd /etc/shadow
247
248     die "no password\n" if !$password;
249
250     my $pamh = new Authen::PAM ('common-auth', $userid, sub {
251         my @res;
252         while(@_) {
253             my $msg_type = shift;
254             my $msg = shift;
255             push @res, (0, $password);
256         }
257         push @res, 0;
258         return @res;
259     });
260
261     if (!ref ($pamh)) {
262         my $err = $pamh->pam_strerror($pamh);
263         die "error during PAM init: $err";
264     }
265
266     my $res;
267
268     if (($res = $pamh->pam_authenticate(0)) != PAM_SUCCESS) {
269         my $err = $pamh->pam_strerror($res);
270         die "$err\n";
271     }
272
273     if (($res = $pamh->pam_acct_mgmt (0)) != PAM_SUCCESS) {
274         my $err = $pamh->pam_strerror($res);
275         die "$err\n";
276     }
277
278     $pamh = 0; # call destructor
279 }
280
281 sub authenticate_user_ad {
282
283     my ($entry, $server, $userid, $password) = @_;
284
285     my $default_port = $entry->{secure} ? 636: 389;
286     my $port = $entry->{port} ? $entry->{port} : $default_port;
287     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
288     my $conn_string = "$scheme://${server}:$port";
289     
290     my $ldap = Net::LDAP->new($server) || die "$@\n";
291
292     $userid = "$userid\@$entry->{domain}" 
293         if $userid !~ m/@/ && $entry->{domain};
294
295     my $res = $ldap->bind($userid, password => $password);
296
297     my $code = $res->code();
298     my $err = $res->error;
299
300     $ldap->unbind();
301
302     die "$err\n" if ($code);
303 }
304
305 sub authenticate_user_ldap {
306
307     my ($entry, $server, $userid, $password) = @_;
308
309     my $default_port = $entry->{secure} ? 636: 389;
310     my $port = $entry->{port} ? $entry->{port} : $default_port;
311     my $scheme = $entry->{secure} ? 'ldaps' : 'ldap';
312     my $conn_string = "$scheme://${server}:$port";
313
314     my $ldap = Net::LDAP->new($conn_string, verify => 'none') || die "$@\n";
315     my $search = $entry->{user_attr} . "=" . $userid;
316     my $result = $ldap->search( base    => "$entry->{base_dn}",
317                                 scope   => "sub",
318                                 filter  => "$search",
319                                 attrs   => ['dn']
320                                 );
321     die "no entries returned\n" if !$result->entries;
322     my @entries = $result->entries;
323     my $res = $ldap->bind($entries[0]->dn, password => $password);
324
325     my $code = $res->code();
326     my $err = $res->error;
327
328     $ldap->unbind();
329
330     die "$err\n" if ($code);
331 }
332
333 sub authenticate_user_domain {
334     my ($realm, $userid, $password) = @_;
335  
336     my $domain_cfg = cfs_read_file($domainconfigfile);
337
338     die "no auth domain specified" if !$realm;
339
340     if ($realm eq 'pam') {
341         authenticate_user_pam($userid, $password);
342         return;
343     } 
344
345     eval {
346         if ($realm eq 'pve') {
347             authenticate_user_shadow($userid, $password);
348         } else { 
349
350             my $cfg = $domain_cfg->{$realm};
351             die "auth domain '$realm' does not exists\n" if !$cfg;
352     
353             if ($cfg->{type} eq 'ad') {
354                 eval { authenticate_user_ad($cfg, $cfg->{server1}, $userid, $password); };
355                 my $err = $@;
356                 return if !$err;
357                 die $err if !$cfg->{server2};
358                 authenticate_user_ad($cfg, $cfg->{server2}, $userid, $password); 
359             } elsif ($cfg->{type} eq 'ldap') {
360                 eval { authenticate_user_ldap($cfg, $cfg->{server1}, $userid, $password); };
361                 my $err = $@;
362                 return if !$err;
363                 die $err if !$cfg->{server2};
364                 authenticate_user_ldap($cfg, $cfg->{server2}, $userid, $password); 
365             } else {
366                 die "unknown auth type '$cfg->{type}'\n";
367             }
368         }
369     };
370     if (my $err = $@) {
371         sleep(2); # timeout after failed auth
372         die $err;
373     }
374 }
375
376 sub check_user_exist {
377     my ($usercfg, $username, $noerr) = @_;
378
379     $username = verify_username($username, $noerr);
380     return undef if !$username;
381  
382     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
383
384     die "no such user ('$username')\n" if !$noerr;
385  
386     return undef;
387 }
388
389 sub check_user_enabled {
390     my ($usercfg, $username, $noerr) = @_;
391
392     my $data = check_user_exist($usercfg, $username, $noerr);
393     return undef if !$data;
394
395     return 1 if $data->{enable};
396
397     return 1 if $username eq 'root@pam'; # root is always enabled
398
399     die "user '$username' is disabled\n" if !$noerr;
400  
401     return undef;
402 }
403
404 # password should be utf8 encoded
405 sub authenticate_user {
406     my ($username, $password) = @_;
407
408     die "no username specified\n" if !$username;
409  
410     my ($userid, $realm);
411
412     ($username, $userid, $realm) = verify_username($username);
413
414     my $usercfg = cfs_read_file('user.cfg');
415
416     eval { check_user_enabled($usercfg, $username); };
417     if (my $err = $@) {
418         sleep(2);
419         die $err;
420     }
421
422     my $ctime = time();
423     my $expire = $usercfg->{users}->{$username}->{expire};
424
425     if ($expire && ($expire < $ctime)) {
426         sleep(2);
427         die "account expired\n"
428     }
429
430     authenticate_user_domain($realm, $userid, $password);
431
432     return $username;
433 }
434
435 sub delete_shadow_password {
436     my ($userid) = @_;
437  
438     lock_shadow_config(sub {
439         my $shadow_cfg = cfs_read_file($shadowconfigfile);
440         delete ($shadow_cfg->{users}->{$userid})
441             if $shadow_cfg->{users}->{$userid};
442         cfs_write_file($shadowconfigfile, $shadow_cfg);
443     });
444 }
445
446 sub store_shadow_password {
447     my ($userid, $password) = @_;
448   
449     lock_shadow_config(sub {
450         my $shadow_cfg = cfs_read_file($shadowconfigfile);
451         $shadow_cfg->{users}->{$userid}->{shadow} = encrypt_pw($password);
452         cfs_write_file($shadowconfigfile, $shadow_cfg);
453     });
454 }
455
456 sub encrypt_pw {
457     my ($pw) = @_;
458
459     my $time = substr (Digest::SHA::sha1_base64 (time), 0, 8);
460     return crypt (encode("utf8", $pw), "\$5\$$time\$");
461 }
462
463 sub store_pam_password {
464     my ($userid, $password) = @_;
465
466     my $cmd = ['usermod'];
467
468     my $epw = encrypt_pw($password);
469     push @$cmd, '-p', $epw;
470
471     push @$cmd, $userid;
472
473     run_command($cmd, errmsg => 'change password failed');
474 }
475
476 sub domain_set_password {
477     my ($realm, $userid, $password) = @_;
478
479     die "no auth domain specified" if !$realm;
480
481     if ($realm eq 'pam') {
482         store_pam_password($userid, $password);
483     } elsif ($realm eq 'pve') {
484         store_shadow_password($userid, $password);
485     } else {
486         die "can't set password on auth domain '$realm'\n";
487     }
488 }
489
490 sub add_user_group {
491
492     my ($username, $usercfg, $group) = @_;
493     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
494     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
495 }
496
497 sub delete_user_group {
498
499     my ($username, $usercfg) = @_;
500     
501     foreach my $group (keys %{$usercfg->{groups}}) {
502
503         delete ($usercfg->{groups}->{$group}->{users}->{$username}) 
504             if $usercfg->{groups}->{$group}->{users}->{$username};
505     }
506 }
507
508 sub delete_user_acl {
509
510     my ($username, $usercfg) = @_;
511
512     foreach my $acl (keys %{$usercfg->{acl}}) {
513
514         delete ($usercfg->{acl}->{$acl}->{users}->{$username}) 
515             if $usercfg->{acl}->{$acl}->{users}->{$username};
516     }
517 }
518
519 sub delete_group_acl {
520
521     my ($group, $usercfg) = @_;
522
523     foreach my $acl (keys %{$usercfg->{acl}}) {
524
525         delete ($usercfg->{acl}->{$acl}->{groups}->{$group}) 
526             if $usercfg->{acl}->{$acl}->{groups}->{$group};
527     }
528 }
529
530 sub delete_pool_acl {
531
532     my ($pool, $usercfg) = @_;
533
534     my $path = "/pool/$pool";
535
536     foreach my $aclpath (keys %{$usercfg->{acl}}) {
537         delete ($usercfg->{acl}->{$aclpath})
538             if $usercfg->{acl}->{$aclpath} eq 'path';
539     }
540 }
541
542 # we automatically create some predefined roles by splitting privs
543 # into 3 groups (per category)
544 # root: only root is allowed to do that
545 # admin: an administrator can to that
546 # user: a normak user/customer can to that
547 my $privgroups = {
548     VM => {
549         root => [],
550         admin => [           
551             'VM.Config.Disk', 
552             'VM.Config.CPU', 
553             'VM.Config.Memory', 
554             'VM.Config.Network', 
555             'VM.Config.HWType',
556             'VM.Config.Options', # covers all other things 
557             'VM.Allocate', 
558             'VM.Migrate',
559             'VM.Monitor', 
560         ],
561         user => [
562             'VM.Config.CDROM', # change CDROM media
563             'VM.Console', 
564             'VM.Backup',
565             'VM.PowerMgmt',
566         ],
567         audit => [ 
568             'VM.Audit',
569         ],
570     },
571     Sys => {
572         root => [
573             'Sys.PowerMgmt',     
574             'Sys.Modify', # edit/change node settings
575         ],
576         admin => [
577             'Permissions.Modify',
578             'Sys.Console',    
579             'Sys.Syslog',
580         ],
581         user => [],
582         audit => [
583             'Sys.Audit',
584         ],
585     },
586     Datastore => {
587         root => [],
588         admin => [
589             'Datastore.Allocate',
590             'Datastore.AllocateTemplate',
591         ],
592         user => [
593             'Datastore.AllocateSpace',
594         ],
595         audit => [
596             'Datastore.Audit',
597         ],
598     },
599     User => {
600         root => [
601             'Realm.Allocate',
602         ],
603         admin => [
604             'User.Modify',
605             'Group.Allocate', # edit/change group settings
606             'Realm.AllocateUser', 
607         ],
608         user => [],
609         audit => [],
610     },
611     Pool => {
612         root => [],
613         admin => [
614             'Pool.Allocate', # create/delete pools
615         ],
616         user => [],
617         audit => [],
618     },
619 };
620
621 my $valid_privs = {};
622
623 my $special_roles = {
624     'NoAccess' => {}, # no priviledges
625     'Administrator' => $valid_privs, # all priviledges
626 };
627
628 sub create_roles {
629
630     foreach my $cat (keys %$privgroups) {
631         my $cd = $privgroups->{$cat};
632         foreach my $p (@{$cd->{root}}, @{$cd->{admin}}, 
633                        @{$cd->{user}}, @{$cd->{audit}}) {
634             $valid_privs->{$p} = 1;
635         }
636         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
637
638             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
639             $special_roles->{"PVEAdmin"}->{$p} = 1;
640         }
641         if (scalar(@{$cd->{user}})) {
642             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
643                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
644             }
645         }
646         foreach my $p (@{$cd->{audit}}) {
647             $special_roles->{"PVEAuditor"}->{$p} = 1;
648         }
649     }
650 };
651
652 create_roles();
653
654 my $valid_attributes = {
655     ad => {
656         server1 => '[\w\d]+(.[\w\d]+)*',
657         server2 => '[\w\d]+(.[\w\d]+)*',
658         domain => '\S+',
659         port => '\d+',
660         secure => '',
661         comment => '.*',
662     },
663     ldap => {
664         server1 => '[\w\d]+(.[\w\d]+)*',
665         server2 => '[\w\d]+(.[\w\d]+)*',
666         base_dn => '\w+=[^,]+(,\s*\w+=[^,]+)*',
667         user_attr => '\S{2,}',
668         secure => '',
669         port => '\d+',
670         comment => '.*',
671     }
672 };
673
674 sub add_role_privs {
675     my ($role, $usercfg, $privs) = @_;
676
677     return if !$privs;
678
679     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
680
681     foreach my $priv (split_list($privs)) {
682         if (defined ($valid_privs->{$priv})) {
683             $usercfg->{roles}->{$role}->{$priv} = 1;
684         } else {
685             die "invalid priviledge '$priv'\n";
686         } 
687     }   
688 }
689
690 sub normalize_path {
691     my $path = shift;
692
693     $path =~ s|/+|/|g;
694
695     $path =~ s|/$||;
696
697     $path = '/' if !$path;
698
699     $path = "/$path" if $path !~ m|^/|;
700
701     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
702
703     return $path;
704
705
706 my $realm_regex = qr/[A-Za-z][A-Za-z0-9\.\-_]+/;
707
708 PVE::JSONSchema::register_format('pve-realm', \&pve_verify_realm);
709 sub pve_verify_realm {
710     my ($realm, $noerr) = @_;
711  
712     if ($realm !~ m/^${realm_regex}$/) {
713         return undef if $noerr;
714         die "value does not look like a valid realm\n"; 
715     }
716     return $realm;
717 }
718
719 PVE::JSONSchema::register_format('pve-userid', \&verify_username);
720 sub verify_username {
721     my ($username, $noerr) = @_;
722
723     $username = '' if !$username;
724     my $len = length($username);
725     if ($len < 3) {
726         die "user name '$username' is too short\n" if !$noerr;
727         return undef;
728     }
729     if ($len > 64) {
730         die "user name '$username' is too long ($len > 64)\n" if !$noerr;
731         return undef;
732     }
733
734     # we only allow a limited set of characters (colon is not allowed,
735     # because we store usernames in colon separated lists)!
736     if ($username =~ m/^([^\s:]+)\@(${realm_regex})$/) {
737         return wantarray ? ($username, $1, $2) : $username;
738     }
739
740     die "value '$username' does not look like a valid user name\n" if !$noerr;
741
742     return undef;
743 }
744 PVE::JSONSchema::register_standard_option('userid', {
745     description => "User ID",
746     type => 'string', format => 'pve-userid',
747     maxLength => 64,
748 });
749
750 PVE::JSONSchema::register_standard_option('realm', {
751     description => "Authentication domain ID",
752     type => 'string', format => 'pve-realm',
753     maxLength => 32,
754 });
755
756 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
757 sub verify_groupname {
758     my ($groupname, $noerr) = @_;
759
760     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
761
762         die "group name '$groupname' contains invalid characters\n" if !$noerr;
763
764         return undef;
765     }
766     
767     return $groupname;
768 }
769
770 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
771 sub verify_rolename {
772     my ($rolename, $noerr) = @_;
773
774     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
775
776         die "role name '$rolename' contains invalid characters\n" if !$noerr;
777
778         return undef;
779     }
780     
781     return $rolename;
782 }
783
784 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
785 sub verify_poolname {
786     my ($poolname, $noerr) = @_;
787
788     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
789
790         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
791
792         return undef;
793     }
794     
795     return $poolname;
796 }
797
798 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
799 sub verify_privname {
800     my ($priv, $noerr) = @_;
801
802     if (!$valid_privs->{$priv}) {
803         die "invalid priviledge '$priv'\n" if !$noerr;
804
805         return undef;
806     }
807     
808     return $priv;
809 }
810
811 sub userconfig_force_defaults {
812     my ($cfg) = @_;
813
814     foreach my $r (keys %$special_roles) {
815         $cfg->{roles}->{$r} = $special_roles->{$r};
816     }
817
818     # fixme: remove 'root' group (not required)?
819
820     # add root user 
821     $cfg->{users}->{'root@pam'}->{enable} = 1;
822 }
823
824 sub parse_user_config {
825     my ($filename, $raw) = @_;
826
827     my $cfg = {};
828
829     userconfig_force_defaults($cfg);
830
831     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
832         my $line = $1;
833
834         next if $line =~ m/^\s*$/; # skip empty lines
835
836         my @data;
837
838         foreach my $d (split (/:/, $line)) {
839             $d =~ s/^\s+//; 
840             $d =~ s/\s+$//;
841             push @data, $d
842         }
843
844         my $et = shift @data;
845
846         if ($et eq 'user') {
847             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
848
849             my (undef, undef, $realm) = verify_username($user, 1);
850             if (!$realm) {
851                 warn "user config - ignore user '$user' - invalid user name\n";
852                 next;
853             }
854
855             $enable = $enable ? 1 : 0;
856
857             $expire = 0 if !$expire;
858
859             if ($expire !~ m/^\d+$/) {
860                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
861                 next;
862             }
863             $expire = int($expire);
864
865             #if (!verify_groupname ($group, 1)) {
866             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
867             #    next;
868             #}
869
870             $cfg->{users}->{$user} = {
871                 enable => $enable,
872                 # group => $group,
873             };
874             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
875             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
876             $cfg->{users}->{$user}->{email} = $email;
877             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
878             $cfg->{users}->{$user}->{expire} = $expire;
879
880             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
881             #$cfg->{groups}->{$group}->{$user} = 1;
882
883         } elsif ($et eq 'group') {
884             my ($group, $userlist, $comment) = @data;
885
886             if (!verify_groupname($group, 1)) {
887                 warn "user config - ignore group '$group' - invalid characters in group name\n";
888                 next;
889             }
890
891             # make sure to add the group (even if there are no members)
892             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
893
894             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
895
896             foreach my $user (split_list($userlist)) {
897
898                 if (!verify_username($user, 1)) {
899                     warn "user config - ignore invalid group member '$user'\n";
900                     next;
901                 }
902
903                 if ($cfg->{users}->{$user}) { # user exists 
904                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
905                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
906                 } else {
907                     warn "user config - ignore invalid group member '$user'\n";
908                 }
909             }
910
911         } elsif ($et eq 'role') {
912             my ($role, $privlist) = @data;
913                 
914             if (!verify_rolename($role, 1)) {
915                 warn "user config - ignore role '$role' - invalid characters in role name\n";
916                 next;
917             }
918
919             # make sure to add the role (even if there are no privileges)
920             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
921
922             foreach my $priv (split_list($privlist)) {
923                 if (defined ($valid_privs->{$priv})) {
924                     $cfg->{roles}->{$role}->{$priv} = 1;
925                 } else {
926                     warn "user config - ignore invalid priviledge '$priv'\n";
927                 } 
928             }
929             
930         } elsif ($et eq 'acl') {
931             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
932
933             if (my $path = normalize_path($pathtxt)) {
934                 foreach my $role (split_list($rolelist)) {
935                         
936                     if (!verify_rolename($role, 1)) {
937                         warn "user config - ignore invalid role name '$role' in acl\n";
938                         next;
939                     }
940
941                     foreach my $ug (split_list($uglist)) {
942                         if ($ug =~ m/^@(\S+)$/) {
943                             my $group = $1;
944                             if ($cfg->{groups}->{$group}) { # group exists 
945                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
946                             } else {
947                                 warn "user config - ignore invalid acl group '$group'\n";
948                             }
949                         } elsif (verify_username($ug, 1)) {
950                             if ($cfg->{users}->{$ug}) { # user exists 
951                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
952                             } else {
953                                 warn "user config - ignore invalid acl member '$ug'\n";
954                             }
955                         } else {
956                             warn "user config - invalid user/group '$ug' in acl\n";
957                         }
958                     }
959                 }
960             } else {
961                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
962             }
963         } elsif ($et eq 'pool') {
964             my ($pool, $comment, $vmlist, $storelist) = @data;
965
966             if (!verify_poolname($pool, 1)) {
967                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
968                 next;
969             }
970
971             # make sure to add the pool (even if there are no members)
972             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
973
974             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
975
976             foreach my $vmid (split_list($vmlist)) {
977                 if ($vmid !~ m/^\d+$/) {
978                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
979                     next;
980                 }
981                 $vmid = int($vmid);
982
983                 if ($cfg->{vms}->{$vmid}) {
984                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
985                     next;
986                 }
987
988                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
989                     
990                 # record vmid ==> pool relation
991                 $cfg->{vms}->{$vmid} = $pool;
992             }
993
994             foreach my $storeid (split_list($storelist)) {
995                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
996                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
997                     next;
998                 }
999                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1000             }
1001         } else {
1002             warn "user config - ignore config line: $line\n";
1003         }
1004     }
1005
1006     userconfig_force_defaults($cfg);
1007
1008     return $cfg;
1009 }
1010
1011 sub parse_shadow_passwd {
1012     my ($filename, $raw) = @_;
1013
1014     my $shadow = {};
1015
1016     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1017         my $line = $1;
1018
1019         next if $line =~ m/^\s*$/; # skip empty lines
1020
1021         if ($line !~ m/^\S+:\S+:$/) {
1022             warn "pve shadow password: ignore invalid line $.\n";
1023             next;
1024         }
1025
1026         my ($userid, $crypt_pass) = split (/:/, $line);
1027         $shadow->{users}->{$userid}->{shadow} = $crypt_pass;
1028     }
1029
1030     return $shadow;
1031 }
1032
1033 sub write_domains {
1034     my ($filename, $cfg) = @_;
1035
1036     my $data = '';
1037
1038     my $wrote_default;
1039
1040     foreach my $realm (sort keys %$cfg) {
1041         my $entry = $cfg->{$realm};
1042         my $type = lc($entry->{type});
1043
1044         next if !$type;
1045
1046         next if ($type eq 'pam') || ($type eq 'pve');
1047
1048         my $formats = $valid_attributes->{$type};
1049         next if !$formats;
1050
1051         $data .= "$type: $realm\n";
1052
1053         foreach my $k (sort keys %$entry) {
1054             next if $k eq 'type';
1055             my $v = $entry->{$k};
1056             if ($k eq 'default') {
1057                     $data .= "\t$k\n" if $v && !$wrote_default;
1058                     $wrote_default = 1;
1059             } elsif (defined($formats->{$k})) {
1060                 if (!$formats->{$k}) {
1061                     $data .= "\t$k\n" if $v;
1062                 } elsif ($v =~ m/^$formats->{$k}$/) {
1063                     $v = PVE::Tools::encode_text($v) if $k eq 'comment';
1064                     $data .= "\t$k $v\n";
1065                 } else {
1066                     die "invalid value '$v' for attribute '$k'\n";
1067                 }
1068             } else {
1069                 die "invalid attribute '$k' - not supported\n";
1070             }
1071         }
1072
1073         $data .= "\n";
1074     }
1075
1076     return $data;
1077 }
1078
1079 sub parse_domains {
1080     my ($filename, $raw) = @_;
1081
1082     my $cfg = {};
1083
1084     my $default;
1085
1086     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1087         my $line = $1;
1088  
1089         next if $line =~ m/^\#/; # skip comment lines
1090         next if $line =~ m/^\s*$/; # skip empty lines
1091
1092         if ($line =~ m/^(\S+):\s*(\S+)\s*$/) {
1093             my $realm = $2;
1094             my $type = lc($1);
1095
1096             my $ignore = 0;
1097             my $entry;
1098
1099             my $formats = $valid_attributes->{$type};
1100             if (!$formats) {
1101                 $ignore = 1;
1102                 warn "ignoring domain '$realm' - (unsupported authentication type '$type')\n";
1103             } elsif (!pve_verify_realm($realm, 1)) {
1104                 $ignore = 1;
1105                 warn "ignoring domain '$realm' - (illegal characters)\n";
1106             } else {
1107                 $entry = { type => $type };
1108             }
1109
1110             while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
1111                 $line = $1;
1112
1113                 next if $line =~ m/^\#/; #skip comment lines
1114                 last if $line =~ m/^\s*$/;
1115                     
1116                 next if $ignore; # skip
1117
1118                 if ($line =~ m/^\s+(default)\s*$/) {
1119                     $default = $realm if !$default;
1120                 } elsif ($line =~ m/^\s+(\S+)(\s+(.*\S))?\s*$/) {
1121                     my ($k, $v) = (lc($1), $3);
1122                     if (defined($formats->{$k})) {
1123                         if (!$formats->{$k} && !defined($v)) {
1124                                 $entry->{$k} = 1;                           
1125                         } elsif ($formats->{$k} && $v =~ m/^$formats->{$k}$/) {
1126                             if (!defined($entry->{$k})) {
1127                                 $v = PVE::Tools::decode_text($v) if $k eq 'comment';
1128                                 $entry->{$k} = $v;
1129                             } else {
1130                                 warn "ignoring duplicate attribute '$k $v'\n";
1131                             }
1132                         } else {
1133                             warn "ignoring value '$v' for attribute '$k' - invalid format\n";
1134                         }
1135                     } else {
1136                         warn "ignoring attribute '$k' - not supported\n";
1137                     }
1138                 } else {
1139                     warn "ignore config line: $line\n";
1140                 }
1141             }
1142
1143             if ($entry->{server2} && !$entry->{server1}) {
1144                 $entry->{server1} = $entry->{server2};
1145                 delete $entry->{server2};
1146             }
1147
1148             if ($ignore) {
1149                 # do nothing
1150             } elsif (!$entry->{server1}) {
1151                 warn "ignoring domain '$realm' - missing server attribute\n";
1152             } elsif (($entry->{type} eq "ldap") && !$entry->{user_attr}) {
1153                 warn "ignoring domain '$realm' - missing user attribute\n";
1154             } elsif (($entry->{type} eq "ldap") && !$entry->{base_dn}) {
1155                 warn "ignoring domain '$realm' - missing base_dn attribute\n";
1156             } elsif (($entry->{type} eq "ad") && !$entry->{domain}) {
1157                 warn "ignoring domain '$realm' - missing domain attribute\n";
1158             } else {
1159                 $cfg->{$realm} = $entry;
1160             }
1161      
1162         } else {
1163             warn "ignore config line: $line\n";
1164         }
1165     }
1166
1167     $cfg->{$default}->{default} = 1 if $default;
1168
1169     # add default domains
1170
1171     $cfg->{pve} = {
1172         type => 'builtin',
1173         comment => "Proxmox VE authentication server", 
1174     };
1175
1176     $cfg->{pam} = {
1177         type => 'builtin',
1178         comment => "Linux PAM standard authentication", 
1179     };
1180         
1181     return $cfg;
1182 }
1183
1184 sub write_shadow_config {
1185     my ($filename, $cfg) = @_;
1186
1187     my $data = '';
1188     foreach my $userid (keys %{$cfg->{users}}) {
1189         my $crypt_pass = $cfg->{users}->{$userid}->{shadow};
1190         $data .= "$userid:$crypt_pass:\n";
1191     }
1192
1193     return $data
1194 }
1195
1196 sub write_user_config {
1197     my ($filename, $cfg) = @_;
1198
1199     my $data = '';
1200
1201     foreach my $user (keys %{$cfg->{users}}) {
1202         my $d = $cfg->{users}->{$user};
1203         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1204         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1205         my $email = $d->{email} || '';
1206         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1207         my $expire = int($d->{expire} || 0);
1208         my $enable = $d->{enable} ? 1 : 0;
1209         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
1210     }
1211
1212     $data .= "\n";
1213
1214     foreach my $group (keys %{$cfg->{groups}}) {
1215         my $d = $cfg->{groups}->{$group};
1216         my $list = join (',', keys %{$d->{users}});
1217         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
1218         $data .= "group:$group:$list:$comment:\n";
1219     }
1220
1221     $data .= "\n";
1222
1223     foreach my $pool (keys %{$cfg->{pools}}) {
1224         my $d = $cfg->{pools}->{$pool};
1225         my $vmlist = join (',', keys %{$d->{vms}});
1226         my $storelist = join (',', keys %{$d->{storage}});
1227         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
1228         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1229     }
1230
1231     $data .= "\n";
1232
1233     foreach my $role (keys %{$cfg->{roles}}) {
1234         next if $special_roles->{$role};
1235
1236         my $d = $cfg->{roles}->{$role};
1237         my $list = join (',', keys %$d);
1238         $data .= "role:$role:$list:\n";
1239     }
1240
1241     $data .= "\n";
1242
1243     foreach my $path (sort keys %{$cfg->{acl}}) {
1244         my $d = $cfg->{acl}->{$path};
1245
1246         my $ra = {};
1247
1248         foreach my $group (keys %{$d->{groups}}) {
1249             my $l0 = '';
1250             my $l1 = '';
1251             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
1252                 my $propagate = $d->{groups}->{$group}->{$role};
1253                 if ($propagate) {
1254                     $l1 .= ',' if $l1;
1255                     $l1 .= $role;
1256                 } else {
1257                     $l0 .= ',' if $l0;
1258                     $l0 .= $role;
1259                 }
1260             }
1261             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
1262             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
1263         }
1264
1265         foreach my $user (keys %{$d->{users}}) {
1266             # no need to save, because root is always 'Administartor'
1267             next if $user eq 'root@pam'; 
1268
1269             my $l0 = '';
1270             my $l1 = '';
1271             foreach my $role (sort keys %{$d->{users}->{$user}}) {
1272                 my $propagate = $d->{users}->{$user}->{$role};
1273                 if ($propagate) {
1274                     $l1 .= ',' if $l1;
1275                     $l1 .= $role;
1276                 } else {
1277                     $l0 .= ',' if $l0;
1278                     $l0 .= $role;
1279                 }
1280             }
1281             $ra->{0}->{$l0}->{$user} = 1 if $l0;
1282             $ra->{1}->{$l1}->{$user} = 1 if $l1;
1283         }
1284
1285         foreach my $rolelist (sort keys %{$ra->{0}}) {
1286             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
1287             $data .= "acl:0:$path:$uglist:$rolelist:\n";
1288         }
1289         foreach my $rolelist (sort keys %{$ra->{1}}) {
1290             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
1291             $data .= "acl:1:$path:$uglist:$rolelist:\n";
1292         }
1293     }
1294
1295     return $data;
1296 }
1297
1298 sub roles {
1299     my ($cfg, $user, $path) = @_;
1300
1301     # NOTE: we do not consider pools here. 
1302     # You need to use $rpcenv->roles() instead if you want that.
1303
1304     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1305
1306     my $perm = {};
1307
1308     foreach my $p (sort keys %{$cfg->{acl}}) {
1309         my $final = ($path eq $p);
1310
1311         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1312
1313         my $acl = $cfg->{acl}->{$p};
1314
1315         #print "CHECKACL $path $p\n";
1316         #print "ACL $path = " . Dumper ($acl);
1317
1318         if (my $ri = $acl->{users}->{$user}) {
1319             my $new;
1320             foreach my $role (keys %$ri) {
1321                 my $propagate = $ri->{$role};
1322                 if ($final || $propagate) {
1323                     #print "APPLY ROLE $p $user $role\n";
1324                     $new = {} if !$new;
1325                     $new->{$role} = 1;
1326                 }
1327             }
1328             if ($new) {
1329                 $perm = $new; # overwrite previous settings
1330                 next; # user privs always override group privs
1331             }
1332         }
1333
1334         my $new;
1335         foreach my $g (keys %{$acl->{groups}}) {
1336             next if !$cfg->{groups}->{$g}->{users}->{$user};
1337             if (my $ri = $acl->{groups}->{$g}) {
1338                 foreach my $role (keys %$ri) {
1339                     my $propagate = $ri->{$role};
1340                     if ($final || $propagate) {
1341                         #print "APPLY ROLE $p \@$g $role\n";
1342                         $new = {} if !$new;
1343                         $new->{$role} = 1;
1344                     }
1345                 }
1346             }
1347         }
1348         if ($new) {
1349             $perm = $new; # overwrite previous settings
1350             next;
1351         }
1352     }
1353
1354     return ('NoAccess') if defined ($perm->{NoAccess});
1355     #return () if defined ($perm->{NoAccess});
1356    
1357     #print "permission $user $path = " . Dumper ($perm);
1358
1359     my @ra = keys %$perm;
1360
1361     #print "roles $user $path = " . join (',', @ra) . "\n";
1362
1363     return @ra;
1364 }
1365     
1366 sub permission {
1367     my ($cfg, $user, $path) = @_;
1368
1369     $user = verify_username($user, 1);
1370     return {} if !$user;
1371
1372     my @ra = roles($cfg, $user, $path);
1373     
1374     my $privs = {};
1375
1376     foreach my $role (@ra) {
1377         if (my $privset = $cfg->{roles}->{$role}) {
1378             foreach my $p (keys %$privset) {
1379                 $privs->{$p} = 1;
1380             }
1381         }
1382     }
1383
1384     #print "priviledges $user $path = " . Dumper ($privs);
1385
1386     return $privs;
1387 }
1388
1389 sub check_permissions {
1390     my ($username, $path, $privlist) = @_;
1391
1392     $path = normalize_path($path);
1393     my $usercfg = cfs_read_file('user.cfg');
1394     my $perm = permission($usercfg, $username, $path);
1395
1396     foreach my $priv (split_list($privlist)) {
1397         return undef if !$perm->{$priv};
1398     };
1399
1400     return 1;
1401 }
1402
1403 1;