enable yubico OTP (by removing debuging code)
[pve-access-control.git] / PVE / AccessControl.pm
1 package PVE::AccessControl;
2
3 use strict;
4 use warnings;
5 use Encode;
6 use Crypt::OpenSSL::Random;
7 use Crypt::OpenSSL::RSA;
8 use Net::SSLeay;
9 use MIME::Base64;
10 use Digest::SHA;
11 use Digest::HMAC_SHA1;
12 use URI::Escape;
13 use LWP::UserAgent;
14 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
15 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
16 use PVE::JSONSchema;
17
18 use PVE::Auth::Plugin;
19 use PVE::Auth::AD;
20 use PVE::Auth::LDAP;
21 use PVE::Auth::PVE;
22 use PVE::Auth::PAM;
23
24 use Data::Dumper; # fixme: remove
25
26 # load and initialize all plugins
27
28 PVE::Auth::AD->register();
29 PVE::Auth::LDAP->register();
30 PVE::Auth::PVE->register();
31 PVE::Auth::PAM->register();
32 PVE::Auth::Plugin->init();
33
34 # $authdir must be writable by root only!
35 my $confdir = "/etc/pve";
36 my $authdir = "$confdir/priv";
37 my $authprivkeyfn = "$authdir/authkey.key";
38 my $authpubkeyfn = "$confdir/authkey.pub";
39 my $pve_www_key_fn = "$confdir/pve-www.key";
40
41 my $ticket_lifetime = 3600*2; # 2 hours
42
43 Crypt::OpenSSL::RSA->import_random_seed();
44
45 cfs_register_file('user.cfg', 
46                   \&parse_user_config,  
47                   \&write_user_config);
48
49
50 sub verify_username {
51     PVE::Auth::Plugin::verify_username(@_);
52 }
53
54 sub pve_verify_realm {
55     PVE::Auth::Plugin::pve_verify_realm(@_);
56 }
57
58 sub lock_user_config {
59     my ($code, $errmsg) = @_;
60
61     cfs_lock_file("user.cfg", undef, $code);
62     if (my $err = $@) {
63         $errmsg ? die "$errmsg: $err" : die $err;
64     }
65 }
66
67 my $pve_auth_pub_key;
68 sub get_pubkey {    
69
70     return $pve_auth_pub_key if $pve_auth_pub_key;
71
72     my $input = PVE::Tools::file_get_contents($authpubkeyfn); 
73
74     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
75
76     return $pve_auth_pub_key;
77 }
78
79 my $csrf_prevention_secret;
80 my $get_csrfr_secret = sub {
81     if (!$csrf_prevention_secret) {
82         my $input = PVE::Tools::file_get_contents($pve_www_key_fn); 
83         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
84     }
85     return $csrf_prevention_secret;
86 };
87
88 sub assemble_csrf_prevention_token {
89     my ($username) = @_;
90
91     my $timestamp = sprintf("%08X", time());
92
93     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
94
95     return "$timestamp:$digest"; 
96 }
97
98 sub verify_csrf_prevention_token {
99     my ($username, $token, $noerr) = @_;
100
101     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
102         my $sig = $2;
103         my $timestamp = $1;
104         my $ttime = hex($timestamp);
105
106         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
107
108         my $age = time() - $ttime;
109         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
110     }
111
112     die "Permission denied - invalid csrf token\n" if !$noerr;
113
114     return undef;
115 }
116
117 my $pve_auth_priv_key;
118 sub get_privkey {
119
120     return $pve_auth_priv_key if $pve_auth_priv_key;
121
122     my $input = PVE::Tools::file_get_contents($authprivkeyfn); 
123
124     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
125
126     return $pve_auth_priv_key;
127 }
128
129 sub assemble_ticket {
130     my ($username) = @_;
131
132     my $rsa_priv = get_privkey();
133
134     my $timestamp = sprintf("%08X", time());
135
136     my $plain = "PVE:$username:$timestamp";
137
138     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
139
140     return $ticket;
141 }
142
143 sub verify_ticket {
144     my ($ticket, $noerr) = @_;
145
146     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
147         my $plain = $1;
148         my $sig = $2;
149
150         my $rsa_pub = get_pubkey();
151         if ($rsa_pub->verify($plain, decode_base64($sig))) {
152             if ($plain =~ m/^PVE:(\S+):([A-Z0-9]{8})$/) {
153                 my $username = $1;
154                 my $timestamp = $2;
155                 my $ttime = hex($timestamp);
156
157                 my $age = time() - $ttime;
158
159                 if (PVE::Auth::Plugin::verify_username($username, 1) &&
160                     ($age > -300) && ($age < $ticket_lifetime)) {
161                     return wantarray ? ($username, $age) : $username;
162                 }
163             }
164         }
165     }
166
167     die "permission denied - invalid ticket\n" if !$noerr;
168
169     return undef;
170 }
171
172 # VNC tickets
173 # - they do not contain the username in plain text
174 # - they are restricted to a specific resource path (example: '/vms/100')
175 sub assemble_vnc_ticket {
176     my ($username, $path) = @_;
177
178     my $rsa_priv = get_privkey();
179
180     my $timestamp = sprintf("%08X", time());
181
182     my $plain = "PVEVNC:$timestamp";
183
184     $path = normalize_path($path);
185
186     my $full = "$plain:$username:$path";
187
188     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
189
190     return $ticket;
191 }
192
193 sub verify_vnc_ticket {
194     my ($ticket, $username, $path, $noerr) = @_;
195
196     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
197         my $plain = $1;
198         my $sig = $2;
199         my $full = "$plain:$username:$path";
200
201         my $rsa_pub = get_pubkey();
202         # Note: sign only match if $username and  $path is correct
203         if ($rsa_pub->verify($full, decode_base64($sig))) {
204             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
205                 my $ttime = hex($1);
206
207                 my $age = time() - $ttime;
208
209                 if (($age > -20) && ($age < 40)) {
210                     return 1;
211                 }
212             }
213         }
214     }
215
216     die "permission denied - invalid vnc ticket\n" if !$noerr;
217
218     return undef;
219 }
220
221 sub assemble_spice_ticket {
222     my ($username, $vmid, $node) = @_;
223
224     my $rsa_priv = get_privkey();
225
226     my $timestamp = sprintf("%08x", time());
227
228     my $randomstr = "PVESPICE:$timestamp:$vmid:$node:" . rand(10);
229
230     # this should be uses as one-time password
231     # max length is 60 chars (spice limit)
232     # we pass this to qemu set_pasword and limit lifetime there
233     # keep this secret
234     my $ticket = Digest::SHA::sha1_hex($rsa_priv->sign($randomstr));
235
236     # Note: spice proxy connects with HTTP, so $proxyticket is exposed to public
237     # we use a signature/timestamp to make sure nobody can fake such ticket
238     # an attacker can use this $proxyticket, but he will fail because $ticket is
239     # private.
240     # The proxy need to be able to extract/verify the ticket
241     # Note: data needs to be lower case only, because virt-viewer needs that
242     # Note: RSA signature are too long (>=256 charaters) and makes problems with remote-viewer
243
244     my $secret = &$get_csrfr_secret();
245     my $plain = "pvespiceproxy:$timestamp:$vmid:" . lc($node);
246
247     # produces 40 characters
248     my $sig = unpack("H*", Digest::SHA::sha1($plain, &$get_csrfr_secret()));
249
250     #my $sig =  unpack("H*", $rsa_priv->sign($plain)); # this produce too long strings (512)
251
252     my $proxyticket = $plain . "::" . $sig;
253
254     return ($ticket, $proxyticket);
255 }
256
257 sub verify_spice_connect_url {
258     my ($connect_str) = @_;
259
260     # Note: we pass the spice ticket as 'host', so the
261     # spice viewer connects with "$ticket:$port"
262
263     return undef if !$connect_str;
264
265     if ($connect_str =~m/^pvespiceproxy:([a-z0-9]{8}):(\d+):(\S+)::([a-z0-9]{40}):(\d+)$/) {
266         my ($timestamp, $vmid, $node, $hexsig, $port) = ($1, $2, $3, $4, $5, $6);
267         my $ttime = hex($timestamp);
268         my $age = time() - $ttime;
269
270         # use very limited lifetime - is this enough?
271         return undef if !(($age > -20) && ($age < 40));
272
273         my $plain = "pvespiceproxy:$timestamp:$vmid:$node";
274         my $sig = unpack("H*", Digest::SHA::sha1($plain, &$get_csrfr_secret()));
275
276         if ($sig eq $hexsig) {
277             return ($vmid, $node, $port);
278         } 
279     }
280
281     return undef;
282 }
283
284 sub read_x509_subject_spice {
285     my ($filename) = @_;
286
287     # read x509 subject
288     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
289     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
290     Net::SSLeay::BIO_free($bio);
291     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
292     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
293     Net::SSLeay::X509_free($x509);
294   
295     # remote-viewer wants comma as seperator (not '/')
296     $subject =~ s!^/!!;
297     $subject =~ s!/(\w+=)!,$1!g;
298
299     return $subject;
300 }
301
302 # helper to generate SPICE remote-viewer configuration
303 sub remote_viewer_config {
304     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
305
306     if (!$proxy) {
307         my $host = `hostname -f` || PVE::INotify::nodename();
308         chomp $host;
309         $proxy = $host;
310     }
311
312     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
313
314     my $filename = "/etc/pve/local/pve-ssl.pem";
315     my $subject = read_x509_subject_spice($filename);
316
317     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
318     $cacert =~ s/\n/\\n/g;
319
320     my $config = {
321         'secure-attention' => "Ctrl+Alt+Ins",
322         'toggle-fullscreen' => "Shift+F11",
323         'release-cursor' => "Ctrl+Alt+R",
324         type => 'spice',
325         title => $title,
326         host => $proxyticket, # this break tls hostname verification, so we need to use 'host-subject'
327         proxy => "http://$proxy:3128",
328         'tls-port' => $port,
329         'host-subject' => $subject,
330         ca => $cacert,
331         password => $ticket,
332         'delete-this-file' => 1,
333     };
334
335     return ($ticket, $proxyticket, $config);
336 }
337
338 sub check_user_exist {
339     my ($usercfg, $username, $noerr) = @_;
340
341     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
342     return undef if !$username;
343  
344     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
345
346     die "no such user ('$username')\n" if !$noerr;
347  
348     return undef;
349 }
350
351 sub check_user_enabled {
352     my ($usercfg, $username, $noerr) = @_;
353
354     my $data = check_user_exist($usercfg, $username, $noerr);
355     return undef if !$data;
356
357     return 1 if $data->{enable};
358
359     return 1 if $username eq 'root@pam'; # root is always enabled
360
361     die "user '$username' is disabled\n" if !$noerr;
362  
363     return undef;
364 }
365
366 sub verify_one_time_pw {
367     my ($usercfg, $username, $tfa_cfg, $otp) = @_;
368
369     my $type = $tfa_cfg->{type};
370
371     die "missing one time password for Factor-two authentication '$type'\n" if !$otp;
372
373     # fixme: proxy support?
374     my $proxy;
375
376     if ($type eq 'yubico') {
377         my $keys = $usercfg->{users}->{$username}->{keys};
378         yubico_verify_otp($otp, $keys, $tfa_cfg->{url}, $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
379     } else {
380         die "unknown tfa type '$type'\n";
381     }
382 }
383
384 # password should be utf8 encoded
385 # Note: some pluging delay/sleep if auth fails
386 sub authenticate_user {
387     my ($username, $password, $otp) = @_;
388
389     die "no username specified\n" if !$username;
390  
391     my ($ruid, $realm);
392
393     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
394
395     my $usercfg = cfs_read_file('user.cfg');
396
397     check_user_enabled($usercfg, $username);
398
399     my $ctime = time();
400     my $expire = $usercfg->{users}->{$username}->{expire};
401
402     die "account expired\n" if $expire && ($expire < $ctime);
403
404     my $domain_cfg = cfs_read_file('domains.cfg');
405
406     my $cfg = $domain_cfg->{ids}->{$realm};
407     die "auth domain '$realm' does not exists\n" if !$cfg;
408     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
409     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
410
411     if ($cfg->{tfa}) {
412         my $tfa_cfg = PVE::Auth::Plugin::parse_tfa_config($cfg->{tfa});
413         verify_one_time_pw($usercfg, $username, $tfa_cfg, $otp);
414     }
415
416     return $username;
417 }
418
419 sub domain_set_password {
420     my ($realm, $username, $password) = @_;
421
422     die "no auth domain specified" if !$realm;
423
424     my $domain_cfg = cfs_read_file('domains.cfg');
425
426     my $cfg = $domain_cfg->{ids}->{$realm};
427     die "auth domain '$realm' does not exists\n" if !$cfg;
428     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
429     $plugin->store_password($cfg, $realm, $username, $password);
430 }
431
432 sub add_user_group {
433
434     my ($username, $usercfg, $group) = @_;
435     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
436     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
437 }
438
439 sub delete_user_group {
440
441     my ($username, $usercfg) = @_;
442     
443     foreach my $group (keys %{$usercfg->{groups}}) {
444
445         delete ($usercfg->{groups}->{$group}->{users}->{$username}) 
446             if $usercfg->{groups}->{$group}->{users}->{$username};
447     }
448 }
449
450 sub delete_user_acl {
451
452     my ($username, $usercfg) = @_;
453
454     foreach my $acl (keys %{$usercfg->{acl}}) {
455
456         delete ($usercfg->{acl}->{$acl}->{users}->{$username}) 
457             if $usercfg->{acl}->{$acl}->{users}->{$username};
458     }
459 }
460
461 sub delete_group_acl {
462
463     my ($group, $usercfg) = @_;
464
465     foreach my $acl (keys %{$usercfg->{acl}}) {
466
467         delete ($usercfg->{acl}->{$acl}->{groups}->{$group}) 
468             if $usercfg->{acl}->{$acl}->{groups}->{$group};
469     }
470 }
471
472 sub delete_pool_acl {
473
474     my ($pool, $usercfg) = @_;
475
476     my $path = "/pool/$pool";
477
478     foreach my $aclpath (keys %{$usercfg->{acl}}) {
479         delete ($usercfg->{acl}->{$aclpath})
480             if $usercfg->{acl}->{$aclpath} eq 'path';
481     }
482 }
483
484 # we automatically create some predefined roles by splitting privs
485 # into 3 groups (per category)
486 # root: only root is allowed to do that
487 # admin: an administrator can to that
488 # user: a normak user/customer can to that
489 my $privgroups = {
490     VM => {
491         root => [],
492         admin => [           
493             'VM.Config.Disk', 
494             'VM.Config.CPU', 
495             'VM.Config.Memory', 
496             'VM.Config.Network', 
497             'VM.Config.HWType',
498             'VM.Config.Options', # covers all other things 
499             'VM.Allocate', 
500             'VM.Clone', 
501             'VM.Migrate',
502             'VM.Monitor', 
503             'VM.Snapshot', 
504         ],
505         user => [
506             'VM.Config.CDROM', # change CDROM media
507             'VM.Console', 
508             'VM.Backup',
509             'VM.PowerMgmt',
510         ],
511         audit => [ 
512             'VM.Audit',
513         ],
514     },
515     Sys => {
516         root => [
517             'Sys.PowerMgmt',     
518             'Sys.Modify', # edit/change node settings
519         ],
520         admin => [
521             'Permissions.Modify',
522             'Sys.Console',    
523             'Sys.Syslog',
524         ],
525         user => [],
526         audit => [
527             'Sys.Audit',
528         ],
529     },
530     Datastore => {
531         root => [],
532         admin => [
533             'Datastore.Allocate',
534             'Datastore.AllocateTemplate',
535         ],
536         user => [
537             'Datastore.AllocateSpace',
538         ],
539         audit => [
540             'Datastore.Audit',
541         ],
542     },
543     User => {
544         root => [
545             'Realm.Allocate',
546         ],
547         admin => [
548             'User.Modify',
549             'Group.Allocate', # edit/change group settings
550             'Realm.AllocateUser', 
551         ],
552         user => [],
553         audit => [],
554     },
555     Pool => {
556         root => [],
557         admin => [
558             'Pool.Allocate', # create/delete pools
559         ],
560         user => [],
561         audit => [],
562     },
563 };
564
565 my $valid_privs = {};
566
567 my $special_roles = {
568     'NoAccess' => {}, # no priviledges
569     'Administrator' => $valid_privs, # all priviledges
570 };
571
572 sub create_roles {
573
574     foreach my $cat (keys %$privgroups) {
575         my $cd = $privgroups->{$cat};
576         foreach my $p (@{$cd->{root}}, @{$cd->{admin}}, 
577                        @{$cd->{user}}, @{$cd->{audit}}) {
578             $valid_privs->{$p} = 1;
579         }
580         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
581
582             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
583             $special_roles->{"PVEAdmin"}->{$p} = 1;
584         }
585         if (scalar(@{$cd->{user}})) {
586             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
587                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
588             }
589         }
590         foreach my $p (@{$cd->{audit}}) {
591             $special_roles->{"PVEAuditor"}->{$p} = 1;
592         }
593     }
594
595     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
596 };
597
598 create_roles();
599
600 sub add_role_privs {
601     my ($role, $usercfg, $privs) = @_;
602
603     return if !$privs;
604
605     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
606
607     foreach my $priv (split_list($privs)) {
608         if (defined ($valid_privs->{$priv})) {
609             $usercfg->{roles}->{$role}->{$priv} = 1;
610         } else {
611             die "invalid priviledge '$priv'\n";
612         } 
613     }   
614 }
615
616 sub normalize_path {
617     my $path = shift;
618
619     $path =~ s|/+|/|g;
620
621     $path =~ s|/$||;
622
623     $path = '/' if !$path;
624
625     $path = "/$path" if $path !~ m|^/|;
626
627     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
628
629     return $path;
630
631
632
633 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
634 sub verify_groupname {
635     my ($groupname, $noerr) = @_;
636
637     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
638
639         die "group name '$groupname' contains invalid characters\n" if !$noerr;
640
641         return undef;
642     }
643     
644     return $groupname;
645 }
646
647 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
648 sub verify_rolename {
649     my ($rolename, $noerr) = @_;
650
651     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
652
653         die "role name '$rolename' contains invalid characters\n" if !$noerr;
654
655         return undef;
656     }
657     
658     return $rolename;
659 }
660
661 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
662 sub verify_poolname {
663     my ($poolname, $noerr) = @_;
664
665     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
666
667         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
668
669         return undef;
670     }
671     
672     return $poolname;
673 }
674
675 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
676 sub verify_privname {
677     my ($priv, $noerr) = @_;
678
679     if (!$valid_privs->{$priv}) {
680         die "invalid priviledge '$priv'\n" if !$noerr;
681
682         return undef;
683     }
684     
685     return $priv;
686 }
687
688 sub userconfig_force_defaults {
689     my ($cfg) = @_;
690
691     foreach my $r (keys %$special_roles) {
692         $cfg->{roles}->{$r} = $special_roles->{$r};
693     }
694
695     # fixme: remove 'root' group (not required)?
696
697     # add root user 
698     $cfg->{users}->{'root@pam'}->{enable} = 1;
699 }
700
701 sub parse_user_config {
702     my ($filename, $raw) = @_;
703
704     my $cfg = {};
705
706     userconfig_force_defaults($cfg);
707
708     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
709         my $line = $1;
710
711         next if $line =~ m/^\s*$/; # skip empty lines
712
713         my @data;
714
715         foreach my $d (split (/:/, $line)) {
716             $d =~ s/^\s+//; 
717             $d =~ s/\s+$//;
718             push @data, $d
719         }
720
721         my $et = shift @data;
722
723         if ($et eq 'user') {
724             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
725
726             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
727             if (!$realm) {
728                 warn "user config - ignore user '$user' - invalid user name\n";
729                 next;
730             }
731
732             $enable = $enable ? 1 : 0;
733
734             $expire = 0 if !$expire;
735
736             if ($expire !~ m/^\d+$/) {
737                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
738                 next;
739             }
740             $expire = int($expire);
741
742             #if (!verify_groupname ($group, 1)) {
743             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
744             #    next;
745             #}
746
747             $cfg->{users}->{$user} = {
748                 enable => $enable,
749                 # group => $group,
750             };
751             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
752             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
753             $cfg->{users}->{$user}->{email} = $email;
754             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
755             $cfg->{users}->{$user}->{expire} = $expire;
756             $cfg->{users}->{$user}->{keys} = $keys if $keys; # allowed yubico key ids
757
758             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
759             #$cfg->{groups}->{$group}->{$user} = 1;
760
761         } elsif ($et eq 'group') {
762             my ($group, $userlist, $comment) = @data;
763
764             if (!verify_groupname($group, 1)) {
765                 warn "user config - ignore group '$group' - invalid characters in group name\n";
766                 next;
767             }
768
769             # make sure to add the group (even if there are no members)
770             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
771
772             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
773
774             foreach my $user (split_list($userlist)) {
775
776                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
777                     warn "user config - ignore invalid group member '$user'\n";
778                     next;
779                 }
780
781                 if ($cfg->{users}->{$user}) { # user exists 
782                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
783                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
784                 } else {
785                     warn "user config - ignore invalid group member '$user'\n";
786                 }
787             }
788
789         } elsif ($et eq 'role') {
790             my ($role, $privlist) = @data;
791                 
792             if (!verify_rolename($role, 1)) {
793                 warn "user config - ignore role '$role' - invalid characters in role name\n";
794                 next;
795             }
796
797             # make sure to add the role (even if there are no privileges)
798             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
799
800             foreach my $priv (split_list($privlist)) {
801                 if (defined ($valid_privs->{$priv})) {
802                     $cfg->{roles}->{$role}->{$priv} = 1;
803                 } else {
804                     warn "user config - ignore invalid priviledge '$priv'\n";
805                 } 
806             }
807             
808         } elsif ($et eq 'acl') {
809             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
810
811             if (my $path = normalize_path($pathtxt)) {
812                 foreach my $role (split_list($rolelist)) {
813                         
814                     if (!verify_rolename($role, 1)) {
815                         warn "user config - ignore invalid role name '$role' in acl\n";
816                         next;
817                     }
818
819                     foreach my $ug (split_list($uglist)) {
820                         if ($ug =~ m/^@(\S+)$/) {
821                             my $group = $1;
822                             if ($cfg->{groups}->{$group}) { # group exists 
823                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
824                             } else {
825                                 warn "user config - ignore invalid acl group '$group'\n";
826                             }
827                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
828                             if ($cfg->{users}->{$ug}) { # user exists 
829                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
830                             } else {
831                                 warn "user config - ignore invalid acl member '$ug'\n";
832                             }
833                         } else {
834                             warn "user config - invalid user/group '$ug' in acl\n";
835                         }
836                     }
837                 }
838             } else {
839                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
840             }
841         } elsif ($et eq 'pool') {
842             my ($pool, $comment, $vmlist, $storelist) = @data;
843
844             if (!verify_poolname($pool, 1)) {
845                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
846                 next;
847             }
848
849             # make sure to add the pool (even if there are no members)
850             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
851
852             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
853
854             foreach my $vmid (split_list($vmlist)) {
855                 if ($vmid !~ m/^\d+$/) {
856                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
857                     next;
858                 }
859                 $vmid = int($vmid);
860
861                 if ($cfg->{vms}->{$vmid}) {
862                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
863                     next;
864                 }
865
866                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
867                     
868                 # record vmid ==> pool relation
869                 $cfg->{vms}->{$vmid} = $pool;
870             }
871
872             foreach my $storeid (split_list($storelist)) {
873                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
874                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
875                     next;
876                 }
877                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
878             }
879         } else {
880             warn "user config - ignore config line: $line\n";
881         }
882     }
883
884     userconfig_force_defaults($cfg);
885
886     return $cfg;
887 }
888
889 sub write_user_config {
890     my ($filename, $cfg) = @_;
891
892     my $data = '';
893
894     foreach my $user (keys %{$cfg->{users}}) {
895         my $d = $cfg->{users}->{$user};
896         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
897         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
898         my $email = $d->{email} || '';
899         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
900         my $expire = int($d->{expire} || 0);
901         my $enable = $d->{enable} ? 1 : 0;
902         my $keys = $d->{keys} ? $d->{keys} : '';
903         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
904     }
905
906     $data .= "\n";
907
908     foreach my $group (keys %{$cfg->{groups}}) {
909         my $d = $cfg->{groups}->{$group};
910         my $list = join (',', keys %{$d->{users}});
911         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
912         $data .= "group:$group:$list:$comment:\n";
913     }
914
915     $data .= "\n";
916
917     foreach my $pool (keys %{$cfg->{pools}}) {
918         my $d = $cfg->{pools}->{$pool};
919         my $vmlist = join (',', keys %{$d->{vms}});
920         my $storelist = join (',', keys %{$d->{storage}});
921         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';      
922         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
923     }
924
925     $data .= "\n";
926
927     foreach my $role (keys %{$cfg->{roles}}) {
928         next if $special_roles->{$role};
929
930         my $d = $cfg->{roles}->{$role};
931         my $list = join (',', keys %$d);
932         $data .= "role:$role:$list:\n";
933     }
934
935     $data .= "\n";
936
937     foreach my $path (sort keys %{$cfg->{acl}}) {
938         my $d = $cfg->{acl}->{$path};
939
940         my $ra = {};
941
942         foreach my $group (keys %{$d->{groups}}) {
943             my $l0 = '';
944             my $l1 = '';
945             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
946                 my $propagate = $d->{groups}->{$group}->{$role};
947                 if ($propagate) {
948                     $l1 .= ',' if $l1;
949                     $l1 .= $role;
950                 } else {
951                     $l0 .= ',' if $l0;
952                     $l0 .= $role;
953                 }
954             }
955             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
956             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
957         }
958
959         foreach my $user (keys %{$d->{users}}) {
960             # no need to save, because root is always 'Administartor'
961             next if $user eq 'root@pam'; 
962
963             my $l0 = '';
964             my $l1 = '';
965             foreach my $role (sort keys %{$d->{users}->{$user}}) {
966                 my $propagate = $d->{users}->{$user}->{$role};
967                 if ($propagate) {
968                     $l1 .= ',' if $l1;
969                     $l1 .= $role;
970                 } else {
971                     $l0 .= ',' if $l0;
972                     $l0 .= $role;
973                 }
974             }
975             $ra->{0}->{$l0}->{$user} = 1 if $l0;
976             $ra->{1}->{$l1}->{$user} = 1 if $l1;
977         }
978
979         foreach my $rolelist (sort keys %{$ra->{0}}) {
980             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
981             $data .= "acl:0:$path:$uglist:$rolelist:\n";
982         }
983         foreach my $rolelist (sort keys %{$ra->{1}}) {
984             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
985             $data .= "acl:1:$path:$uglist:$rolelist:\n";
986         }
987     }
988
989     return $data;
990 }
991
992 sub roles {
993     my ($cfg, $user, $path) = @_;
994
995     # NOTE: we do not consider pools here. 
996     # You need to use $rpcenv->roles() instead if you want that.
997
998     return 'Administrator' if $user eq 'root@pam'; # root can do anything
999
1000     my $perm = {};
1001
1002     foreach my $p (sort keys %{$cfg->{acl}}) {
1003         my $final = ($path eq $p);
1004
1005         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1006
1007         my $acl = $cfg->{acl}->{$p};
1008
1009         #print "CHECKACL $path $p\n";
1010         #print "ACL $path = " . Dumper ($acl);
1011
1012         if (my $ri = $acl->{users}->{$user}) {
1013             my $new;
1014             foreach my $role (keys %$ri) {
1015                 my $propagate = $ri->{$role};
1016                 if ($final || $propagate) {
1017                     #print "APPLY ROLE $p $user $role\n";
1018                     $new = {} if !$new;
1019                     $new->{$role} = 1;
1020                 }
1021             }
1022             if ($new) {
1023                 $perm = $new; # overwrite previous settings
1024                 next; # user privs always override group privs
1025             }
1026         }
1027
1028         my $new;
1029         foreach my $g (keys %{$acl->{groups}}) {
1030             next if !$cfg->{groups}->{$g}->{users}->{$user};
1031             if (my $ri = $acl->{groups}->{$g}) {
1032                 foreach my $role (keys %$ri) {
1033                     my $propagate = $ri->{$role};
1034                     if ($final || $propagate) {
1035                         #print "APPLY ROLE $p \@$g $role\n";
1036                         $new = {} if !$new;
1037                         $new->{$role} = 1;
1038                     }
1039                 }
1040             }
1041         }
1042         if ($new) {
1043             $perm = $new; # overwrite previous settings
1044             next;
1045         }
1046     }
1047
1048     return ('NoAccess') if defined ($perm->{NoAccess});
1049     #return () if defined ($perm->{NoAccess});
1050    
1051     #print "permission $user $path = " . Dumper ($perm);
1052
1053     my @ra = keys %$perm;
1054
1055     #print "roles $user $path = " . join (',', @ra) . "\n";
1056
1057     return @ra;
1058 }
1059     
1060 sub permission {
1061     my ($cfg, $user, $path) = @_;
1062
1063     $user = PVE::Auth::Plugin::verify_username($user, 1);
1064     return {} if !$user;
1065
1066     my @ra = roles($cfg, $user, $path);
1067     
1068     my $privs = {};
1069
1070     foreach my $role (@ra) {
1071         if (my $privset = $cfg->{roles}->{$role}) {
1072             foreach my $p (keys %$privset) {
1073                 $privs->{$p} = 1;
1074             }
1075         }
1076     }
1077
1078     #print "priviledges $user $path = " . Dumper ($privs);
1079
1080     return $privs;
1081 }
1082
1083 sub check_permissions {
1084     my ($username, $path, $privlist) = @_;
1085
1086     $path = normalize_path($path);
1087     my $usercfg = cfs_read_file('user.cfg');
1088     my $perm = permission($usercfg, $username, $path);
1089
1090     foreach my $priv (split_list($privlist)) {
1091         return undef if !$perm->{$priv};
1092     };
1093
1094     return 1;
1095 }
1096
1097 sub add_vm_to_pool {
1098     my ($vmid, $pool) = @_;
1099
1100     my $addVMtoPoolFn = sub {
1101         my $usercfg = cfs_read_file("user.cfg");
1102         if (my $data = $usercfg->{pools}->{$pool}) {
1103             $data->{vms}->{$vmid} = 1;
1104             $usercfg->{vms}->{$vmid} = $pool;
1105             cfs_write_file("user.cfg", $usercfg);
1106         }
1107     };
1108
1109     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1110 }
1111
1112 sub remove_vm_from_pool {
1113     my ($vmid) = @_;
1114     
1115     my $delVMfromPoolFn = sub {
1116         my $usercfg = cfs_read_file("user.cfg");
1117         if (my $pool = $usercfg->{vms}->{$vmid}) {
1118             if (my $data = $usercfg->{pools}->{$pool}) {
1119                 delete $data->{vms}->{$vmid};
1120                 delete $usercfg->{vms}->{$vmid};
1121                 cfs_write_file("user.cfg", $usercfg);
1122             }
1123         }
1124     };
1125
1126     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1127 }
1128
1129 # experimental code for yubico OTP verification
1130
1131 sub yubico_compute_param_sig {
1132     my ($param, $api_key) = @_;
1133
1134     my $paramstr = '';
1135     foreach my $key (sort keys %$param) {
1136         $paramstr .= '&' if $paramstr;
1137         $paramstr .= "$key=$param->{$key}";
1138     }
1139
1140     my $sig = uri_escape(encode_base64(Digest::HMAC_SHA1::hmac_sha1($paramstr, decode_base64($api_key || '')), ''));
1141
1142     return ($paramstr, $sig);
1143 }
1144
1145 sub yubico_verify_otp {
1146     my ($otp, $keys, $url, $api_id, $api_key, $proxy) = @_;
1147
1148     die "yubico: missing password\n" if !defined($otp);
1149     die "yubico: missing API ID\n" if !defined($api_id);
1150     die "yubico: missing API KEY\n" if !defined($api_key);
1151     die "yubico: no associated yubico keys\n" if $keys =~ m/^\s+$/; 
1152
1153     die "yubico: wrong OTP lenght\n" if (length($otp) < 32) || (length($otp) > 48);
1154
1155     # we always use http, because https cert verification always make problem, and
1156     # some proxies does not work with https.
1157
1158     $url = 'http://api2.yubico.com/wsapi/2.0/verify' if !defined($url);
1159     
1160     my $params = {
1161         nonce =>  Digest::HMAC_SHA1::hmac_sha1_hex(time(), rand()),
1162         id => $api_id,
1163         otp => uri_escape($otp),
1164         timestamp => 1,
1165     };
1166
1167     my ($paramstr, $sig) = yubico_compute_param_sig($params, $api_key);
1168
1169     $paramstr .= "&h=$sig" if $api_key;
1170
1171     my $req = HTTP::Request->new('GET' => "$url?$paramstr");
1172
1173     my $ua = LWP::UserAgent->new(protocols_allowed => ['http'], timeout => 30);
1174
1175     if ($proxy) {
1176         $ua->proxy(['http'], $proxy);
1177     } else {
1178         $ua->env_proxy;
1179     }
1180
1181     my $response = $ua->request($req);
1182     my $code = $response->code;
1183
1184     if ($code != 200) {
1185         my $msg = $response->message || 'unknown';
1186         die "Invalid response from server: $code $msg\n";
1187     }
1188
1189     my $raw = $response->decoded_content;
1190
1191     my $result = {};
1192     foreach my $kvpair (split(/\n/, $raw)) {
1193         chomp $kvpair;
1194         if($kvpair =~ /^\S+=/) {
1195             my ($k, $v) = split(/=/, $kvpair, 2);
1196             $v =~ s/\s//g;
1197             $result->{$k} = $v;
1198         }
1199     }
1200
1201     my $rsig = $result->{h};
1202     delete $result->{h};
1203
1204     if ($api_key) {
1205         my ($datastr, $vsig) = yubico_compute_param_sig($result, $api_key);
1206         $vsig = uri_unescape($vsig);
1207         die "yubico: result signature verification failed\n" if $rsig ne $vsig;
1208     }
1209
1210     die "yubico auth failed: $result->{status}\n" if $result->{status} ne 'OK';
1211
1212     my $publicid = $result->{publicid} = substr(lc($result->{otp}), 0, 12);
1213
1214     my $found;
1215     foreach my $k (PVE::Tools::split_list($keys)) {
1216         if ($k eq $publicid) {
1217             $found = 1;
1218             last;
1219         }
1220     }
1221
1222     die "yubico auth failed: key does not belong to user\n" if !$found;
1223
1224     return $result;
1225 }
1226
1227 1;