PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use Encode;
   5 use Crypt::OpenSSL::Random;
   6 use Crypt::OpenSSL::RSA;
   7 use MIME::Base64;
   8 use Digest::SHA;
   9 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  10 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  11 use PVE::JSONSchema;
  12
  13 use PVE::Auth::Plugin;
  14 use PVE::Auth::AD;
  15 use PVE::Auth::LDAP;
  16 use PVE::Auth::PVE;
  17 use PVE::Auth::PAM;
  18
  19 use Data::Dumper; # fixme: remove
  20
  21 # load and initialize all plugins
  22
  23 PVE::Auth::AD->register();
  24 PVE::Auth::LDAP->register();
  25 PVE::Auth::PVE->register();
  26 PVE::Auth::PAM->register();
  27 PVE::Auth::Plugin->init();
  28
  29 # $authdir must be writable by root only!
  30 my $confdir = "/etc/pve";
  31 my $authdir = "$confdir/priv";
  32 my $authprivkeyfn = "$authdir/authkey.key";
  33 my $authpubkeyfn = "$confdir/authkey.pub";
  34 my $pve_www_key_fn = "$confdir/pve-www.key";
  35
  36 my $ticket_lifetime = 3600*2; # 2 hours
  37
  38 Crypt::OpenSSL::RSA->import_random_seed();
  39
  40 cfs_register_file('user.cfg',
  41                   \&parse_user_config,
  42                   \&write_user_config);
  43
  44
  45 sub verify_username {
  46     PVE::Auth::Plugin::verify_username(@_);
  47 }
  48
  49 sub pve_verify_realm {
  50     PVE::Auth::Plugin::pve_verify_realm(@_);
  51 }
  52
  53 sub lock_user_config {
  54     my ($code, $errmsg) = @_;
  55
  56     cfs_lock_file("user.cfg", undef, $code);
  57     if (my $err = $@) {
  58         $errmsg ? die "$errmsg: $err" : die $err;
  59     }
  60 }
  61
  62 my $pve_auth_pub_key;
  63 sub get_pubkey {
  64
  65     return $pve_auth_pub_key if $pve_auth_pub_key;
  66
  67     my $input = PVE::Tools::file_get_contents($authpubkeyfn);
  68
  69     $pve_auth_pub_key = Crypt::OpenSSL::RSA->new_public_key($input);
  70
  71     return $pve_auth_pub_key;
  72 }
  73
  74 my $csrf_prevention_secret;
  75 my $get_csrfr_secret = sub {
  76     if (!$csrf_prevention_secret) {
  77         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
  78         $csrf_prevention_secret = Digest::SHA::sha1_base64($input);
  79     }
  80     return $csrf_prevention_secret;
  81 };
  82
  83 sub assemble_csrf_prevention_token {
  84     my ($username) = @_;
  85
  86     my $timestamp = sprintf("%08X", time());
  87
  88     my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
  89
  90     return "$timestamp:$digest";
  91 }
  92
  93 sub verify_csrf_prevention_token {
  94     my ($username, $token, $noerr) = @_;
  95
  96     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
  97         my $sig = $2;
  98         my $timestamp = $1;
  99         my $ttime = hex($timestamp);
 100
 101         my $digest = Digest::SHA::sha1_base64("$timestamp:$username", &$get_csrfr_secret());
 102
 103         my $age = time() - $ttime;
 104         return if ($digest eq $sig) && ($age > -300) && ($age < $ticket_lifetime);
 105     }
 106
 107     die "Permission denied - invalid csrf token\n" if !$noerr;
 108
 109     return undef;
 110 }
 111
 112 my $pve_auth_priv_key;
 113 sub get_privkey {
 114
 115     return $pve_auth_priv_key if $pve_auth_priv_key;
 116
 117     my $input = PVE::Tools::file_get_contents($authprivkeyfn);
 118
 119     $pve_auth_priv_key = Crypt::OpenSSL::RSA->new_private_key($input);
 120
 121     return $pve_auth_priv_key;
 122 }
 123
 124 sub assemble_ticket {
 125     my ($username) = @_;
 126
 127     my $rsa_priv = get_privkey();
 128
 129     my $timestamp = sprintf("%08X", time());
 130
 131     my $plain = "PVE:$username:$timestamp";
 132
 133     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($plain), '');
 134
 135     return $ticket;
 136 }
 137
 138 sub verify_ticket {
 139     my ($ticket, $noerr) = @_;
 140
 141     if ($ticket && $ticket =~ m/^(PVE:\S+)::([^:\s]+)$/) {
 142         my $plain = $1;
 143         my $sig = $2;
 144
 145         my $rsa_pub = get_pubkey();
 146         if ($rsa_pub->verify($plain, decode_base64($sig))) {
 147             if ($plain =~ m/^PVE:(\S+):([A-Z0-9]{8})$/) {
 148                 my $username = $1;
 149                 my $timestamp = $2;
 150                 my $ttime = hex($timestamp);
 151
 152                 my $age = time() - $ttime;
 153
 154                 if (PVE::Auth::Plugin::verify_username($username, 1) &&
 155                     ($age > -300) && ($age < $ticket_lifetime)) {
 156                     return wantarray ? ($username, $age) : $username;
 157                 }
 158             }
 159         }
 160     }
 161
 162     die "permission denied - invalid ticket\n" if !$noerr;
 163
 164     return undef;
 165 }
 166
 167 # VNC tickets
 168 # - they do not contain the username in plain text
 169 # - they are restricted to a specific resource path (example: '/vms/100')
 170 sub assemble_vnc_ticket {
 171     my ($username, $path) = @_;
 172
 173     my $rsa_priv = get_privkey();
 174
 175     my $timestamp = sprintf("%08X", time());
 176
 177     my $plain = "PVEVNC:$timestamp";
 178
 179     $path = normalize_path($path);
 180
 181     my $full = "$plain:$username:$path";
 182
 183     my $ticket = $plain . "::" . encode_base64($rsa_priv->sign($full), '');
 184
 185     return $ticket;
 186 }
 187
 188 sub verify_vnc_ticket {
 189     my ($ticket, $username, $path, $noerr) = @_;
 190
 191     if ($ticket && $ticket =~ m/^(PVEVNC:\S+)::([^:\s]+)$/) {
 192         my $plain = $1;
 193         my $sig = $2;
 194         my $full = "$plain:$username:$path";
 195
 196         my $rsa_pub = get_pubkey();
 197         # Note: sign only match if $username and  $path is correct
 198         if ($rsa_pub->verify($full, decode_base64($sig))) {
 199             if ($plain =~ m/^PVEVNC:([A-Z0-9]{8})$/) {
 200                 my $ttime = hex($1);
 201
 202                 my $age = time() - $ttime;
 203
 204                 if (($age > -20) && ($age < 40)) {
 205                     return 1;
 206                 }
 207             }
 208         }
 209     }
 210
 211     die "permission denied - invalid vnc ticket\n" if !$noerr;
 212
 213     return undef;
 214 }
 215
 216 sub check_user_exist {
 217     my ($usercfg, $username, $noerr) = @_;
 218
 219     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 220     return undef if !$username;
 221
 222     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 223
 224     die "no such user ('$username')\n" if !$noerr;
 225
 226     return undef;
 227 }
 228
 229 sub check_user_enabled {
 230     my ($usercfg, $username, $noerr) = @_;
 231
 232     my $data = check_user_exist($usercfg, $username, $noerr);
 233     return undef if !$data;
 234
 235     return 1 if $data->{enable};
 236
 237     return 1 if $username eq 'root@pam'; # root is always enabled
 238
 239     die "user '$username' is disabled\n" if !$noerr;
 240
 241     return undef;
 242 }
 243
 244 # password should be utf8 encoded
 245 sub authenticate_user {
 246     my ($username, $password) = @_;
 247
 248     die "no username specified\n" if !$username;
 249
 250     my ($ruid, $realm);
 251
 252     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 253
 254     my $usercfg = cfs_read_file('user.cfg');
 255
 256     eval { check_user_enabled($usercfg, $username); };
 257     if (my $err = $@) {
 258         sleep(2);
 259         die $err;
 260     }
 261
 262     my $ctime = time();
 263     my $expire = $usercfg->{users}->{$username}->{expire};
 264
 265     if ($expire && ($expire < $ctime)) {
 266         sleep(2);
 267         die "account expired\n"
 268     }
 269
 270     my $domain_cfg = cfs_read_file('domains.cfg');
 271
 272     eval {
 273         my $cfg = $domain_cfg->{ids}->{$realm};
 274         die "auth domain '$realm' does not exists\n" if !$cfg;
 275         my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 276         $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 277     };
 278     if (my $err = $@) {
 279         sleep(2); # timeout after failed auth
 280         die $err;
 281     }
 282
 283     return $username;
 284 }
 285
 286 sub domain_set_password {
 287     my ($realm, $username, $password) = @_;
 288
 289     die "no auth domain specified" if !$realm;
 290
 291     my $domain_cfg = cfs_read_file('domains.cfg');
 292
 293     my $cfg = $domain_cfg->{ids}->{$realm};
 294     die "auth domain '$realm' does not exists\n" if !$cfg;
 295     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 296     $plugin->store_password($cfg, $realm, $username, $password);
 297 }
 298
 299 sub add_user_group {
 300
 301     my ($username, $usercfg, $group) = @_;
 302     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 303     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 304 }
 305
 306 sub delete_user_group {
 307
 308     my ($username, $usercfg) = @_;
 309
 310     foreach my $group (keys %{$usercfg->{groups}}) {
 311
 312         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 313             if $usercfg->{groups}->{$group}->{users}->{$username};
 314     }
 315 }
 316
 317 sub delete_user_acl {
 318
 319     my ($username, $usercfg) = @_;
 320
 321     foreach my $acl (keys %{$usercfg->{acl}}) {
 322
 323         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 324             if $usercfg->{acl}->{$acl}->{users}->{$username};
 325     }
 326 }
 327
 328 sub delete_group_acl {
 329
 330     my ($group, $usercfg) = @_;
 331
 332     foreach my $acl (keys %{$usercfg->{acl}}) {
 333
 334         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 335             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 336     }
 337 }
 338
 339 sub delete_pool_acl {
 340
 341     my ($pool, $usercfg) = @_;
 342
 343     my $path = "/pool/$pool";
 344
 345     foreach my $aclpath (keys %{$usercfg->{acl}}) {
 346         delete ($usercfg->{acl}->{$aclpath})
 347             if $usercfg->{acl}->{$aclpath} eq 'path';
 348     }
 349 }
 350
 351 # we automatically create some predefined roles by splitting privs
 352 # into 3 groups (per category)
 353 # root: only root is allowed to do that
 354 # admin: an administrator can to that
 355 # user: a normak user/customer can to that
 356 my $privgroups = {
 357     VM => {
 358         root => [],
 359         admin => [
 360             'VM.Config.Disk',
 361             'VM.Config.CPU',
 362             'VM.Config.Memory',
 363             'VM.Config.Network',
 364             'VM.Config.HWType',
 365             'VM.Config.Options', # covers all other things
 366             'VM.Allocate',
 367             'VM.Migrate',
 368             'VM.Monitor',
 369             'VM.Snapshot',
 370         ],
 371         user => [
 372             'VM.Config.CDROM', # change CDROM media
 373             'VM.Console',
 374             'VM.Backup',
 375             'VM.PowerMgmt',
 376         ],
 377         audit => [
 378             'VM.Audit',
 379         ],
 380     },
 381     Sys => {
 382         root => [
 383             'Sys.PowerMgmt',
 384             'Sys.Modify', # edit/change node settings
 385         ],
 386         admin => [
 387             'Permissions.Modify',
 388             'Sys.Console',
 389             'Sys.Syslog',
 390         ],
 391         user => [],
 392         audit => [
 393             'Sys.Audit',
 394         ],
 395     },
 396     Datastore => {
 397         root => [],
 398         admin => [
 399             'Datastore.Allocate',
 400             'Datastore.AllocateTemplate',
 401         ],
 402         user => [
 403             'Datastore.AllocateSpace',
 404         ],
 405         audit => [
 406             'Datastore.Audit',
 407         ],
 408     },
 409     User => {
 410         root => [
 411             'Realm.Allocate',
 412         ],
 413         admin => [
 414             'User.Modify',
 415             'Group.Allocate', # edit/change group settings
 416             'Realm.AllocateUser',
 417         ],
 418         user => [],
 419         audit => [],
 420     },
 421     Pool => {
 422         root => [],
 423         admin => [
 424             'Pool.Allocate', # create/delete pools
 425         ],
 426         user => [],
 427         audit => [],
 428     },
 429 };
 430
 431 my $valid_privs = {};
 432
 433 my $special_roles = {
 434     'NoAccess' => {}, # no priviledges
 435     'Administrator' => $valid_privs, # all priviledges
 436 };
 437
 438 sub create_roles {
 439
 440     foreach my $cat (keys %$privgroups) {
 441         my $cd = $privgroups->{$cat};
 442         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
 443                        @{$cd->{user}}, @{$cd->{audit}}) {
 444             $valid_privs->{$p} = 1;
 445         }
 446         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
 447
 448             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
 449             $special_roles->{"PVEAdmin"}->{$p} = 1;
 450         }
 451         if (scalar(@{$cd->{user}})) {
 452             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
 453                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
 454             }
 455         }
 456         foreach my $p (@{$cd->{audit}}) {
 457             $special_roles->{"PVEAuditor"}->{$p} = 1;
 458         }
 459     }
 460 };
 461
 462 create_roles();
 463
 464 sub add_role_privs {
 465     my ($role, $usercfg, $privs) = @_;
 466
 467     return if !$privs;
 468
 469     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
 470
 471     foreach my $priv (split_list($privs)) {
 472         if (defined ($valid_privs->{$priv})) {
 473             $usercfg->{roles}->{$role}->{$priv} = 1;
 474         } else {
 475             die "invalid priviledge '$priv'\n";
 476         }
 477     }
 478 }
 479
 480 sub normalize_path {
 481     my $path = shift;
 482
 483     $path =~ s|/+|/|g;
 484
 485     $path =~ s|/$||;
 486
 487     $path = '/' if !$path;
 488
 489     $path = "/$path" if $path !~ m|^/|;
 490
 491     return undef if $path !~ m|^[[:alnum:]\-\_\/]+$|;
 492
 493     return $path;
 494 }
 495
 496
 497 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
 498 sub verify_groupname {
 499     my ($groupname, $noerr) = @_;
 500
 501     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 502
 503         die "group name '$groupname' contains invalid characters\n" if !$noerr;
 504
 505         return undef;
 506     }
 507
 508     return $groupname;
 509 }
 510
 511 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
 512 sub verify_rolename {
 513     my ($rolename, $noerr) = @_;
 514
 515     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
 516
 517         die "role name '$rolename' contains invalid characters\n" if !$noerr;
 518
 519         return undef;
 520     }
 521
 522     return $rolename;
 523 }
 524
 525 PVE::JSONSchema::register_format('pve-poolid', \&verify_groupname);
 526 sub verify_poolname {
 527     my ($poolname, $noerr) = @_;
 528
 529     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
 530
 531         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
 532
 533         return undef;
 534     }
 535
 536     return $poolname;
 537 }
 538
 539 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
 540 sub verify_privname {
 541     my ($priv, $noerr) = @_;
 542
 543     if (!$valid_privs->{$priv}) {
 544         die "invalid priviledge '$priv'\n" if !$noerr;
 545
 546         return undef;
 547     }
 548
 549     return $priv;
 550 }
 551
 552 sub userconfig_force_defaults {
 553     my ($cfg) = @_;
 554
 555     foreach my $r (keys %$special_roles) {
 556         $cfg->{roles}->{$r} = $special_roles->{$r};
 557     }
 558
 559     # fixme: remove 'root' group (not required)?
 560
 561     # add root user
 562     $cfg->{users}->{'root@pam'}->{enable} = 1;
 563 }
 564
 565 sub parse_user_config {
 566     my ($filename, $raw) = @_;
 567
 568     my $cfg = {};
 569
 570     userconfig_force_defaults($cfg);
 571
 572     while ($raw && $raw =~ s/^(.*?)(\n|$)//) {
 573         my $line = $1;
 574
 575         next if $line =~ m/^\s*$/; # skip empty lines
 576
 577         my @data;
 578
 579         foreach my $d (split (/:/, $line)) {
 580             $d =~ s/^\s+//;
 581             $d =~ s/\s+$//;
 582             push @data, $d
 583         }
 584
 585         my $et = shift @data;
 586
 587         if ($et eq 'user') {
 588             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment) = @data;
 589
 590             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
 591             if (!$realm) {
 592                 warn "user config - ignore user '$user' - invalid user name\n";
 593                 next;
 594             }
 595
 596             $enable = $enable ? 1 : 0;
 597
 598             $expire = 0 if !$expire;
 599
 600             if ($expire !~ m/^\d+$/) {
 601                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
 602                 next;
 603             }
 604             $expire = int($expire);
 605
 606             #if (!verify_groupname ($group, 1)) {
 607             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
 608             #    next;
 609             #}
 610
 611             $cfg->{users}->{$user} = {
 612                 enable => $enable,
 613                 # group => $group,
 614             };
 615             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
 616             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
 617             $cfg->{users}->{$user}->{email} = $email;
 618             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 619             $cfg->{users}->{$user}->{expire} = $expire;
 620
 621             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
 622             #$cfg->{groups}->{$group}->{$user} = 1;
 623
 624         } elsif ($et eq 'group') {
 625             my ($group, $userlist, $comment) = @data;
 626
 627             if (!verify_groupname($group, 1)) {
 628                 warn "user config - ignore group '$group' - invalid characters in group name\n";
 629                 next;
 630             }
 631
 632             # make sure to add the group (even if there are no members)
 633             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
 634
 635             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 636
 637             foreach my $user (split_list($userlist)) {
 638
 639                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
 640                     warn "user config - ignore invalid group member '$user'\n";
 641                     next;
 642                 }
 643
 644                 if ($cfg->{users}->{$user}) { # user exists
 645                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
 646                     $cfg->{groups}->{$group}->{users}->{$user} = 1;
 647                 } else {
 648                     warn "user config - ignore invalid group member '$user'\n";
 649                 }
 650             }
 651
 652         } elsif ($et eq 'role') {
 653             my ($role, $privlist) = @data;
 654
 655             if (!verify_rolename($role, 1)) {
 656                 warn "user config - ignore role '$role' - invalid characters in role name\n";
 657                 next;
 658             }
 659
 660             # make sure to add the role (even if there are no privileges)
 661             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
 662
 663             foreach my $priv (split_list($privlist)) {
 664                 if (defined ($valid_privs->{$priv})) {
 665                     $cfg->{roles}->{$role}->{$priv} = 1;
 666                 } else {
 667                     warn "user config - ignore invalid priviledge '$priv'\n";
 668                 }
 669             }
 670
 671         } elsif ($et eq 'acl') {
 672             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
 673
 674             if (my $path = normalize_path($pathtxt)) {
 675                 foreach my $role (split_list($rolelist)) {
 676
 677                     if (!verify_rolename($role, 1)) {
 678                         warn "user config - ignore invalid role name '$role' in acl\n";
 679                         next;
 680                     }
 681
 682                     foreach my $ug (split_list($uglist)) {
 683                         if ($ug =~ m/^@(\S+)$/) {
 684                             my $group = $1;
 685                             if ($cfg->{groups}->{$group}) { # group exists
 686                                 $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
 687                             } else {
 688                                 warn "user config - ignore invalid acl group '$group'\n";
 689                             }
 690                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
 691                             if ($cfg->{users}->{$ug}) { # user exists
 692                                 $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
 693                             } else {
 694                                 warn "user config - ignore invalid acl member '$ug'\n";
 695                             }
 696                         } else {
 697                             warn "user config - invalid user/group '$ug' in acl\n";
 698                         }
 699                     }
 700                 }
 701             } else {
 702                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
 703             }
 704         } elsif ($et eq 'pool') {
 705             my ($pool, $comment, $vmlist, $storelist) = @data;
 706
 707             if (!verify_poolname($pool, 1)) {
 708                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
 709                 next;
 710             }
 711
 712             # make sure to add the pool (even if there are no members)
 713             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
 714
 715             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
 716
 717             foreach my $vmid (split_list($vmlist)) {
 718                 if ($vmid !~ m/^\d+$/) {
 719                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
 720                     next;
 721                 }
 722                 $vmid = int($vmid);
 723
 724                 if ($cfg->{vms}->{$vmid}) {
 725                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
 726                     next;
 727                 }
 728
 729                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
 730
 731                 # record vmid ==> pool relation
 732                 $cfg->{vms}->{$vmid} = $pool;
 733             }
 734
 735             foreach my $storeid (split_list($storelist)) {
 736                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
 737                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
 738                     next;
 739                 }
 740                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
 741             }
 742         } else {
 743             warn "user config - ignore config line: $line\n";
 744         }
 745     }
 746
 747     userconfig_force_defaults($cfg);
 748
 749     return $cfg;
 750 }
 751
 752 sub write_user_config {
 753     my ($filename, $cfg) = @_;
 754
 755     my $data = '';
 756
 757     foreach my $user (keys %{$cfg->{users}}) {
 758         my $d = $cfg->{users}->{$user};
 759         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
 760         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
 761         my $email = $d->{email} || '';
 762         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 763         my $expire = int($d->{expire} || 0);
 764         my $enable = $d->{enable} ? 1 : 0;
 765         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:\n";
 766     }
 767
 768     $data .= "\n";
 769
 770     foreach my $group (keys %{$cfg->{groups}}) {
 771         my $d = $cfg->{groups}->{$group};
 772         my $list = join (',', keys %{$d->{users}});
 773         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 774         $data .= "group:$group:$list:$comment:\n";
 775     }
 776
 777     $data .= "\n";
 778
 779     foreach my $pool (keys %{$cfg->{pools}}) {
 780         my $d = $cfg->{pools}->{$pool};
 781         my $vmlist = join (',', keys %{$d->{vms}});
 782         my $storelist = join (',', keys %{$d->{storage}});
 783         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
 784         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
 785     }
 786
 787     $data .= "\n";
 788
 789     foreach my $role (keys %{$cfg->{roles}}) {
 790         next if $special_roles->{$role};
 791
 792         my $d = $cfg->{roles}->{$role};
 793         my $list = join (',', keys %$d);
 794         $data .= "role:$role:$list:\n";
 795     }
 796
 797     $data .= "\n";
 798
 799     foreach my $path (sort keys %{$cfg->{acl}}) {
 800         my $d = $cfg->{acl}->{$path};
 801
 802         my $ra = {};
 803
 804         foreach my $group (keys %{$d->{groups}}) {
 805             my $l0 = '';
 806             my $l1 = '';
 807             foreach my $role (sort keys %{$d->{groups}->{$group}}) {
 808                 my $propagate = $d->{groups}->{$group}->{$role};
 809                 if ($propagate) {
 810                     $l1 .= ',' if $l1;
 811                     $l1 .= $role;
 812                 } else {
 813                     $l0 .= ',' if $l0;
 814                     $l0 .= $role;
 815                 }
 816             }
 817             $ra->{0}->{$l0}->{"\@$group"} = 1 if $l0;
 818             $ra->{1}->{$l1}->{"\@$group"} = 1 if $l1;
 819         }
 820
 821         foreach my $user (keys %{$d->{users}}) {
 822             # no need to save, because root is always 'Administartor'
 823             next if $user eq 'root@pam';
 824
 825             my $l0 = '';
 826             my $l1 = '';
 827             foreach my $role (sort keys %{$d->{users}->{$user}}) {
 828                 my $propagate = $d->{users}->{$user}->{$role};
 829                 if ($propagate) {
 830                     $l1 .= ',' if $l1;
 831                     $l1 .= $role;
 832                 } else {
 833                     $l0 .= ',' if $l0;
 834                     $l0 .= $role;
 835                 }
 836             }
 837             $ra->{0}->{$l0}->{$user} = 1 if $l0;
 838             $ra->{1}->{$l1}->{$user} = 1 if $l1;
 839         }
 840
 841         foreach my $rolelist (sort keys %{$ra->{0}}) {
 842             my $uglist = join (',', keys %{$ra->{0}->{$rolelist}});
 843             $data .= "acl:0:$path:$uglist:$rolelist:\n";
 844         }
 845         foreach my $rolelist (sort keys %{$ra->{1}}) {
 846             my $uglist = join (',', keys %{$ra->{1}->{$rolelist}});
 847             $data .= "acl:1:$path:$uglist:$rolelist:\n";
 848         }
 849     }
 850
 851     return $data;
 852 }
 853
 854 sub roles {
 855     my ($cfg, $user, $path) = @_;
 856
 857     # NOTE: we do not consider pools here.
 858     # You need to use $rpcenv->roles() instead if you want that.
 859
 860     return 'Administrator' if $user eq 'root@pam'; # root can do anything
 861
 862     my $perm = {};
 863
 864     foreach my $p (sort keys %{$cfg->{acl}}) {
 865         my $final = ($path eq $p);
 866
 867         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
 868
 869         my $acl = $cfg->{acl}->{$p};
 870
 871         #print "CHECKACL $path $p\n";
 872         #print "ACL $path = " . Dumper ($acl);
 873
 874         if (my $ri = $acl->{users}->{$user}) {
 875             my $new;
 876             foreach my $role (keys %$ri) {
 877                 my $propagate = $ri->{$role};
 878                 if ($final || $propagate) {
 879                     #print "APPLY ROLE $p $user $role\n";
 880                     $new = {} if !$new;
 881                     $new->{$role} = 1;
 882                 }
 883             }
 884             if ($new) {
 885                 $perm = $new; # overwrite previous settings
 886                 next; # user privs always override group privs
 887             }
 888         }
 889
 890         my $new;
 891         foreach my $g (keys %{$acl->{groups}}) {
 892             next if !$cfg->{groups}->{$g}->{users}->{$user};
 893             if (my $ri = $acl->{groups}->{$g}) {
 894                 foreach my $role (keys %$ri) {
 895                     my $propagate = $ri->{$role};
 896                     if ($final || $propagate) {
 897                         #print "APPLY ROLE $p \@$g $role\n";
 898                         $new = {} if !$new;
 899                         $new->{$role} = 1;
 900                     }
 901                 }
 902             }
 903         }
 904         if ($new) {
 905             $perm = $new; # overwrite previous settings
 906             next;
 907         }
 908     }
 909
 910     return ('NoAccess') if defined ($perm->{NoAccess});
 911     #return () if defined ($perm->{NoAccess});
 912
 913     #print "permission $user $path = " . Dumper ($perm);
 914
 915     my @ra = keys %$perm;
 916
 917     #print "roles $user $path = " . join (',', @ra) . "\n";
 918
 919     return @ra;
 920 }
 921
 922 sub permission {
 923     my ($cfg, $user, $path) = @_;
 924
 925     $user = PVE::Auth::Plugin::verify_username($user, 1);
 926     return {} if !$user;
 927
 928     my @ra = roles($cfg, $user, $path);
 929
 930     my $privs = {};
 931
 932     foreach my $role (@ra) {
 933         if (my $privset = $cfg->{roles}->{$role}) {
 934             foreach my $p (keys %$privset) {
 935                 $privs->{$p} = 1;
 936             }
 937         }
 938     }
 939
 940     #print "priviledges $user $path = " . Dumper ($privs);
 941
 942     return $privs;
 943 }
 944
 945 sub check_permissions {
 946     my ($username, $path, $privlist) = @_;
 947
 948     $path = normalize_path($path);
 949     my $usercfg = cfs_read_file('user.cfg');
 950     my $perm = permission($usercfg, $username, $path);
 951
 952     foreach my $priv (split_list($privlist)) {
 953         return undef if !$perm->{$priv};
 954     };
 955
 956     return 1;
 957 }
 958
 959 1;