PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base64;
  11 use MIME::Base32; #libmime-base32-perl
  12 use Digest::SHA;
  13
  14 use PVE::Ticket;
  15 use URI::Escape;
  16 use LWP::UserAgent;
  17 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  18 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  19 use PVE::JSONSchema;
  20
  21 use PVE::Auth::Plugin;
  22 use PVE::Auth::AD;
  23 use PVE::Auth::LDAP;
  24 use PVE::Auth::PVE;
  25 use PVE::Auth::PAM;
  26
  27 use Data::Dumper; # fixme: remove
  28
  29 # load and initialize all plugins
  30
  31 PVE::Auth::AD->register();
  32 PVE::Auth::LDAP->register();
  33 PVE::Auth::PVE->register();
  34 PVE::Auth::PAM->register();
  35 PVE::Auth::Plugin->init();
  36
  37 # $authdir must be writable by root only!
  38 my $confdir = "/etc/pve";
  39 my $authdir = "$confdir/priv";
  40 my $authprivkeyfn = "$authdir/authkey.key";
  41 my $authpubkeyfn = "$confdir/authkey.pub";
  42 my $pve_www_key_fn = "$confdir/pve-www.key";
  43
  44 my $ticket_lifetime = 3600*2; # 2 hours
  45
  46 Crypt::OpenSSL::RSA->import_random_seed();
  47
  48 cfs_register_file('user.cfg',
  49                   \&parse_user_config,
  50                   \&write_user_config);
  51
  52
  53 sub verify_username {
  54     PVE::Auth::Plugin::verify_username(@_);
  55 }
  56
  57 sub pve_verify_realm {
  58     PVE::Auth::Plugin::pve_verify_realm(@_);
  59 }
  60
  61 sub lock_user_config {
  62     my ($code, $errmsg) = @_;
  63
  64     cfs_lock_file("user.cfg", undef, $code);
  65     if (my $err = $@) {
  66         $errmsg ? die "$errmsg: $err" : die $err;
  67     }
  68 }
  69
  70 my $pve_auth_pub_key;
  71 sub get_pubkey {
  72
  73     return $pve_auth_pub_key if $pve_auth_pub_key;
  74
  75     my $input = PVE::Tools::file_get_contents($authpubkeyfn);
  76
  77     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
  78
  79     return $pve_auth_pub_key;
  80 }
  81
  82 my $csrf_prevention_secret;
  83 my $get_csrfr_secret = sub {
  84     if (!$csrf_prevention_secret) {
  85         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
  86         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
  87     }
  88     return $csrf_prevention_secret;
  89 };
  90
  91 sub assemble_csrf_prevention_token {
  92     my ($username) = @_;
  93
  94     my $secret =  &$get_csrfr_secret();
  95
  96     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
  97 }
  98
  99 sub verify_csrf_prevention_token {
 100     my ($username, $token, $noerr) = @_;
 101
 102     my $secret =  &$get_csrfr_secret();
 103
 104     return PVE::Ticket::verify_csrf_prevention_token(
 105         $secret, $username, $token, -300, $ticket_lifetime, $noerr);
 106 }
 107
 108 my $pve_auth_priv_key;
 109 sub get_privkey {
 110
 111     return $pve_auth_priv_key if $pve_auth_priv_key;
 112
 113     my $input = PVE::Tools::file_get_contents($authprivkeyfn);
 114
 115     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
 116
 117     return $pve_auth_priv_key;
 118 }
 119
 120 sub assemble_ticket {
 121     my ($username) = @_;
 122
 123     my $rsa_priv = get_privkey();
 124
 125     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $username);
 126 }
 127
 128 sub verify_ticket {
 129     my ($ticket, $noerr) = @_;
 130
 131     my $rsa_pub = get_pubkey();
 132
 133     my ($username, $age) = PVE::Ticket::verify_rsa_ticket(
 134         $rsa_pub, 'PVE', $ticket, undef, -300, $ticket_lifetime, $noerr);
 135
 136     return undef if $noerr && !defined($username);
 137
 138     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 139
 140     return wantarray ? ($username, $age) : $username;
 141 }
 142
 143 # VNC tickets
 144 # - they do not contain the username in plain text
 145 # - they are restricted to a specific resource path (example: '/vms/100')
 146 sub assemble_vnc_ticket {
 147     my ($username, $path) = @_;
 148
 149     my $rsa_priv = get_privkey();
 150
 151     $path = normalize_path($path);
 152
 153     my $secret_data = "$username:$path";
 154
 155     return PVE::Ticket::assemble_rsa_ticket(
 156         $rsa_priv, 'PVEVNC', undef, $secret_data);
 157 }
 158
 159 sub verify_vnc_ticket {
 160     my ($ticket, $username, $path, $noerr) = @_;
 161
 162     my $rsa_pub = get_pubkey();
 163
 164     my $secret_data = "$username:$path";
 165
 166     return PVE::Ticket::verify_rsa_ticket(
 167         $rsa_pub, 'PVEVNC', $ticket, $secret_data, -20, 40, $noerr);
 168 }
 169
 170 sub assemble_spice_ticket {
 171     my ($username, $vmid, $node) = @_;
 172
 173     my $secret = &$get_csrfr_secret();
 174
 175     return PVE::Ticket::assemble_spice_ticket(
 176         $secret, $username, $vmid, $node);
 177 }
 178
 179
 180 sub verify_spice_connect_url {
 181     my ($connect_str) = @_;
 182
 183     my $secret = &$get_csrfr_secret();
 184
 185     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 186 }
 187
 188 sub read_x509_subject_spice {
 189     my ($filename) = @_;
 190
 191     # read x509 subject
 192     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 193     die "Could not open $filename using OpenSSL\n"
 194         if !$bio;
 195
 196     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 197     Net::SSLeay::BIO_free($bio);
 198
 199     die "Could not parse X509 certificate in $filename\n"
 200         if !$x509;
 201
 202     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 203     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 204     Net::SSLeay::X509_free($x509);
 205
 206     # remote-viewer wants comma as seperator (not '/')
 207     $subject =~ s!^/!!;
 208     $subject =~ s!/(\w+=)!,$1!g;
 209
 210     return $subject;
 211 }
 212
 213 # helper to generate SPICE remote-viewer configuration
 214 sub remote_viewer_config {
 215     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 216
 217     if (!$proxy) {
 218         my $host = `hostname -f` || PVE::INotify::nodename();
 219         chomp $host;
 220         $proxy = $host;
 221     }
 222
 223     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 224
 225     my $filename = "/etc/pve/local/pve-ssl.pem";
 226     my $subject = read_x509_subject_spice($filename);
 227
 228     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 229     $cacert =~ s/\n/\\n/g;
 230
 231     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 232     my $config = {
 233         'secure-attention' => "Ctrl+Alt+Ins",
 234         'toggle-fullscreen' => "Shift+F11",
 235         'release-cursor' => "Ctrl+Alt+R",
 236         type => 'spice',
 237         title => $title,
 238         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 239         proxy => "http://$proxy:3128",
 240         'tls-port' => $port,
 241         'host-subject' => $subject,
 242         ca => $cacert,
 243         password => $ticket,
 244         'delete-this-file' => 1,
 245     };
 246
 247     return ($ticket, $proxyticket, $config);
 248 }
 249
 250 sub check_user_exist {
 251     my ($usercfg, $username, $noerr) = @_;
 252
 253     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 254     return undef if !$username;
 255
 256     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 257
 258     die "no such user ('$username')\n" if !$noerr;
 259
 260     return undef;
 261 }
 262
 263 sub check_user_enabled {
 264     my ($usercfg, $username, $noerr) = @_;
 265
 266     my $data = check_user_exist($usercfg, $username, $noerr);
 267     return undef if !$data;
 268
 269     return 1 if $data->{enable};
 270
 271     die "user '$username' is disabled\n" if !$noerr;
 272
 273     return undef;
 274 }
 275
 276 sub verify_one_time_pw {
 277     my ($usercfg, $username, $tfa_cfg, $otp) = @_;
 278
 279     my $type = $tfa_cfg->{type};
 280
 281     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 282
 283     # fixme: proxy support?
 284     my $proxy;
 285
 286     if ($type eq 'yubico') {
 287         my $keys = $usercfg->{users}->{$username}->{keys};
 288         yubico_verify_otp($otp, $keys, $tfa_cfg->{url}, $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 289     } elsif ($type eq 'oath') {
 290         my $keys = $usercfg->{users}->{$username}->{keys};
 291         oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 292     } else {
 293         die "unknown tfa type '$type'\n";
 294     }
 295 }
 296
 297 # password should be utf8 encoded
 298 # Note: some plugins delay/sleep if auth fails
 299 sub authenticate_user {
 300     my ($username, $password, $otp) = @_;
 301
 302     die "no username specified\n" if !$username;
 303
 304     my ($ruid, $realm);
 305
 306     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 307
 308     my $usercfg = cfs_read_file('user.cfg');
 309
 310     check_user_enabled($usercfg, $username);
 311
 312     my $ctime = time();
 313     my $expire = $usercfg->{users}->{$username}->{expire};
 314
 315     die "account expired\n" if $expire && ($expire < $ctime);
 316
 317     my $domain_cfg = cfs_read_file('domains.cfg');
 318
 319     my $cfg = $domain_cfg->{ids}->{$realm};
 320     die "auth domain '$realm' does not exists\n" if !$cfg;
 321     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 322     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 323
 324     if ($cfg->{tfa}) {
 325         my $tfa_cfg = PVE::Auth::Plugin::parse_tfa_config($cfg->{tfa});
 326         verify_one_time_pw($usercfg, $username, $tfa_cfg, $otp);
 327     }
 328
 329     return $username;
 330 }
 331
 332 sub domain_set_password {
 333     my ($realm, $username, $password) = @_;
 334
 335     die "no auth domain specified" if !$realm;
 336
 337     my $domain_cfg = cfs_read_file('domains.cfg');
 338
 339     my $cfg = $domain_cfg->{ids}->{$realm};
 340     die "auth domain '$realm' does not exist\n" if !$cfg;
 341     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 342     $plugin->store_password($cfg, $realm, $username, $password);
 343 }
 344
 345 sub add_user_group {
 346     my ($username, $usercfg, $group) = @_;
 347
 348     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 349     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 350 }
 351
 352 sub delete_user_group {
 353     my ($username, $usercfg) = @_;
 354
 355     foreach my $group (keys %{$usercfg->{groups}}) {
 356
 357         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 358             if $usercfg->{groups}->{$group}->{users}->{$username};
 359     }
 360 }
 361
 362 sub delete_user_acl {
 363     my ($username, $usercfg) = @_;
 364
 365     foreach my $acl (keys %{$usercfg->{acl}}) {
 366
 367         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 368             if $usercfg->{acl}->{$acl}->{users}->{$username};
 369     }
 370 }
 371
 372 sub delete_group_acl {
 373     my ($group, $usercfg) = @_;
 374
 375     foreach my $acl (keys %{$usercfg->{acl}}) {
 376
 377         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 378             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 379     }
 380 }
 381
 382 sub delete_pool_acl {
 383     my ($pool, $usercfg) = @_;
 384
 385     my $path = "/pool/$pool";
 386
 387     delete ($usercfg->{acl}->{$path})
 388 }
 389
 390 # we automatically create some predefined roles by splitting privs
 391 # into 3 groups (per category)
 392 # root: only root is allowed to do that
 393 # admin: an administrator can to that
 394 # user: a normal user/customer can to that
 395 my $privgroups = {
 396     VM => {
 397         root => [],
 398         admin => [
 399             'VM.Config.Disk',
 400             'VM.Config.CPU',
 401             'VM.Config.Memory',
 402             'VM.Config.Network',
 403             'VM.Config.HWType',
 404             'VM.Config.Options', # covers all other things
 405             'VM.Allocate',
 406             'VM.Clone',
 407             'VM.Migrate',
 408             'VM.Monitor',
 409             'VM.Snapshot',
 410         ],
 411         user => [
 412             'VM.Config.CDROM', # change CDROM media
 413             'VM.Console',
 414             'VM.Backup',
 415             'VM.PowerMgmt',
 416         ],
 417         audit => [
 418             'VM.Audit',
 419         ],
 420     },
 421     Sys => {
 422         root => [
 423             'Sys.PowerMgmt',
 424             'Sys.Modify', # edit/change node settings
 425         ],
 426         admin => [
 427             'Permissions.Modify',
 428             'Sys.Console',
 429             'Sys.Syslog',
 430         ],
 431         user => [],
 432         audit => [
 433             'Sys.Audit',
 434         ],
 435     },
 436     Datastore => {
 437         root => [],
 438         admin => [
 439             'Datastore.Allocate',
 440             'Datastore.AllocateTemplate',
 441         ],
 442         user => [
 443             'Datastore.AllocateSpace',
 444         ],
 445         audit => [
 446             'Datastore.Audit',
 447         ],
 448     },
 449     User => {
 450         root => [
 451             'Realm.Allocate',
 452         ],
 453         admin => [
 454             'User.Modify',
 455             'Group.Allocate', # edit/change group settings
 456             'Realm.AllocateUser',
 457         ],
 458         user => [],
 459         audit => [],
 460     },
 461     Pool => {
 462         root => [],
 463         admin => [
 464             'Pool.Allocate', # create/delete pools
 465         ],
 466         user => [],
 467         audit => [],
 468     },
 469 };
 470
 471 my $valid_privs = {};
 472
 473 my $special_roles = {
 474     'NoAccess' => {}, # no privileges
 475     'Administrator' => $valid_privs, # all privileges
 476 };
 477
 478 sub create_roles {
 479
 480     foreach my $cat (keys %$privgroups) {
 481         my $cd = $privgroups->{$cat};
 482         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 483                        @{$cd->{user}}, @{$cd->{audit}}) {
 484             $valid_privs->{$p} = 1;
 485         }
 486         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 487
 488             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 489             $special_roles->{"PVEAdmin"}->{$p} = 1;
 490         }
 491         if (scalar(@{$cd->{user}})) {
 492             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 493                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 494             }
 495         }
 496         foreach my $p (@{$cd->{audit}}) {
 497             $special_roles->{"PVEAuditor"}->{$p} = 1;
 498         }
 499     }
 500
 501     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
 502 };
 503
 504 create_roles();
 505
 506 sub add_role_privs {
 507     my ($role, $usercfg, $privs) = @_;
 508
 509     return if !$privs;
 510
 511     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 512
 513     foreach my $priv (split_list($privs)) {
 514         if (defined ($valid_privs->{$priv})) {
 515             $usercfg->{roles}->{$role}->{$priv} = 1;
 516         } else {
 517             die "invalid privilege '$priv'\n";
 518         }
 519     }
 520 }
 521
 522 sub normalize_path {
 523     my $path = shift;
 524
 525     $path =~ s|/+|/|g;
 526
 527     $path =~ s|/$||;
 528
 529     $path = '/' if !$path;
 530
 531     $path = "/$path" if $path !~ m|^/|;
 532
 533     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
 534
 535     return $path;
 536 }
 537
 538
 539 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 540 sub verify_groupname {
 541     my ($groupname, $noerr) = @_;
 542
 543     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 544
 545         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 546
 547         return undef;
 548     }
 549
 550     return $groupname;
 551 }
 552
 553 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 554 sub verify_rolename {
 555     my ($rolename, $noerr) = @_;
 556
 557     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 558
 559         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 560
 561         return undef;
 562     }
 563
 564     return $rolename;
 565 }
 566
 567 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
 568 sub verify_poolname {
 569     my ($poolname, $noerr) = @_;
 570
 571     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 572
 573         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 574
 575         return undef;
 576     }
 577
 578     return $poolname;
 579 }
 580
 581 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 582 sub verify_privname {
 583     my ($priv, $noerr) = @_;
 584
 585     if (!$valid_privs->{$priv}) {
 586         die "invalid privilege '$priv'\n" if !$noerr;
 587
 588         return undef;
 589     }
 590
 591     return $priv;
 592 }
 593
 594 sub userconfig_force_defaults {
 595     my ($cfg) = @_;
 596
 597     foreach my $r (keys %$special_roles) {
 598         $cfg->{roles}->{$r} = $special_roles->{$r};
 599     }
 600
 601     # add root user if not exists
 602     if (!$cfg->{users}->{'root@pam'}) {
 603         $cfg->{users}->{'root@pam'}->{enable} = 1;
 604     }
 605 }
 606
 607 sub parse_user_config {
 608     my ($filename, $raw) = @_;
 609
 610     my $cfg = {};
 611
 612     userconfig_force_defaults($cfg);
 613
 614     $raw = '' if !defined($raw);
 615     while ($raw =~ /^\s*(.+?)\s*$/gm) {
 616         my $line = $1;
 617         my @data;
 618
 619         foreach my $d (split (/:/, $line)) {
 620             $d =~ s/^\s+//;
 621             $d =~ s/\s+$//;
 622             push @data, $d
 623         }
 624
 625         my $et = shift @data;
 626
 627         if ($et eq 'user') {
 628             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
 629
 630             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 631             if (!$realm) {
 632                 warn "user config - ignore user '$user' - invalid user name\n";
 633                 next;
 634             }
 635
 636             $enable = $enable ? 1 : 0;
 637
 638             $expire = 0 if !$expire;
 639
 640             if ($expire !~ m/^\d+$/) {
 641                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 642                 next;
 643             }
 644             $expire = int($expire);
 645
 646             #if (!verify_groupname ($group, 1)) {
 647             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 648             #    next;
 649             #}
 650
 651             $cfg->{users}->{$user} = {
 652                 enable => $enable,
 653                 # group => $group,
 654             };
 655             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 656             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 657             $cfg->{users}->{$user}->{email} = $email;
 658             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 659             $cfg->{users}->{$user}->{expire} = $expire;
 660             # keys: allowed yubico key ids or oath secrets (base32 encoded)
 661             $cfg->{users}->{$user}->{keys} = $keys if $keys;
 662
 663             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 664             #$cfg->{groups}->{$group}->{$user} = 1;
 665
 666         } elsif ($et eq 'group') {
 667             my ($group, $userlist, $comment) = @data;
 668
 669             if (!verify_groupname($group, 1)) {
 670                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 671                 next;
 672             }
 673
 674             # make sure to add the group (even if there are no members)
 675             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 676
 677             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 678
 679             foreach my $user (split_list($userlist)) {
 680
 681                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
 682                     warn "user config - ignore invalid group member '$user'\n";
 683                     next;
 684                 }
 685
 686                 if ($cfg->{users}->{$user}) { # user exists
 687                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
 688                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
 689                 } else {
 690                     warn "user config - ignore invalid group member '$user'\n";
 691                 }
 692             }
 693
 694         } elsif ($et eq 'role') {
 695             my ($role, $privlist) = @data;
 696
 697             if (!verify_rolename($role, 1)) {
 698                 warn "user config - ignore role '$role' - invalid characters in role name\n";
 699                 next;
 700             }
 701
 702             # make sure to add the role (even if there are no privileges)
 703             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
 704
 705             foreach my $priv (split_list($privlist)) {
 706                 if (defined ($valid_privs->{$priv})) {
 707                     $cfg->{roles}->{$role}->{$priv} = 1;
 708                 } else {
 709                     warn "user config - ignore invalid priviledge '$priv'\n";
 710                 }
 711             }
 712
 713         } elsif ($et eq 'acl') {
 714             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
 715
 716             if (my $path = normalize_path($pathtxt)) {
 717                 foreach my $role (split_list($rolelist)) {
 718
 719                     if (!verify_rolename($role, 1)) {
 720                         warn "user config - ignore invalid role name '$role' in acl\n";
 721                         next;
 722                     }
 723
 724                     foreach my $ug (split_list($uglist)) {
 725                         if ($ug =~ m/^@(\S+)$/) {
 726                             my $group = $1;
 727                             if ($cfg->{groups}->{$group}) { # group exists
 728                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
 729                             } else {
 730                                 warn "user config - ignore invalid acl group '$group'\n";
 731                             }
 732                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
 733                             if ($cfg->{users}->{$ug}) { # user exists
 734                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
 735                             } else {
 736                                 warn "user config - ignore invalid acl member '$ug'\n";
 737                             }
 738                         } else {
 739                             warn "user config - invalid user/group '$ug' in acl\n";
 740                         }
 741                     }
 742                 }
 743             } else {
 744                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
 745             }
 746         } elsif ($et eq 'pool') {
 747             my ($pool, $comment, $vmlist, $storelist) = @data;
 748
 749             if (!verify_poolname($pool, 1)) {
 750                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
 751                 next;
 752             }
 753
 754             # make sure to add the pool (even if there are no members)
 755             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
 756
 757             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 758
 759             foreach my $vmid (split_list($vmlist)) {
 760                 if ($vmid !~ m/^\d+$/) {
 761                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
 762                     next;
 763                 }
 764                 $vmid = int($vmid);
 765
 766                 if ($cfg->{vms}->{$vmid}) {
 767                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
 768                     next;
 769                 }
 770
 771                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
 772
 773                 # record vmid ==> pool relation
 774                 $cfg->{vms}->{$vmid} = $pool;
 775             }
 776
 777             foreach my $storeid (split_list($storelist)) {
 778                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 779                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
 780                     next;
 781                 }
 782                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
 783             }
 784         } else {
 785             warn "user config - ignore config line: $line\n";
 786         }
 787     }
 788
 789     userconfig_force_defaults($cfg);
 790
 791     return $cfg;
 792 }
 793
 794 sub write_user_config {
 795     my ($filename, $cfg) = @_;
 796
 797     my $data = '';
 798
 799     foreach my $user (keys %{$cfg->{users}}) {
 800         my $d = $cfg->{users}->{$user};
 801         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
 802         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
 803         my $email = $d->{email} || '';
 804         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 805         my $expire = int($d->{expire} || 0);
 806         my $enable = $d->{enable} ? 1 : 0;
 807         my $keys = $d->{keys} ? $d->{keys} : '';
 808         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
 809     }
 810
 811     $data .= "\n";
 812
 813     foreach my $group (keys %{$cfg->{groups}}) {
 814         my $d = $cfg->{groups}->{$group};
 815         my $list = join (',', keys %{$d->{users}});
 816         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 817         $data .= "group:$group:$list:$comment:\n";
 818     }
 819
 820     $data .= "\n";
 821
 822     foreach my $pool (keys %{$cfg->{pools}}) {
 823         my $d = $cfg->{pools}->{$pool};
 824         my $vmlist = join (',', keys %{$d->{vms}});
 825         my $storelist = join (',', keys %{$d->{storage}});
 826         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 827         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
 828     }
 829
 830     $data .= "\n";
 831
 832     foreach my $role (keys %{$cfg->{roles}}) {
 833         next if $special_roles->{$role};
 834
 835         my $d = $cfg->{roles}->{$role};
 836         my $list = join (',', keys %$d);
 837         $data .= "role:$role:$list:\n";
 838     }
 839
 840     $data .= "\n";
 841
 842     foreach my $path (sort keys %{$cfg->{acl}}) {
 843         my $d = $cfg->{acl}->{$path};
 844
 845         my $ra = {};
 846
 847         foreach my $group (keys %{$d->{groups}}) {
 848             my $l0 = '';
 849             my $l1 = '';
 850             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
 851                 my $propagate = $d->{groups}->{$group}->{$role};
 852                 if ($propagate) {
 853                     $l1 .= ',' if $l1;
 854                     $l1 .= $role;
 855                 } else {
 856                     $l0 .= ',' if $l0;
 857                     $l0 .= $role;
 858                 }
 859             }
 860             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
 861             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
 862         }
 863
 864         foreach my $user (keys %{$d->{users}}) {
 865             # no need to save, because root is always 'Administrator'
 866             next if $user eq 'root@pam';
 867
 868             my $l0 = '';
 869             my $l1 = '';
 870             foreach my $role (sort keys %{$d->{users}->{$user}}) {
 871                 my $propagate = $d->{users}->{$user}->{$role};
 872                 if ($propagate) {
 873                     $l1 .= ',' if $l1;
 874                     $l1 .= $role;
 875                 } else {
 876                     $l0 .= ',' if $l0;
 877                     $l0 .= $role;
 878                 }
 879             }
 880             $ra->{0}->{$l0}->{$user} = 1 if $l0;
 881             $ra->{1}->{$l1}->{$user} = 1 if $l1;
 882         }
 883
 884         foreach my $rolelist (sort keys %{$ra->{0}}) {
 885             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
 886             $data .= "acl:0:$path:$uglist:$rolelist:\n";
 887         }
 888         foreach my $rolelist (sort keys %{$ra->{1}}) {
 889             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
 890             $data .= "acl:1:$path:$uglist:$rolelist:\n";
 891         }
 892     }
 893
 894     return $data;
 895 }
 896
 897 sub roles {
 898     my ($cfg, $user, $path) = @_;
 899
 900     # NOTE: we do not consider pools here.
 901     # You need to use $rpcenv->roles() instead if you want that.
 902
 903     return 'Administrator' if $user eq 'root@pam'; # root can do anything
 904
 905     my $perm = {};
 906
 907     foreach my $p (sort keys %{$cfg->{acl}}) {
 908         my $final = ($path eq $p);
 909
 910         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
 911
 912         my $acl = $cfg->{acl}->{$p};
 913
 914         #print "CHECKACL $path $p\n";
 915         #print "ACL $path = " . Dumper ($acl);
 916
 917         if (my $ri = $acl->{users}->{$user}) {
 918             my $new;
 919             foreach my $role (keys %$ri) {
 920                 my $propagate = $ri->{$role};
 921                 if ($final || $propagate) {
 922                     #print "APPLY ROLE $p $user $role\n";
 923                     $new = {} if !$new;
 924                     $new->{$role} = 1;
 925                 }
 926             }
 927             if ($new) {
 928                 $perm = $new; # overwrite previous settings
 929                 next; # user privs always override group privs
 930             }
 931         }
 932
 933         my $new;
 934         foreach my $g (keys %{$acl->{groups}}) {
 935             next if !$cfg->{groups}->{$g}->{users}->{$user};
 936             if (my $ri = $acl->{groups}->{$g}) {
 937                 foreach my $role (keys %$ri) {
 938                     my $propagate = $ri->{$role};
 939                     if ($final || $propagate) {
 940                         #print "APPLY ROLE $p \@$g $role\n";
 941                         $new = {} if !$new;
 942                         $new->{$role} = 1;
 943                     }
 944                 }
 945             }
 946         }
 947         if ($new) {
 948             $perm = $new; # overwrite previous settings
 949             next;
 950         }
 951     }
 952
 953     return ('NoAccess') if defined ($perm->{NoAccess});
 954     #return () if defined ($perm->{NoAccess});
 955
 956     #print "permission $user $path = " . Dumper ($perm);
 957
 958     my @ra = keys %$perm;
 959
 960     #print "roles $user $path = " . join (',', @ra) . "\n";
 961
 962     return @ra;
 963 }
 964
 965 sub permission {
 966     my ($cfg, $user, $path) = @_;
 967
 968     $user = PVE::Auth::Plugin::verify_username($user, 1);
 969     return {} if !$user;
 970
 971     my @ra = roles($cfg, $user, $path);
 972
 973     my $privs = {};
 974
 975     foreach my $role (@ra) {
 976         if (my $privset = $cfg->{roles}->{$role}) {
 977             foreach my $p (keys %$privset) {
 978                 $privs->{$p} = 1;
 979             }
 980         }
 981     }
 982
 983     #print "priviledges $user $path = " . Dumper ($privs);
 984
 985     return $privs;
 986 }
 987
 988 sub check_permissions {
 989     my ($username, $path, $privlist) = @_;
 990
 991     $path = normalize_path($path);
 992     my $usercfg = cfs_read_file('user.cfg');
 993     my $perm = permission($usercfg, $username, $path);
 994
 995     foreach my $priv (split_list($privlist)) {
 996         return undef if !$perm->{$priv};
 997     };
 998
 999     return 1;
1000 }
1001
1002 sub remove_vm_access {
1003     my ($vmid) = @_;
1004     my $delVMaccessFn = sub {
1005         my $usercfg = cfs_read_file("user.cfg");
1006         my $modified;
1007
1008         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1009             delete $usercfg->{acl}->{"/vms/$vmid"};
1010             $modified = 1;
1011         }
1012         if (my $pool = $usercfg->{vms}->{$vmid}) {
1013             if (my $data = $usercfg->{pools}->{$pool}) {
1014                 delete $data->{vms}->{$vmid};
1015                 delete $usercfg->{vms}->{$vmid};
1016                 $modified = 1;
1017             }
1018         }
1019         cfs_write_file("user.cfg", $usercfg) if $modified;
1020     };
1021
1022     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1023 }
1024
1025 sub remove_storage_access {
1026     my ($storeid) = @_;
1027
1028     my $deleteStorageAccessFn = sub {
1029         my $usercfg = cfs_read_file("user.cfg");
1030         my $modified;
1031
1032         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1033             delete $usercfg->{acl}->{"/storage/$storeid"};
1034             $modified = 1;
1035         }
1036         foreach my $pool (keys %{$usercfg->{pools}}) {
1037             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1038             $modified = 1;
1039         }
1040         cfs_write_file("user.cfg", $usercfg) if $modified;
1041     };
1042
1043     lock_user_config($deleteStorageAccessFn,
1044                      "access permissions cleanup for storage $storeid failed");
1045 }
1046
1047 sub add_vm_to_pool {
1048     my ($vmid, $pool) = @_;
1049
1050     my $addVMtoPoolFn = sub {
1051         my $usercfg = cfs_read_file("user.cfg");
1052         if (my $data = $usercfg->{pools}->{$pool}) {
1053             $data->{vms}->{$vmid} = 1;
1054             $usercfg->{vms}->{$vmid} = $pool;
1055             cfs_write_file("user.cfg", $usercfg);
1056         }
1057     };
1058
1059     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1060 }
1061
1062 sub remove_vm_from_pool {
1063     my ($vmid) = @_;
1064
1065     my $delVMfromPoolFn = sub {
1066         my $usercfg = cfs_read_file("user.cfg");
1067         if (my $pool = $usercfg->{vms}->{$vmid}) {
1068             if (my $data = $usercfg->{pools}->{$pool}) {
1069                 delete $data->{vms}->{$vmid};
1070                 delete $usercfg->{vms}->{$vmid};
1071                 cfs_write_file("user.cfg", $usercfg);
1072             }
1073         }
1074     };
1075
1076     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1077 }
1078
1079 # hotp/totp code
1080
1081 sub hotp($$;$) {
1082         my ($binsecret, $number, $digits) = @_;
1083
1084         $digits = 6 if !defined($digits);
1085
1086         my $bincounter = pack('Q>', $number);
1087         my $hmac = Digest::SHA::hmac_sha1($bincounter, $binsecret);
1088
1089         my $offset = unpack('C', substr($hmac,19) & pack('C', 0x0F));
1090         my $part = substr($hmac, $offset, 4);
1091         my $otp = unpack('N', $part);
1092         my $value = ($otp & 0x7fffffff) % (10**$digits);
1093         return sprintf("%0${digits}d", $value);
1094 }
1095
1096 # experimental code for yubico OTP verification
1097
1098 sub yubico_compute_param_sig {
1099     my ($param, $api_key) = @_;
1100
1101     my $paramstr = '';
1102     foreach my $key (sort keys %$param) {
1103         $paramstr .= '&' if $paramstr;
1104         $paramstr .= "$key=$param->{$key}";
1105     }
1106
1107     # hmac_sha1_base64 does not add '=' padding characters, so we use encode_base64
1108     my $sig = uri_escape(encode_base64(Digest::SHA::hmac_sha1($paramstr, decode_base64($api_key || '')), ''));
1109
1110     return ($paramstr, $sig);
1111 }
1112
1113 sub yubico_verify_otp {
1114     my ($otp, $keys, $url, $api_id, $api_key, $proxy) = @_;
1115
1116     die "yubico: missing password\n" if !defined($otp);
1117     die "yubico: missing API ID\n" if !defined($api_id);
1118     die "yubico: missing API KEY\n" if !defined($api_key);
1119     die "yubico: no associated yubico keys\n" if $keys =~ m/^\s+$/;
1120
1121     die "yubico: wrong OTP length\n" if (length($otp) < 32) || (length($otp) > 48);
1122
1123     $url = 'http://api2.yubico.com/wsapi/2.0/verify' if !defined($url);
1124
1125     my $params = {
1126         nonce =>  Digest::SHA::hmac_sha1_hex(time(), rand()),
1127         id => $api_id,
1128         otp => uri_escape($otp),
1129         timestamp => 1,
1130     };
1131
1132     my ($paramstr, $sig) = yubico_compute_param_sig($params, $api_key);
1133
1134     $paramstr .= "&h=$sig" if $api_key;
1135
1136     my $req = HTTP::Request->new('GET' => "$url?$paramstr");
1137
1138     my $ua = LWP::UserAgent->new(protocols_allowed => ['http', 'https'], timeout => 30);
1139
1140     if ($proxy) {
1141         $ua->proxy(['http', 'https'], $proxy);
1142     } else {
1143         $ua->env_proxy;
1144     }
1145
1146     my $response = $ua->request($req);
1147     my $code = $response->code;
1148
1149     if ($code != 200) {
1150         my $msg = $response->message || 'unknown';
1151         die "Invalid response from server: $code $msg\n";
1152     }
1153
1154     my $raw = $response->decoded_content;
1155
1156     my $result = {};
1157     foreach my $kvpair (split(/\n/, $raw)) {
1158         chomp $kvpair;
1159         if($kvpair =~ /^\S+=/) {
1160             my ($k, $v) = split(/=/, $kvpair, 2);
1161             $v =~ s/\s//g;
1162             $result->{$k} = $v;
1163         }
1164     }
1165
1166     my $rsig = $result->{h};
1167     delete $result->{h};
1168
1169     if ($api_key) {
1170         my ($datastr, $vsig) = yubico_compute_param_sig($result, $api_key);
1171         $vsig = uri_unescape($vsig);
1172         die "yubico: result signature verification failed\n" if $rsig ne $vsig;
1173     }
1174
1175     die "yubico auth failed: $result->{status}\n" if $result->{status} ne 'OK';
1176
1177     my $publicid = $result->{publicid} = substr(lc($result->{otp}), 0, 12);
1178
1179     my $found;
1180     foreach my $k (PVE::Tools::split_list($keys)) {
1181         if ($k eq $publicid) {
1182             $found = 1;
1183             last;
1184         }
1185     }
1186
1187     die "yubico auth failed: key does not belong to user\n" if !$found;
1188
1189     return $result;
1190 }
1191
1192 sub oath_verify_otp {
1193     my ($otp, $keys, $step, $digits) = @_;
1194
1195     die "oath: missing password\n" if !defined($otp);
1196     die "oath: no associated oath keys\n" if $keys =~ m/^\s+$/;
1197
1198     $step = 30 if !$step;
1199     $digits = 6 if !$digits;
1200
1201     my $found;
1202     foreach my $k (PVE::Tools::split_list($keys)) {
1203         # Note: we generate 3 values to allow small time drift
1204         my $binkey;
1205         if ($k =~ /^[A-Z2-7=]{16}$/) {
1206             $binkey = MIME::Base32::decode_rfc3548($k);
1207         } elsif ($k =~ /^[A-Fa-f0-9]{40}$/) {
1208             $binkey = pack('H*', $k);
1209         } else {
1210             die "unrecognized key format, must be hex or base32 encoded\n";
1211         }
1212
1213         # force integer division for time/step
1214         use integer;
1215         my $now = time()/$step - 1;
1216         $found = 1 if $otp eq hotp($binkey, $now+0, $digits);
1217         $found = 1 if $otp eq hotp($binkey, $now+1, $digits);
1218         $found = 1 if $otp eq hotp($binkey, $now+2, $digits);
1219         last if $found;
1220     }
1221
1222     die "oath auth failed\n" if !$found;
1223 }
1224
1225 # bash completion helpers
1226
1227 sub complete_username {
1228
1229     my $user_cfg = cfs_read_file('user.cfg');
1230
1231     return [ keys %{$user_cfg->{users}} ];
1232 }
1233
1234 sub complete_group {
1235
1236     my $user_cfg = cfs_read_file('user.cfg');
1237
1238     return [ keys %{$user_cfg->{groups}} ];
1239 }
1240
1241 sub complete_realm {
1242
1243     my $domain_cfg = cfs_read_file('domains.cfg');
1244
1245     return [ keys %{$domain_cfg->{ids}} ];
1246 }
1247
1248 1;