PVE/RPCEnvironment.pm

   1 package PVE::RPCEnvironment;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX ":sys_wait_h";
   6 use IO::File;
   7 use Fcntl qw(:flock);
   8 use PVE::SafeSyslog;
   9 use PVE::Tools;
  10 use PVE::INotify;
  11 use PVE::Cluster;
  12 use PVE::ProcFSTools;
  13 use PVE::AccessControl;
  14
  15 # we use this singleton class to pass RPC related environment values
  16
  17 my $pve_env;
  18
  19 # save $SIG{CHLD} handler implementation.
  20 # simply set $SIG{CHLD} = $worker_reaper;
  21 # and register forked processes with &$register_worker(pid)
  22 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
  23 # has serious side effects, because perls built in system() and open()
  24 # functions can't get the correct exit status of a child. So we cant use
  25 # that (also see perlipc)
  26
  27 my $WORKER_PIDS;
  28
  29 my $log_task_result = sub {
  30     my ($upid, $user, $status) = @_;
  31
  32     my $msg = 'successful';
  33     my $pri = 'info';
  34     if ($status != 0) {
  35         my $ec = $status >> 8;
  36         my $ic = $status & 255;
  37         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
  38         $pri = 'err';
  39     }
  40     my $tlist = active_workers($upid);
  41     PVE::Cluster::broadcast_tasklist($tlist);
  42     my $task;
  43     foreach my $t (@$tlist) {
  44         if ($t->{upid} eq $upid) {
  45             $task = $t;
  46             last;
  47         }
  48     }
  49     if ($task && $task->{status}) {
  50         $msg = $task->{status};
  51     }
  52     PVE::Cluster::log_msg($pri, $user, "end task $upid $msg");
  53 };
  54
  55 my $worker_reaper = sub {
  56     local $!; local $?;
  57     foreach my $pid (keys %$WORKER_PIDS) {
  58         my $waitpid = waitpid ($pid, WNOHANG);
  59         if (defined($waitpid) && ($waitpid == $pid)) {
  60             my $info = $WORKER_PIDS->{$pid};
  61             if ($info && $info->{upid} && $info->{user}) {
  62                 &$log_task_result($info->{upid}, $info->{user}, $?);
  63             }
  64             delete ($WORKER_PIDS->{$pid});
  65         }
  66     }
  67 };
  68
  69 my $register_worker = sub {
  70     my ($pid, $user, $upid) = @_;
  71
  72     return if !$pid;
  73
  74     # do not register if already finished
  75     my $waitpid = waitpid ($pid, WNOHANG);
  76     if (defined($waitpid) && ($waitpid == $pid)) {
  77         delete ($WORKER_PIDS->{$pid});
  78         return;
  79     }
  80
  81     $WORKER_PIDS->{$pid} = {
  82         user => $user,
  83         upid => $upid,
  84     };
  85 };
  86
  87 # ACL cache
  88
  89 my $compile_acl = sub {
  90     my ($self, $user) = @_;
  91
  92     my $res = {};
  93     my $cfg = $self->{user_cfg};
  94
  95     return undef if !$cfg->{roles};
  96
  97     if ($user eq 'root@pam') { # root can do anything
  98         return {'/' => $cfg->{roles}->{'Administrator'}};
  99     }
 100
 101     foreach my $path (sort keys %{$cfg->{acl}}) {
 102         my @ra = PVE::AccessControl::roles($cfg, $user, $path);
 103
 104         my $privs = {};
 105         foreach my $role (@ra) {
 106             if (my $privset = $cfg->{roles}->{$role}) {
 107                 foreach my $p (keys %$privset) {
 108                     $privs->{$p} = 1;
 109                 }
 110             }
 111         }
 112
 113         $res->{$path} = $privs;
 114     }
 115
 116     return $res;
 117 };
 118
 119 sub permissions {
 120     my ($self, $user, $path) = @_;
 121
 122     $user = PVE::AccessControl::verify_username($user, 1);
 123     return {} if !$user;
 124
 125     my $cache = $self->{aclcache};
 126
 127     my $acl = $cache->{$user};
 128
 129     if (!$acl) {
 130         if (!($acl = &$compile_acl($self, $user))) {
 131             return {};
 132         }
 133         $cache->{$user} = $acl;
 134     }
 135
 136     my $perm;
 137
 138     if (!($perm = $acl->{$path})) {
 139         $perm = {};
 140         foreach my $p (sort keys %$acl) {
 141             my $final = ($path eq $p);
 142
 143             next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
 144
 145             $perm = $acl->{$p};
 146         }
 147         $acl->{$path} = $perm;
 148     }
 149
 150     return $perm;
 151 }
 152
 153 sub check {
 154     my ($self, $user, $path, $privs) = @_;
 155
 156     my $perm = $self->permissions($user, $path);
 157
 158     foreach my $priv (@$privs) {
 159         return undef if !$perm->{$priv};
 160     };
 161
 162     return 1;
 163 };
 164
 165 sub user_enabled {
 166     my ($self, $user) = @_;
 167
 168     my $cfg = $self->{user_cfg};
 169     return PVE::AccessControl::user_enabled($cfg, $user);
 170 }
 171
 172 # initialize environment - must be called once at program startup
 173 sub init {
 174     my ($class, $type, %params) = @_;
 175
 176     $class = ref($class) || $class;
 177
 178     die "already initialized" if $pve_env;
 179
 180     die "unknown environment type" if !$type || $type !~ m/^(cli|pub|priv)$/;
 181
 182     $SIG{CHLD} = $worker_reaper;
 183
 184     # environment types
 185     # cli  ... command started fron command line
 186     # pub  ... access from public server (apache)
 187     # priv ... access from private server (pvedaemon)
 188
 189     my $self = {
 190         user_cfg => {},
 191         aclcache => {},
 192         aclversion => undef,
 193         type => $type,
 194     };
 195
 196     bless $self, $class;
 197
 198     foreach my $p (keys %params) {
 199         if ($p eq 'atfork') {
 200             $self->{$p} = $params{$p};
 201         } else {
 202             die "unknown option '$p'";
 203         }
 204     }
 205
 206     $pve_env = $self;
 207
 208     my ($sysname, $nodename) = POSIX::uname();
 209
 210     $nodename =~ s/\..*$//; # strip domain part, if any
 211
 212     $self->{nodename} = $nodename;
 213
 214     return $self;
 215 };
 216
 217 # get the singleton
 218 sub get {
 219
 220     die "not initialized" if !$pve_env;
 221
 222     return $pve_env;
 223 }
 224
 225 # init_request - must be called before each RPC request
 226 sub init_request {
 227     my ($self, %params) = @_;
 228
 229     PVE::Cluster::cfs_update();
 230
 231     my $userconfig; # we use this for regression tests
 232     foreach my $p (keys %params) {
 233         if ($p eq 'userconfig') {
 234             $userconfig = $params{$p};
 235         } else {
 236             die "unknown parameter '$p'";
 237         }
 238     }
 239
 240     eval {
 241         $self->{aclcache} = {};
 242         if ($userconfig) {
 243             my $ucdata = PVE::Tools::file_get_contents($userconfig);
 244             my $cfg = PVE::AccessControl::parse_user_config($userconfig, $ucdata);
 245             $self->{user_cfg} = $cfg;
 246         } else {
 247             my $ucvers = PVE::Cluster::cfs_file_version('user.cfg');
 248             if (!$self->{aclcache} || !defined($self->{aclversion}) ||
 249                 !defined($ucvers) ||  ($ucvers ne $self->{aclversion})) {
 250                 $self->{aclversion} = $ucvers;
 251                 my $cfg = PVE::Cluster::cfs_read_file('user.cfg');
 252                 $self->{user_cfg} = $cfg;
 253             }
 254         }
 255     };
 256     if (my $err = $@) {
 257         $self->{user_cfg} = {};
 258         die "Unable to load access control list: $err";
 259     }
 260 }
 261
 262 sub set_client_ip {
 263     my ($self, $ip) = @_;
 264
 265     $self->{client_ip} = $ip;
 266 }
 267
 268 sub get_client_ip {
 269     my ($self) = @_;
 270
 271     return $self->{client_ip};
 272 }
 273
 274 sub set_result_count {
 275     my ($self, $count) = @_;
 276
 277     $self->{result_count} = $count;
 278 }
 279
 280 sub get_result_count {
 281     my ($self) = @_;
 282
 283     return $self->{result_count};
 284 }
 285
 286 sub set_language {
 287     my ($self, $lang) = @_;
 288
 289     # fixme: initialize I18N
 290
 291     $self->{language} = $lang;
 292 }
 293
 294 sub get_language {
 295     my ($self) = @_;
 296
 297     return $self->{language};
 298 }
 299
 300 sub set_user {
 301     my ($self, $user) = @_;
 302
 303     # fixme: get ACLs
 304
 305     $self->{user} = $user;
 306 }
 307
 308 sub get_user {
 309     my ($self) = @_;
 310
 311     die "user name not set\n" if !$self->{user};
 312
 313     return $self->{user};
 314 }
 315
 316 # read/update list of active workers
 317 # we move all finished tasks to the archive index,
 318 # but keep aktive and most recent task in the active file.
 319 sub active_workers  {
 320     my ($new_upid) = @_;
 321
 322     my $lkfn = "/var/log/pve/tasks/.active.lock";
 323
 324     my $timeout = 10;
 325
 326     my $code = sub {
 327
 328         my $tasklist = PVE::INotify::read_file('active');
 329
 330         my @ta;
 331         my $tlist = [];
 332         my $thash = {}; # only list task once
 333
 334         my $check_task = sub {
 335             my ($task) = @_;
 336
 337             if (PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
 338                 push @$tlist, $task;
 339             } else {
 340                 delete $task->{pid};
 341                 push @ta, $task;
 342             }
 343             delete $task->{pstart};
 344         };
 345
 346         foreach my $task (@$tasklist) {
 347             my $upid = $task->{upid};
 348             next if $thash->{$upid};
 349             $thash->{$upid} = $task;
 350             &$check_task($task);
 351         }
 352
 353         if ($new_upid && !(my $task = $thash->{$new_upid})) {
 354             $task = PVE::Tools::upid_decode($new_upid);
 355             $task->{upid} = $new_upid;
 356             $thash->{$new_upid} = $task;
 357             &$check_task($task);
 358         }
 359
 360
 361         @ta = sort { $b->{starttime} cmp $a->{starttime} } @ta;
 362
 363         my $save = defined($new_upid);
 364
 365         foreach my $task (@ta) {
 366             next if $task->{endtime};
 367             $task->{endtime} = time();
 368             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
 369             $save = 1;
 370         }
 371
 372         my $archive = '';
 373         my @arlist = ();
 374         foreach my $task (@ta) {
 375             if (!$task->{saved}) {
 376                 $archive .= sprintf("$task->{upid} %08X $task->{status}\n", $task->{endtime});
 377                 $save = 1;
 378                 push @arlist, $task;
 379                 $task->{saved} = 1;
 380             }
 381         }
 382
 383         if ($archive) {
 384             my $size = 0;
 385             my $filename = "/var/log/pve/tasks/index";
 386             eval {
 387                 my $fh = IO::File->new($filename, '>>', 0644) ||
 388                     die "unable to open file '$filename' - $!\n";
 389                 PVE::Tools::safe_print($filename, $fh, $archive);
 390                 $size = -s $fh;
 391                 close($fh) ||
 392                     die "unable to close file '$filename' - $!\n";
 393             };
 394             my $err = $@;
 395             if ($err) {
 396                 syslog('err', $err);
 397                 foreach my $task (@arlist) { # mark as not saved
 398                     $task->{saved} = 0;
 399                 }
 400             }
 401             my $maxsize = 50000; # about 1000 entries
 402             if ($size > $maxsize) {
 403                 rename($filename, "$filename.1");
 404             }
 405         }
 406
 407         # we try to reduce the amount of data
 408         # list all running tasks and task and a few others
 409         # try to limit to 25 tasks
 410         my $ctime = time();
 411         my $max = 25 - scalar(@$tlist);
 412         foreach my $task (@ta) {
 413             last if $max <= 0;
 414             push @$tlist, $task;
 415             $max--;
 416         }
 417
 418         PVE::INotify::write_file('active', $tlist) if $save;
 419
 420         return $tlist;
 421     };
 422
 423     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
 424     die $@ if $@;
 425
 426     return $res;
 427 }
 428
 429 my $kill_process_group = sub {
 430     my ($pid, $pstart) = @_;
 431
 432     # send kill to process group (negative pid)
 433     my $kpid = -$pid;
 434
 435     # always send signal to all pgrp members
 436     kill(15, $kpid); # send TERM signal
 437
 438     # give max 5 seconds to shut down
 439     for (my $i = 0; $i < 5; $i++) {
 440         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
 441         sleep (1);
 442     }
 443
 444     # to be sure
 445     kill(9, $kpid);
 446 };
 447
 448 sub check_worker {
 449     my ($upid, $killit) = @_;
 450
 451     my $task = PVE::Tools::upid_decode($upid);
 452
 453     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
 454
 455     return 0 if !$running;
 456
 457     if ($killit) {
 458         &$kill_process_group($task->{pid});
 459         return 0;
 460     }
 461
 462     return 1;
 463 }
 464
 465 # start long running workers
 466 # STDIN is redirected to /dev/null
 467 # STDOUT,STDERR are redirected to the filename returned by upid_decode
 468 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
 469 sub fork_worker {
 470     my ($self, $dtype, $id, $user, $function) = @_;
 471
 472     $dtype = 'unknown' if !defined ($dtype);
 473     $id = '' if !defined ($id);
 474
 475     $user = 'root@pve' if !defined ($user);
 476
 477     my $sync = $self->{type} eq 'cli' ? 1 : 0;
 478
 479     local $SIG{INT} =
 480         local $SIG{QUIT} =
 481         local $SIG{PIPE} =
 482         local $SIG{TERM} = 'IGNORE';
 483
 484     my $starttime = time ();
 485
 486     my @psync = POSIX::pipe();
 487     my @csync = POSIX::pipe();
 488
 489     my $node = $self->{nodename};
 490
 491     my $cpid = fork();
 492     die "unable to fork worker - $!" if !defined($cpid);
 493
 494     my $workerpuid = $cpid ? $cpid : $$;
 495
 496     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
 497         die "unable to read process start time";
 498
 499     my $upid = PVE::Tools::upid_encode ({
 500         node => $node, pid => $workerpuid, pstart => $pstart,
 501         starttime => $starttime, type => $dtype, id => $id, user => $user });
 502
 503     my $outfh;
 504
 505     if (!$cpid) { # child
 506
 507         $0 = "task $upid";
 508
 509         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
 510
 511         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
 512
 513         # set sess/process group - we want to be able to kill the
 514         # whole process group
 515         POSIX::setsid();
 516
 517         POSIX::close ($psync[0]);
 518         POSIX::close ($csync[1]);
 519
 520         $outfh = $sync ? $psync[1] : undef;
 521
 522         eval {
 523             PVE::INotify::inotify_close();
 524
 525             if (my $atfork = $self->{atfork}) {
 526                 &$atfork();
 527             }
 528
 529             # same algorythm as used inside SA
 530             # STDIN = /dev/null
 531             my $fd = fileno (STDIN);
 532             close STDIN;
 533             POSIX::close(0) if $fd != 0;
 534
 535             die "unable to redirect STDIN - $!"
 536                 if !open(STDIN, "</dev/null");
 537
 538             $outfh = PVE::Tools::upid_open($upid) if !$sync;
 539
 540             # redirect STDOUT
 541             $fd = fileno(STDOUT);
 542             close STDOUT;
 543             POSIX::close (1) if $fd != 1;
 544
 545             die "unable to redirect STDOUT - $!"
 546                 if !open(STDOUT, ">&", $outfh);
 547
 548             STDOUT->autoflush (1);
 549
 550             #  redirect STDERR to STDOUT
 551             $fd = fileno (STDERR);
 552             close STDERR;
 553             POSIX::close(2) if $fd != 2;
 554
 555             die "unable to redirect STDERR - $!"
 556                 if !open(STDERR, ">&1");
 557
 558             STDERR->autoflush(1);
 559         };
 560         if (my $err = $@) {
 561             my $msg =  "ERROR: $err";
 562             POSIX::write($psync[1], $msg, length ($msg));
 563             POSIX::close($psync[1]);
 564             POSIX::_exit(1);
 565             kill(-9, $$);
 566         }
 567
 568         # sync with parent (signal that we are ready)
 569         if ($sync) {
 570             print "$upid\n";
 571         } else {
 572             POSIX::write($psync[1], $upid, length ($upid));
 573             POSIX::close($psync[1]);
 574         }
 575
 576         my $readbuf = '';
 577         # sync with parent (wait until parent is ready)
 578         POSIX::read($csync[0], $readbuf, 4096);
 579         die "parent setup error\n" if $readbuf ne 'OK';
 580
 581         eval { &$function($upid); };
 582         my $err = $@;
 583         if ($err) {
 584             chomp $err;
 585             $err =~ s/\n/ /mg;
 586             syslog('err', $err);
 587             print STDERR "TASK ERROR: $err\n";
 588             POSIX::_exit(-1);
 589         } else {
 590             print STDERR "TASK OK\n";
 591             POSIX::_exit(0);
 592         }
 593         kill(-9, $$);
 594     }
 595
 596     # parent
 597
 598     POSIX::close ($psync[1]);
 599     POSIX::close ($csync[0]);
 600
 601     my $readbuf = '';
 602     # sync with child (wait until child starts)
 603     POSIX::read($psync[0], $readbuf, 4096);
 604
 605     if (!$sync) {
 606         POSIX::close($psync[0]);
 607         &$register_worker($cpid, $user, $upid);
 608     } else {
 609         chomp $readbuf;
 610     }
 611
 612     eval {
 613         die "got no worker upid - start worker failed\n" if !$readbuf;
 614
 615         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
 616             die "starting worker failed: $1\n";
 617         }
 618
 619         if ($readbuf ne $upid) {
 620             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
 621         }
 622
 623         if ($sync) {
 624             $outfh = PVE::Tools::upid_open($upid);
 625         }
 626     };
 627     my $err = $@;
 628
 629     if (!$err) {
 630         my $msg = 'OK';
 631         POSIX::write($csync[1], $msg, length ($msg));
 632         POSIX::close($csync[1]);
 633
 634     } else {
 635         POSIX::close($csync[1]);
 636         kill(-9, $cpid); # make sure it gets killed
 637         die $err;
 638     }
 639
 640     PVE::Cluster::log_msg('info', $user, "starting task $upid");
 641
 642     my $tlist = active_workers($upid);
 643     PVE::Cluster::broadcast_tasklist($tlist);
 644
 645     my $res = 0;
 646
 647     if ($sync) {
 648         my $count;
 649         my $outbuf = '';
 650         eval {
 651             local $SIG{INT} =
 652                 local $SIG{QUIT} =
 653                 local $SIG{TERM} = sub { die "got interrupt\n"; };
 654             local $SIG{PIPE} = sub { die "broken pipe\n"; };
 655
 656             while (($count = POSIX::read($psync[0], $readbuf, 4096)) && ($count > 0)) {
 657                 $outbuf .= $readbuf;
 658                 while ($outbuf =~ s/^(([^\010\r\n]*)(\r|\n|(\010)+|\r\n))//s) {
 659                     my $line = $1;
 660                     my $data = $2;
 661                     if ($data =~ m/^TASK OK$/) {
 662                         # skip
 663                     } elsif ($data =~ m/^TASK ERROR: (.+)$/) {
 664                         print STDERR "$1\n";
 665                     } else {
 666                         print $line;
 667                     }
 668                     if ($outfh) {
 669                         print $outfh $line;
 670                         $outfh->flush();
 671                     }
 672                 }
 673             }
 674         };
 675         my $err = $@;
 676
 677         POSIX::close($psync[0]);
 678
 679         if ($outbuf) { # just to be sure
 680             print $outbuf;
 681             if ($outfh) {
 682                 print $outfh $outbuf;
 683             }
 684         }
 685
 686         if ($err) {
 687             $err =~ s/\n/ /mg;
 688             print STDERR "$err\n";
 689             if ($outfh) {
 690                 print $outfh "TASK ERROR: $err\n";
 691             }
 692         }
 693
 694         &$kill_process_group($cpid, $pstart); # make sure it gets killed
 695
 696         close($outfh);
 697
 698         waitpid($cpid, 0);
 699         $res = $?;
 700         &$log_task_result($upid, $user, $res);
 701     }
 702
 703     return wantarray ? ($upid, $res) : $upid;
 704 }
 705
 706 1;