PVE/RPCEnvironment.pm

   1 package PVE::RPCEnvironment;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX qw(:sys_wait_h EINTR);
   6 use IO::Handle;
   7 use IO::File;
   8 use IO::Select;
   9 use Fcntl qw(:flock);
  10 use PVE::Exception qw(raise raise_perm_exc);
  11 use PVE::SafeSyslog;
  12 use PVE::Tools;
  13 use PVE::INotify;
  14 use PVE::Cluster;
  15 use PVE::ProcFSTools;
  16 use PVE::AccessControl;
  17
  18 # we use this singleton class to pass RPC related environment values
  19
  20 my $pve_env;
  21
  22 # save $SIG{CHLD} handler implementation.
  23 # simply set $SIG{CHLD} = $worker_reaper;
  24 # and register forked processes with &$register_worker(pid)
  25 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
  26 # has serious side effects, because perls built in system() and open()
  27 # functions can't get the correct exit status of a child. So we cant use
  28 # that (also see perlipc)
  29
  30 my $WORKER_PIDS;
  31 my $WORKER_FLAG = 0;
  32
  33 my $log_task_result = sub {
  34     my ($upid, $user, $status) = @_;
  35
  36     my $msg = 'successful';
  37     my $pri = 'info';
  38     if ($status != 0) {
  39         my $ec = $status >> 8;
  40         my $ic = $status & 255;
  41         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
  42         $pri = 'err';
  43     }
  44     my $tlist = active_workers($upid);
  45     PVE::Cluster::broadcast_tasklist($tlist);
  46     my $task;
  47     foreach my $t (@$tlist) {
  48         if ($t->{upid} eq $upid) {
  49             $task = $t;
  50             last;
  51         }
  52     }
  53     if ($task && $task->{status}) {
  54         $msg = $task->{status};
  55     }
  56     PVE::Cluster::log_msg($pri, $user, "end task $upid $msg");
  57 };
  58
  59 my $worker_reaper = sub {
  60     local $!; local $?;
  61     foreach my $pid (keys %$WORKER_PIDS) {
  62         my $waitpid = waitpid ($pid, WNOHANG);
  63         if (defined($waitpid) && ($waitpid == $pid)) {
  64             my $info = $WORKER_PIDS->{$pid};
  65             if ($info && $info->{upid} && $info->{user}) {
  66                 &$log_task_result($info->{upid}, $info->{user}, $?);
  67             }
  68             delete ($WORKER_PIDS->{$pid});
  69         }
  70     }
  71 };
  72
  73 my $register_worker = sub {
  74     my ($pid, $user, $upid) = @_;
  75
  76     return if !$pid;
  77
  78     # do not register if already finished
  79     my $waitpid = waitpid ($pid, WNOHANG);
  80     if (defined($waitpid) && ($waitpid == $pid)) {
  81         delete ($WORKER_PIDS->{$pid});
  82         return;
  83     }
  84
  85     $WORKER_PIDS->{$pid} = {
  86         user => $user,
  87         upid => $upid,
  88     };
  89 };
  90
  91 # ACL cache
  92
  93 my $compile_acl_path = sub {
  94     my ($self, $user, $path) = @_;
  95
  96     my $cfg = $self->{user_cfg};
  97
  98     return undef if !$cfg->{roles};
  99
 100     die "internal error" if $user eq 'root@pam';
 101
 102     my $cache = $self->{aclcache};
 103     $cache->{$user} = {} if !$cache->{$user};
 104     my $data = $cache->{$user};
 105
 106     if (!$data->{poolroles}) {
 107         $data->{poolroles} = {};
 108
 109         foreach my $pool (keys %{$cfg->{pools}}) {
 110             my $d = $cfg->{pools}->{$pool};
 111             my @ra = PVE::AccessControl::roles($cfg, $user, "/pool/$pool"); # pool roles
 112             next if !scalar(@ra);
 113             foreach my $vmid (keys %{$d->{vms}}) {
 114                 for my $role (@ra) {
 115                     $data->{poolroles}->{"/vms/$vmid"}->{$role} = 1;
 116                 }
 117             }
 118             foreach my $storeid (keys %{$d->{storage}}) {
 119                 for my $role (@ra) {
 120                     $data->{poolroles}->{"/storage/$storeid"}->{$role} = 1;
 121                 }
 122             }
 123         }
 124     }
 125
 126     my @ra = PVE::AccessControl::roles($cfg, $user, $path);
 127
 128     # apply roles inherited from pools
 129     # Note: assume we do not want to propagate those privs
 130     if ($data->{poolroles}->{$path}) {
 131         if (!($ra[0] && $ra[0] eq 'NoAccess')) {
 132             if ($data->{poolroles}->{$path}->{NoAccess}) {
 133                 @ra = ('NoAccess');
 134             } else {
 135                 foreach my $role (keys %{$data->{poolroles}->{$path}}) {
 136                     push @ra, $role;
 137                 }
 138             }
 139         }
 140     }
 141
 142     $data->{roles}->{$path} = [ @ra ];
 143
 144     my $privs = {};
 145     foreach my $role (@ra) {
 146         if (my $privset = $cfg->{roles}->{$role}) {
 147             foreach my $p (keys %$privset) {
 148                 $privs->{$p} = 1;
 149             }
 150         }
 151     }
 152     $data->{privs}->{$path} = $privs;
 153
 154     return $privs;
 155 };
 156
 157 sub roles {
 158    my ($self, $user, $path) = @_;
 159
 160    if ($user eq 'root@pam') { # root can do anything
 161        return ('Administrator');
 162    }
 163
 164    $user = PVE::AccessControl::verify_username($user, 1);
 165    return () if !$user;
 166
 167    my $cache = $self->{aclcache};
 168    $cache->{$user} = {} if !$cache->{$user};
 169
 170    my $acl = $cache->{$user};
 171
 172    my $roles = $acl->{roles}->{$path};
 173    return @$roles if $roles;
 174
 175    &$compile_acl_path($self, $user, $path);
 176    $roles = $acl->{roles}->{$path} || [];
 177    return @$roles;
 178 }
 179
 180 sub permissions {
 181     my ($self, $user, $path) = @_;
 182
 183     if ($user eq 'root@pam') { # root can do anything
 184         my $cfg = $self->{user_cfg};
 185         return $cfg->{roles}->{'Administrator'};
 186     }
 187
 188     $user = PVE::AccessControl::verify_username($user, 1);
 189     return {} if !$user;
 190
 191     my $cache = $self->{aclcache};
 192     $cache->{$user} = {} if !$cache->{$user};
 193
 194     my $acl = $cache->{$user};
 195
 196     my $perm = $acl->{privs}->{$path};
 197     return $perm if $perm;
 198
 199     return &$compile_acl_path($self, $user, $path);
 200 }
 201
 202 sub check {
 203     my ($self, $user, $path, $privs, $noerr) = @_;
 204
 205     my $perm = $self->permissions($user, $path);
 206
 207     foreach my $priv (@$privs) {
 208         PVE::AccessControl::verify_privname($priv);
 209         if (!$perm->{$priv}) {
 210             return undef if $noerr;
 211             raise_perm_exc("$path, $priv");
 212         }
 213     };
 214
 215     return 1;
 216 };
 217
 218 sub check_any {
 219     my ($self, $user, $path, $privs, $noerr) = @_;
 220
 221     my $perm = $self->permissions($user, $path);
 222
 223     my $found = 0;
 224     foreach my $priv (@$privs) {
 225         PVE::AccessControl::verify_privname($priv);
 226         if ($perm->{$priv}) {
 227             $found = 1;
 228             last;
 229         }
 230     };
 231
 232     return 1 if $found;
 233
 234     return undef if $noerr;
 235
 236     raise_perm_exc("$path, " . join("|", @$privs));
 237 };
 238
 239 sub check_full {
 240     my ($self, $username, $path, $privs, $any, $noerr) = @_;
 241     if ($any) {
 242         return $self->check_any($username, $path, $privs, $noerr);
 243     } else {
 244         return $self->check($username, $path, $privs, $noerr);
 245     }
 246 }
 247
 248 sub check_user_enabled {
 249     my ($self, $user, $noerr) = @_;
 250
 251     my $cfg = $self->{user_cfg};
 252     return PVE::AccessControl::check_user_enabled($cfg, $user, $noerr);
 253 }
 254
 255 sub check_user_exist {
 256     my ($self, $user, $noerr) = @_;
 257
 258     my $cfg = $self->{user_cfg};
 259     return PVE::AccessControl::check_user_exist($cfg, $user, $noerr);
 260 }
 261
 262 sub check_pool_exist {
 263     my ($self, $pool, $noerr) = @_;
 264
 265     my $cfg = $self->{user_cfg};
 266
 267     return 1 if $cfg->{pools}->{$pool};
 268
 269     return undef if $noerr;
 270
 271     raise_perm_exc("pool '$pool' does not exist");
 272 }
 273
 274 sub check_vm_perm {
 275     my ($self, $user, $vmid, $pool, $privs, $any, $noerr) = @_;
 276
 277     my $cfg = $self->{user_cfg};
 278
 279     if ($pool) {
 280         return if $self->check_full($user, "/pool/$pool", $privs, $any, 1);
 281     }
 282     return $self->check_full($user, "/vms/$vmid", $privs, $any, $noerr);
 283 };
 284
 285 sub check_volume_access {
 286     my ($self, $user, $storecfg, $vmid, $volid) = @_;
 287
 288     # test if we have read access to volid
 289
 290     my ($sid, $volname) = PVE::Storage::parse_volume_id($volid, 1);
 291     if ($sid) {
 292         my ($vtype, undef, $ownervm) = PVE::Storage::parse_volname($storecfg, $volid);
 293         if ($vtype eq 'iso' || $vtype eq 'vztmpl') {
 294             # we simply allow access
 295         } elsif (defined($ownervm) && defined($vmid) && ($ownervm == $vmid)) {
 296             # we are owner - allow access
 297         } elsif ($vtype eq 'backup' && $ownervm) {
 298             $self->check($user, "/storage/$sid", ['Datastore.AllocateSpace']);
 299             $self->check($user, "/vms/$ownervm", ['VM.Backup']);
 300         } else {
 301             # allow if we are Datastore administrator
 302             $self->check($user, "/storage/$sid", ['Datastore.Allocate']);
 303         }
 304     } else {
 305         die "Only root can pass arbitrary filesystem paths."
 306             if $user ne 'root@pam';
 307     }
 308
 309     return undef;
 310 }
 311
 312 sub is_group_member {
 313     my ($self, $group, $user) = @_;
 314
 315     my $cfg = $self->{user_cfg};
 316
 317     return 0 if !$cfg->{groups}->{$group};
 318
 319     return defined($cfg->{groups}->{$group}->{users}->{$user});
 320 }
 321
 322 sub filter_groups {
 323     my ($self, $user, $privs, $any) = @_;
 324
 325     my $cfg = $self->{user_cfg};
 326
 327     my $groups = {};
 328     foreach my $group (keys %{$cfg->{groups}}) {
 329         my $path = "/access/groups/$group";
 330         if ($self->check_full($user, $path, $privs, $any, 1)) {
 331             $groups->{$group} = $cfg->{groups}->{$group};
 332         }
 333     }
 334
 335     return $groups;
 336 }
 337
 338 sub group_member_join {
 339     my ($self, $grouplist) = @_;
 340
 341     my $users = {};
 342
 343     my $cfg = $self->{user_cfg};
 344     foreach my $group (@$grouplist) {
 345         my $data = $cfg->{groups}->{$group};
 346         next if !$data;
 347         foreach my $user (keys %{$data->{users}}) {
 348             $users->{$user} = 1;
 349         }
 350     }
 351
 352     return $users;
 353 }
 354
 355 sub check_perm_modify {
 356     my ($self, $username, $path, $noerr) = @_;
 357
 358     return $self->check($username, '/access', [ 'Permissions.Modify' ], $noerr) if !$path;
 359
 360     my $testperms = [ 'Permissions.Modify' ];
 361     if ($path =~ m|^/storage/.+$|) {
 362         push @$testperms, 'Datastore.Allocate';
 363     } elsif ($path =~ m|^/vms/.+$|) {
 364         push @$testperms, 'VM.Allocate';
 365     } elsif ($path =~ m|^/pool/.+$|) {
 366         push @$testperms, 'Pool.Allocate';
 367     }
 368
 369     return $self->check_any($username, $path, $testperms, $noerr);
 370 }
 371
 372 sub exec_api2_perm_check {
 373     my ($self, $check, $username, $param, $noerr) = @_;
 374
 375     # syslog("info", "CHECK " . join(', ', @$check));
 376
 377     my $ind = 0;
 378     my $test = $check->[$ind++];
 379     die "no permission test specified" if !$test;
 380
 381     if ($test eq 'and') {
 382         while (my $subcheck = $check->[$ind++]) {
 383             $self->exec_api2_perm_check($subcheck, $username, $param);
 384         }
 385         return 1;
 386     } elsif ($test eq 'or') {
 387         while (my $subcheck = $check->[$ind++]) {
 388             return 1 if $self->exec_api2_perm_check($subcheck, $username, $param, 1);
 389         }
 390         return 0 if $noerr;
 391         raise_perm_exc();
 392     } elsif ($test eq 'perm') {
 393         my ($t, $tmplpath, $privs, %options) = @$check;
 394         my $any = $options{any};
 395         die "missing parameters" if !($tmplpath && $privs);
 396         my $require_param = $options{require_param};
 397         if ($require_param && !defined($param->{$require_param})) {
 398             return 0 if $noerr;
 399             raise_perm_exc();
 400         }
 401         my $path = PVE::Tools::template_replace($tmplpath, $param);
 402         $path = PVE::AccessControl::normalize_path($path);
 403         return $self->check_full($username, $path, $privs, $any, $noerr);
 404     } elsif ($test eq 'userid-group') {
 405         my $userid = $param->{userid};
 406         my ($t, $privs, %options) = @$check;
 407         return 0 if !$options{groups_param} && !$self->check_user_exist($userid, $noerr);
 408         if (!$self->check_any($username, "/access/groups", $privs, 1)) {
 409             my $groups = $self->filter_groups($username, $privs, 1);
 410             if ($options{groups_param}) {
 411                 my @group_param = PVE::Tools::split_list($param->{groups});
 412                 raise_perm_exc("/access/groups, " . join("|", @$privs)) if !scalar(@group_param);
 413                 foreach my $pg (@group_param) {
 414                     raise_perm_exc("/access/groups/$pg, " . join("|", @$privs))
 415                         if !$groups->{$pg};
 416                 }
 417             } else {
 418                 my $allowed_users = $self->group_member_join([keys %$groups]);
 419                 if (!$allowed_users->{$userid}) {
 420                     return 0 if $noerr;
 421                     raise_perm_exc();
 422                 }
 423             }
 424         }
 425         return 1;
 426     } elsif ($test eq 'userid-param') {
 427         my ($userid, undef, $realm) = PVE::AccessControl::verify_username($param->{userid});
 428         my ($t, $subtest) = @$check;
 429         die "missing parameters" if !$subtest;
 430         if ($subtest eq 'self') {
 431             return 0 if !$self->check_user_exist($userid, $noerr);
 432             return 1 if $username eq $userid;
 433             return 0 if $noerr;
 434             raise_perm_exc();
 435         } elsif ($subtest eq 'Realm.AllocateUser') {
 436             my $path =  "/access/realm/$realm";
 437             return $self->check($username, $path, ['Realm.AllocateUser'], $noerr);
 438         } else {
 439             die "unknown userid-param test";
 440         }
 441      } elsif ($test eq 'perm-modify') {
 442         my ($t, $tmplpath) = @$check;
 443         my $path = PVE::Tools::template_replace($tmplpath, $param);
 444         $path = PVE::AccessControl::normalize_path($path);
 445         return $self->check_perm_modify($username, $path, $noerr);
 446    } else {
 447         die "unknown permission test";
 448     }
 449 };
 450
 451 sub check_api2_permissions {
 452     my ($self, $perm, $username, $param) = @_;
 453
 454     return 1 if !$username && $perm->{user} eq 'world';
 455
 456     raise_perm_exc("user != null") if !$username;
 457
 458     return 1 if $username eq 'root@pam';
 459
 460     raise_perm_exc('user != root@pam') if !$perm;
 461
 462     return 1 if $perm->{user} && $perm->{user} eq 'all';
 463
 464     return $self->exec_api2_perm_check($perm->{check}, $username, $param)
 465         if $perm->{check};
 466
 467     raise_perm_exc();
 468 }
 469
 470 # initialize environment - must be called once at program startup
 471 sub init {
 472     my ($class, $type, %params) = @_;
 473
 474     $class = ref($class) || $class;
 475
 476     die "already initialized" if $pve_env;
 477
 478     die "unknown environment type" if !$type || $type !~ m/^(cli|pub|priv|ha)$/;
 479
 480     $SIG{CHLD} = $worker_reaper;
 481
 482     # environment types
 483     # cli  ... command started fron command line
 484     # pub  ... access from public server (apache)
 485     # priv ... access from private server (pvedaemon)
 486     # ha   ... access from HA resource manager agent (rgmanager)
 487
 488     my $self = {
 489         user_cfg => {},
 490         aclcache => {},
 491         aclversion => undef,
 492         type => $type,
 493     };
 494
 495     bless $self, $class;
 496
 497     foreach my $p (keys %params) {
 498         if ($p eq 'atfork') {
 499             $self->{$p} = $params{$p};
 500         } else {
 501             die "unknown option '$p'";
 502         }
 503     }
 504
 505     $pve_env = $self;
 506
 507     my ($sysname, $nodename) = POSIX::uname();
 508
 509     $nodename =~ s/\..*$//; # strip domain part, if any
 510
 511     $self->{nodename} = $nodename;
 512
 513     return $self;
 514 };
 515
 516 # convenience function for command line tools
 517 sub setup_default_cli_env {
 518     my ($class, $username) = @_;
 519
 520     $class = ref($class) || $class;
 521
 522     $username //= 'root@pam';
 523
 524     PVE::INotify::inotify_init();
 525
 526     my $rpcenv = $class->init('cli');
 527     $rpcenv->init_request();
 528     $rpcenv->set_language($ENV{LANG});
 529     $rpcenv->set_user($username);
 530
 531     die "please run as root\n"
 532         if ($username eq 'root@pam') && ($> != 0);
 533 }
 534
 535 # get the singleton
 536 sub get {
 537
 538     die "not initialized" if !$pve_env;
 539
 540     return $pve_env;
 541 }
 542
 543 # init_request - must be called before each RPC request
 544 sub init_request {
 545     my ($self, %params) = @_;
 546
 547     PVE::Cluster::cfs_update();
 548
 549     $self->{result_attributes} = {};
 550
 551     my $userconfig; # we use this for regression tests
 552     foreach my $p (keys %params) {
 553         if ($p eq 'userconfig') {
 554             $userconfig = $params{$p};
 555         } else {
 556             die "unknown parameter '$p'";
 557         }
 558     }
 559
 560     eval {
 561         $self->{aclcache} = {};
 562         if ($userconfig) {
 563             my $ucdata = PVE::Tools::file_get_contents($userconfig);
 564             my $cfg = PVE::AccessControl::parse_user_config($userconfig, $ucdata);
 565             $self->{user_cfg} = $cfg;
 566             #print Dumper($cfg);
 567         } else {
 568             my $ucvers = PVE::Cluster::cfs_file_version('user.cfg');
 569             if (!$self->{aclcache} || !defined($self->{aclversion}) ||
 570                 !defined($ucvers) ||  ($ucvers ne $self->{aclversion})) {
 571                 $self->{aclversion} = $ucvers;
 572                 my $cfg = PVE::Cluster::cfs_read_file('user.cfg');
 573                 $self->{user_cfg} = $cfg;
 574             }
 575         }
 576     };
 577     if (my $err = $@) {
 578         $self->{user_cfg} = {};
 579         die "Unable to load access control list: $err";
 580     }
 581 }
 582
 583 sub set_client_ip {
 584     my ($self, $ip) = @_;
 585
 586     $self->{client_ip} = $ip;
 587 }
 588
 589 sub get_client_ip {
 590     my ($self) = @_;
 591
 592     return $self->{client_ip};
 593 }
 594
 595 sub set_result_attrib {
 596     my ($self, $key, $value) = @_;
 597
 598     $self->{result_attributes}->{$key} = $value;
 599 }
 600
 601 sub get_result_attrib {
 602     my ($self, $key) = @_;
 603
 604     return $self->{result_attributes}->{$key};
 605 }
 606
 607 sub set_language {
 608     my ($self, $lang) = @_;
 609
 610     # fixme: initialize I18N
 611
 612     $self->{language} = $lang;
 613 }
 614
 615 sub get_language {
 616     my ($self) = @_;
 617
 618     return $self->{language};
 619 }
 620
 621 sub set_user {
 622     my ($self, $user) = @_;
 623
 624     # fixme: get ACLs
 625
 626     $self->{user} = $user;
 627 }
 628
 629 sub get_user {
 630     my ($self) = @_;
 631
 632     die "user name not set\n" if !$self->{user};
 633
 634     return $self->{user};
 635 }
 636
 637 sub is_worker {
 638     return $WORKER_FLAG;
 639 }
 640
 641 # read/update list of active workers
 642 # we move all finished tasks to the archive index,
 643 # but keep aktive and most recent task in the active file.
 644 # $nocheck ... consider $new_upid still running (avoid that
 645 # we try to read the reult to early.
 646 sub active_workers  {
 647     my ($new_upid, $nocheck) = @_;
 648
 649     my $lkfn = "/var/log/pve/tasks/.active.lock";
 650
 651     my $timeout = 10;
 652
 653     my $code = sub {
 654
 655         my $tasklist = PVE::INotify::read_file('active');
 656
 657         my @ta;
 658         my $tlist = [];
 659         my $thash = {}; # only list task once
 660
 661         my $check_task = sub {
 662             my ($task, $running) = @_;
 663
 664             if ($running || PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
 665                 push @$tlist, $task;
 666             } else {
 667                 delete $task->{pid};
 668                 push @ta, $task;
 669             }
 670             delete $task->{pstart};
 671         };
 672
 673         foreach my $task (@$tasklist) {
 674             my $upid = $task->{upid};
 675             next if $thash->{$upid};
 676             $thash->{$upid} = $task;
 677             &$check_task($task);
 678         }
 679
 680         if ($new_upid && !(my $task = $thash->{$new_upid})) {
 681             $task = PVE::Tools::upid_decode($new_upid);
 682             $task->{upid} = $new_upid;
 683             $thash->{$new_upid} = $task;
 684             &$check_task($task, $nocheck);
 685         }
 686
 687
 688         @ta = sort { $b->{starttime} cmp $a->{starttime} } @ta;
 689
 690         my $save = defined($new_upid);
 691
 692         foreach my $task (@ta) {
 693             next if $task->{endtime};
 694             $task->{endtime} = time();
 695             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
 696             $save = 1;
 697         }
 698
 699         my $archive = '';
 700         my @arlist = ();
 701         foreach my $task (@ta) {
 702             if (!$task->{saved}) {
 703                 $archive .= sprintf("%s %08X %s\n", $task->{upid}, $task->{endtime}, $task->{status});
 704                 $save = 1;
 705                 push @arlist, $task;
 706                 $task->{saved} = 1;
 707             }
 708         }
 709
 710         if ($archive) {
 711             my $size = 0;
 712             my $filename = "/var/log/pve/tasks/index";
 713             eval {
 714                 my $fh = IO::File->new($filename, '>>', 0644) ||
 715                     die "unable to open file '$filename' - $!\n";
 716                 PVE::Tools::safe_print($filename, $fh, $archive);
 717                 $size = -s $fh;
 718                 close($fh) ||
 719                     die "unable to close file '$filename' - $!\n";
 720             };
 721             my $err = $@;
 722             if ($err) {
 723                 syslog('err', $err);
 724                 foreach my $task (@arlist) { # mark as not saved
 725                     $task->{saved} = 0;
 726                 }
 727             }
 728             my $maxsize = 50000; # about 1000 entries
 729             if ($size > $maxsize) {
 730                 rename($filename, "$filename.1");
 731             }
 732         }
 733
 734         # we try to reduce the amount of data
 735         # list all running tasks and task and a few others
 736         # try to limit to 25 tasks
 737         my $ctime = time();
 738         my $max = 25 - scalar(@$tlist);
 739         foreach my $task (@ta) {
 740             last if $max <= 0;
 741             push @$tlist, $task;
 742             $max--;
 743         }
 744
 745         PVE::INotify::write_file('active', $tlist) if $save;
 746
 747         return $tlist;
 748     };
 749
 750     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
 751     die $@ if $@;
 752
 753     return $res;
 754 }
 755
 756 my $kill_process_group = sub {
 757     my ($pid, $pstart) = @_;
 758
 759     # send kill to process group (negative pid)
 760     my $kpid = -$pid;
 761
 762     # always send signal to all pgrp members
 763     kill(15, $kpid); # send TERM signal
 764
 765     # give max 5 seconds to shut down
 766     for (my $i = 0; $i < 5; $i++) {
 767         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
 768         sleep (1);
 769     }
 770
 771     # to be sure
 772     kill(9, $kpid);
 773 };
 774
 775 sub check_worker {
 776     my ($upid, $killit) = @_;
 777
 778     my $task = PVE::Tools::upid_decode($upid);
 779
 780     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
 781
 782     return 0 if !$running;
 783
 784     if ($killit) {
 785         &$kill_process_group($task->{pid});
 786         return 0;
 787     }
 788
 789     return 1;
 790 }
 791
 792 # start long running workers
 793 # STDIN is redirected to /dev/null
 794 # STDOUT,STDERR are redirected to the filename returned by upid_decode
 795 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
 796 sub fork_worker {
 797     my ($self, $dtype, $id, $user, $function, $background) = @_;
 798
 799     $dtype = 'unknown' if !defined ($dtype);
 800     $id = '' if !defined ($id);
 801
 802     $user = 'root@pve' if !defined ($user);
 803
 804     my $sync = ($self->{type} eq 'cli' && !$background) ? 1 : 0;
 805
 806     local $SIG{INT} =
 807         local $SIG{QUIT} =
 808         local $SIG{PIPE} =
 809         local $SIG{TERM} = 'IGNORE';
 810
 811     my $starttime = time ();
 812
 813     my @psync = POSIX::pipe();
 814     my @csync = POSIX::pipe();
 815
 816     my $node = $self->{nodename};
 817
 818     my $cpid = fork();
 819     die "unable to fork worker - $!" if !defined($cpid);
 820
 821     my $workerpuid = $cpid ? $cpid : $$;
 822
 823     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
 824         die "unable to read process start time";
 825
 826     my $upid = PVE::Tools::upid_encode ({
 827         node => $node, pid => $workerpuid, pstart => $pstart,
 828         starttime => $starttime, type => $dtype, id => $id, user => $user });
 829
 830     my $outfh;
 831
 832     if (!$cpid) { # child
 833
 834         $0 = "task $upid";
 835         $WORKER_FLAG = 1;
 836
 837         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
 838
 839         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
 840
 841         # set sess/process group - we want to be able to kill the
 842         # whole process group
 843         POSIX::setsid();
 844
 845         POSIX::close ($psync[0]);
 846         POSIX::close ($csync[1]);
 847
 848         $outfh = $sync ? $psync[1] : undef;
 849
 850         eval {
 851             PVE::INotify::inotify_close();
 852
 853             if (my $atfork = $self->{atfork}) {
 854                 &$atfork();
 855             }
 856
 857             # same algorythm as used inside SA
 858             # STDIN = /dev/null
 859             my $fd = fileno (STDIN);
 860
 861             if (!$sync) {
 862                 close STDIN;
 863                 POSIX::close(0) if $fd != 0;
 864
 865                 die "unable to redirect STDIN - $!"
 866                     if !open(STDIN, "</dev/null");
 867
 868                 $outfh = PVE::Tools::upid_open($upid);
 869             }
 870
 871
 872             # redirect STDOUT
 873             $fd = fileno(STDOUT);
 874             close STDOUT;
 875             POSIX::close (1) if $fd != 1;
 876
 877             die "unable to redirect STDOUT - $!"
 878                 if !open(STDOUT, ">&", $outfh);
 879
 880             STDOUT->autoflush (1);
 881
 882             #  redirect STDERR to STDOUT
 883             $fd = fileno (STDERR);
 884             close STDERR;
 885             POSIX::close(2) if $fd != 2;
 886
 887             die "unable to redirect STDERR - $!"
 888                 if !open(STDERR, ">&1");
 889
 890             STDERR->autoflush(1);
 891         };
 892         if (my $err = $@) {
 893             my $msg =  "ERROR: $err";
 894             POSIX::write($psync[1], $msg, length ($msg));
 895             POSIX::close($psync[1]);
 896             POSIX::_exit(1);
 897             kill(-9, $$);
 898         }
 899
 900         # sync with parent (signal that we are ready)
 901         if ($sync) {
 902             print "$upid\n";
 903         } else {
 904             POSIX::write($psync[1], $upid, length ($upid));
 905             POSIX::close($psync[1]);
 906         }
 907
 908         my $readbuf = '';
 909         # sync with parent (wait until parent is ready)
 910         POSIX::read($csync[0], $readbuf, 4096);
 911         die "parent setup error\n" if $readbuf ne 'OK';
 912
 913         if ($self->{type} eq 'ha') {
 914             print "task started by HA resource agent\n";
 915         }
 916         eval { &$function($upid); };
 917         my $err = $@;
 918         if ($err) {
 919             chomp $err;
 920             $err =~ s/\n/ /mg;
 921             syslog('err', $err);
 922             print STDERR "TASK ERROR: $err\n";
 923             POSIX::_exit(-1);
 924         } else {
 925             print STDERR "TASK OK\n";
 926             POSIX::_exit(0);
 927         }
 928         kill(-9, $$);
 929     }
 930
 931     # parent
 932
 933     POSIX::close ($psync[1]);
 934     POSIX::close ($csync[0]);
 935
 936     my $readbuf = '';
 937     # sync with child (wait until child starts)
 938     POSIX::read($psync[0], $readbuf, 4096);
 939
 940     if (!$sync) {
 941         POSIX::close($psync[0]);
 942         &$register_worker($cpid, $user, $upid);
 943     } else {
 944         chomp $readbuf;
 945     }
 946
 947     eval {
 948         die "got no worker upid - start worker failed\n" if !$readbuf;
 949
 950         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
 951             die "starting worker failed: $1\n";
 952         }
 953
 954         if ($readbuf ne $upid) {
 955             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
 956         }
 957
 958         if ($sync) {
 959             $outfh = PVE::Tools::upid_open($upid);
 960         }
 961     };
 962     my $err = $@;
 963
 964     if (!$err) {
 965         my $msg = 'OK';
 966         POSIX::write($csync[1], $msg, length ($msg));
 967         POSIX::close($csync[1]);
 968
 969     } else {
 970         POSIX::close($csync[1]);
 971         kill(-9, $cpid); # make sure it gets killed
 972         die $err;
 973     }
 974
 975     PVE::Cluster::log_msg('info', $user, "starting task $upid");
 976
 977     my $tlist = active_workers($upid, $sync);
 978     PVE::Cluster::broadcast_tasklist($tlist);
 979
 980     my $res = 0;
 981
 982     if ($sync) {
 983         my $count;
 984         my $outbuf = '';
 985         my $int_count = 0;
 986         eval {
 987             local $SIG{INT} = local $SIG{QUIT} = local $SIG{TERM} = sub {
 988                 # always send signal to all pgrp members
 989                 my $kpid = -$cpid;
 990                 if ($int_count < 3) {
 991                     kill(15, $kpid); # send TERM signal
 992                 } else {
 993                     kill(9, $kpid); # send KILL signal
 994                 }
 995                 $int_count++;
 996             };
 997             local $SIG{PIPE} = sub { die "broken pipe\n"; };
 998
 999             my $select = new IO::Select;
1000             my $fh = IO::Handle->new_from_fd($psync[0], 'r');
1001             $select->add($fh);
1002
1003             while ($select->count) {
1004                 my @handles = $select->can_read(1);
1005                 if (scalar(@handles)) {
1006                     my $count = sysread ($handles[0], $readbuf, 4096);
1007                     if (!defined ($count)) {
1008                         my $err = $!;
1009                         die "sync pipe read error: $err\n";
1010                     }
1011                     last if $count == 0; # eof
1012
1013                     $outbuf .= $readbuf;
1014                     while ($outbuf =~ s/^(([^\010\r\n]*)(\r|\n|(\010)+|\r\n))//s) {
1015                         my $line = $1;
1016                         my $data = $2;
1017                         if ($data =~ m/^TASK OK$/) {
1018                             # skip
1019                         } elsif ($data =~ m/^TASK ERROR: (.+)$/) {
1020                             print STDERR "$1\n";
1021                         } else {
1022                             print $line;
1023                         }
1024                         if ($outfh) {
1025                             print $outfh $line;
1026                             $outfh->flush();
1027                         }
1028                     }
1029                 } else {
1030                     # some commands daemonize without closing stdout
1031                     last if !PVE::ProcFSTools::check_process_running($cpid);
1032                 }
1033             }
1034         };
1035         my $err = $@;
1036
1037         POSIX::close($psync[0]);
1038
1039         if ($outbuf) { # just to be sure
1040             print $outbuf;
1041             if ($outfh) {
1042                 print $outfh $outbuf;
1043             }
1044         }
1045
1046         if ($err) {
1047             $err =~ s/\n/ /mg;
1048             print STDERR "$err\n";
1049             if ($outfh) {
1050                 print $outfh "TASK ERROR: $err\n";
1051             }
1052         }
1053
1054         &$kill_process_group($cpid, $pstart); # make sure it gets killed
1055
1056         close($outfh);
1057
1058         waitpid($cpid, 0);
1059         $res = $?;
1060         &$log_task_result($upid, $user, $res);
1061     }
1062
1063     return wantarray ? ($upid, $res) : $upid;
1064 }
1065
1066 1;