src/PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base32;
  11 use MIME::Base64;
  12 use Digest::SHA;
  13 use IO::File;
  14 use File::stat;
  15 use JSON;
  16 use Scalar::Util 'weaken';
  17 use URI::Escape;
  18
  19 use PVE::OTP;
  20 use PVE::Ticket;
  21 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  22 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  23 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  24
  25 use PVE::RS::TFA;
  26
  27 use PVE::Auth::Plugin;
  28 use PVE::Auth::AD;
  29 use PVE::Auth::LDAP;
  30 use PVE::Auth::PVE;
  31 use PVE::Auth::PAM;
  32 use PVE::Auth::OpenId;
  33
  34 # load and initialize all plugins
  35
  36 PVE::Auth::AD->register();
  37 PVE::Auth::LDAP->register();
  38 PVE::Auth::PVE->register();
  39 PVE::Auth::PAM->register();
  40 PVE::Auth::OpenId->register();
  41 PVE::Auth::Plugin->init();
  42
  43 # $authdir must be writable by root only!
  44 my $confdir = "/etc/pve";
  45 my $authdir = "$confdir/priv";
  46
  47 my $pve_www_key_fn = "$confdir/pve-www.key";
  48
  49 my $pve_auth_key_files = {
  50     priv => "$authdir/authkey.key",
  51     pub =>  "$confdir/authkey.pub",
  52     pubold => "$confdir/authkey.pub.old",
  53 };
  54
  55 my $pve_auth_key_cache = {};
  56
  57 my $ticket_lifetime = 3600 * 2; # 2 hours
  58 my $auth_graceperiod = 60 * 5; # 5 minutes
  59 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  60
  61 Crypt::OpenSSL::RSA->import_random_seed();
  62
  63 cfs_register_file('user.cfg', \&parse_user_config, \&write_user_config);
  64 cfs_register_file('priv/tfa.cfg', \&parse_priv_tfa_config, \&write_priv_tfa_config);
  65
  66 sub verify_username {
  67     PVE::Auth::Plugin::verify_username(@_);
  68 }
  69
  70 sub pve_verify_realm {
  71     PVE::Auth::Plugin::pve_verify_realm(@_);
  72 }
  73
  74 # Locking both config files together is only ever allowed in one order:
  75 #  1) tfa config
  76 #  2) user config
  77 # If we permit the other way round, too, we might end up deadlocking!
  78 my $user_config_locked;
  79 sub lock_user_config {
  80     my ($code, $errmsg) = @_;
  81
  82     my $locked = 1;
  83     $user_config_locked = \$locked;
  84     weaken $user_config_locked; # make this scope guard signal safe...
  85
  86     cfs_lock_file("user.cfg", undef, $code);
  87     $user_config_locked = undef;
  88     if (my $err = $@) {
  89         $errmsg ? die "$errmsg: $err" : die $err;
  90     }
  91 }
  92
  93 sub lock_tfa_config {
  94     my ($code, $errmsg) = @_;
  95
  96     die "tfa config lock cannot be acquired while holding user config lock\n"
  97         if ($user_config_locked && $$user_config_locked);
  98
  99     my $res = cfs_lock_file("priv/tfa.cfg", undef, $code);
 100     if (my $err = $@) {
 101         $errmsg ? die "$errmsg: $err" : die $err;
 102     }
 103
 104     return $res;
 105 }
 106
 107 my $cache_read_key = sub {
 108     my ($type) = @_;
 109
 110     my $path = $pve_auth_key_files->{$type};
 111
 112     my $read_key_and_mtime = sub {
 113         my $fh = IO::File->new($path, "r");
 114
 115         return undef if !defined($fh);
 116
 117         my $st = stat($fh);
 118         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
 119
 120         close $fh;
 121
 122         my $key;
 123         if ($type eq 'pub' || $type eq 'pubold') {
 124             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
 125         } elsif ($type eq 'priv') {
 126             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
 127         } else {
 128             die "Invalid authkey type '$type'\n";
 129         }
 130
 131         return { key => $key, mtime => $st->mtime };
 132     };
 133
 134     if (!defined($pve_auth_key_cache->{$type})) {
 135         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 136     } else {
 137         my $st = stat($path);
 138         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 139             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 140         }
 141     }
 142
 143     return $pve_auth_key_cache->{$type};
 144 };
 145
 146 sub get_pubkey {
 147     my ($old) = @_;
 148
 149     my $type = $old ? 'pubold' : 'pub';
 150
 151     my $res = $cache_read_key->($type);
 152     return undef if !defined($res);
 153
 154     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 155 }
 156
 157 sub get_privkey {
 158     my $res = $cache_read_key->('priv');
 159
 160     if (!defined($res) || !check_authkey(1)) {
 161         rotate_authkey();
 162         $res = $cache_read_key->('priv');
 163     }
 164
 165     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 166 }
 167
 168 sub check_authkey {
 169     my ($quiet) = @_;
 170
 171     # skip check if non-quorate, as rotation is not possible anyway
 172     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 173
 174     my ($pub_key, $mtime) = get_pubkey();
 175     if (!$pub_key) {
 176         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 177         return 0;
 178     } else {
 179         my $now = time();
 180         if ($now - $mtime >= $authkey_lifetime) {
 181             warn "auth key pair too old, rotating..\n" if !$quiet;;
 182             return 0;
 183         } elsif ($mtime > $now + $auth_graceperiod) {
 184             # a nodes RTC had a time set in the future during key generation -> ticket
 185             # validity is clamped to 0+5 min grace period until now >= mtime again
 186             my (undef, $old_mtime) = get_pubkey(1);
 187             if ($old_mtime && $mtime >= $old_mtime && $mtime - $old_mtime < $ticket_lifetime) {
 188                 warn "auth key pair generated in the future (key $mtime > host $now),"
 189                     ." but old key still exists and in valid grace period so avoid automatic"
 190                     ." fixup. Cluster time not in sync?\n" if !$quiet;
 191                 return 1;
 192             }
 193             warn "auth key pair generated in the future (key $mtime > host $now), rotating..\n" if !$quiet;
 194             return 0;
 195         } else {
 196             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 197             return 1;
 198         }
 199     }
 200 }
 201
 202 sub rotate_authkey {
 203     return if $authkey_lifetime == 0;
 204
 205     PVE::Cluster::cfs_lock_authkey(undef, sub {
 206         # re-check with lock to avoid double rotation in clusters
 207         return if check_authkey();
 208
 209         my $old = get_pubkey();
 210         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 211
 212         if ($old) {
 213             eval {
 214                 my $pem = $old->get_public_key_x509_string();
 215                 # mtime is used for caching and ticket age range calculation
 216                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 217             };
 218             die "Failed to store old auth key: $@\n" if $@;
 219         }
 220
 221         eval {
 222             my $pem = $new->get_public_key_x509_string();
 223             # mtime is used for caching and ticket age range calculation,
 224             # should be close to that of pubold above
 225             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 226         };
 227         if ($@) {
 228             if ($old) {
 229                 warn "Failed to store new auth key - $@\n";
 230                 warn "Reverting to previous auth key\n";
 231                 eval {
 232                     my $pem = $old->get_public_key_x509_string();
 233                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 234                 };
 235                 die "Failed to restore old auth key: $@\n" if $@;
 236             } else {
 237                 die "Failed to store new auth key - $@\n";
 238             }
 239         }
 240
 241         eval {
 242             my $pem = $new->get_private_key_string();
 243             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 244         };
 245         if ($@) {
 246             warn "Failed to store new auth key - $@\n";
 247             warn "Deleting auth key to force regeneration\n";
 248             unlink $pve_auth_key_files->{pub};
 249             unlink $pve_auth_key_files->{priv};
 250         }
 251     });
 252     die $@ if $@;
 253 }
 254
 255 PVE::JSONSchema::register_standard_option('tokenid', {
 256     description => "API token identifier.",
 257     type => "string",
 258     format => "pve-tokenid",
 259 });
 260
 261 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 262
 263 # username@realm username realm tokenid
 264 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 265
 266 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 267
 268 sub split_tokenid {
 269     my ($tokenid, $noerr) = @_;
 270
 271     if ($tokenid =~ /^${token_full_regex}$/) {
 272         return ($1, $4);
 273     }
 274
 275     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 276
 277     return undef;
 278 }
 279
 280 sub join_tokenid {
 281     my ($username, $tokensubid) = @_;
 282
 283     my $joined = "${username}!${tokensubid}";
 284
 285     return pve_verify_tokenid($joined);
 286 }
 287
 288 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 289 sub pve_verify_tokenid {
 290     my ($tokenid, $noerr) = @_;
 291
 292     if ($tokenid =~ /^${token_full_regex}$/) {
 293         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 294     }
 295
 296     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 297
 298     return undef;
 299 }
 300
 301
 302 my $csrf_prevention_secret;
 303 my $csrf_prevention_secret_legacy;
 304 my $get_csrfr_secret = sub {
 305     if (!$csrf_prevention_secret) {
 306         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 307         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 308         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 309     }
 310     return $csrf_prevention_secret;
 311 };
 312
 313 sub assemble_csrf_prevention_token {
 314     my ($username) = @_;
 315
 316     my $secret =  &$get_csrfr_secret();
 317
 318     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 319 }
 320
 321 sub verify_csrf_prevention_token {
 322     my ($username, $token, $noerr) = @_;
 323
 324     my $secret = $get_csrfr_secret->();
 325
 326     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 327     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 328         my $sig = $2;
 329         if (length($sig) == 27) {
 330             # the legacy secret got populated by above get_csrfr_secret call
 331             $secret = $csrf_prevention_secret_legacy;
 332         }
 333     }
 334
 335     return PVE::Ticket::verify_csrf_prevention_token(
 336         $secret, $username, $token, -$auth_graceperiod, $ticket_lifetime, $noerr);
 337 }
 338
 339 my $get_ticket_age_range = sub {
 340     my ($now, $mtime, $rotated) = @_;
 341
 342     my $key_age = $now - $mtime;
 343     $key_age = 0 if $key_age < 0;
 344
 345     my $min = -$auth_graceperiod;
 346     my $max = $ticket_lifetime;
 347
 348     if ($rotated) {
 349         # ticket creation after rotation is not allowed
 350         $min = $key_age - $auth_graceperiod;
 351     } else {
 352         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 353             if (PVE::Cluster::check_cfs_quorum(1)) {
 354                 # key should have been rotated, clamp range accordingly
 355                 $min = $key_age - $authkey_lifetime;
 356             } else {
 357                 warn "Cluster not quorate - extending auth key lifetime!\n";
 358             }
 359         }
 360
 361         $max = $key_age + $auth_graceperiod if $key_age < $ticket_lifetime;
 362     }
 363
 364     return undef if $min > $ticket_lifetime;
 365     return ($min, $max);
 366 };
 367
 368 sub assemble_ticket : prototype($;$) {
 369     my ($data, $aad) = @_;
 370
 371     my $rsa_priv = get_privkey();
 372
 373     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data, $aad);
 374 }
 375
 376 # Returns the username, "age" and tfa info.
 377 #
 378 # Note that for the new-style outh, tfa info is never set, as it only uses the `/ticket` api call
 379 # via the new 'tfa-challenge' parameter, so this part can go with PVE-8.
 380 #
 381 # New-style auth still uses this function, but sets `$tfa_ticket` to true when validating the tfa
 382 # ticket.
 383 sub verify_ticket : prototype($;$$) {
 384     my ($ticket, $noerr, $tfa_ticket_aad) = @_;
 385
 386     my $now = time();
 387
 388     my $check = sub {
 389         my ($old) = @_;
 390
 391         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 392         return undef if !$rsa_pub;
 393
 394         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 395         return undef if !defined($min);
 396
 397         return PVE::Ticket::verify_rsa_ticket(
 398             $rsa_pub, 'PVE', $ticket, $tfa_ticket_aad, $min, $max, 1);
 399     };
 400
 401     my ($data, $age) = $check->();
 402
 403     # check with old, rotated key if current key failed
 404     ($data, $age) = $check->(1) if !defined($data);
 405
 406     my $auth_failure = sub {
 407         if ($noerr) {
 408             return undef;
 409         } else {
 410             # raise error via undef ticket
 411             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 412         }
 413     };
 414
 415     if (!defined($data)) {
 416         return $auth_failure->();
 417     }
 418
 419     if ($tfa_ticket_aad) {
 420         # We're validating a ticket-call's 'tfa-challenge' parameter, so just return its data.
 421         if ($data =~ /^!tfa!(.*)$/) {
 422             return $1;
 423         }
 424         die "bad ticket\n";
 425     }
 426
 427     my ($username, $tfa_info);
 428     if ($data =~ /^!tfa!(.*)$/) {
 429         # PBS style half-authenticated ticket, contains a json string form of a `TfaChallenge`
 430         # object.
 431         # This type of ticket does not contain the user name.
 432         return { type => 'new', data => $1 };
 433     }
 434     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 435         # Ticket for u2f-users:
 436         ($username, my $challenge) = ($1, $2);
 437         if ($challenge eq 'verified') {
 438             # u2f challenge was completed
 439             $challenge = undef;
 440         } elsif (!wantarray) {
 441             # The caller is not aware there could be an ongoing challenge,
 442             # so we treat this ticket as invalid:
 443             return $auth_failure->();
 444         }
 445         $tfa_info = {
 446             type => 'u2f',
 447             challenge => $challenge,
 448         };
 449     } elsif ($data =~ /^tfa!(.*)$/) {
 450         # TOTP and Yubico don't require a challenge so this is the generic
 451         # 'missing 2nd factor ticket'
 452         $username = $1;
 453         $tfa_info = { type => 'tfa' };
 454     } else {
 455         # Regular ticket (full access)
 456         $username = $data;
 457     }
 458
 459     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 460
 461     return wantarray ? ($username, $age, $tfa_info) : $username;
 462 }
 463
 464 sub verify_token {
 465     my ($api_token) = @_;
 466
 467     die "no API token specified\n" if !$api_token;
 468
 469     my ($tokenid, $value);
 470     if ($api_token =~ /^(.*)=(.*)$/) {
 471         $tokenid = $1;
 472         $value = $2;
 473     } else {
 474         die "no tokenid specified\n";
 475     }
 476
 477     my ($username, $token) = split_tokenid($tokenid);
 478
 479     my $usercfg = cfs_read_file('user.cfg');
 480     check_user_enabled($usercfg, $username);
 481     check_token_exist($usercfg, $username, $token);
 482
 483     my $user = $usercfg->{users}->{$username};
 484     my $token_info = $user->{tokens}->{$token};
 485
 486     my $ctime = time();
 487     die "token expired\n" if $token_info->{expire} && ($token_info->{expire} < $ctime);
 488
 489     die "invalid token value!\n" if !PVE::Cluster::verify_token($tokenid, $value);
 490
 491     return wantarray ? ($tokenid) : $tokenid;
 492 }
 493
 494 my $assemble_short_lived_ticket = sub {
 495     my ($prefix, $username, $path) = @_;
 496
 497     my $rsa_priv = get_privkey();
 498
 499     $path = normalize_path($path);
 500
 501     my $secret_data = "$username:$path";
 502
 503     return PVE::Ticket::assemble_rsa_ticket(
 504         $rsa_priv, $prefix, undef, $secret_data);
 505 };
 506
 507 my $verify_short_lived_ticket = sub {
 508     my ($ticket, $prefix, $username, $path, $noerr) = @_;
 509
 510     $path = normalize_path($path);
 511
 512     my $secret_data = "$username:$path";
 513
 514     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 515     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 516         if ($noerr) {
 517             return undef;
 518         } else {
 519             # raise error via undef ticket
 520             PVE::Ticket::verify_rsa_ticket($rsa_pub, $prefix);
 521         }
 522     }
 523
 524     return PVE::Ticket::verify_rsa_ticket(
 525         $rsa_pub, $prefix, $ticket, $secret_data, -20, 40, $noerr);
 526 };
 527
 528 # VNC tickets
 529 # - they do not contain the username in plain text
 530 # - they are restricted to a specific resource path (example: '/vms/100')
 531 sub assemble_vnc_ticket {
 532     my ($username, $path) = @_;
 533
 534     return $assemble_short_lived_ticket->('PVEVNC', $username, $path);
 535 }
 536
 537 sub verify_vnc_ticket {
 538     my ($ticket, $username, $path, $noerr) = @_;
 539
 540     return $verify_short_lived_ticket->($ticket, 'PVEVNC', $username, $path, $noerr);
 541 }
 542
 543 # Tunnel tickets
 544 # - they do not contain the username in plain text
 545 # - they are restricted to a specific resource path (example: '/vms/100', '/socket/run/qemu-server/123.storage')
 546 sub assemble_tunnel_ticket {
 547     my ($username, $path) = @_;
 548
 549     return $assemble_short_lived_ticket->('PVETUNNEL', $username, $path);
 550 }
 551
 552 sub verify_tunnel_ticket {
 553     my ($ticket, $username, $path, $noerr) = @_;
 554
 555     return $verify_short_lived_ticket->($ticket, 'PVETUNNEL', $username, $path, $noerr);
 556 }
 557
 558 sub assemble_spice_ticket {
 559     my ($username, $vmid, $node) = @_;
 560
 561     my $secret = &$get_csrfr_secret();
 562
 563     return PVE::Ticket::assemble_spice_ticket(
 564         $secret, $username, $vmid, $node);
 565 }
 566
 567 sub verify_spice_connect_url {
 568     my ($connect_str) = @_;
 569
 570     my $secret = &$get_csrfr_secret();
 571
 572     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 573 }
 574
 575 sub read_x509_subject_spice {
 576     my ($filename) = @_;
 577
 578     # read x509 subject
 579     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 580     die "Could not open $filename using OpenSSL\n"
 581         if !$bio;
 582
 583     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 584     Net::SSLeay::BIO_free($bio);
 585
 586     die "Could not parse X509 certificate in $filename\n"
 587         if !$x509;
 588
 589     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 590     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 591     Net::SSLeay::X509_free($x509);
 592
 593     # remote-viewer wants comma as seperator (not '/')
 594     $subject =~ s!^/!!;
 595     $subject =~ s!/(\w+=)!,$1!g;
 596
 597     return $subject;
 598 }
 599
 600 # helper to generate SPICE remote-viewer configuration
 601 sub remote_viewer_config {
 602     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 603
 604     if (!$proxy) {
 605         my $host = `hostname -f` || PVE::INotify::nodename();
 606         chomp $host;
 607         $proxy = $host;
 608     }
 609
 610     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 611
 612     my $filename = "/etc/pve/local/pve-ssl.pem";
 613     my $subject = read_x509_subject_spice($filename);
 614
 615     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 616     $cacert =~ s/\n/\\n/g;
 617
 618     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 619     my $config = {
 620         'secure-attention' => "Ctrl+Alt+Ins",
 621         'toggle-fullscreen' => "Shift+F11",
 622         'release-cursor' => "Ctrl+Alt+R",
 623         type => 'spice',
 624         title => $title,
 625         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 626         proxy => "http://$proxy:3128",
 627         'tls-port' => $port,
 628         'host-subject' => $subject,
 629         ca => $cacert,
 630         password => $ticket,
 631         'delete-this-file' => 1,
 632     };
 633
 634     return ($ticket, $proxyticket, $config);
 635 }
 636
 637 sub check_user_exist {
 638     my ($usercfg, $username, $noerr) = @_;
 639
 640     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 641     return undef if !$username;
 642
 643     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 644
 645     die "no such user ('$username')\n" if !$noerr;
 646
 647     return undef;
 648 }
 649
 650 sub check_user_enabled {
 651     my ($usercfg, $username, $noerr) = @_;
 652
 653     my $data = check_user_exist($usercfg, $username, $noerr);
 654     return undef if !$data;
 655
 656     return 1 if $data->{enable};
 657
 658     die "user '$username' is disabled\n" if !$noerr;
 659
 660     my $ctime = time();
 661     my $expire = $usercfg->{users}->{$username}->{expire};
 662
 663     die "account expired\n" if $expire && ($expire < $ctime);
 664
 665     return undef;
 666 }
 667
 668 sub check_token_exist {
 669     my ($usercfg, $username, $tokenid, $noerr) = @_;
 670
 671     my $user = check_user_exist($usercfg, $username, $noerr);
 672     return undef if !$user;
 673
 674     return $user->{tokens}->{$tokenid}
 675         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 676
 677     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 678
 679     return undef;
 680 }
 681
 682 # deprecated
 683 sub verify_one_time_pw {
 684     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 685
 686     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 687
 688     # fixme: proxy support?
 689     my $proxy;
 690
 691     if ($type eq 'yubico') {
 692         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 693                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 694     } elsif ($type eq 'oath') {
 695         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 696     } else {
 697         die "unknown tfa type '$type'\n";
 698     }
 699 }
 700
 701 # password should be utf8 encoded
 702 # Note: some plugins delay/sleep if auth fails
 703 sub authenticate_user : prototype($$$$;$) {
 704     my ($username, $password, $otp, $new_format, $tfa_challenge) = @_;
 705
 706     die "no username specified\n" if !$username;
 707
 708     my ($ruid, $realm);
 709
 710     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 711
 712     my $usercfg = cfs_read_file('user.cfg');
 713
 714     check_user_enabled($usercfg, $username);
 715
 716     my $domain_cfg = cfs_read_file('domains.cfg');
 717
 718     my $cfg = $domain_cfg->{ids}->{$realm};
 719     die "auth domain '$realm' does not exist\n" if !$cfg;
 720     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 721
 722     if ($tfa_challenge) {
 723         # This is the 2nd factor, use the password for the OTP response.
 724         my $tfa_challenge = authenticate_2nd_new($username, $realm, $password, $tfa_challenge);
 725         return wantarray ? ($username, $tfa_challenge) : $username;
 726     }
 727
 728     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 729
 730     if ($new_format) {
 731         # This is the first factor with an optional immediate 2nd factor for TOTP:
 732         my $tfa_challenge = authenticate_2nd_new($username, $realm, $otp, $tfa_challenge);
 733         return wantarray ? ($username, $tfa_challenge) : $username;
 734     } else {
 735         return authenticate_2nd_old($username, $realm, $otp);
 736     }
 737 }
 738
 739 sub authenticate_2nd_old : prototype($$$) {
 740     my ($username, $realm, $otp) = @_;
 741
 742     my ($type, $tfa_data) = user_get_tfa($username, $realm, 0);
 743     if ($type) {
 744         if ($type eq 'incompatible') {
 745             die "old login api disabled, user has incompatible TFA entries\n";
 746         } elsif ($type eq 'u2f') {
 747             # Note that if the user did not manage to complete the initial u2f registration
 748             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 749             $tfa_data = undef if exists $tfa_data->{challenge};
 750         } elsif (!defined($otp)) {
 751             # The user requires a 2nd factor but has not provided one. Return success but
 752             # don't clear $tfa_data.
 753         } else {
 754             my $keys = $tfa_data->{keys};
 755             my $tfa_cfg = $tfa_data->{config};
 756             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 757             $tfa_data = undef;
 758         }
 759
 760         # Return the type along with the rest:
 761         if ($tfa_data) {
 762             $tfa_data = {
 763                 type => $type,
 764                 data => $tfa_data,
 765             };
 766         }
 767     }
 768
 769     return wantarray ? ($username, $tfa_data) : $username;
 770 }
 771
 772 # Returns a tfa challenge or undef.
 773 sub authenticate_2nd_new : prototype($$$$) {
 774     my ($username, $realm, $otp, $tfa_challenge) = @_;
 775
 776     my $result = lock_tfa_config(sub {
 777         my ($tfa_cfg, $realm_tfa) = user_get_tfa($username, $realm, 1);
 778
 779         if (!defined($tfa_cfg)) {
 780             return undef;
 781         }
 782
 783         my $realm_type = $realm_tfa && $realm_tfa->{type};
 784         $realm_type = 'totp' if $realm_type eq 'oath'; # we used to call it that
 785         # verify realm type unless using recovery keys:
 786         if (defined($realm_type)) {
 787             if ($realm_type eq 'yubico') {
 788                 # Yubico auth will not be supported in rust for now...
 789                 if (!defined($tfa_challenge)) {
 790                     my $challenge = { yubico => JSON::true };
 791                     # Even with yubico auth we do allow recovery keys to be used:
 792                     if (my $recovery = $tfa_cfg->recovery_state($username)) {
 793                         $challenge->{recovery} = $recovery;
 794                     }
 795                     return to_json($challenge);
 796                 }
 797
 798                 if ($otp =~ /^yubico:(.*)$/) {
 799                     $otp = $1;
 800                     # Defer to after unlocking the TFA config:
 801                     return sub {
 802                         authenticate_yubico_new(
 803                             $tfa_cfg, $username, $realm_tfa, $tfa_challenge, $otp,
 804                         );
 805                     };
 806                 }
 807             }
 808
 809             my $response_type;
 810             if (defined($otp)) {
 811                 if ($otp !~ /^([^:]+):/) {
 812                     die "bad otp response\n";
 813                 }
 814                 $response_type = $1;
 815             }
 816
 817             die "realm requires $realm_type authentication\n"
 818                 if $response_type && $response_type ne 'recovery' && $response_type ne $realm_type;
 819         }
 820
 821         configure_u2f_and_wa($tfa_cfg);
 822
 823         my $must_save = 0;
 824         if (defined($tfa_challenge)) {
 825             $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 826             $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 827             $tfa_challenge = undef;
 828         } else {
 829             $tfa_challenge = $tfa_cfg->authentication_challenge($username);
 830             if (defined($otp)) {
 831                 if (defined($tfa_challenge)) {
 832                     $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 833                 } else {
 834                     die "no such challenge\n";
 835                 }
 836             }
 837         }
 838
 839         if ($must_save) {
 840             cfs_write_file('priv/tfa.cfg', $tfa_cfg);
 841         }
 842
 843         return $tfa_challenge;
 844     });
 845
 846     # Yubico auth returns the authentication sub:
 847     if (ref($result) eq 'CODE') {
 848         $result = $result->();
 849     }
 850
 851     return $result;
 852 }
 853
 854 sub authenticate_yubico_new : prototype($$$) {
 855     my ($tfa_cfg, $username, $realm, $tfa_challenge, $otp) = @_;
 856
 857     $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 858     $tfa_challenge = from_json($tfa_challenge);
 859
 860     if (!$tfa_challenge->{yubico}) {
 861         die "no such challenge\n";
 862     }
 863
 864     my $keys = $tfa_cfg->get_yubico_keys($username);
 865     die "no keys configured\n" if !defined($keys) || !length($keys);
 866
 867     authenticate_yubico_do($otp, $keys, $realm);
 868
 869     # return `undef` to clear the tfa challenge.
 870     return undef;
 871 }
 872
 873 sub authenticate_yubico_do : prototype($$$) {
 874     my ($value, $keys, $realm) = @_;
 875
 876     # fixme: proxy support?
 877     my $proxy = undef;
 878
 879     PVE::OTP::yubico_verify_otp($value, $keys, $realm->{url}, $realm->{id}, $realm->{key}, $proxy);
 880 }
 881
 882 sub configure_u2f_and_wa : prototype($) {
 883     my ($tfa_cfg) = @_;
 884
 885     my $rpc_origin;
 886     my $get_origin = sub {
 887         return $rpc_origin if defined($rpc_origin);
 888         my $rpcenv = PVE::RPCEnvironment::get();
 889         if (my $origin = $rpcenv->get_request_host(1)) {
 890             $rpc_origin = "https://$origin";
 891             return $rpc_origin;
 892         }
 893         die "failed to figure out origin\n";
 894     };
 895
 896     my $dc = cfs_read_file('datacenter.cfg');
 897     if (my $u2f = $dc->{u2f}) {
 898         $tfa_cfg->set_u2f_config({
 899             origin => $u2f->{origin} // $get_origin->(),
 900             appid => $u2f->{appid},
 901         });
 902     }
 903     if (my $wa = $dc->{webauthn}) {
 904         $tfa_cfg->set_webauthn_config({
 905             origin => $wa->{origin} // $get_origin->(),
 906             rp => $wa->{rp},
 907             id => $wa->{id},
 908         });
 909     }
 910 }
 911
 912 sub domain_set_password {
 913     my ($realm, $username, $password) = @_;
 914
 915     die "no auth domain specified" if !$realm;
 916
 917     my $domain_cfg = cfs_read_file('domains.cfg');
 918
 919     my $cfg = $domain_cfg->{ids}->{$realm};
 920     die "auth domain '$realm' does not exist\n" if !$cfg;
 921     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 922     $plugin->store_password($cfg, $realm, $username, $password);
 923 }
 924
 925 sub add_user_group {
 926     my ($username, $usercfg, $group) = @_;
 927
 928     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 929     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 930 }
 931
 932 sub delete_user_group {
 933     my ($username, $usercfg) = @_;
 934
 935     foreach my $group (keys %{$usercfg->{groups}}) {
 936
 937         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 938             if $usercfg->{groups}->{$group}->{users}->{$username};
 939     }
 940 }
 941
 942 sub delete_user_acl {
 943     my ($username, $usercfg) = @_;
 944
 945     foreach my $acl (keys %{$usercfg->{acl}}) {
 946
 947         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 948             if $usercfg->{acl}->{$acl}->{users}->{$username};
 949     }
 950 }
 951
 952 sub delete_group_acl {
 953     my ($group, $usercfg) = @_;
 954
 955     foreach my $acl (keys %{$usercfg->{acl}}) {
 956
 957         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 958             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 959     }
 960 }
 961
 962 sub delete_pool_acl {
 963     my ($pool, $usercfg) = @_;
 964
 965     my $path = "/pool/$pool";
 966
 967     delete ($usercfg->{acl}->{$path})
 968 }
 969
 970 # we automatically create some predefined roles by splitting privs
 971 # into 3 groups (per category)
 972 # root: only root is allowed to do that
 973 # admin: an administrator can to that
 974 # user: a normal user/customer can to that
 975 my $privgroups = {
 976     VM => {
 977         root => [],
 978         admin => [
 979             'VM.Config.Disk',
 980             'VM.Config.CPU',
 981             'VM.Config.Memory',
 982             'VM.Config.Network',
 983             'VM.Config.HWType',
 984             'VM.Config.Options', # covers all other things
 985             'VM.Allocate',
 986             'VM.Clone',
 987             'VM.Migrate',
 988             'VM.Monitor',
 989             'VM.Snapshot',
 990             'VM.Snapshot.Rollback',
 991         ],
 992         user => [
 993             'VM.Config.CDROM', # change CDROM media
 994             'VM.Config.Cloudinit',
 995             'VM.Console',
 996             'VM.Backup',
 997             'VM.PowerMgmt',
 998         ],
 999         audit => [
1000             'VM.Audit',
1001         ],
1002     },
1003     Sys => {
1004         root => [
1005             'Sys.PowerMgmt',
1006             'Sys.Modify', # edit/change node settings
1007         ],
1008         admin => [
1009             'Permissions.Modify',
1010             'Sys.Console',
1011             'Sys.Syslog',
1012         ],
1013         user => [],
1014         audit => [
1015             'Sys.Audit',
1016         ],
1017     },
1018     Datastore => {
1019         root => [],
1020         admin => [
1021             'Datastore.Allocate',
1022             'Datastore.AllocateTemplate',
1023         ],
1024         user => [
1025             'Datastore.AllocateSpace',
1026         ],
1027         audit => [
1028             'Datastore.Audit',
1029         ],
1030     },
1031     SDN => {
1032         root => [],
1033         admin => [
1034             'SDN.Allocate',
1035             'SDN.Audit',
1036         ],
1037         audit => [
1038             'SDN.Audit',
1039         ],
1040     },
1041     User => {
1042         root => [
1043             'Realm.Allocate',
1044         ],
1045         admin => [
1046             'User.Modify',
1047             'Group.Allocate', # edit/change group settings
1048             'Realm.AllocateUser',
1049         ],
1050         user => [],
1051         audit => [],
1052     },
1053     Pool => {
1054         root => [],
1055         admin => [
1056             'Pool.Allocate', # create/delete pools
1057         ],
1058         user => [
1059             'Pool.Audit',
1060         ],
1061         audit => [
1062             'Pool.Audit',
1063         ],
1064     },
1065 };
1066
1067 my $valid_privs = {};
1068
1069 my $special_roles = {
1070     'NoAccess' => {}, # no privileges
1071     'Administrator' => $valid_privs, # all privileges
1072 };
1073
1074 sub create_roles {
1075
1076     foreach my $cat (keys %$privgroups) {
1077         my $cd = $privgroups->{$cat};
1078         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
1079                        @{$cd->{user}}, @{$cd->{audit}}) {
1080             $valid_privs->{$p} = 1;
1081         }
1082         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
1083
1084             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
1085             $special_roles->{"PVEAdmin"}->{$p} = 1;
1086         }
1087         if (scalar(@{$cd->{user}})) {
1088             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
1089                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
1090             }
1091         }
1092         foreach my $p (@{$cd->{audit}}) {
1093             $special_roles->{"PVEAuditor"}->{$p} = 1;
1094         }
1095     }
1096
1097     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
1098 };
1099
1100 create_roles();
1101
1102 sub create_priv_properties {
1103     my $properties = {};
1104     foreach my $priv (keys %$valid_privs) {
1105         $properties->{$priv} = {
1106             type => 'boolean',
1107             optional => 1,
1108         };
1109     }
1110     return $properties;
1111 }
1112
1113 sub role_is_special {
1114     my ($role) = @_;
1115     return (exists $special_roles->{$role}) ? 1 : 0;
1116 }
1117
1118 sub add_role_privs {
1119     my ($role, $usercfg, $privs) = @_;
1120
1121     return if !$privs;
1122
1123     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
1124
1125     foreach my $priv (split_list($privs)) {
1126         if (defined ($valid_privs->{$priv})) {
1127             $usercfg->{roles}->{$role}->{$priv} = 1;
1128         } else {
1129             die "invalid privilege '$priv'\n";
1130         }
1131     }
1132 }
1133
1134 sub lookup_username {
1135     my ($username, $noerr) = @_;
1136
1137     $username =~ m!^(${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex})$!;
1138
1139     my $realm = $2;
1140     my $domain_cfg = cfs_read_file("domains.cfg");
1141     my $casesensitive = $domain_cfg->{ids}->{$realm}->{'case-sensitive'} // 1;
1142     my $usercfg = cfs_read_file('user.cfg');
1143
1144     if (!$casesensitive) {
1145         my @matches = grep { lc $username eq lc $_ } (keys %{$usercfg->{users}});
1146
1147         die "ambiguous case insensitive match of username '$username', cannot safely grant access!\n"
1148             if scalar @matches > 1 && !$noerr;
1149
1150         return $matches[0]
1151     }
1152
1153     return $username;
1154 }
1155
1156 sub normalize_path {
1157     my $path = shift;
1158
1159     $path =~ s|/+|/|g;
1160
1161     $path =~ s|/$||;
1162
1163     $path = '/' if !$path;
1164
1165     $path = "/$path" if $path !~ m|^/|;
1166
1167     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
1168
1169     return $path;
1170 }
1171
1172 sub check_path {
1173     my ($path) = @_;
1174     return $path =~ m!^(
1175         /
1176         |/access
1177         |/access/groups
1178         |/access/groups/[[:alnum:]\.\-\_]+
1179         |/access/realm
1180         |/access/realm/[[:alnum:]\.\-\_]+
1181         |/nodes
1182         |/nodes/[[:alnum:]\.\-\_]+
1183         |/pool
1184         |/pool/[[:alnum:]\.\-\_]+
1185         |/sdn
1186         |/sdn/zones/[[:alnum:]\.\-\_]+
1187         |/sdn/vnets/[[:alnum:]\.\-\_]+
1188         |/storage
1189         |/storage/[[:alnum:]\.\-\_]+
1190         |/vms
1191         |/vms/[1-9][0-9]{2,}
1192     )$!xs;
1193 }
1194
1195 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
1196 sub verify_groupname {
1197     my ($groupname, $noerr) = @_;
1198
1199     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1200
1201         die "group name '$groupname' contains invalid characters\n" if !$noerr;
1202
1203         return undef;
1204     }
1205
1206     return $groupname;
1207 }
1208
1209 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
1210 sub verify_rolename {
1211     my ($rolename, $noerr) = @_;
1212
1213     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
1214
1215         die "role name '$rolename' contains invalid characters\n" if !$noerr;
1216
1217         return undef;
1218     }
1219
1220     return $rolename;
1221 }
1222
1223 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
1224 sub verify_poolname {
1225     my ($poolname, $noerr) = @_;
1226
1227     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1228
1229         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
1230
1231         return undef;
1232     }
1233
1234     return $poolname;
1235 }
1236
1237 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
1238 sub verify_privname {
1239     my ($priv, $noerr) = @_;
1240
1241     if (!$valid_privs->{$priv}) {
1242         die "invalid privilege '$priv'\n" if !$noerr;
1243
1244         return undef;
1245     }
1246
1247     return $priv;
1248 }
1249
1250 sub userconfig_force_defaults {
1251     my ($cfg) = @_;
1252
1253     foreach my $r (keys %$special_roles) {
1254         $cfg->{roles}->{$r} = $special_roles->{$r};
1255     }
1256
1257     # add root user if not exists
1258     if (!$cfg->{users}->{'root@pam'}) {
1259         $cfg->{users}->{'root@pam'}->{enable} = 1;
1260     }
1261 }
1262
1263 sub parse_user_config {
1264     my ($filename, $raw) = @_;
1265
1266     my $cfg = {};
1267
1268     userconfig_force_defaults($cfg);
1269
1270     $raw = '' if !defined($raw);
1271     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1272         my $line = $1;
1273         my @data;
1274
1275         foreach my $d (split (/:/, $line)) {
1276             $d =~ s/^\s+//;
1277             $d =~ s/\s+$//;
1278             push @data, $d
1279         }
1280
1281         my $et = shift @data;
1282
1283         if ($et eq 'user') {
1284             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
1285
1286             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1287             if (!$realm) {
1288                 warn "user config - ignore user '$user' - invalid user name\n";
1289                 next;
1290             }
1291
1292             $enable = $enable ? 1 : 0;
1293
1294             $expire = 0 if !$expire;
1295
1296             if ($expire !~ m/^\d+$/) {
1297                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
1298                 next;
1299             }
1300             $expire = int($expire);
1301
1302             #if (!verify_groupname ($group, 1)) {
1303             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
1304             #    next;
1305             #}
1306
1307             $cfg->{users}->{$user} = {
1308                 enable => $enable,
1309                 # group => $group,
1310             };
1311             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
1312             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
1313             $cfg->{users}->{$user}->{email} = $email;
1314             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1315             $cfg->{users}->{$user}->{expire} = $expire;
1316             # keys: allowed yubico key ids or oath secrets (base32 encoded)
1317             $cfg->{users}->{$user}->{keys} = $keys if $keys;
1318
1319             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
1320             #$cfg->{groups}->{$group}->{$user} = 1;
1321
1322         } elsif ($et eq 'group') {
1323             my ($group, $userlist, $comment) = @data;
1324
1325             if (!verify_groupname($group, 1)) {
1326                 warn "user config - ignore group '$group' - invalid characters in group name\n";
1327                 next;
1328             }
1329
1330             # make sure to add the group (even if there are no members)
1331             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
1332
1333             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1334
1335             foreach my $user (split_list($userlist)) {
1336
1337                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1338                     warn "user config - ignore invalid group member '$user'\n";
1339                     next;
1340                 }
1341
1342                 if ($cfg->{users}->{$user}) { # user exists
1343                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1344                 } else {
1345                     warn "user config - ignore invalid group member '$user'\n";
1346                 }
1347                 $cfg->{groups}->{$group}->{users}->{$user} = 1;
1348             }
1349
1350         } elsif ($et eq 'role') {
1351             my ($role, $privlist) = @data;
1352
1353             if (!verify_rolename($role, 1)) {
1354                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1355                 next;
1356             }
1357
1358             # make sure to add the role (even if there are no privileges)
1359             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1360
1361             foreach my $priv (split_list($privlist)) {
1362                 if (defined ($valid_privs->{$priv})) {
1363                     $cfg->{roles}->{$role}->{$priv} = 1;
1364                 } else {
1365                     warn "user config - ignore invalid privilege '$priv'\n";
1366                 }
1367             }
1368
1369         } elsif ($et eq 'acl') {
1370             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1371
1372             $propagate = $propagate ? 1 : 0;
1373
1374             if (my $path = normalize_path($pathtxt)) {
1375                 foreach my $role (split_list($rolelist)) {
1376
1377                     if (!verify_rolename($role, 1)) {
1378                         warn "user config - ignore invalid role name '$role' in acl\n";
1379                         next;
1380                     }
1381
1382                     if (!$cfg->{roles}->{$role}) {
1383                         warn "user config - ignore invalid acl role '$role'\n";
1384                         next;
1385                     }
1386
1387                     foreach my $ug (split_list($uglist)) {
1388                         my ($group) = $ug =~ m/^@(\S+)$/;
1389
1390                         if ($group && verify_groupname($group, 1)) {
1391                             if (!$cfg->{groups}->{$group}) { # group does not exist
1392                                 warn "user config - ignore invalid acl group '$group'\n";
1393                             }
1394                             $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1395                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1396                             if (!$cfg->{users}->{$ug}) { # user does not exist
1397                                 warn "user config - ignore invalid acl member '$ug'\n";
1398                             }
1399                             $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1400                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1401                             if (check_token_exist($cfg, $user, $token, 1)) {
1402                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1403                             } else {
1404                                 warn "user config - ignore invalid acl token '$ug'\n";
1405                             }
1406                         } else {
1407                             warn "user config - invalid user/group '$ug' in acl\n";
1408                         }
1409                     }
1410                 }
1411             } else {
1412                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1413             }
1414         } elsif ($et eq 'pool') {
1415             my ($pool, $comment, $vmlist, $storelist) = @data;
1416
1417             if (!verify_poolname($pool, 1)) {
1418                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1419                 next;
1420             }
1421
1422             # make sure to add the pool (even if there are no members)
1423             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1424
1425             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1426
1427             foreach my $vmid (split_list($vmlist)) {
1428                 if ($vmid !~ m/^\d+$/) {
1429                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1430                     next;
1431                 }
1432                 $vmid = int($vmid);
1433
1434                 if ($cfg->{vms}->{$vmid}) {
1435                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1436                     next;
1437                 }
1438
1439                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1440
1441                 # record vmid ==> pool relation
1442                 $cfg->{vms}->{$vmid} = $pool;
1443             }
1444
1445             foreach my $storeid (split_list($storelist)) {
1446                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1447                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1448                     next;
1449                 }
1450                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1451             }
1452         } elsif ($et eq 'token') {
1453             my ($tokenid, $expire, $privsep, $comment) = @data;
1454
1455             my ($user, $token) = split_tokenid($tokenid, 1);
1456             if (!($user && $token)) {
1457                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1458                 next;
1459             }
1460
1461             $privsep = $privsep ? 1 : 0;
1462
1463             $expire = 0 if !$expire;
1464
1465             if ($expire !~ m/^\d+$/) {
1466                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1467                 next;
1468             }
1469             $expire = int($expire);
1470
1471             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1472                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1473                 my $token_cfg = $user_cfg->{tokens}->{$token};
1474                 $token_cfg->{privsep} = $privsep;
1475                 $token_cfg->{expire} = $expire;
1476                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1477             } else {
1478                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1479             }
1480         } else {
1481             warn "user config - ignore config line: $line\n";
1482         }
1483     }
1484
1485     userconfig_force_defaults($cfg);
1486
1487     return $cfg;
1488 }
1489
1490 sub write_user_config {
1491     my ($filename, $cfg) = @_;
1492
1493     my $data = '';
1494
1495     foreach my $user (sort keys %{$cfg->{users}}) {
1496         my $d = $cfg->{users}->{$user};
1497         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1498         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1499         my $email = $d->{email} || '';
1500         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1501         my $expire = int($d->{expire} || 0);
1502         my $enable = $d->{enable} ? 1 : 0;
1503         my $keys = $d->{keys} ? $d->{keys} : '';
1504         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1505
1506         my $user_tokens = $d->{tokens};
1507         foreach my $token (sort keys %$user_tokens) {
1508             my $td = $user_tokens->{$token};
1509             my $full_tokenid = join_tokenid($user, $token);
1510             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1511             my $expire = int($td->{expire} || 0);
1512             my $privsep = $td->{privsep} ? 1 : 0;
1513             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1514         }
1515     }
1516
1517     $data .= "\n";
1518
1519     foreach my $group (sort keys %{$cfg->{groups}}) {
1520         my $d = $cfg->{groups}->{$group};
1521         my $list = join (',', sort keys %{$d->{users}});
1522         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1523         $data .= "group:$group:$list:$comment:\n";
1524     }
1525
1526     $data .= "\n";
1527
1528     foreach my $pool (sort keys %{$cfg->{pools}}) {
1529         my $d = $cfg->{pools}->{$pool};
1530         my $vmlist = join (',', sort keys %{$d->{vms}});
1531         my $storelist = join (',', sort keys %{$d->{storage}});
1532         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1533         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1534     }
1535
1536     $data .= "\n";
1537
1538     foreach my $role (sort keys %{$cfg->{roles}}) {
1539         next if $special_roles->{$role};
1540
1541         my $d = $cfg->{roles}->{$role};
1542         my $list = join (',', sort keys %$d);
1543         $data .= "role:$role:$list:\n";
1544     }
1545
1546     $data .= "\n";
1547
1548     my $collect_rolelist_members = sub {
1549         my ($acl_members, $result, $prefix, $exclude) = @_;
1550
1551         foreach my $member (keys %$acl_members) {
1552             next if $exclude && $member eq $exclude;
1553
1554             my $l0 = '';
1555             my $l1 = '';
1556             foreach my $role (sort keys %{$acl_members->{$member}}) {
1557                 my $propagate = $acl_members->{$member}->{$role};
1558                 if ($propagate) {
1559                     $l1 .= ',' if $l1;
1560                     $l1 .= $role;
1561                 } else {
1562                     $l0 .= ',' if $l0;
1563                     $l0 .= $role;
1564                 }
1565             }
1566             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1567             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1568         }
1569     };
1570
1571     foreach my $path (sort keys %{$cfg->{acl}}) {
1572         my $d = $cfg->{acl}->{$path};
1573
1574         my $rolelist_members = {};
1575
1576         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1577
1578         # no need to save 'root@pam', it is always 'Administrator'
1579         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1580
1581         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1582
1583         foreach my $propagate (0,1) {
1584             my $filtered = $rolelist_members->{$propagate};
1585             foreach my $rolelist (sort keys %$filtered) {
1586                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1587                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1588             }
1589
1590         }
1591     }
1592
1593     return $data;
1594 }
1595
1596 # Creates a `PVE::RS::TFA` instance from the raw config data.
1597 # Its contained hash will also support the legacy functionality.
1598 sub parse_priv_tfa_config {
1599     my ($filename, $raw) = @_;
1600
1601     $raw = '' if !defined($raw);
1602     my $cfg = PVE::RS::TFA->new($raw);
1603
1604     # Purge invalid users:
1605     foreach my $user ($cfg->users()->@*) {
1606         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1607         if (!$realm) {
1608             warn "user tfa config - ignore user '$user' - invalid user name\n";
1609             $cfg->remove_user($user);
1610         }
1611     }
1612
1613     return $cfg;
1614 }
1615
1616 sub write_priv_tfa_config {
1617     my ($filename, $cfg) = @_;
1618
1619     assert_new_tfa_config_available();
1620
1621     return $cfg->write();
1622 }
1623
1624 sub roles {
1625     my ($cfg, $user, $path) = @_;
1626
1627     # NOTE: we do not consider pools here.
1628     # NOTE: for privsep tokens, this does not filter roles by those that the
1629     # corresponding user has.
1630     # Use $rpcenv->permission() for any actual permission checks!
1631
1632     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1633
1634     if (pve_verify_tokenid($user, 1)) {
1635         my $tokenid = $user;
1636         my ($username, $token) = split_tokenid($tokenid);
1637
1638         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
1639         return () if !$token_info;
1640
1641         my $user_roles = roles($cfg, $username, $path);
1642
1643         # return full user privileges
1644         return $user_roles if !$token_info->{privsep};
1645     }
1646
1647     my $roles = {};
1648
1649     foreach my $p (sort keys %{$cfg->{acl}}) {
1650         my $final = ($path eq $p);
1651
1652         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1653
1654         my $acl = $cfg->{acl}->{$p};
1655
1656         #print "CHECKACL $path $p\n";
1657         #print "ACL $path = " . Dumper ($acl);
1658         if (my $ri = $acl->{tokens}->{$user}) {
1659             my $new;
1660             foreach my $role (keys %$ri) {
1661                 my $propagate = $ri->{$role};
1662                 if ($final || $propagate) {
1663                     #print "APPLY ROLE $p $user $role\n";
1664                     $new = {} if !$new;
1665                     $new->{$role} = $propagate;
1666                 }
1667             }
1668             if ($new) {
1669                 $roles = $new; # overwrite previous settings
1670                 next;
1671             }
1672         }
1673
1674         if (my $ri = $acl->{users}->{$user}) {
1675             my $new;
1676             foreach my $role (keys %$ri) {
1677                 my $propagate = $ri->{$role};
1678                 if ($final || $propagate) {
1679                     #print "APPLY ROLE $p $user $role\n";
1680                     $new = {} if !$new;
1681                     $new->{$role} = $propagate;
1682                 }
1683             }
1684             if ($new) {
1685                 $roles = $new; # overwrite previous settings
1686                 next; # user privs always override group privs
1687             }
1688         }
1689
1690         my $new;
1691         foreach my $g (keys %{$acl->{groups}}) {
1692             next if !$cfg->{groups}->{$g}->{users}->{$user};
1693             if (my $ri = $acl->{groups}->{$g}) {
1694                 foreach my $role (keys %$ri) {
1695                     my $propagate = $ri->{$role};
1696                     if ($final || $propagate) {
1697                         #print "APPLY ROLE $p \@$g $role\n";
1698                         $new = {} if !$new;
1699                         $new->{$role} = $propagate;
1700                     }
1701                 }
1702             }
1703         }
1704         if ($new) {
1705             $roles = $new; # overwrite previous settings
1706             next;
1707         }
1708     }
1709
1710     return { 'NoAccess' => $roles->{NoAccess} } if defined ($roles->{NoAccess});
1711     #return () if defined ($roles->{NoAccess});
1712
1713     #print "permission $user $path = " . Dumper ($roles);
1714
1715     #print "roles $user $path = " . join (',', @ra) . "\n";
1716
1717     return $roles;
1718 }
1719
1720 sub remove_vm_access {
1721     my ($vmid) = @_;
1722     my $delVMaccessFn = sub {
1723         my $usercfg = cfs_read_file("user.cfg");
1724         my $modified;
1725
1726         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1727             delete $usercfg->{acl}->{"/vms/$vmid"};
1728             $modified = 1;
1729         }
1730         if (my $pool = $usercfg->{vms}->{$vmid}) {
1731             if (my $data = $usercfg->{pools}->{$pool}) {
1732                 delete $data->{vms}->{$vmid};
1733                 delete $usercfg->{vms}->{$vmid};
1734                 $modified = 1;
1735             }
1736         }
1737         cfs_write_file("user.cfg", $usercfg) if $modified;
1738     };
1739
1740     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1741 }
1742
1743 sub remove_storage_access {
1744     my ($storeid) = @_;
1745
1746     my $deleteStorageAccessFn = sub {
1747         my $usercfg = cfs_read_file("user.cfg");
1748         my $modified;
1749
1750         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1751             delete $usercfg->{acl}->{"/storage/$storeid"};
1752             $modified = 1;
1753         }
1754         foreach my $pool (keys %{$usercfg->{pools}}) {
1755             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1756             $modified = 1;
1757         }
1758         cfs_write_file("user.cfg", $usercfg) if $modified;
1759     };
1760
1761     lock_user_config($deleteStorageAccessFn,
1762                      "access permissions cleanup for storage $storeid failed");
1763 }
1764
1765 sub add_vm_to_pool {
1766     my ($vmid, $pool) = @_;
1767
1768     my $addVMtoPoolFn = sub {
1769         my $usercfg = cfs_read_file("user.cfg");
1770         if (my $data = $usercfg->{pools}->{$pool}) {
1771             $data->{vms}->{$vmid} = 1;
1772             $usercfg->{vms}->{$vmid} = $pool;
1773             cfs_write_file("user.cfg", $usercfg);
1774         }
1775     };
1776
1777     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1778 }
1779
1780 sub remove_vm_from_pool {
1781     my ($vmid) = @_;
1782
1783     my $delVMfromPoolFn = sub {
1784         my $usercfg = cfs_read_file("user.cfg");
1785         if (my $pool = $usercfg->{vms}->{$vmid}) {
1786             if (my $data = $usercfg->{pools}->{$pool}) {
1787                 delete $data->{vms}->{$vmid};
1788                 delete $usercfg->{vms}->{$vmid};
1789                 cfs_write_file("user.cfg", $usercfg);
1790             }
1791         }
1792     };
1793
1794     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1795 }
1796
1797 my $USER_CONTROLLED_TFA_TYPES = {
1798     u2f => 1,
1799     oath => 1,
1800 };
1801
1802 sub assert_new_tfa_config_available() {
1803     PVE::Cluster::cfs_update();
1804     my $version_info = PVE::Cluster::get_node_kv('version-info');
1805     die "cannot update tfa config, please make sure all cluster nodes are up to date\n"
1806         if !$version_info;
1807     my $members = PVE::Cluster::get_members() or return; # get_members returns undef on no cluster
1808     my $old = '';
1809     foreach my $node (keys $members->%*) {
1810         my $info = $version_info->{$node};
1811         if (!$info) {
1812             $old .= "  cluster node '$node' is too old, did not broadcast its version info\n";
1813             next;
1814         }
1815         $info = from_json($info);
1816         my $ver = $info->{version};
1817         if ($ver !~ /^(\d+\.\d+)-(\d+)/) {
1818             $old .= "  cluster node '$node' provided an invalid version string: '$ver'\n";
1819             next;
1820         }
1821         my ($maj, $rel) = ($1, $2);
1822         if (!($maj > 7.0 || ($maj == 7.0 && $rel >= 15))) {
1823             $old .= "  cluster node '$node' is too old ($ver < 7.0-15)\n";
1824             next;
1825         }
1826     }
1827     die "cannot update tfa config, following nodes are not up to date:\n$old" if length($old);
1828 }
1829
1830 sub user_remove_tfa : prototype($) {
1831     my ($userid) = @_;
1832
1833     assert_new_tfa_config_available();
1834
1835     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1836     $tfa_cfg->remove_user($userid);
1837     cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1838 }
1839
1840 my sub add_old_yubico_keys : prototype($$$) {
1841     my ($userid, $tfa_cfg, $keys) = @_;
1842
1843     my $count = 0;
1844     foreach my $key (split_list($keys)) {
1845         my $description = "<old userconfig key $count>";
1846         ++$count;
1847         $tfa_cfg->add_yubico_entry($userid, $description, $key);
1848     }
1849 }
1850
1851 my sub normalize_totp_secret : prototype($) {
1852     my ($key) = @_;
1853
1854     my $binkey;
1855     # See PVE::OTP::oath_verify_otp:
1856     if ($key =~ /^v2-0x([0-9a-fA-F]+)$/) {
1857         # v2, hex
1858         $binkey = pack('H*', $1);
1859     } elsif ($key =~ /^v2-([A-Z2-7=]+)$/) {
1860         # v2, base32
1861         $binkey = MIME::Base32::decode_rfc3548($1);
1862     } elsif ($key =~ /^[A-Z2-7=]{16}$/) {
1863         $binkey = MIME::Base32::decode_rfc3548($key);
1864     } elsif ($key =~ /^[A-Fa-f0-9]{40}$/) {
1865         $binkey = pack('H*', $key);
1866     } else {
1867         return undef;
1868     }
1869
1870     return MIME::Base32::encode_rfc3548($binkey);
1871 }
1872
1873 my sub add_old_totp_keys : prototype($$$$) {
1874     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1875
1876     my $issuer = 'Proxmox%20VE';
1877     my $account = uri_escape("Old key for $userid");
1878     my $digits = $realm_tfa->{digits} || 6;
1879     my $step = $realm_tfa->{step} || 30;
1880     my $uri = "otpauth://totp/$issuer:$account?digits=$digits&period=$step&algorithm=SHA1&secret=";
1881
1882     my $count = 0;
1883     foreach my $key (split_list($keys)) {
1884         $key = normalize_totp_secret($key);
1885         # and just skip invalid keys:
1886         next if !defined($key);
1887
1888         my $description = "<old userconfig key $count>";
1889         ++$count;
1890         eval { $tfa_cfg->add_totp_entry($userid, $description, $uri . $key) };
1891         warn $@ if $@;
1892     }
1893 }
1894
1895 sub add_old_keys_to_realm_tfa : prototype($$$$) {
1896     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1897
1898     # if there's no realm tfa configured, we don't know what the keys mean, so we just ignore
1899     # them...
1900     return if !$realm_tfa;
1901
1902     my $type = $realm_tfa->{type};
1903     if ($type eq 'oath') {
1904         add_old_totp_keys($userid, $tfa_cfg, $realm_tfa, $keys);
1905     } elsif ($type eq 'yubico') {
1906         add_old_yubico_keys($userid, $tfa_cfg, $keys);
1907     } else {
1908         # invalid keys, we'll just drop them now...
1909     }
1910 }
1911
1912 sub user_get_tfa : prototype($$$) {
1913     my ($username, $realm, $new_format) = @_;
1914
1915     my $user_cfg = cfs_read_file('user.cfg');
1916     my $user = $user_cfg->{users}->{$username}
1917         or die "user '$username' not found\n";
1918
1919     my $keys = $user->{keys};
1920
1921     my $domain_cfg = cfs_read_file('domains.cfg');
1922     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1923     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1924
1925     my $realm_tfa = $realm_cfg->{tfa};
1926     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1927         if $realm_tfa;
1928
1929     if (!$keys) {
1930         return if !$realm_tfa;
1931         die "missing required 2nd keys\n";
1932     }
1933
1934     if ($new_format) {
1935         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1936         if (defined($keys) && $keys !~ /^x(?:!.*)$/) {
1937             add_old_keys_to_realm_tfa($username, $tfa_cfg, $realm_tfa, $keys);
1938         }
1939         return ($tfa_cfg, $realm_tfa);
1940     }
1941
1942     # new style config starts with an 'x' and optionally contains a !<type> suffix
1943     if ($keys !~ /^x(?:!.*)?$/) {
1944         # old style config, find the type via the realm
1945         return if !$realm_tfa;
1946         return ($realm_tfa->{type}, {
1947             keys => $keys,
1948             config => $realm_tfa,
1949         });
1950     } else {
1951         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1952         my $tfa = $tfa_cfg->{users}->{$username};
1953         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1954
1955         if ($realm_tfa) {
1956             # if the realm has a tfa setting we need to verify the type:
1957             die "auth domain '$realm' and user have mismatching TFA settings\n"
1958                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1959         }
1960
1961         return ($tfa->{type}, $tfa->{data});
1962     }
1963 }
1964
1965 # bash completion helpers
1966
1967 register_standard_option('userid-completed',
1968     get_standard_option('userid', { completion => \&complete_username}),
1969 );
1970
1971 sub complete_username {
1972
1973     my $user_cfg = cfs_read_file('user.cfg');
1974
1975     return [ keys %{$user_cfg->{users}} ];
1976 }
1977
1978 sub complete_group {
1979
1980     my $user_cfg = cfs_read_file('user.cfg');
1981
1982     return [ keys %{$user_cfg->{groups}} ];
1983 }
1984
1985 sub complete_realm {
1986
1987     my $domain_cfg = cfs_read_file('domains.cfg');
1988
1989     return [ keys %{$domain_cfg->{ids}} ];
1990 }
1991
1992 1;