src/PVE/API2/User.pm

   1 package PVE::API2::User;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::Exception qw(raise raise_perm_exc raise_param_exc);
   7 use PVE::Cluster qw (cfs_read_file cfs_write_file);
   8 use PVE::Tools qw(split_list extract_param);
   9 use PVE::JSONSchema qw(get_standard_option register_standard_option);
  10 use PVE::SafeSyslog;
  11
  12 use PVE::AccessControl;
  13 use PVE::Auth::Plugin;
  14 use PVE::TokenConfig;
  15
  16 use PVE::RESTHandler;
  17
  18 use base qw(PVE::RESTHandler);
  19
  20 register_standard_option('user-enable', {
  21     description => "Enable the account (default). You can set this to '0' to disable the account",
  22     type => 'boolean',
  23     optional => 1,
  24     default => 1,
  25 });
  26 register_standard_option('user-expire', {
  27     description => "Account expiration date (seconds since epoch). '0' means no expiration date.",
  28     type => 'integer',
  29     minimum => 0,
  30     optional => 1,
  31 });
  32 register_standard_option('user-firstname', { type => 'string', optional => 1 });
  33 register_standard_option('user-lastname', { type => 'string', optional => 1 });
  34 register_standard_option('user-email', { type => 'string', optional => 1, format => 'email-opt' });
  35 register_standard_option('user-comment', { type => 'string', optional => 1 });
  36 register_standard_option('user-keys', {
  37     description => "Keys for two factor auth (yubico).",
  38     type => 'string',
  39     optional => 1,
  40 });
  41 register_standard_option('group-list', {
  42     type => 'string', format => 'pve-groupid-list',
  43     optional => 1,
  44     completion => \&PVE::AccessControl::complete_group,
  45 });
  46 register_standard_option('token-subid', {
  47     type => 'string',
  48     pattern => $PVE::AccessControl::token_subid_regex,
  49     description => 'User-specific token identifier.',
  50 });
  51 register_standard_option('token-expire', {
  52     description => "API token expiration date (seconds since epoch). '0' means no expiration date.",
  53     type => 'integer',
  54     minimum => 0,
  55     optional => 1,
  56     default => 'same as user',
  57 });
  58 register_standard_option('token-privsep', {
  59     description => "Restrict API token privileges with separate ACLs (default), or give full privileges of corresponding user.",
  60     type => 'boolean',
  61     optional => 1,
  62     default => 1,
  63 });
  64 register_standard_option('token-comment', { type => 'string', optional => 1 });
  65 register_standard_option('token-info', {
  66     type => 'object',
  67     properties => {
  68         expire => get_standard_option('token-expire'),
  69         privsep => get_standard_option('token-privsep'),
  70         comment => get_standard_option('token-comment'),
  71     }
  72 });
  73
  74 my $token_info_extend = sub {
  75     my ($props) = @_;
  76
  77     my $obj = get_standard_option('token-info');
  78     my $base_props = $obj->{properties};
  79     $obj->{properties} = {};
  80
  81     foreach my $prop (keys %$base_props) {
  82         $obj->{properties}->{$prop} = $base_props->{$prop};
  83     }
  84
  85     foreach my $add_prop (keys %$props) {
  86         $obj->{properties}->{$add_prop} = $props->{$add_prop};
  87     }
  88
  89     return $obj;
  90 };
  91
  92 my $extract_user_data = sub {
  93     my ($data, $full) = @_;
  94
  95     my $res = {};
  96
  97     foreach my $prop (qw(enable expire firstname lastname email comment keys)) {
  98         $res->{$prop} = $data->{$prop} if defined($data->{$prop});
  99     }
 100
 101     return $res if !$full;
 102
 103     $res->{groups} = $data->{groups} ? [ keys %{$data->{groups}} ] : [];
 104     $res->{tokens} = $data->{tokens};
 105
 106     return $res;
 107 };
 108
 109 __PACKAGE__->register_method ({
 110     name => 'index',
 111     path => '',
 112     method => 'GET',
 113     description => "User index.",
 114     permissions => {
 115         description => "The returned list is restricted to users where you have 'User.Modify' or 'Sys.Audit' permissions on '/access/groups' or on a group the user belongs too. But it always includes the current (authenticated) user.",
 116         user => 'all',
 117     },
 118     parameters => {
 119         additionalProperties => 0,
 120         properties => {
 121             enabled => {
 122                 type => 'boolean',
 123                 description => "Optional filter for enable property.",
 124                 optional => 1,
 125             },
 126             full => {
 127                 type => 'boolean',
 128                 description => "Include group and token information.",
 129                 optional => 1,
 130                 default => 0,
 131             }
 132         },
 133     },
 134     returns => {
 135         type => 'array',
 136         items => {
 137             type => "object",
 138             properties => {
 139                 userid => get_standard_option('userid-completed'),
 140                 enable => get_standard_option('user-enable'),
 141                 expire => get_standard_option('user-expire'),
 142                 firstname => get_standard_option('user-firstname'),
 143                 lastname => get_standard_option('user-lastname'),
 144                 email => get_standard_option('user-email'),
 145                 comment => get_standard_option('user-comment'),
 146                 keys => get_standard_option('user-keys'),
 147                 groups => get_standard_option('group-list'),
 148                 tokens => {
 149                     type => 'array',
 150                     optional => 1,
 151                     items => $token_info_extend->({
 152                         tokenid => get_standard_option('token-subid'),
 153                     }),
 154                 },
 155                 'realm-type' => {
 156                     type => 'string', format => 'pve-realm',
 157                     description => 'The type of the users realm',
 158                     optional => 1, # it should always be there, but we use conditional code below, so..
 159                 },
 160             },
 161         },
 162         links => [ { rel => 'child', href => "{userid}" } ],
 163     },
 164     code => sub {
 165         my ($param) = @_;
 166
 167         my $rpcenv = PVE::RPCEnvironment::get();
 168         my $usercfg = $rpcenv->{user_cfg};
 169         my $authuser = $rpcenv->get_user();
 170
 171         my $domainscfg = cfs_read_file('domains.cfg');
 172         my $domainids = $domainscfg->{ids};
 173
 174         my $res = [];
 175
 176         my $privs = [ 'User.Modify', 'Sys.Audit' ];
 177         my $canUserMod = $rpcenv->check_any($authuser, "/access/groups", $privs, 1);
 178         my $groups = $rpcenv->filter_groups($authuser, $privs, 1);
 179         my $allowed_users = $rpcenv->group_member_join([keys %$groups]);
 180
 181         foreach my $user (sort keys %{$usercfg->{users}}) {
 182             if (!($canUserMod || $user eq $authuser)) {
 183                 next if !$allowed_users->{$user};
 184             }
 185
 186             my $entry = $extract_user_data->($usercfg->{users}->{$user}, $param->{full});
 187
 188             if (defined($param->{enabled})) {
 189                 next if $entry->{enable} && !$param->{enabled};
 190                 next if !$entry->{enable} && $param->{enabled};
 191             }
 192
 193             $entry->{groups} = join(',', @{$entry->{groups}}) if $entry->{groups};
 194
 195             if (defined(my $tokens = $entry->{tokens})) {
 196                 $entry->{tokens} = [
 197                     map { { tokenid => $_, %{$tokens->{$_}} } } sort keys %$tokens
 198                 ];
 199             }
 200
 201             if ($user =~ /($PVE::Auth::Plugin::realm_regex)$/) {
 202                 my $realm = $1;
 203                 $entry->{'realm-type'} = $domainids->{$realm}->{type} if exists $domainids->{$realm};
 204             }
 205
 206             $entry->{userid} = $user;
 207
 208             push @$res, $entry;
 209         }
 210
 211         return $res;
 212     }});
 213
 214 __PACKAGE__->register_method ({
 215     name => 'create_user',
 216     protected => 1,
 217     path => '',
 218     method => 'POST',
 219     permissions => {
 220         description => "You need 'Realm.AllocateUser' on '/access/realm/<realm>' on the realm of user <userid>, and 'User.Modify' permissions to '/access/groups/<group>' for any group specified (or 'User.Modify' on '/access/groups' if you pass no groups.",
 221         check => [
 222             'and',
 223             [ 'userid-param', 'Realm.AllocateUser'],
 224             [ 'userid-group', ['User.Modify'], groups_param => 1],
 225         ],
 226     },
 227     description => "Create new user.",
 228     parameters => {
 229         additionalProperties => 0,
 230         properties => {
 231             userid => get_standard_option('userid-completed'),
 232             enable => get_standard_option('user-enable'),
 233             expire => get_standard_option('user-expire'),
 234             firstname => get_standard_option('user-firstname'),
 235             lastname => get_standard_option('user-lastname'),
 236             email => get_standard_option('user-email'),
 237             comment => get_standard_option('user-comment'),
 238             keys => get_standard_option('user-keys'),
 239             password => {
 240                 description => "Initial password.",
 241                 type => 'string',
 242                 optional => 1,
 243                 minLength => 5,
 244                 maxLength => 64
 245             },
 246             groups => get_standard_option('group-list'),
 247         },
 248     },
 249     returns => { type => 'null' },
 250     code => sub {
 251         my ($param) = @_;
 252
 253         PVE::AccessControl::lock_user_config(sub {
 254             my ($username, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 255
 256             my $usercfg = cfs_read_file("user.cfg");
 257
 258             # ensure "user exists" check works for case insensitive realms
 259             $username = PVE::AccessControl::lookup_username($username, 1);
 260             die "user '$username' already exists\n" if $usercfg->{users}->{$username};
 261
 262             PVE::AccessControl::domain_set_password($realm, $ruid, $param->{password})
 263                 if defined($param->{password});
 264
 265             my $enable = defined($param->{enable}) ? $param->{enable} : 1;
 266             $usercfg->{users}->{$username} = { enable => $enable };
 267             $usercfg->{users}->{$username}->{expire} = $param->{expire} if $param->{expire};
 268
 269             if ($param->{groups}) {
 270                 foreach my $group (split_list($param->{groups})) {
 271                     if ($usercfg->{groups}->{$group}) {
 272                         PVE::AccessControl::add_user_group($username, $usercfg, $group);
 273                     } else {
 274                         die "no such group '$group'\n";
 275                     }
 276                 }
 277             }
 278
 279             $usercfg->{users}->{$username}->{firstname} = $param->{firstname} if $param->{firstname};
 280             $usercfg->{users}->{$username}->{lastname} = $param->{lastname} if $param->{lastname};
 281             $usercfg->{users}->{$username}->{email} = $param->{email} if $param->{email};
 282             $usercfg->{users}->{$username}->{comment} = $param->{comment} if $param->{comment};
 283             $usercfg->{users}->{$username}->{keys} = $param->{keys} if $param->{keys};
 284
 285             cfs_write_file("user.cfg", $usercfg);
 286         }, "create user failed");
 287
 288         return undef;
 289     }});
 290
 291 __PACKAGE__->register_method ({
 292     name => 'read_user',
 293     path => '{userid}',
 294     method => 'GET',
 295     description => "Get user configuration.",
 296     permissions => {
 297         check => ['userid-group', ['User.Modify', 'Sys.Audit']],
 298     },
 299     parameters => {
 300         additionalProperties => 0,
 301         properties => {
 302             userid => get_standard_option('userid-completed'),
 303         },
 304     },
 305     returns => {
 306         additionalProperties => 0,
 307         properties => {
 308             enable => get_standard_option('user-enable'),
 309             expire => get_standard_option('user-expire'),
 310             firstname => get_standard_option('user-firstname'),
 311             lastname => get_standard_option('user-lastname'),
 312             email => get_standard_option('user-email'),
 313             comment => get_standard_option('user-comment'),
 314             keys => get_standard_option('user-keys'),
 315             groups => {
 316                 type => 'array',
 317                 optional => 1,
 318                 items => {
 319                     type => 'string',
 320                     format => 'pve-groupid',
 321                 },
 322             },
 323             tokens => {
 324                 optional => 1,
 325                 type => 'object',
 326             },
 327         },
 328         type => "object"
 329     },
 330     code => sub {
 331         my ($param) = @_;
 332
 333         my ($username, undef, $domain) = PVE::AccessControl::verify_username($param->{userid});
 334
 335         my $usercfg = cfs_read_file("user.cfg");
 336
 337         my $data = PVE::AccessControl::check_user_exist($usercfg, $username);
 338
 339         return &$extract_user_data($data, 1);
 340     }});
 341
 342 __PACKAGE__->register_method ({
 343     name => 'update_user',
 344     protected => 1,
 345     path => '{userid}',
 346     method => 'PUT',
 347     permissions => {
 348         check => ['userid-group', ['User.Modify'], groups_param => 1 ],
 349     },
 350     description => "Update user configuration.",
 351     parameters => {
 352         additionalProperties => 0,
 353         properties => {
 354             userid => get_standard_option('userid-completed'),
 355             enable => get_standard_option('user-enable'),
 356             expire => get_standard_option('user-expire'),
 357             firstname => get_standard_option('user-firstname'),
 358             lastname => get_standard_option('user-lastname'),
 359             email => get_standard_option('user-email'),
 360             comment => get_standard_option('user-comment'),
 361             keys => get_standard_option('user-keys'),
 362             groups => get_standard_option('group-list'),
 363             append => {
 364                 type => 'boolean',
 365                 optional => 1,
 366                 requires => 'groups',
 367             },
 368         },
 369     },
 370     returns => { type => 'null' },
 371     code => sub {
 372         my ($param) = @_;
 373
 374         my ($username, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 375
 376         PVE::AccessControl::lock_user_config(sub {
 377             my $usercfg = cfs_read_file("user.cfg");
 378
 379             PVE::AccessControl::check_user_exist($usercfg, $username);
 380
 381             $usercfg->{users}->{$username}->{enable} = $param->{enable} if defined($param->{enable});
 382             $usercfg->{users}->{$username}->{expire} = $param->{expire} if defined($param->{expire});
 383
 384             PVE::AccessControl::delete_user_group($username, $usercfg)
 385                 if (!$param->{append} && defined($param->{groups}));
 386
 387             if ($param->{groups}) {
 388                 foreach my $group (split_list($param->{groups})) {
 389                     if ($usercfg->{groups}->{$group}) {
 390                         PVE::AccessControl::add_user_group($username, $usercfg, $group);
 391                     } else {
 392                         die "no such group '$group'\n";
 393                     }
 394                 }
 395             }
 396
 397             $usercfg->{users}->{$username}->{firstname} = $param->{firstname} if defined($param->{firstname});
 398             $usercfg->{users}->{$username}->{lastname} = $param->{lastname} if defined($param->{lastname});
 399             $usercfg->{users}->{$username}->{email} = $param->{email} if defined($param->{email});
 400             $usercfg->{users}->{$username}->{comment} = $param->{comment} if defined($param->{comment});
 401             $usercfg->{users}->{$username}->{keys} = $param->{keys} if defined($param->{keys});
 402
 403             cfs_write_file("user.cfg", $usercfg);
 404         }, "update user failed");
 405
 406         return undef;
 407     }});
 408
 409 __PACKAGE__->register_method ({
 410     name => 'delete_user',
 411     protected => 1,
 412     path => '{userid}',
 413     method => 'DELETE',
 414     description => "Delete user.",
 415     permissions => {
 416         check => [ 'and',
 417             [ 'userid-param', 'Realm.AllocateUser'],
 418             [ 'userid-group', ['User.Modify']],
 419         ],
 420     },
 421     parameters => {
 422         additionalProperties => 0,
 423         properties => {
 424             userid => get_standard_option('userid-completed'),
 425         }
 426     },
 427     returns => { type => 'null' },
 428     code => sub {
 429         my ($param) = @_;
 430
 431         my $rpcenv = PVE::RPCEnvironment::get();
 432         my $authuser = $rpcenv->get_user();
 433
 434         my ($userid, $ruid, $realm) = PVE::AccessControl::verify_username($param->{userid});
 435
 436         PVE::AccessControl::lock_user_config(sub {
 437             my $usercfg = cfs_read_file("user.cfg");
 438
 439             # NOTE: disable the user first (transaction like), so if (e.g.) we fail in the middle of
 440             # TFA deletion the user will be still disabled and not just without TFA protection.
 441             $usercfg->{users}->{$userid}->{enable} = 0;
 442             cfs_write_file("user.cfg", $usercfg);
 443
 444             my $domain_cfg = cfs_read_file('domains.cfg');
 445             if (my $cfg = $domain_cfg->{ids}->{$realm}) {
 446                 my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 447                 $plugin->delete_user($cfg, $realm, $ruid);
 448             }
 449
 450             # Remove user from cache before removing the TFA entry so realms with TFA-enforcement
 451             # know that it's OK to drop any TFA entry in that case.
 452             delete $usercfg->{users}->{$userid};
 453
 454             my $partial_deletion = '';
 455             eval {
 456                 PVE::AccessControl::user_set_tfa($userid, $realm, undef, undef, $usercfg, $domain_cfg);
 457                 $partial_deletion = ' - but deleted related TFA';
 458
 459                 PVE::AccessControl::delete_user_group($userid, $usercfg);
 460                 $partial_deletion .= ', Groups';
 461                 PVE::AccessControl::delete_user_acl($userid, $usercfg);
 462                 $partial_deletion .= ', ACLs';
 463
 464                 cfs_write_file("user.cfg", $usercfg);
 465             };
 466             die "$@$partial_deletion\n" if $@;
 467         }, "delete user failed");
 468
 469         return undef;
 470     }});
 471
 472 __PACKAGE__->register_method ({
 473     name => 'read_user_tfa_type',
 474     path => '{userid}/tfa',
 475     method => 'GET',
 476     protected => 1,
 477     description => "Get user TFA types (Personal and Realm).",
 478     permissions => {
 479         check => [ 'or',
 480             ['userid-param', 'self'],
 481             ['userid-group', ['User.Modify', 'Sys.Audit']],
 482         ],
 483     },
 484     parameters => {
 485         additionalProperties => 0,
 486         properties => {
 487             userid => get_standard_option('userid-completed'),
 488         },
 489     },
 490     returns => {
 491         additionalProperties => 0,
 492         properties => {
 493             realm => {
 494                 type => 'string',
 495                 enum => [qw(oath yubico)],
 496                 description => "The type of TFA the users realm has set, if any.",
 497                 optional => 1,
 498             },
 499             user => {
 500                 type => 'string',
 501                 enum => [qw(oath u2f)],
 502                 description => "The type of TFA the user has set, if any.",
 503                 optional => 1,
 504             },
 505         },
 506         type => "object"
 507     },
 508     code => sub {
 509         my ($param) = @_;
 510
 511         my ($username, undef, $realm) = PVE::AccessControl::verify_username($param->{userid});
 512
 513         my $domain_cfg = cfs_read_file('domains.cfg');
 514         my $realm_cfg = $domain_cfg->{ids}->{$realm};
 515         die "auth domain '$realm' does not exist\n" if !$realm_cfg;
 516
 517         my $realm_tfa = {};
 518         $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_cfg->{tfa}) if $realm_cfg->{tfa};
 519
 520         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
 521         my $tfa = $tfa_cfg->{users}->{$username};
 522
 523         my $res = {};
 524         $res->{realm} = $realm_tfa->{type} if $realm_tfa->{type};
 525         $res->{user} = $tfa->{type} if $tfa->{type};
 526         return $res;
 527     }});
 528
 529 __PACKAGE__->register_method ({
 530     name => 'token_index',
 531     path => '{userid}/token',
 532     method => 'GET',
 533     description => "Get user API tokens.",
 534     permissions => {
 535         check => [
 536             'or',
 537             ['userid-param', 'self'],
 538             ['perm', '/access/users/{userid}', ['User.Modify']],
 539         ],
 540     },
 541     parameters => {
 542         additionalProperties => 0,
 543         properties => {
 544             userid => get_standard_option('userid-completed'),
 545         },
 546     },
 547     returns => {
 548         type => "array",
 549         items => $token_info_extend->({
 550                     tokenid => get_standard_option('token-subid'),
 551         }),
 552         links => [ { rel => 'child', href => "{tokenid}" } ],
 553     },
 554     code => sub {
 555         my ($param) = @_;
 556
 557         my $userid = PVE::AccessControl::verify_username($param->{userid});
 558         my $usercfg = cfs_read_file("user.cfg");
 559
 560         my $user = PVE::AccessControl::check_user_exist($usercfg, $userid);
 561
 562         my $tokens = $user->{tokens} // {};
 563         return [ map { $tokens->{$_}->{tokenid} = $_; $tokens->{$_} } keys %$tokens];
 564     }});
 565
 566 __PACKAGE__->register_method ({
 567     name => 'read_token',
 568     path => '{userid}/token/{tokenid}',
 569     method => 'GET',
 570     description => "Get specific API token information.",
 571     permissions => {
 572         check => [
 573             'or',
 574             ['userid-param', 'self'],
 575             ['perm', '/access/users/{userid}', ['User.Modify']],
 576         ],
 577     },
 578     parameters => {
 579         additionalProperties => 0,
 580         properties => {
 581             userid => get_standard_option('userid-completed'),
 582             tokenid => get_standard_option('token-subid'),
 583         },
 584     },
 585     returns => get_standard_option('token-info'),
 586     code => sub {
 587         my ($param) = @_;
 588
 589         my $userid = PVE::AccessControl::verify_username($param->{userid});
 590         my $tokenid = $param->{tokenid};
 591
 592         my $usercfg = cfs_read_file("user.cfg");
 593
 594         return PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid);
 595     }});
 596
 597 __PACKAGE__->register_method ({
 598     name => 'generate_token',
 599     path => '{userid}/token/{tokenid}',
 600     method => 'POST',
 601     description => "Generate a new API token for a specific user. NOTE: returns API token value, which needs to be stored as it cannot be retrieved afterwards!",
 602     protected => 1,
 603     permissions => {
 604         check => [
 605             'or',
 606             ['userid-param', 'self'],
 607             ['perm', '/access/users/{userid}', ['User.Modify']],
 608         ],
 609     },
 610     parameters => {
 611         additionalProperties => 0,
 612         properties => {
 613             userid => get_standard_option('userid-completed'),
 614             tokenid => get_standard_option('token-subid'),
 615             expire => get_standard_option('token-expire'),
 616             privsep => get_standard_option('token-privsep'),
 617             comment => get_standard_option('token-comment'),
 618         },
 619     },
 620     returns => {
 621         additionalProperties => 0,
 622         type => "object",
 623         properties => {
 624             info => get_standard_option('token-info'),
 625             value => {
 626                 type => 'string',
 627                 description => 'API token value used for authentication.',
 628             },
 629             'full-tokenid' => {
 630                 type => 'string',
 631                 format_description => '<userid>!<tokenid>',
 632                 description => 'The full token id.',
 633             },
 634         },
 635     },
 636     code => sub {
 637         my ($param) = @_;
 638
 639         my $userid = PVE::AccessControl::verify_username(extract_param($param, 'userid'));
 640         my $tokenid = extract_param($param, 'tokenid');
 641
 642         my $usercfg = cfs_read_file("user.cfg");
 643
 644         my $token = PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid, 1);
 645         my ($full_tokenid, $value);
 646
 647         PVE::AccessControl::check_user_exist($usercfg, $userid);
 648         raise_param_exc({ 'tokenid' => 'Token already exists.' }) if defined($token);
 649
 650         my $generate_and_add_token = sub {
 651             $usercfg = cfs_read_file("user.cfg");
 652             PVE::AccessControl::check_user_exist($usercfg, $userid);
 653             die "Token already exists.\n" if defined(PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid, 1));
 654
 655             $full_tokenid = PVE::AccessControl::join_tokenid($userid, $tokenid);
 656             $value = PVE::TokenConfig::generate_token($full_tokenid);
 657
 658             $token = {};
 659             $token->{privsep} = defined($param->{privsep}) ? $param->{privsep} : 1;
 660             $token->{expire} = $param->{expire} if defined($param->{expire});
 661             $token->{comment} = $param->{comment} if $param->{comment};
 662
 663             $usercfg->{users}->{$userid}->{tokens}->{$tokenid} = $token;
 664             cfs_write_file("user.cfg", $usercfg);
 665         };
 666
 667         PVE::AccessControl::lock_user_config($generate_and_add_token, 'generating token failed');
 668
 669         return {
 670             info => $token,
 671             value => $value,
 672             'full-tokenid' => $full_tokenid,
 673         };
 674     }});
 675
 676
 677 __PACKAGE__->register_method ({
 678     name => 'update_token_info',
 679     path => '{userid}/token/{tokenid}',
 680     method => 'PUT',
 681     description => "Update API token for a specific user.",
 682     protected => 1,
 683     permissions => {
 684         check => [
 685             'or',
 686             ['userid-param', 'self'],
 687             ['perm', '/access/users/{userid}', ['User.Modify']],
 688         ],
 689     },
 690     parameters => {
 691         additionalProperties => 0,
 692         properties => {
 693             userid => get_standard_option('userid-completed'),
 694             tokenid => get_standard_option('token-subid'),
 695             expire => get_standard_option('token-expire'),
 696             privsep => get_standard_option('token-privsep'),
 697             comment => get_standard_option('token-comment'),
 698         },
 699     },
 700     returns => get_standard_option('token-info', { description => "Updated token information." }),
 701     code => sub {
 702         my ($param) = @_;
 703
 704         my $userid = PVE::AccessControl::verify_username(extract_param($param, 'userid'));
 705         my $tokenid = extract_param($param, 'tokenid');
 706
 707         my $usercfg = cfs_read_file("user.cfg");
 708         my $token = PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid);
 709
 710         PVE::AccessControl::lock_user_config(sub {
 711             $usercfg = cfs_read_file("user.cfg");
 712             $token = PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid);
 713
 714             my $full_tokenid = PVE::AccessControl::join_tokenid($userid, $tokenid);
 715
 716             $token->{privsep} = $param->{privsep} if defined($param->{privsep});
 717             $token->{expire} = $param->{expire} if defined($param->{expire});
 718             $token->{comment} = $param->{comment} if $param->{comment};
 719
 720             $usercfg->{users}->{$userid}->{tokens}->{$tokenid} = $token;
 721             cfs_write_file("user.cfg", $usercfg);
 722         }, 'updating token info failed');
 723
 724         return $token;
 725     }});
 726
 727
 728 __PACKAGE__->register_method ({
 729     name => 'remove_token',
 730     path => '{userid}/token/{tokenid}',
 731     method => 'DELETE',
 732     description => "Remove API token for a specific user.",
 733     protected => 1,
 734     permissions => {
 735         check => [
 736             'or',
 737             ['userid-param', 'self'],
 738             ['perm', '/access/users/{userid}', ['User.Modify']],
 739         ],
 740     },
 741     parameters => {
 742         additionalProperties => 0,
 743         properties => {
 744             userid => get_standard_option('userid-completed'),
 745             tokenid => get_standard_option('token-subid'),
 746         },
 747     },
 748     returns => { type => 'null' },
 749     code => sub {
 750         my ($param) = @_;
 751
 752         my $userid = PVE::AccessControl::verify_username(extract_param($param, 'userid'));
 753         my $tokenid = extract_param($param, 'tokenid');
 754
 755         my $usercfg = cfs_read_file("user.cfg");
 756         my $token = PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid);
 757
 758         PVE::AccessControl::lock_user_config(sub {
 759             $usercfg = cfs_read_file("user.cfg");
 760
 761             PVE::AccessControl::check_token_exist($usercfg, $userid, $tokenid);
 762
 763             my $full_tokenid = PVE::AccessControl::join_tokenid($userid, $tokenid);
 764             PVE::TokenConfig::delete_token($full_tokenid);
 765             delete $usercfg->{users}->{$userid}->{tokens}->{$tokenid};
 766
 767             cfs_write_file("user.cfg", $usercfg);
 768         }, 'deleting token failed');
 769
 770         return;
 771     }});
 772 1;