implement helper to check if we can modify permission
[pve-access-control.git] / PVE / RPCEnvironment.pm
1 package PVE::RPCEnvironment;
2
3 use strict;
4 use warnings;
5 use POSIX qw(:sys_wait_h EINTR);
6 use IO::Handle;
7 use IO::File;
8 use IO::Select;
9 use Fcntl qw(:flock);
10 use PVE::Exception qw(raise raise_perm_exc);
11 use PVE::SafeSyslog;
12 use PVE::Tools;
13 use PVE::INotify;
14 use PVE::Cluster;
15 use PVE::ProcFSTools;
16 use PVE::AccessControl;
17 use CGI;
18
19 # we use this singleton class to pass RPC related environment values
20
21 my $pve_env;
22
23 # save $SIG{CHLD} handler implementation.
24 # simply set $SIG{CHLD} = $worker_reaper;
25 # and register forked processes with &$register_worker(pid)
26 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
27 # has serious side effects, because perls built in system() and open()
28 # functions can't get the correct exit status of a child. So we cant use 
29 # that (also see perlipc)
30
31 my $WORKER_PIDS;
32
33 my $log_task_result = sub {
34     my ($upid, $user, $status) = @_;
35
36     my $msg = 'successful';
37     my $pri = 'info';
38     if ($status != 0) {
39         my $ec = $status >> 8;
40         my $ic = $status & 255;
41         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
42         $pri = 'err';
43     }
44     my $tlist = active_workers($upid);
45     PVE::Cluster::broadcast_tasklist($tlist);
46     my $task;
47     foreach my $t (@$tlist) {
48         if ($t->{upid} eq $upid) {
49             $task = $t;
50             last;
51         }
52     }
53     if ($task && $task->{status}) {
54         $msg = $task->{status};
55     }
56     PVE::Cluster::log_msg($pri, $user, "end task $upid $msg");
57 };
58
59 my $worker_reaper = sub {
60     local $!; local $?;
61     foreach my $pid (keys %$WORKER_PIDS) {
62         my $waitpid = waitpid ($pid, WNOHANG);
63         if (defined($waitpid) && ($waitpid == $pid)) {
64             my $info = $WORKER_PIDS->{$pid};
65             if ($info && $info->{upid} && $info->{user}) {
66                 &$log_task_result($info->{upid}, $info->{user}, $?);
67             }
68             delete ($WORKER_PIDS->{$pid});
69         }
70     }
71 };
72
73 my $register_worker = sub {
74     my ($pid, $user, $upid) = @_;
75
76     return if !$pid;
77
78     # do not register if already finished
79     my $waitpid = waitpid ($pid, WNOHANG);
80     if (defined($waitpid) && ($waitpid == $pid)) {
81         delete ($WORKER_PIDS->{$pid});
82         return;
83     }
84
85     $WORKER_PIDS->{$pid} = {
86         user => $user,
87         upid => $upid,
88     };
89 };
90
91 # ACL cache
92
93 my $compile_acl_path = sub {
94     my ($self, $user, $path) = @_;
95
96     my $cfg = $self->{user_cfg};
97
98     return undef if !$cfg->{roles};
99
100     die "internal error" if $user eq 'root@pam';
101
102     my $cache = $self->{aclcache};
103     $cache->{$user} = {} if !$cache->{$user};
104     my $data = $cache->{$user};
105
106     if (!$data->{poolroles}) {
107         $data->{poolroles} = {}; 
108  
109         foreach my $poolpath (keys %{$cfg->{pools}}) {
110             my $d = $cfg->{pools}->{$poolpath};
111             my @ra = PVE::AccessControl::roles($cfg, $user, "/pool$poolpath"); # pool roles
112             next if !scalar(@ra);
113             foreach my $vmid (keys %{$d->{vms}}) {
114                 for my $role (@ra) {
115                     $data->{poolroles}->{"/vms/$vmid"}->{$role} = 1;
116                 }
117             }
118             foreach my $storeid (keys %{$d->{storage}}) {
119                 for my $role (@ra) {
120                     $data->{poolroles}->{"/storage/$storeid"}->{$role} = 1;
121                 }
122             }
123         }
124     }
125
126     my @ra = PVE::AccessControl::roles($cfg, $user, $path);
127
128     # apply roles inherited from pools
129     # Note: assume we do not want to propagate those privs
130     if ($data->{poolroles}->{$path}) {
131         if (!($ra[0] && $ra[0] eq 'NoAccess')) {
132             if ($data->{poolroles}->{$path}->{NoAccess}) {
133                 @ra = ('NoAccess');
134             } else {
135                 foreach my $role (keys %{$data->{poolroles}->{$path}}) {
136                     push @ra, $role;
137                 }
138             }
139         }
140     }
141
142     $data->{roles}->{$path} = [ @ra ];
143  
144     my $privs = {};
145     foreach my $role (@ra) {
146         if (my $privset = $cfg->{roles}->{$role}) {
147             foreach my $p (keys %$privset) {
148                 $privs->{$p} = 1;
149             }
150         }
151     }
152     $data->{privs}->{$path} = $privs;
153
154     return $privs;
155 };
156
157 sub roles {
158    my ($self, $user, $path) = @_;
159
160    if ($user eq 'root@pam') { # root can do anything
161        return ('Administrator');
162    } 
163
164    $user = PVE::AccessControl::verify_username($user, 1);
165    return () if !$user;
166
167    my $cache = $self->{aclcache};
168    $cache->{$user} = {} if !$cache->{$user};
169
170    my $acl = $cache->{$user};
171
172    my $roles = $acl->{roles}->{$path};
173    return @$roles if $roles;
174
175    &$compile_acl_path($self, $user, $path);
176    $roles = $acl->{roles}->{$path} || [];
177    return @$roles;
178 }
179
180 sub permissions {
181     my ($self, $user, $path) = @_;
182
183     if ($user eq 'root@pam') { # root can do anything
184         my $cfg = $self->{user_cfg};
185         return $cfg->{roles}->{'Administrator'};
186     } 
187
188     $user = PVE::AccessControl::verify_username($user, 1);
189     return {} if !$user;
190
191     my $cache = $self->{aclcache};
192     $cache->{$user} = {} if !$cache->{$user};
193
194     my $acl = $cache->{$user};
195
196     my $perm = $acl->{privs}->{$path};
197     return $perm if $perm;
198
199     return &$compile_acl_path($self, $user, $path);
200 }
201
202 sub check {
203     my ($self, $user, $path, $privs, $noerr) = @_;
204
205     my $perm = $self->permissions($user, $path);
206
207     foreach my $priv (@$privs) {
208         PVE::AccessControl::verify_privname($priv);
209         if (!$perm->{$priv}) {
210             return undef if $noerr;
211             raise_perm_exc("$path, $priv"); 
212         }
213     };
214
215     return 1;
216 };
217
218 sub check_any {
219     my ($self, $user, $path, $privs, $noerr) = @_;
220
221     my $perm = $self->permissions($user, $path);
222
223     my $found = 0;
224     foreach my $priv (@$privs) {
225         PVE::AccessControl::verify_privname($priv);
226         if ($perm->{$priv}) {
227             $found = 1;
228             last;
229         }
230     };
231
232     return 1 if $found;
233
234     return undef if $noerr;
235
236     raise_perm_exc("$path, " . join("|", @$privs)); 
237 };
238
239 sub check_user_enabled {
240     my ($self, $user, $noerr) = @_;
241     
242     my $cfg = $self->{user_cfg};
243     return PVE::AccessControl::check_user_enabled($cfg, $user, $noerr);
244 }
245
246 sub check_user_exist {
247     my ($self, $user, $noerr) = @_;
248     
249     my $cfg = $self->{user_cfg};
250     return PVE::AccessControl::check_user_exist($cfg, $user, $noerr);
251 }
252
253 sub is_group_member {
254     my ($self, $group, $user) = @_;
255
256     my $cfg = $self->{user_cfg};
257
258     return 0 if !$cfg->{groups}->{$group};
259
260     return defined($cfg->{groups}->{$group}->{users}->{$user});
261 }
262
263 sub filter_groups {
264     my ($self, $user, $privs, $any) = @_;
265
266     my $cfg = $self->{user_cfg};
267
268     my $groups = {};
269     foreach my $group (keys %{$cfg->{groups}}) {
270         my $path = "/access/groups/$group";
271         if ($any) {
272             if ($self->check_any($user, $path, $privs, 1)) {
273                 $groups->{$group} = $cfg->{groups}->{$group};
274             }
275         } else {
276             if ($self->check($user, $path, $privs, 1)) {
277                 $groups->{$group} = $cfg->{groups}->{$group};
278             }
279         }
280     }
281
282     return $groups;
283 }
284
285 sub group_member_join {
286     my ($self, $grouplist) = @_;
287
288     my $users = {};
289
290     my $cfg = $self->{user_cfg};
291     foreach my $group (@$grouplist) {
292         my $data = $cfg->{groups}->{$group};
293         next if !$data;
294         foreach my $user (keys %{$data->{users}}) {
295             $users->{$user} = 1;
296         }
297     }
298
299     return $users;
300 }
301
302 sub check_perm_modify {
303     my ($self, $username, $path, $noerr) = @_;
304
305     return $self->check($username, '/access', [ 'Permissions.Modify' ], $noerr) if !$path;
306
307     my $testperms = [ 'Permissions.Modify' ];
308     if ($path =~ m|^/storage/.+$|) {
309         push @$testperms, 'Datastore.Allocate';
310     } elsif ($path =~ m|^/vms/.+$|) {
311         push @$testperms, 'VM.Allocate';
312     }
313
314     return $self->check_any($username, $path, $testperms, $noerr);
315 }
316
317 sub exec_api2_perm_check {
318     my ($self, $check, $username, $param, $noerr) = @_;
319
320     # syslog("info", "CHECK " . join(', ', @$check));
321
322     my $ind = 0;
323     my $test = $check->[$ind++];
324     die "no permission test specified" if !$test;
325  
326     if ($test eq 'and') {
327         while (my $subcheck = $check->[$ind++]) {
328             $self->exec_api2_perm_check($subcheck, $username, $param); 
329         }
330         return 1;
331     } elsif ($test eq 'or') {
332         while (my $subcheck = $check->[$ind++]) {
333             return 1 if $self->exec_api2_perm_check($subcheck, $username, $param, 1); 
334         }
335         return 0 if $noerr;
336         raise_perm_exc();
337     } elsif ($test eq 'perm') {
338         my ($t, $tmplpath, $privs, %options) = @$check;
339         my $any = $options{any};
340         die "missing parameters" if !($tmplpath && $privs);
341         my $path = PVE::Tools::template_replace($tmplpath, $param);
342         $path = PVE::AccessControl::normalize_path($path);
343         if ($any) {
344             return $self->check_any($username, $path, $privs, $noerr);
345         } else {
346             return $self->check($username, $path, $privs, $noerr);
347         }
348     } elsif ($test eq 'userid-group') {
349         my $userid = $param->{userid};
350         my ($t, $privs, %options) = @$check;
351         return if !$options{groups_param} && !$self->check_user_exist($userid, $noerr);
352         if (!$self->check_any($username, "/access", $privs, 1)) {
353             my $groups = $self->filter_groups($username, $privs, 1);
354             if ($options{groups_param}) {
355                 my @group_param = PVE::Tools::split_list($param->{groups});
356                 raise_perm_exc("/access, " . join("|", @$privs)) if !scalar(@group_param);
357                 foreach my $pg (@group_param) {
358                     raise_perm_exc("/access/groups/$pg, " . join("|", @$privs))
359                         if !$groups->{$pg};
360                 }
361             } else {
362                 my $allowed_users = $self->group_member_join([keys %$groups]);
363                 if (!$allowed_users->{$userid}) {
364                     return 0 if $noerr;
365                     raise_perm_exc();
366                 }
367             }
368         }
369         return 1;
370     } elsif ($test eq 'userid-param') {
371         my $userid = $param->{userid};
372         return if !$self->check_user_exist($userid, $noerr);
373         my ($t, $subtest) = @$check;
374         die "missing parameters" if !$subtest;
375         if ($subtest eq 'self') {
376             return 1 if $username eq 'userid';
377             return 0 if $noerr;
378             raise_perm_exc();
379         } else {
380             die "unknown userid-param test";
381         }
382     } elsif ($test eq 'perm-modify') {
383         my ($t, $tmplpath) = @$check;
384         my $path = PVE::Tools::template_replace($tmplpath, $param);
385         $path = PVE::AccessControl::normalize_path($path);
386         return $self->check_perm_modify($username, $path, $noerr);
387    } else {
388         die "unknown permission test";
389     }
390 };
391
392 sub check_api2_permissions {
393     my ($self, $perm, $username, $param) = @_;
394
395     return 1 if !$username && $perm->{user} eq 'world';
396
397     raise_perm_exc("user != null") if !$username;
398
399     return 1 if $username eq 'root@pam';
400
401     raise_perm_exc('user != root@pam') if !$perm;
402
403     return 1 if $perm->{user} && $perm->{user} eq 'all';
404
405     return $self->exec_api2_perm_check($perm->{check}, $username, $param) 
406         if $perm->{check};
407
408     raise_perm_exc();
409 }
410
411 # initialize environment - must be called once at program startup
412 sub init {
413     my ($class, $type, %params) = @_;
414
415     $class = ref($class) || $class;
416
417     die "already initialized" if $pve_env;
418
419     die "unknown environment type" if !$type || $type !~ m/^(cli|pub|priv|ha)$/;
420
421     $SIG{CHLD} = $worker_reaper;
422
423     # environment types
424     # cli  ... command started fron command line
425     # pub  ... access from public server (apache)
426     # priv ... access from private server (pvedaemon)
427     # ha   ... access from HA resource manager agent (rgmanager)
428     
429     my $self = {
430         user_cfg => {},
431         aclcache => {},
432         aclversion => undef,
433         type => $type,
434     };
435
436     bless $self, $class;
437
438     foreach my $p (keys %params) {
439         if ($p eq 'atfork') {
440             $self->{$p} = $params{$p};
441         } else {
442             die "unknown option '$p'";
443         }
444     }
445
446     $pve_env = $self;
447
448     my ($sysname, $nodename) = POSIX::uname();
449
450     $nodename =~ s/\..*$//; # strip domain part, if any
451
452     $self->{nodename} = $nodename;
453
454     return $self;
455 }; 
456
457 # get the singleton 
458 sub get {
459
460     die "not initialized" if !$pve_env;
461
462     return $pve_env;
463 }
464
465 sub parse_params {
466     my ($self, $enable_upload) = @_;
467
468     if ($self->{request_rec}) {
469         my $cgi;
470         if ($enable_upload) {
471             $cgi = CGI->new($self->{request_rec});
472         } else {
473             # disable upload using empty upload_hook
474             $cgi = CGI->new($self->{request_rec}, sub {}, undef, 0);
475         }
476         $self->{cgi} = $cgi;
477         my $params = $cgi->Vars();
478         return PVE::Tools::decode_utf8_parameters($params);
479     } elsif ($self->{params}) {
480         return $self->{params};
481     } else {
482         die "no parameters registered";
483     }
484 }
485
486 sub get_upload_info {
487     my ($self, $param) = @_;
488
489     my $cgi = $self->{cgi};
490     die "CGI not initialized" if !$cgi;
491
492     my $pd = $cgi->param($param);
493     die "unable to get cgi parameter info\n" if !$pd;
494     my $info = $cgi->uploadInfo($pd);
495     die "unable to get cgi upload info\n" if !$info;
496
497     my $res = { %$info };
498
499     my $tmpfilename = $cgi->tmpFileName($pd);
500     die "unable to get cgi upload file name\n" if !$tmpfilename;
501     $res->{tmpfilename} = $tmpfilename;
502
503     #my $hndl = $cgi->upload($param);
504     #die "unable to get cgi upload handle\n" if !$hndl;
505     #$res->{handle} = $hndl->handle;
506
507     return $res;
508 }
509
510 # init_request - must be called before each RPC request
511 sub init_request {
512     my ($self, %params) = @_;
513
514     PVE::Cluster::cfs_update();
515
516     $self->{result_attributes} = {};
517
518     my $userconfig; # we use this for regression tests
519     foreach my $p (keys %params) {
520         if ($p eq 'userconfig') {
521             $userconfig = $params{$p};
522         } elsif ($p eq 'request_rec') {
523             # pass Apache2::RequestRec
524             $self->{request_rec} = $params{$p};
525         } elsif ($p eq 'params') {
526             $self->{params} = $params{$p};
527         } else {
528             die "unknown parameter '$p'";
529         }
530     }
531
532     eval {
533         $self->{aclcache} = {};
534         if ($userconfig) {
535             my $ucdata = PVE::Tools::file_get_contents($userconfig);
536             my $cfg = PVE::AccessControl::parse_user_config($userconfig, $ucdata);
537             $self->{user_cfg} = $cfg;
538             #print Dumper($cfg);
539         } else {
540             my $ucvers = PVE::Cluster::cfs_file_version('user.cfg'); 
541             if (!$self->{aclcache} || !defined($self->{aclversion}) || 
542                 !defined($ucvers) ||  ($ucvers ne $self->{aclversion})) {
543                 $self->{aclversion} = $ucvers;
544                 my $cfg = PVE::Cluster::cfs_read_file('user.cfg');
545                 $self->{user_cfg} = $cfg;
546             }
547         }
548     };
549     if (my $err = $@) {
550         $self->{user_cfg} = {};
551         die "Unable to load access control list: $err";
552     }
553 }
554
555 sub set_client_ip {
556     my ($self, $ip) = @_;
557
558     $self->{client_ip} = $ip;
559 }
560
561 sub get_client_ip {
562     my ($self) = @_;
563
564     return $self->{client_ip};
565 }
566
567 sub set_result_attrib {
568     my ($self, $key, $value) = @_;
569
570     $self->{result_attributes}->{$key} = $value;
571 }
572
573 sub get_result_attrib {
574     my ($self, $key) = @_;
575
576     return $self->{result_attributes}->{$key};
577 }
578
579 sub set_language {
580     my ($self, $lang) = @_;
581
582     # fixme: initialize I18N
583
584     $self->{language} = $lang;
585 }
586
587 sub get_language {
588     my ($self) = @_;
589
590     return $self->{language};
591 }
592
593 sub set_user {
594     my ($self, $user) = @_;
595
596     # fixme: get ACLs
597
598     $self->{user} = $user;
599 }
600
601 sub get_user {
602     my ($self) = @_;
603
604     die "user name not set\n" if !$self->{user};
605
606     return $self->{user};
607 }
608
609 # read/update list of active workers 
610 # we move all finished tasks to the archive index,
611 # but keep aktive and most recent task in the active file.
612 # $nocheck ... consider $new_upid still running (avoid that
613 # we try to read the reult to early.
614 sub active_workers  {
615     my ($new_upid, $nocheck) = @_;
616
617     my $lkfn = "/var/log/pve/tasks/.active.lock";
618
619     my $timeout = 10;
620
621     my $code = sub {
622
623         my $tasklist = PVE::INotify::read_file('active');
624
625         my @ta;
626         my $tlist = [];
627         my $thash = {}; # only list task once
628
629         my $check_task = sub {
630             my ($task, $running) = @_;
631
632             if ($running || PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
633                 push @$tlist, $task;
634             } else {
635                 delete $task->{pid};
636                 push @ta, $task;
637             }
638             delete $task->{pstart};
639         };
640
641         foreach my $task (@$tasklist) {
642             my $upid = $task->{upid};
643             next if $thash->{$upid};
644             $thash->{$upid} = $task;
645             &$check_task($task);
646         }
647
648         if ($new_upid && !(my $task = $thash->{$new_upid})) {
649             $task = PVE::Tools::upid_decode($new_upid);
650             $task->{upid} = $new_upid;
651             $thash->{$new_upid} = $task;
652             &$check_task($task, $nocheck);
653         }
654
655
656         @ta = sort { $b->{starttime} cmp $a->{starttime} } @ta;
657
658         my $save = defined($new_upid);
659
660         foreach my $task (@ta) {
661             next if $task->{endtime};
662             $task->{endtime} = time();
663             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
664             $save = 1;
665         }
666
667         my $archive = '';
668         my @arlist = ();
669         foreach my $task (@ta) {
670             if (!$task->{saved}) {
671                 $archive .= sprintf("$task->{upid} %08X $task->{status}\n", $task->{endtime});
672                 $save = 1;
673                 push @arlist, $task;
674                 $task->{saved} = 1;
675             }
676         }
677
678         if ($archive) {
679             my $size = 0;
680             my $filename = "/var/log/pve/tasks/index";
681             eval {
682                 my $fh = IO::File->new($filename, '>>', 0644) ||
683                     die "unable to open file '$filename' - $!\n";
684                 PVE::Tools::safe_print($filename, $fh, $archive);
685                 $size = -s $fh;
686                 close($fh) ||
687                     die "unable to close file '$filename' - $!\n";
688             };
689             my $err = $@;
690             if ($err) {
691                 syslog('err', $err);
692                 foreach my $task (@arlist) { # mark as not saved
693                     $task->{saved} = 0;
694                 }
695             }
696             my $maxsize = 50000; # about 1000 entries
697             if ($size > $maxsize) {
698                 rename($filename, "$filename.1");
699             }
700         }
701
702         # we try to reduce the amount of data
703         # list all running tasks and task and a few others
704         # try to limit to 25 tasks
705         my $ctime = time();
706         my $max = 25 - scalar(@$tlist);
707         foreach my $task (@ta) {
708             last if $max <= 0;
709             push @$tlist, $task;
710             $max--;
711         }
712
713         PVE::INotify::write_file('active', $tlist) if $save;
714
715         return $tlist;
716     };
717
718     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
719     die $@ if $@;
720
721     return $res;
722 }
723
724 my $kill_process_group = sub {
725     my ($pid, $pstart) = @_;
726
727     # send kill to process group (negative pid)
728     my $kpid = -$pid;
729
730     # always send signal to all pgrp members
731     kill(15, $kpid); # send TERM signal
732
733     # give max 5 seconds to shut down
734     for (my $i = 0; $i < 5; $i++) {
735         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
736         sleep (1);
737     }
738        
739     # to be sure
740     kill(9, $kpid); 
741 };
742
743 sub check_worker {
744     my ($upid, $killit) = @_;
745
746     my $task = PVE::Tools::upid_decode($upid);
747
748     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
749
750     return 0 if !$running;
751
752     if ($killit) {
753         &$kill_process_group($task->{pid});
754         return 0;
755     }
756
757     return 1;
758 }
759
760 # start long running workers
761 # STDIN is redirected to /dev/null
762 # STDOUT,STDERR are redirected to the filename returned by upid_decode
763 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
764 sub fork_worker {
765     my ($self, $dtype, $id, $user, $function) = @_;
766
767     $dtype = 'unknown' if !defined ($dtype);
768     $id = '' if !defined ($id);
769
770     $user = 'root@pve' if !defined ($user);
771
772     my $sync = $self->{type} eq 'cli' ? 1 : 0;
773
774     local $SIG{INT} = 
775         local $SIG{QUIT} = 
776         local $SIG{PIPE} = 
777         local $SIG{TERM} = 'IGNORE';
778
779     my $starttime = time ();
780
781     my @psync = POSIX::pipe();
782     my @csync = POSIX::pipe();
783
784     my $node = $self->{nodename};
785
786     my $cpid = fork();
787     die "unable to fork worker - $!" if !defined($cpid);
788
789     my $workerpuid = $cpid ? $cpid : $$;
790
791     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
792         die "unable to read process start time";
793
794     my $upid = PVE::Tools::upid_encode ({
795         node => $node, pid => $workerpuid, pstart => $pstart, 
796         starttime => $starttime, type => $dtype, id => $id, user => $user });
797
798     my $outfh;
799
800     if (!$cpid) { # child
801
802         $0 = "task $upid";
803
804         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
805
806         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
807
808         # set sess/process group - we want to be able to kill the
809         # whole process group
810         POSIX::setsid(); 
811
812         POSIX::close ($psync[0]);
813         POSIX::close ($csync[1]);
814
815         $outfh = $sync ? $psync[1] : undef;
816
817         eval {
818             PVE::INotify::inotify_close();
819
820             if (my $atfork = $self->{atfork}) {
821                 &$atfork();
822             }
823
824             # same algorythm as used inside SA
825             # STDIN = /dev/null
826             my $fd = fileno (STDIN);
827
828             if (!$sync) {
829                 close STDIN;
830                 POSIX::close(0) if $fd != 0;
831
832                 die "unable to redirect STDIN - $!" 
833                     if !open(STDIN, "</dev/null");
834
835                 $outfh = PVE::Tools::upid_open($upid);
836             }
837
838
839             # redirect STDOUT
840             $fd = fileno(STDOUT);
841             close STDOUT;
842             POSIX::close (1) if $fd != 1;
843
844             die "unable to redirect STDOUT - $!" 
845                 if !open(STDOUT, ">&", $outfh);
846
847             STDOUT->autoflush (1);
848       
849             #  redirect STDERR to STDOUT
850             $fd = fileno (STDERR);
851             close STDERR;
852             POSIX::close(2) if $fd != 2;
853
854             die "unable to redirect STDERR - $!" 
855                 if !open(STDERR, ">&1");
856             
857             STDERR->autoflush(1);
858         };
859         if (my $err = $@) {
860             my $msg =  "ERROR: $err";
861             POSIX::write($psync[1], $msg, length ($msg));
862             POSIX::close($psync[1]);
863             POSIX::_exit(1); 
864             kill(-9, $$); 
865         }
866
867         # sync with parent (signal that we are ready)
868         if ($sync) {
869             print "$upid\n";
870         } else {
871             POSIX::write($psync[1], $upid, length ($upid));
872             POSIX::close($psync[1]);
873         }
874
875         my $readbuf = '';
876         # sync with parent (wait until parent is ready)
877         POSIX::read($csync[0], $readbuf, 4096);
878         die "parent setup error\n" if $readbuf ne 'OK';
879
880         if ($self->{type} eq 'ha') {
881             print "task started by HA resource agent\n";
882         }
883         eval { &$function($upid); };
884         my $err = $@;
885         if ($err) {
886             chomp $err;
887             $err =~ s/\n/ /mg;
888             syslog('err', $err);
889             print STDERR "TASK ERROR: $err\n";
890             POSIX::_exit(-1); 
891         } else {
892             print STDERR "TASK OK\n";
893             POSIX::_exit(0);
894         } 
895         kill(-9, $$); 
896     }
897
898     # parent
899
900     POSIX::close ($psync[1]);
901     POSIX::close ($csync[0]);
902
903     my $readbuf = '';
904     # sync with child (wait until child starts)
905     POSIX::read($psync[0], $readbuf, 4096);
906
907     if (!$sync) {
908         POSIX::close($psync[0]);
909         &$register_worker($cpid, $user, $upid);
910     } else {
911         chomp $readbuf;
912     }
913
914     eval {
915         die "got no worker upid - start worker failed\n" if !$readbuf;
916
917         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
918             die "starting worker failed: $1\n";
919         }
920
921         if ($readbuf ne $upid) {
922             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
923         }
924
925         if ($sync) {
926             $outfh = PVE::Tools::upid_open($upid);
927         }
928     };
929     my $err = $@;
930
931     if (!$err) {
932         my $msg = 'OK';
933         POSIX::write($csync[1], $msg, length ($msg));
934         POSIX::close($csync[1]);
935        
936     } else {
937         POSIX::close($csync[1]);
938         kill(-9, $cpid); # make sure it gets killed
939         die $err;
940     }
941
942     PVE::Cluster::log_msg('info', $user, "starting task $upid");
943
944     my $tlist = active_workers($upid, $sync);
945     PVE::Cluster::broadcast_tasklist($tlist);
946    
947     my $res = 0;
948
949     if ($sync) {
950         my $count;
951         my $outbuf = '';
952         my $int_count = 0;
953         eval {
954             local $SIG{INT} = local $SIG{QUIT} = local $SIG{TERM} = sub { 
955                 # always send signal to all pgrp members
956                 my $kpid = -$cpid;
957                 if ($int_count < 3) {
958                     kill(15, $kpid); # send TERM signal
959                 } else {
960                     kill(9, $kpid); # send KILL signal
961                 }
962                 $int_count++;
963             };
964             local $SIG{PIPE} = sub { die "broken pipe\n"; };
965
966             my $select = new IO::Select;    
967             my $fh = IO::Handle->new_from_fd($psync[0], 'r');
968             $select->add($fh);
969
970             while ($select->count) {
971                 my @handles = $select->can_read(1);
972                 if (scalar(@handles)) {
973                     my $count = sysread ($handles[0], $readbuf, 4096);
974                     if (!defined ($count)) {
975                         my $err = $!;
976                         die "sync pipe read error: $err\n";
977                     }
978                     last if $count == 0; # eof
979
980                     $outbuf .= $readbuf;
981                     while ($outbuf =~ s/^(([^\010\r\n]*)(\r|\n|(\010)+|\r\n))//s) {
982                         my $line = $1;
983                         my $data = $2;
984                         if ($data =~ m/^TASK OK$/) {
985                             # skip
986                         } elsif ($data =~ m/^TASK ERROR: (.+)$/) {
987                             print STDERR "$1\n";
988                         } else {
989                             print $line;
990                         }
991                         if ($outfh) {
992                             print $outfh $line;
993                             $outfh->flush();
994                         }
995                     }
996                 } else {
997                     # some commands daemonize without closing stdout
998                     last if !PVE::ProcFSTools::check_process_running($cpid);
999                 }
1000             }
1001         };
1002         my $err = $@;
1003
1004         POSIX::close($psync[0]);
1005
1006         if ($outbuf) { # just to be sure
1007             print $outbuf;
1008             if ($outfh) {
1009                 print $outfh $outbuf;
1010             }
1011         }
1012
1013         if ($err) {
1014             $err =~ s/\n/ /mg;
1015             print STDERR "$err\n";
1016             if ($outfh) {
1017                 print $outfh "TASK ERROR: $err\n";
1018             }
1019         }
1020
1021         &$kill_process_group($cpid, $pstart); # make sure it gets killed
1022
1023         close($outfh);
1024
1025         waitpid($cpid, 0);
1026         $res = $?;
1027         &$log_task_result($upid, $user, $res);
1028     }
1029
1030     return wantarray ? ($upid, $res) : $upid;
1031 }
1032
1033 1;