src/PVE/AccessControl.pm

   1 package PVE::AccessControl;
   2
   3 use strict;
   4 use warnings;
   5 use Encode;
   6 use Crypt::OpenSSL::Random;
   7 use Crypt::OpenSSL::RSA;
   8 use Net::SSLeay;
   9 use Net::IP;
  10 use MIME::Base32;
  11 use MIME::Base64;
  12 use Digest::SHA;
  13 use IO::File;
  14 use File::stat;
  15 use JSON;
  16 use Scalar::Util 'weaken';
  17 use URI::Escape;
  18
  19 use PVE::OTP;
  20 use PVE::Ticket;
  21 use PVE::Tools qw(run_command lock_file file_get_contents split_list safe_print);
  22 use PVE::Cluster qw(cfs_register_file cfs_read_file cfs_write_file cfs_lock_file);
  23 use PVE::JSONSchema qw(register_standard_option get_standard_option);
  24
  25 use PVE::RS::TFA;
  26
  27 use PVE::Auth::Plugin;
  28 use PVE::Auth::AD;
  29 use PVE::Auth::LDAP;
  30 use PVE::Auth::PVE;
  31 use PVE::Auth::PAM;
  32 use PVE::Auth::OpenId;
  33
  34 # load and initialize all plugins
  35
  36 PVE::Auth::AD->register();
  37 PVE::Auth::LDAP->register();
  38 PVE::Auth::PVE->register();
  39 PVE::Auth::PAM->register();
  40 PVE::Auth::OpenId->register();
  41 PVE::Auth::Plugin->init();
  42
  43 # $authdir must be writable by root only!
  44 my $confdir = "/etc/pve";
  45 my $authdir = "$confdir/priv";
  46
  47 my $pve_www_key_fn = "$confdir/pve-www.key";
  48
  49 my $pve_auth_key_files = {
  50     priv => "$authdir/authkey.key",
  51     pub =>  "$confdir/authkey.pub",
  52     pubold => "$confdir/authkey.pub.old",
  53 };
  54
  55 my $pve_auth_key_cache = {};
  56
  57 my $ticket_lifetime = 3600 * 2; # 2 hours
  58 my $auth_graceperiod = 60 * 5; # 5 minutes
  59 my $authkey_lifetime = 3600 * 24; # rotate every 24 hours
  60
  61 Crypt::OpenSSL::RSA->import_random_seed();
  62
  63 cfs_register_file('user.cfg', \&parse_user_config, \&write_user_config);
  64 cfs_register_file('priv/tfa.cfg', \&parse_priv_tfa_config, \&write_priv_tfa_config);
  65
  66 sub verify_username {
  67     PVE::Auth::Plugin::verify_username(@_);
  68 }
  69
  70 sub pve_verify_realm {
  71     PVE::Auth::Plugin::pve_verify_realm(@_);
  72 }
  73
  74 # Locking both config files together is only ever allowed in one order:
  75 #  1) tfa config
  76 #  2) user config
  77 # If we permit the other way round, too, we might end up deadlocking!
  78 my $user_config_locked;
  79 sub lock_user_config {
  80     my ($code, $errmsg) = @_;
  81
  82     my $locked = 1;
  83     $user_config_locked = \$locked;
  84     weaken $user_config_locked; # make this scope guard signal safe...
  85
  86     cfs_lock_file("user.cfg", undef, $code);
  87     $user_config_locked = undef;
  88     if (my $err = $@) {
  89         $errmsg ? die "$errmsg: $err" : die $err;
  90     }
  91 }
  92
  93 sub lock_tfa_config {
  94     my ($code, $errmsg) = @_;
  95
  96     die "tfa config lock cannot be acquired while holding user config lock\n"
  97         if ($user_config_locked && $$user_config_locked);
  98
  99     my $res = cfs_lock_file("priv/tfa.cfg", undef, $code);
 100     if (my $err = $@) {
 101         $errmsg ? die "$errmsg: $err" : die $err;
 102     }
 103
 104     return $res;
 105 }
 106
 107 my $cache_read_key = sub {
 108     my ($type) = @_;
 109
 110     my $path = $pve_auth_key_files->{$type};
 111
 112     my $read_key_and_mtime = sub {
 113         my $fh = IO::File->new($path, "r");
 114
 115         return undef if !defined($fh);
 116
 117         my $st = stat($fh);
 118         my $pem = PVE::Tools::safe_read_from($fh, 0, 0, $path);
 119
 120         close $fh;
 121
 122         my $key;
 123         if ($type eq 'pub' || $type eq 'pubold') {
 124             $key = eval { Crypt::OpenSSL::RSA->new_public_key($pem); };
 125         } elsif ($type eq 'priv') {
 126             $key = eval { Crypt::OpenSSL::RSA->new_private_key($pem); };
 127         } else {
 128             die "Invalid authkey type '$type'\n";
 129         }
 130
 131         return { key => $key, mtime => $st->mtime };
 132     };
 133
 134     if (!defined($pve_auth_key_cache->{$type})) {
 135         $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 136     } else {
 137         my $st = stat($path);
 138         if (!$st || $st->mtime != $pve_auth_key_cache->{$type}->{mtime}) {
 139             $pve_auth_key_cache->{$type} = $read_key_and_mtime->();
 140         }
 141     }
 142
 143     return $pve_auth_key_cache->{$type};
 144 };
 145
 146 sub get_pubkey {
 147     my ($old) = @_;
 148
 149     my $type = $old ? 'pubold' : 'pub';
 150
 151     my $res = $cache_read_key->($type);
 152     return undef if !defined($res);
 153
 154     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 155 }
 156
 157 sub get_privkey {
 158     my $res = $cache_read_key->('priv');
 159
 160     if (!defined($res) || !check_authkey(1)) {
 161         rotate_authkey();
 162         $res = $cache_read_key->('priv');
 163     }
 164
 165     return wantarray ? ($res->{key}, $res->{mtime}) : $res->{key};
 166 }
 167
 168 sub check_authkey {
 169     my ($quiet) = @_;
 170
 171     # skip check if non-quorate, as rotation is not possible anyway
 172     return 1 if !PVE::Cluster::check_cfs_quorum(1);
 173
 174     my ($pub_key, $mtime) = get_pubkey();
 175     if (!$pub_key) {
 176         warn "auth key pair missing, generating new one..\n"  if !$quiet;
 177         return 0;
 178     } else {
 179         my $now = time();
 180         if ($now - $mtime >= $authkey_lifetime) {
 181             warn "auth key pair too old, rotating..\n" if !$quiet;;
 182             return 0;
 183         } elsif ($mtime > $now + $auth_graceperiod) {
 184             # a nodes RTC had a time set in the future during key generation -> ticket
 185             # validity is clamped to 0+5 min grace period until now >= mtime again
 186             my (undef, $old_mtime) = get_pubkey(1);
 187             if ($old_mtime && $mtime >= $old_mtime && $mtime - $old_mtime < $ticket_lifetime) {
 188                 warn "auth key pair generated in the future (key $mtime > host $now),"
 189                     ." but old key still exists and in valid grace period so avoid automatic"
 190                     ." fixup. Cluster time not in sync?\n" if !$quiet;
 191                 return 1;
 192             }
 193             warn "auth key pair generated in the future (key $mtime > host $now), rotating..\n" if !$quiet;
 194             return 0;
 195         } else {
 196             warn "auth key new enough, skipping rotation\n" if !$quiet;;
 197             return 1;
 198         }
 199     }
 200 }
 201
 202 sub rotate_authkey {
 203     return if $authkey_lifetime == 0;
 204
 205     PVE::Cluster::cfs_lock_authkey(undef, sub {
 206         # re-check with lock to avoid double rotation in clusters
 207         return if check_authkey();
 208
 209         my $old = get_pubkey();
 210         my $new = Crypt::OpenSSL::RSA->generate_key(2048);
 211
 212         if ($old) {
 213             eval {
 214                 my $pem = $old->get_public_key_x509_string();
 215                 # mtime is used for caching and ticket age range calculation
 216                 PVE::Tools::file_set_contents($pve_auth_key_files->{pubold}, $pem);
 217             };
 218             die "Failed to store old auth key: $@\n" if $@;
 219         }
 220
 221         eval {
 222             my $pem = $new->get_public_key_x509_string();
 223             # mtime is used for caching and ticket age range calculation,
 224             # should be close to that of pubold above
 225             PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 226         };
 227         if ($@) {
 228             if ($old) {
 229                 warn "Failed to store new auth key - $@\n";
 230                 warn "Reverting to previous auth key\n";
 231                 eval {
 232                     my $pem = $old->get_public_key_x509_string();
 233                     PVE::Tools::file_set_contents($pve_auth_key_files->{pub}, $pem);
 234                 };
 235                 die "Failed to restore old auth key: $@\n" if $@;
 236             } else {
 237                 die "Failed to store new auth key - $@\n";
 238             }
 239         }
 240
 241         eval {
 242             my $pem = $new->get_private_key_string();
 243             PVE::Tools::file_set_contents($pve_auth_key_files->{priv}, $pem);
 244         };
 245         if ($@) {
 246             warn "Failed to store new auth key - $@\n";
 247             warn "Deleting auth key to force regeneration\n";
 248             unlink $pve_auth_key_files->{pub};
 249             unlink $pve_auth_key_files->{priv};
 250         }
 251     });
 252     die $@ if $@;
 253 }
 254
 255 PVE::JSONSchema::register_standard_option('tokenid', {
 256     description => "API token identifier.",
 257     type => "string",
 258     format => "pve-tokenid",
 259 });
 260
 261 our $token_subid_regex = $PVE::Auth::Plugin::realm_regex;
 262
 263 # username@realm username realm tokenid
 264 our $token_full_regex = qr/((${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex}))!(${token_subid_regex})/;
 265
 266 our $userid_or_token_regex = qr/^$PVE::Auth::Plugin::user_regex\@$PVE::Auth::Plugin::realm_regex(?:!$token_subid_regex)?$/;
 267
 268 sub split_tokenid {
 269     my ($tokenid, $noerr) = @_;
 270
 271     if ($tokenid =~ /^${token_full_regex}$/) {
 272         return ($1, $4);
 273     }
 274
 275     die "'$tokenid' is not a valid token ID - not able to split into user and token parts\n" if !$noerr;
 276
 277     return undef;
 278 }
 279
 280 sub join_tokenid {
 281     my ($username, $tokensubid) = @_;
 282
 283     my $joined = "${username}!${tokensubid}";
 284
 285     return pve_verify_tokenid($joined);
 286 }
 287
 288 PVE::JSONSchema::register_format('pve-tokenid', \&pve_verify_tokenid);
 289 sub pve_verify_tokenid {
 290     my ($tokenid, $noerr) = @_;
 291
 292     if ($tokenid =~ /^${token_full_regex}$/) {
 293         return wantarray ? ($tokenid, $2, $3, $4) : $tokenid;
 294     }
 295
 296     die "value '$tokenid' does not look like a valid token ID\n" if !$noerr;
 297
 298     return undef;
 299 }
 300
 301
 302 my $csrf_prevention_secret;
 303 my $csrf_prevention_secret_legacy;
 304 my $get_csrfr_secret = sub {
 305     if (!$csrf_prevention_secret) {
 306         my $input = PVE::Tools::file_get_contents($pve_www_key_fn);
 307         $csrf_prevention_secret = Digest::SHA::hmac_sha256_base64($input);
 308         $csrf_prevention_secret_legacy = Digest::SHA::sha1_base64($input);
 309     }
 310     return $csrf_prevention_secret;
 311 };
 312
 313 sub assemble_csrf_prevention_token {
 314     my ($username) = @_;
 315
 316     my $secret =  &$get_csrfr_secret();
 317
 318     return PVE::Ticket::assemble_csrf_prevention_token ($secret, $username);
 319 }
 320
 321 sub verify_csrf_prevention_token {
 322     my ($username, $token, $noerr) = @_;
 323
 324     my $secret = $get_csrfr_secret->();
 325
 326     # FIXME: remove with PVE 7 and/or refactor all into PVE::Ticket ?
 327     if ($token =~ m/^([A-Z0-9]{8}):(\S+)$/) {
 328         my $sig = $2;
 329         if (length($sig) == 27) {
 330             # the legacy secret got populated by above get_csrfr_secret call
 331             $secret = $csrf_prevention_secret_legacy;
 332         }
 333     }
 334
 335     return PVE::Ticket::verify_csrf_prevention_token(
 336         $secret, $username, $token, -$auth_graceperiod, $ticket_lifetime, $noerr);
 337 }
 338
 339 my $get_ticket_age_range = sub {
 340     my ($now, $mtime, $rotated) = @_;
 341
 342     my $key_age = $now - $mtime;
 343     $key_age = 0 if $key_age < 0;
 344
 345     my $min = -$auth_graceperiod;
 346     my $max = $ticket_lifetime;
 347
 348     if ($rotated) {
 349         # ticket creation after rotation is not allowed
 350         $min = $key_age - $auth_graceperiod;
 351     } else {
 352         if ($key_age > $authkey_lifetime && $authkey_lifetime > 0) {
 353             if (PVE::Cluster::check_cfs_quorum(1)) {
 354                 # key should have been rotated, clamp range accordingly
 355                 $min = $key_age - $authkey_lifetime;
 356             } else {
 357                 warn "Cluster not quorate - extending auth key lifetime!\n";
 358             }
 359         }
 360
 361         $max = $key_age + $auth_graceperiod if $key_age < $ticket_lifetime;
 362     }
 363
 364     return undef if $min > $ticket_lifetime;
 365     return ($min, $max);
 366 };
 367
 368 sub assemble_ticket : prototype($;$) {
 369     my ($data, $aad) = @_;
 370
 371     my $rsa_priv = get_privkey();
 372
 373     return PVE::Ticket::assemble_rsa_ticket($rsa_priv, 'PVE', $data, $aad);
 374 }
 375
 376 # Returns the username, "age" and tfa info.
 377 #
 378 # Note that for the new-style outh, tfa info is never set, as it only uses the `/ticket` api call
 379 # via the new 'tfa-challenge' parameter, so this part can go with PVE-8.
 380 #
 381 # New-style auth still uses this function, but sets `$tfa_ticket` to true when validating the tfa
 382 # ticket.
 383 sub verify_ticket : prototype($;$$) {
 384     my ($ticket, $noerr, $tfa_ticket_aad) = @_;
 385
 386     my $now = time();
 387
 388     my $check = sub {
 389         my ($old) = @_;
 390
 391         my ($rsa_pub, $rsa_mtime) = get_pubkey($old);
 392         return undef if !$rsa_pub;
 393
 394         my ($min, $max) = $get_ticket_age_range->($now, $rsa_mtime, $old);
 395         return undef if !defined($min);
 396
 397         return PVE::Ticket::verify_rsa_ticket(
 398             $rsa_pub, 'PVE', $ticket, $tfa_ticket_aad, $min, $max, 1);
 399     };
 400
 401     my ($data, $age) = $check->();
 402
 403     # check with old, rotated key if current key failed
 404     ($data, $age) = $check->(1) if !defined($data);
 405
 406     my $auth_failure = sub {
 407         if ($noerr) {
 408             return undef;
 409         } else {
 410             # raise error via undef ticket
 411             PVE::Ticket::verify_rsa_ticket(undef, 'PVE');
 412         }
 413     };
 414
 415     if (!defined($data)) {
 416         return $auth_failure->();
 417     }
 418
 419     if ($tfa_ticket_aad) {
 420         # We're validating a ticket-call's 'tfa-challenge' parameter, so just return its data.
 421         if ($data =~ /^!tfa!(.*)$/) {
 422             return $1;
 423         }
 424         die "bad ticket\n";
 425     }
 426
 427     my ($username, $tfa_info);
 428     if ($data =~ /^!tfa!(.*)$/) {
 429         # PBS style half-authenticated ticket, contains a json string form of a `TfaChallenge`
 430         # object.
 431         # This type of ticket does not contain the user name.
 432         return { type => 'new', data => $1 };
 433     }
 434     if ($data =~ m{^u2f!([^!]+)!([0-9a-zA-Z/.=_\-+]+)$}) {
 435         # Ticket for u2f-users:
 436         ($username, my $challenge) = ($1, $2);
 437         if ($challenge eq 'verified') {
 438             # u2f challenge was completed
 439             $challenge = undef;
 440         } elsif (!wantarray) {
 441             # The caller is not aware there could be an ongoing challenge,
 442             # so we treat this ticket as invalid:
 443             return $auth_failure->();
 444         }
 445         $tfa_info = {
 446             type => 'u2f',
 447             challenge => $challenge,
 448         };
 449     } elsif ($data =~ /^tfa!(.*)$/) {
 450         # TOTP and Yubico don't require a challenge so this is the generic
 451         # 'missing 2nd factor ticket'
 452         $username = $1;
 453         $tfa_info = { type => 'tfa' };
 454     } else {
 455         # Regular ticket (full access)
 456         $username = $data;
 457     }
 458
 459     return undef if !PVE::Auth::Plugin::verify_username($username, $noerr);
 460
 461     return wantarray ? ($username, $age, $tfa_info) : $username;
 462 }
 463
 464 sub verify_token {
 465     my ($api_token) = @_;
 466
 467     die "no API token specified\n" if !$api_token;
 468
 469     my ($tokenid, $value);
 470     if ($api_token =~ /^(.*)=(.*)$/) {
 471         $tokenid = $1;
 472         $value = $2;
 473     } else {
 474         die "no tokenid specified\n";
 475     }
 476
 477     my ($username, $token) = split_tokenid($tokenid);
 478
 479     my $usercfg = cfs_read_file('user.cfg');
 480     check_user_enabled($usercfg, $username);
 481     check_token_exist($usercfg, $username, $token);
 482
 483     my $user = $usercfg->{users}->{$username};
 484     my $token_info = $user->{tokens}->{$token};
 485
 486     my $ctime = time();
 487     die "token expired\n" if $token_info->{expire} && ($token_info->{expire} < $ctime);
 488
 489     die "invalid token value!\n" if !PVE::Cluster::verify_token($tokenid, $value);
 490
 491     return wantarray ? ($tokenid) : $tokenid;
 492 }
 493
 494 my $assemble_short_lived_ticket = sub {
 495     my ($prefix, $username, $path) = @_;
 496
 497     my $rsa_priv = get_privkey();
 498
 499     $path = normalize_path($path);
 500
 501     my $secret_data = "$username:$path";
 502
 503     return PVE::Ticket::assemble_rsa_ticket(
 504         $rsa_priv, $prefix, undef, $secret_data);
 505 };
 506
 507 my $verify_short_lived_ticket = sub {
 508     my ($ticket, $prefix, $username, $path, $noerr) = @_;
 509
 510     $path = normalize_path($path);
 511
 512     my $secret_data = "$username:$path";
 513
 514     my ($rsa_pub, $rsa_mtime) = get_pubkey();
 515     if (!$rsa_pub || (time() - $rsa_mtime > $authkey_lifetime && $authkey_lifetime > 0)) {
 516         if ($noerr) {
 517             return undef;
 518         } else {
 519             # raise error via undef ticket
 520             PVE::Ticket::verify_rsa_ticket($rsa_pub, $prefix);
 521         }
 522     }
 523
 524     return PVE::Ticket::verify_rsa_ticket(
 525         $rsa_pub, $prefix, $ticket, $secret_data, -20, 40, $noerr);
 526 };
 527
 528 # VNC tickets
 529 # - they do not contain the username in plain text
 530 # - they are restricted to a specific resource path (example: '/vms/100')
 531 sub assemble_vnc_ticket {
 532     my ($username, $path) = @_;
 533
 534     return $assemble_short_lived_ticket->('PVEVNC', $username, $path);
 535 }
 536
 537 sub verify_vnc_ticket {
 538     my ($ticket, $username, $path, $noerr) = @_;
 539
 540     return $verify_short_lived_ticket->($ticket, 'PVEVNC', $username, $path, $noerr);
 541 }
 542
 543 # Tunnel tickets
 544 # - they do not contain the username in plain text
 545 # - they are restricted to a specific resource path (example: '/vms/100', '/socket/run/qemu-server/123.storage')
 546 sub assemble_tunnel_ticket {
 547     my ($username, $path) = @_;
 548
 549     return $assemble_short_lived_ticket->('PVETUNNEL', $username, $path);
 550 }
 551
 552 sub verify_tunnel_ticket {
 553     my ($ticket, $username, $path, $noerr) = @_;
 554
 555     return $verify_short_lived_ticket->($ticket, 'PVETUNNEL', $username, $path, $noerr);
 556 }
 557
 558 sub assemble_spice_ticket {
 559     my ($username, $vmid, $node) = @_;
 560
 561     my $secret = &$get_csrfr_secret();
 562
 563     return PVE::Ticket::assemble_spice_ticket(
 564         $secret, $username, $vmid, $node);
 565 }
 566
 567 sub verify_spice_connect_url {
 568     my ($connect_str) = @_;
 569
 570     my $secret = &$get_csrfr_secret();
 571
 572     return PVE::Ticket::verify_spice_connect_url($secret, $connect_str);
 573 }
 574
 575 sub read_x509_subject_spice {
 576     my ($filename) = @_;
 577
 578     # read x509 subject
 579     my $bio = Net::SSLeay::BIO_new_file($filename, 'r');
 580     die "Could not open $filename using OpenSSL\n"
 581         if !$bio;
 582
 583     my $x509 = Net::SSLeay::PEM_read_bio_X509($bio);
 584     Net::SSLeay::BIO_free($bio);
 585
 586     die "Could not parse X509 certificate in $filename\n"
 587         if !$x509;
 588
 589     my $nameobj = Net::SSLeay::X509_get_subject_name($x509);
 590     my $subject = Net::SSLeay::X509_NAME_oneline($nameobj);
 591     Net::SSLeay::X509_free($x509);
 592
 593     # remote-viewer wants comma as seperator (not '/')
 594     $subject =~ s!^/!!;
 595     $subject =~ s!/(\w+=)!,$1!g;
 596
 597     return $subject;
 598 }
 599
 600 # helper to generate SPICE remote-viewer configuration
 601 sub remote_viewer_config {
 602     my ($authuser, $vmid, $node, $proxy, $title, $port) = @_;
 603
 604     if (!$proxy) {
 605         my $host = `hostname -f` || PVE::INotify::nodename();
 606         chomp $host;
 607         $proxy = $host;
 608     }
 609
 610     my ($ticket, $proxyticket) = assemble_spice_ticket($authuser, $vmid, $node);
 611
 612     my $filename = "/etc/pve/local/pve-ssl.pem";
 613     my $subject = read_x509_subject_spice($filename);
 614
 615     my $cacert = PVE::Tools::file_get_contents("/etc/pve/pve-root-ca.pem", 8192);
 616     $cacert =~ s/\n/\\n/g;
 617
 618     $proxy = "[$proxy]" if Net::IP::ip_is_ipv6($proxy);
 619     my $config = {
 620         'secure-attention' => "Ctrl+Alt+Ins",
 621         'toggle-fullscreen' => "Shift+F11",
 622         'release-cursor' => "Ctrl+Alt+R",
 623         type => 'spice',
 624         title => $title,
 625         host => $proxyticket, # this breaks tls hostname verification, so we need to use 'host-subject'
 626         proxy => "http://$proxy:3128",
 627         'tls-port' => $port,
 628         'host-subject' => $subject,
 629         ca => $cacert,
 630         password => $ticket,
 631         'delete-this-file' => 1,
 632     };
 633
 634     return ($ticket, $proxyticket, $config);
 635 }
 636
 637 sub check_user_exist {
 638     my ($usercfg, $username, $noerr) = @_;
 639
 640     $username = PVE::Auth::Plugin::verify_username($username, $noerr);
 641     return undef if !$username;
 642
 643     return $usercfg->{users}->{$username} if $usercfg && $usercfg->{users}->{$username};
 644
 645     die "no such user ('$username')\n" if !$noerr;
 646
 647     return undef;
 648 }
 649
 650 sub check_user_enabled {
 651     my ($usercfg, $username, $noerr) = @_;
 652
 653     my $data = check_user_exist($usercfg, $username, $noerr);
 654     return undef if !$data;
 655
 656     return 1 if $data->{enable};
 657
 658     die "user '$username' is disabled\n" if !$noerr;
 659
 660     my $ctime = time();
 661     my $expire = $usercfg->{users}->{$username}->{expire};
 662
 663     die "account expired\n" if $expire && ($expire < $ctime);
 664
 665     return undef;
 666 }
 667
 668 sub check_token_exist {
 669     my ($usercfg, $username, $tokenid, $noerr) = @_;
 670
 671     my $user = check_user_exist($usercfg, $username, $noerr);
 672     return undef if !$user;
 673
 674     return $user->{tokens}->{$tokenid}
 675         if defined($user->{tokens}) && $user->{tokens}->{$tokenid};
 676
 677     die "no such token '$tokenid' for user '$username'\n" if !$noerr;
 678
 679     return undef;
 680 }
 681
 682 # deprecated
 683 sub verify_one_time_pw {
 684     my ($type, $username, $keys, $tfa_cfg, $otp) = @_;
 685
 686     die "missing one time password for two-factor authentication '$type'\n" if !$otp;
 687
 688     # fixme: proxy support?
 689     my $proxy;
 690
 691     if ($type eq 'yubico') {
 692         PVE::OTP::yubico_verify_otp($otp, $keys, $tfa_cfg->{url},
 693                                     $tfa_cfg->{id}, $tfa_cfg->{key}, $proxy);
 694     } elsif ($type eq 'oath') {
 695         PVE::OTP::oath_verify_otp($otp, $keys, $tfa_cfg->{step}, $tfa_cfg->{digits});
 696     } else {
 697         die "unknown tfa type '$type'\n";
 698     }
 699 }
 700
 701 # password should be utf8 encoded
 702 # Note: some plugins delay/sleep if auth fails
 703 sub authenticate_user : prototype($$$$;$) {
 704     my ($username, $password, $otp, $new_format, $tfa_challenge) = @_;
 705
 706     die "no username specified\n" if !$username;
 707
 708     my ($ruid, $realm);
 709
 710     ($username, $ruid, $realm) = PVE::Auth::Plugin::verify_username($username);
 711
 712     my $usercfg = cfs_read_file('user.cfg');
 713
 714     check_user_enabled($usercfg, $username);
 715
 716     my $domain_cfg = cfs_read_file('domains.cfg');
 717
 718     my $cfg = $domain_cfg->{ids}->{$realm};
 719     die "auth domain '$realm' does not exist\n" if !$cfg;
 720     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 721
 722     if ($tfa_challenge) {
 723         # This is the 2nd factor, use the password for the OTP response.
 724         my $tfa_challenge = authenticate_2nd_new($username, $realm, $password, $tfa_challenge);
 725         return wantarray ? ($username, $tfa_challenge) : $username;
 726     }
 727
 728     $plugin->authenticate_user($cfg, $realm, $ruid, $password);
 729
 730     if ($new_format) {
 731         # This is the first factor with an optional immediate 2nd factor for TOTP:
 732         my $tfa_challenge = authenticate_2nd_new($username, $realm, $otp, $tfa_challenge);
 733         return wantarray ? ($username, $tfa_challenge) : $username;
 734     } else {
 735         return authenticate_2nd_old($username, $realm, $otp);
 736     }
 737 }
 738
 739 sub authenticate_2nd_old : prototype($$$) {
 740     my ($username, $realm, $otp) = @_;
 741
 742     my ($type, $tfa_data) = user_get_tfa($username, $realm, 0);
 743     if ($type) {
 744         if ($type eq 'incompatible') {
 745             die "old login api disabled, user has incompatible TFA entries\n";
 746         } elsif ($type eq 'u2f') {
 747             # Note that if the user did not manage to complete the initial u2f registration
 748             # challenge we have a hash containing a 'challenge' entry in the user's tfa.cfg entry:
 749             $tfa_data = undef if exists $tfa_data->{challenge};
 750         } elsif (!defined($otp)) {
 751             # The user requires a 2nd factor but has not provided one. Return success but
 752             # don't clear $tfa_data.
 753         } else {
 754             my $keys = $tfa_data->{keys};
 755             my $tfa_cfg = $tfa_data->{config};
 756             verify_one_time_pw($type, $username, $keys, $tfa_cfg, $otp);
 757             $tfa_data = undef;
 758         }
 759
 760         # Return the type along with the rest:
 761         if ($tfa_data) {
 762             $tfa_data = {
 763                 type => $type,
 764                 data => $tfa_data,
 765             };
 766         }
 767     }
 768
 769     return wantarray ? ($username, $tfa_data) : $username;
 770 }
 771
 772 # Returns a tfa challenge or undef.
 773 sub authenticate_2nd_new : prototype($$$$) {
 774     my ($username, $realm, $otp, $tfa_challenge) = @_;
 775
 776     my $result = lock_tfa_config(sub {
 777         my ($tfa_cfg, $realm_tfa) = user_get_tfa($username, $realm, 1);
 778
 779         if (!defined($tfa_cfg)) {
 780             return undef;
 781         }
 782
 783         my $realm_type = $realm_tfa && $realm_tfa->{type};
 784         $realm_type = 'totp' if $realm_type eq 'oath'; # we used to call it that
 785         # verify realm type unless using recovery keys:
 786         if (defined($realm_type)) {
 787             if ($realm_type eq 'yubico') {
 788                 # Yubico auth will not be supported in rust for now...
 789                 if (!defined($tfa_challenge)) {
 790                     my $challenge = { yubico => JSON::true };
 791                     # Even with yubico auth we do allow recovery keys to be used:
 792                     if (my $recovery = $tfa_cfg->recovery_state($username)) {
 793                         $challenge->{recovery} = $recovery;
 794                     }
 795                     return to_json($challenge);
 796                 }
 797
 798                 if ($otp =~ /^yubico:(.*)$/) {
 799                     $otp = $1;
 800                     # Defer to after unlocking the TFA config:
 801                     return sub {
 802                         authenticate_yubico_new(
 803                             $tfa_cfg, $username, $realm_tfa, $tfa_challenge, $otp,
 804                         );
 805                     };
 806                 }
 807             }
 808
 809             my $response_type;
 810             if (defined($otp)) {
 811                 if ($otp !~ /^([^:]+):/) {
 812                     die "bad otp response\n";
 813                 }
 814                 $response_type = $1;
 815             }
 816
 817             die "realm requires $realm_type authentication\n"
 818                 if $response_type && $response_type ne 'recovery' && $response_type ne $realm_type;
 819         }
 820
 821         configure_u2f_and_wa($tfa_cfg);
 822
 823         my $must_save = 0;
 824         if (defined($tfa_challenge)) {
 825             $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 826             $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 827             $tfa_challenge = undef;
 828         } else {
 829             $tfa_challenge = $tfa_cfg->authentication_challenge($username);
 830             if (defined($otp)) {
 831                 if (defined($tfa_challenge)) {
 832                     $must_save = $tfa_cfg->authentication_verify($username, $tfa_challenge, $otp);
 833                 } else {
 834                     die "no such challenge\n";
 835                 }
 836             }
 837         }
 838
 839         if ($must_save) {
 840             cfs_write_file('priv/tfa.cfg', $tfa_cfg);
 841         }
 842
 843         return $tfa_challenge;
 844     });
 845
 846     # Yubico auth returns the authentication sub:
 847     if (ref($result) eq 'CODE') {
 848         $result = $result->();
 849     }
 850
 851     return $result;
 852 }
 853
 854 sub authenticate_yubico_new : prototype($$$) {
 855     my ($tfa_cfg, $username, $realm, $tfa_challenge, $otp) = @_;
 856
 857     $tfa_challenge = verify_ticket($tfa_challenge, 0, $username);
 858     $tfa_challenge = from_json($tfa_challenge);
 859
 860     if (!$tfa_challenge->{yubico}) {
 861         die "no such challenge\n";
 862     }
 863
 864     my $keys = $tfa_cfg->get_yubico_keys($username);
 865     die "no keys configured\n" if !defined($keys) || !length($keys);
 866
 867     authenticate_yubico_do($otp, $keys, $realm);
 868
 869     # return `undef` to clear the tfa challenge.
 870     return undef;
 871 }
 872
 873 sub authenticate_yubico_do : prototype($$$) {
 874     my ($value, $keys, $realm) = @_;
 875
 876     # fixme: proxy support?
 877     my $proxy = undef;
 878
 879     PVE::OTP::yubico_verify_otp($value, $keys, $realm->{url}, $realm->{id}, $realm->{key}, $proxy);
 880 }
 881
 882 sub configure_u2f_and_wa : prototype($) {
 883     my ($tfa_cfg) = @_;
 884
 885     my $dc = cfs_read_file('datacenter.cfg');
 886     if (my $u2f = $dc->{u2f}) {
 887         my $origin = $u2f->{origin};
 888         if (!defined($origin)) {
 889             my $rpcenv = PVE::RPCEnvironment::get();
 890             $origin = $rpcenv->get_request_host(1);
 891             if ($origin) {
 892                 $origin = "https://$origin";
 893             } else {
 894                 die "failed to figure out u2f origin\n";
 895             }
 896         }
 897         $tfa_cfg->set_u2f_config({
 898             origin => $origin,
 899             appid => $u2f->{appid},
 900         });
 901     }
 902     if (my $wa = $dc->{webauthn}) {
 903         $tfa_cfg->set_webauthn_config($wa);
 904     }
 905 }
 906
 907 sub domain_set_password {
 908     my ($realm, $username, $password) = @_;
 909
 910     die "no auth domain specified" if !$realm;
 911
 912     my $domain_cfg = cfs_read_file('domains.cfg');
 913
 914     my $cfg = $domain_cfg->{ids}->{$realm};
 915     die "auth domain '$realm' does not exist\n" if !$cfg;
 916     my $plugin = PVE::Auth::Plugin->lookup($cfg->{type});
 917     $plugin->store_password($cfg, $realm, $username, $password);
 918 }
 919
 920 sub add_user_group {
 921     my ($username, $usercfg, $group) = @_;
 922
 923     $usercfg->{users}->{$username}->{groups}->{$group} = 1;
 924     $usercfg->{groups}->{$group}->{users}->{$username} = 1;
 925 }
 926
 927 sub delete_user_group {
 928     my ($username, $usercfg) = @_;
 929
 930     foreach my $group (keys %{$usercfg->{groups}}) {
 931
 932         delete ($usercfg->{groups}->{$group}->{users}->{$username})
 933             if $usercfg->{groups}->{$group}->{users}->{$username};
 934     }
 935 }
 936
 937 sub delete_user_acl {
 938     my ($username, $usercfg) = @_;
 939
 940     foreach my $acl (keys %{$usercfg->{acl}}) {
 941
 942         delete ($usercfg->{acl}->{$acl}->{users}->{$username})
 943             if $usercfg->{acl}->{$acl}->{users}->{$username};
 944     }
 945 }
 946
 947 sub delete_group_acl {
 948     my ($group, $usercfg) = @_;
 949
 950     foreach my $acl (keys %{$usercfg->{acl}}) {
 951
 952         delete ($usercfg->{acl}->{$acl}->{groups}->{$group})
 953             if $usercfg->{acl}->{$acl}->{groups}->{$group};
 954     }
 955 }
 956
 957 sub delete_pool_acl {
 958     my ($pool, $usercfg) = @_;
 959
 960     my $path = "/pool/$pool";
 961
 962     delete ($usercfg->{acl}->{$path})
 963 }
 964
 965 # we automatically create some predefined roles by splitting privs
 966 # into 3 groups (per category)
 967 # root: only root is allowed to do that
 968 # admin: an administrator can to that
 969 # user: a normal user/customer can to that
 970 my $privgroups = {
 971     VM => {
 972         root => [],
 973         admin => [
 974             'VM.Config.Disk',
 975             'VM.Config.CPU',
 976             'VM.Config.Memory',
 977             'VM.Config.Network',
 978             'VM.Config.HWType',
 979             'VM.Config.Options', # covers all other things
 980             'VM.Allocate',
 981             'VM.Clone',
 982             'VM.Migrate',
 983             'VM.Monitor',
 984             'VM.Snapshot',
 985             'VM.Snapshot.Rollback',
 986         ],
 987         user => [
 988             'VM.Config.CDROM', # change CDROM media
 989             'VM.Config.Cloudinit',
 990             'VM.Console',
 991             'VM.Backup',
 992             'VM.PowerMgmt',
 993         ],
 994         audit => [
 995             'VM.Audit',
 996         ],
 997     },
 998     Sys => {
 999         root => [
1000             'Sys.PowerMgmt',
1001             'Sys.Modify', # edit/change node settings
1002         ],
1003         admin => [
1004             'Permissions.Modify',
1005             'Sys.Console',
1006             'Sys.Syslog',
1007         ],
1008         user => [],
1009         audit => [
1010             'Sys.Audit',
1011         ],
1012     },
1013     Datastore => {
1014         root => [],
1015         admin => [
1016             'Datastore.Allocate',
1017             'Datastore.AllocateTemplate',
1018         ],
1019         user => [
1020             'Datastore.AllocateSpace',
1021         ],
1022         audit => [
1023             'Datastore.Audit',
1024         ],
1025     },
1026     SDN => {
1027         root => [],
1028         admin => [
1029             'SDN.Allocate',
1030             'SDN.Audit',
1031         ],
1032         audit => [
1033             'SDN.Audit',
1034         ],
1035     },
1036     User => {
1037         root => [
1038             'Realm.Allocate',
1039         ],
1040         admin => [
1041             'User.Modify',
1042             'Group.Allocate', # edit/change group settings
1043             'Realm.AllocateUser',
1044         ],
1045         user => [],
1046         audit => [],
1047     },
1048     Pool => {
1049         root => [],
1050         admin => [
1051             'Pool.Allocate', # create/delete pools
1052         ],
1053         user => [
1054             'Pool.Audit',
1055         ],
1056         audit => [
1057             'Pool.Audit',
1058         ],
1059     },
1060 };
1061
1062 my $valid_privs = {};
1063
1064 my $special_roles = {
1065     'NoAccess' => {}, # no privileges
1066     'Administrator' => $valid_privs, # all privileges
1067 };
1068
1069 sub create_roles {
1070
1071     foreach my $cat (keys %$privgroups) {
1072         my $cd = $privgroups->{$cat};
1073         foreach my $p (@{$cd->{root}}, @{$cd->{admin}},
1074                        @{$cd->{user}}, @{$cd->{audit}}) {
1075             $valid_privs->{$p} = 1;
1076         }
1077         foreach my $p (@{$cd->{admin}}, @{$cd->{user}}, @{$cd->{audit}}) {
1078
1079             $special_roles->{"PVE${cat}Admin"}->{$p} = 1;
1080             $special_roles->{"PVEAdmin"}->{$p} = 1;
1081         }
1082         if (scalar(@{$cd->{user}})) {
1083             foreach my $p (@{$cd->{user}}, @{$cd->{audit}}) {
1084                 $special_roles->{"PVE${cat}User"}->{$p} = 1;
1085             }
1086         }
1087         foreach my $p (@{$cd->{audit}}) {
1088             $special_roles->{"PVEAuditor"}->{$p} = 1;
1089         }
1090     }
1091
1092     $special_roles->{"PVETemplateUser"} = { 'VM.Clone' => 1, 'VM.Audit' => 1 };
1093 };
1094
1095 create_roles();
1096
1097 sub create_priv_properties {
1098     my $properties = {};
1099     foreach my $priv (keys %$valid_privs) {
1100         $properties->{$priv} = {
1101             type => 'boolean',
1102             optional => 1,
1103         };
1104     }
1105     return $properties;
1106 }
1107
1108 sub role_is_special {
1109     my ($role) = @_;
1110     return (exists $special_roles->{$role}) ? 1 : 0;
1111 }
1112
1113 sub add_role_privs {
1114     my ($role, $usercfg, $privs) = @_;
1115
1116     return if !$privs;
1117
1118     die "role '$role' does not exist\n" if !$usercfg->{roles}->{$role};
1119
1120     foreach my $priv (split_list($privs)) {
1121         if (defined ($valid_privs->{$priv})) {
1122             $usercfg->{roles}->{$role}->{$priv} = 1;
1123         } else {
1124             die "invalid privilege '$priv'\n";
1125         }
1126     }
1127 }
1128
1129 sub lookup_username {
1130     my ($username, $noerr) = @_;
1131
1132     $username =~ m!^(${PVE::Auth::Plugin::user_regex})\@(${PVE::Auth::Plugin::realm_regex})$!;
1133
1134     my $realm = $2;
1135     my $domain_cfg = cfs_read_file("domains.cfg");
1136     my $casesensitive = $domain_cfg->{ids}->{$realm}->{'case-sensitive'} // 1;
1137     my $usercfg = cfs_read_file('user.cfg');
1138
1139     if (!$casesensitive) {
1140         my @matches = grep { lc $username eq lc $_ } (keys %{$usercfg->{users}});
1141
1142         die "ambiguous case insensitive match of username '$username', cannot safely grant access!\n"
1143             if scalar @matches > 1 && !$noerr;
1144
1145         return $matches[0]
1146     }
1147
1148     return $username;
1149 }
1150
1151 sub normalize_path {
1152     my $path = shift;
1153
1154     $path =~ s|/+|/|g;
1155
1156     $path =~ s|/$||;
1157
1158     $path = '/' if !$path;
1159
1160     $path = "/$path" if $path !~ m|^/|;
1161
1162     return undef if $path !~ m|^[[:alnum:]\.\-\_\/]+$|;
1163
1164     return $path;
1165 }
1166
1167 sub check_path {
1168     my ($path) = @_;
1169     return $path =~ m!^(
1170         /
1171         |/access
1172         |/access/groups
1173         |/access/groups/[[:alnum:]\.\-\_]+
1174         |/access/realm
1175         |/access/realm/[[:alnum:]\.\-\_]+
1176         |/nodes
1177         |/nodes/[[:alnum:]\.\-\_]+
1178         |/pool
1179         |/pool/[[:alnum:]\.\-\_]+
1180         |/sdn
1181         |/sdn/zones/[[:alnum:]\.\-\_]+
1182         |/sdn/vnets/[[:alnum:]\.\-\_]+
1183         |/storage
1184         |/storage/[[:alnum:]\.\-\_]+
1185         |/vms
1186         |/vms/[1-9][0-9]{2,}
1187     )$!xs;
1188 }
1189
1190 PVE::JSONSchema::register_format('pve-groupid', \&verify_groupname);
1191 sub verify_groupname {
1192     my ($groupname, $noerr) = @_;
1193
1194     if ($groupname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1195
1196         die "group name '$groupname' contains invalid characters\n" if !$noerr;
1197
1198         return undef;
1199     }
1200
1201     return $groupname;
1202 }
1203
1204 PVE::JSONSchema::register_format('pve-roleid', \&verify_rolename);
1205 sub verify_rolename {
1206     my ($rolename, $noerr) = @_;
1207
1208     if ($rolename !~ m/^[A-Za-z0-9\.\-_]+$/) {
1209
1210         die "role name '$rolename' contains invalid characters\n" if !$noerr;
1211
1212         return undef;
1213     }
1214
1215     return $rolename;
1216 }
1217
1218 PVE::JSONSchema::register_format('pve-poolid', \&verify_poolname);
1219 sub verify_poolname {
1220     my ($poolname, $noerr) = @_;
1221
1222     if ($poolname !~ m/^[A-Za-z0-9\.\-_]+$/) {
1223
1224         die "pool name '$poolname' contains invalid characters\n" if !$noerr;
1225
1226         return undef;
1227     }
1228
1229     return $poolname;
1230 }
1231
1232 PVE::JSONSchema::register_format('pve-priv', \&verify_privname);
1233 sub verify_privname {
1234     my ($priv, $noerr) = @_;
1235
1236     if (!$valid_privs->{$priv}) {
1237         die "invalid privilege '$priv'\n" if !$noerr;
1238
1239         return undef;
1240     }
1241
1242     return $priv;
1243 }
1244
1245 sub userconfig_force_defaults {
1246     my ($cfg) = @_;
1247
1248     foreach my $r (keys %$special_roles) {
1249         $cfg->{roles}->{$r} = $special_roles->{$r};
1250     }
1251
1252     # add root user if not exists
1253     if (!$cfg->{users}->{'root@pam'}) {
1254         $cfg->{users}->{'root@pam'}->{enable} = 1;
1255     }
1256 }
1257
1258 sub parse_user_config {
1259     my ($filename, $raw) = @_;
1260
1261     my $cfg = {};
1262
1263     userconfig_force_defaults($cfg);
1264
1265     $raw = '' if !defined($raw);
1266     while ($raw =~ /^\s*(.+?)\s*$/gm) {
1267         my $line = $1;
1268         my @data;
1269
1270         foreach my $d (split (/:/, $line)) {
1271             $d =~ s/^\s+//;
1272             $d =~ s/\s+$//;
1273             push @data, $d
1274         }
1275
1276         my $et = shift @data;
1277
1278         if ($et eq 'user') {
1279             my ($user, $enable, $expire, $firstname, $lastname, $email, $comment, $keys) = @data;
1280
1281             my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1282             if (!$realm) {
1283                 warn "user config - ignore user '$user' - invalid user name\n";
1284                 next;
1285             }
1286
1287             $enable = $enable ? 1 : 0;
1288
1289             $expire = 0 if !$expire;
1290
1291             if ($expire !~ m/^\d+$/) {
1292                 warn "user config - ignore user '$user' - (illegal characters in expire '$expire')\n";
1293                 next;
1294             }
1295             $expire = int($expire);
1296
1297             #if (!verify_groupname ($group, 1)) {
1298             #    warn "user config - ignore user '$user' - invalid characters in group name\n";
1299             #    next;
1300             #}
1301
1302             $cfg->{users}->{$user} = {
1303                 enable => $enable,
1304                 # group => $group,
1305             };
1306             $cfg->{users}->{$user}->{firstname} = PVE::Tools::decode_text($firstname) if $firstname;
1307             $cfg->{users}->{$user}->{lastname} = PVE::Tools::decode_text($lastname) if $lastname;
1308             $cfg->{users}->{$user}->{email} = $email;
1309             $cfg->{users}->{$user}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1310             $cfg->{users}->{$user}->{expire} = $expire;
1311             # keys: allowed yubico key ids or oath secrets (base32 encoded)
1312             $cfg->{users}->{$user}->{keys} = $keys if $keys;
1313
1314             #$cfg->{users}->{$user}->{groups}->{$group} = 1;
1315             #$cfg->{groups}->{$group}->{$user} = 1;
1316
1317         } elsif ($et eq 'group') {
1318             my ($group, $userlist, $comment) = @data;
1319
1320             if (!verify_groupname($group, 1)) {
1321                 warn "user config - ignore group '$group' - invalid characters in group name\n";
1322                 next;
1323             }
1324
1325             # make sure to add the group (even if there are no members)
1326             $cfg->{groups}->{$group} = { users => {} } if !$cfg->{groups}->{$group};
1327
1328             $cfg->{groups}->{$group}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1329
1330             foreach my $user (split_list($userlist)) {
1331
1332                 if (!PVE::Auth::Plugin::verify_username($user, 1)) {
1333                     warn "user config - ignore invalid group member '$user'\n";
1334                     next;
1335                 }
1336
1337                 if ($cfg->{users}->{$user}) { # user exists
1338                     $cfg->{users}->{$user}->{groups}->{$group} = 1;
1339                 } else {
1340                     warn "user config - ignore invalid group member '$user'\n";
1341                 }
1342                 $cfg->{groups}->{$group}->{users}->{$user} = 1;
1343             }
1344
1345         } elsif ($et eq 'role') {
1346             my ($role, $privlist) = @data;
1347
1348             if (!verify_rolename($role, 1)) {
1349                 warn "user config - ignore role '$role' - invalid characters in role name\n";
1350                 next;
1351             }
1352
1353             # make sure to add the role (even if there are no privileges)
1354             $cfg->{roles}->{$role} = {} if !$cfg->{roles}->{$role};
1355
1356             foreach my $priv (split_list($privlist)) {
1357                 if (defined ($valid_privs->{$priv})) {
1358                     $cfg->{roles}->{$role}->{$priv} = 1;
1359                 } else {
1360                     warn "user config - ignore invalid privilege '$priv'\n";
1361                 }
1362             }
1363
1364         } elsif ($et eq 'acl') {
1365             my ($propagate, $pathtxt, $uglist, $rolelist) = @data;
1366
1367             $propagate = $propagate ? 1 : 0;
1368
1369             if (my $path = normalize_path($pathtxt)) {
1370                 foreach my $role (split_list($rolelist)) {
1371
1372                     if (!verify_rolename($role, 1)) {
1373                         warn "user config - ignore invalid role name '$role' in acl\n";
1374                         next;
1375                     }
1376
1377                     if (!$cfg->{roles}->{$role}) {
1378                         warn "user config - ignore invalid acl role '$role'\n";
1379                         next;
1380                     }
1381
1382                     foreach my $ug (split_list($uglist)) {
1383                         my ($group) = $ug =~ m/^@(\S+)$/;
1384
1385                         if ($group && verify_groupname($group, 1)) {
1386                             if (!$cfg->{groups}->{$group}) { # group does not exist
1387                                 warn "user config - ignore invalid acl group '$group'\n";
1388                             }
1389                             $cfg->{acl}->{$path}->{groups}->{$group}->{$role} = $propagate;
1390                         } elsif (PVE::Auth::Plugin::verify_username($ug, 1)) {
1391                             if (!$cfg->{users}->{$ug}) { # user does not exist
1392                                 warn "user config - ignore invalid acl member '$ug'\n";
1393                             }
1394                             $cfg->{acl}->{$path}->{users}->{$ug}->{$role} = $propagate;
1395                         } elsif (my ($user, $token) = split_tokenid($ug, 1)) {
1396                             if (check_token_exist($cfg, $user, $token, 1)) {
1397                                 $cfg->{acl}->{$path}->{tokens}->{$ug}->{$role} = $propagate;
1398                             } else {
1399                                 warn "user config - ignore invalid acl token '$ug'\n";
1400                             }
1401                         } else {
1402                             warn "user config - invalid user/group '$ug' in acl\n";
1403                         }
1404                     }
1405                 }
1406             } else {
1407                 warn "user config - ignore invalid path in acl '$pathtxt'\n";
1408             }
1409         } elsif ($et eq 'pool') {
1410             my ($pool, $comment, $vmlist, $storelist) = @data;
1411
1412             if (!verify_poolname($pool, 1)) {
1413                 warn "user config - ignore pool '$pool' - invalid characters in pool name\n";
1414                 next;
1415             }
1416
1417             # make sure to add the pool (even if there are no members)
1418             $cfg->{pools}->{$pool} = { vms => {}, storage => {} } if !$cfg->{pools}->{$pool};
1419
1420             $cfg->{pools}->{$pool}->{comment} = PVE::Tools::decode_text($comment) if $comment;
1421
1422             foreach my $vmid (split_list($vmlist)) {
1423                 if ($vmid !~ m/^\d+$/) {
1424                     warn "user config - ignore invalid vmid '$vmid' in pool '$pool'\n";
1425                     next;
1426                 }
1427                 $vmid = int($vmid);
1428
1429                 if ($cfg->{vms}->{$vmid}) {
1430                     warn "user config - ignore duplicate vmid '$vmid' in pool '$pool'\n";
1431                     next;
1432                 }
1433
1434                 $cfg->{pools}->{$pool}->{vms}->{$vmid} = 1;
1435
1436                 # record vmid ==> pool relation
1437                 $cfg->{vms}->{$vmid} = $pool;
1438             }
1439
1440             foreach my $storeid (split_list($storelist)) {
1441                 if ($storeid !~ m/^[a-z][a-z0-9\-\_\.]*[a-z0-9]$/i) {
1442                     warn "user config - ignore invalid storage '$storeid' in pool '$pool'\n";
1443                     next;
1444                 }
1445                 $cfg->{pools}->{$pool}->{storage}->{$storeid} = 1;
1446             }
1447         } elsif ($et eq 'token') {
1448             my ($tokenid, $expire, $privsep, $comment) = @data;
1449
1450             my ($user, $token) = split_tokenid($tokenid, 1);
1451             if (!($user && $token)) {
1452                 warn "user config - ignore invalid tokenid '$tokenid'\n";
1453                 next;
1454             }
1455
1456             $privsep = $privsep ? 1 : 0;
1457
1458             $expire = 0 if !$expire;
1459
1460             if ($expire !~ m/^\d+$/) {
1461                 warn "user config - ignore token '$tokenid' - (illegal characters in expire '$expire')\n";
1462                 next;
1463             }
1464             $expire = int($expire);
1465
1466             if (my $user_cfg = $cfg->{users}->{$user}) { # user exists
1467                 $user_cfg->{tokens}->{$token} = {} if !$user_cfg->{tokens}->{$token};
1468                 my $token_cfg = $user_cfg->{tokens}->{$token};
1469                 $token_cfg->{privsep} = $privsep;
1470                 $token_cfg->{expire} = $expire;
1471                 $token_cfg->{comment} = PVE::Tools::decode_text($comment) if $comment;
1472             } else {
1473                 warn "user config - ignore token '$tokenid' - user does not exist\n";
1474             }
1475         } else {
1476             warn "user config - ignore config line: $line\n";
1477         }
1478     }
1479
1480     userconfig_force_defaults($cfg);
1481
1482     return $cfg;
1483 }
1484
1485 sub write_user_config {
1486     my ($filename, $cfg) = @_;
1487
1488     my $data = '';
1489
1490     foreach my $user (sort keys %{$cfg->{users}}) {
1491         my $d = $cfg->{users}->{$user};
1492         my $firstname = $d->{firstname} ? PVE::Tools::encode_text($d->{firstname}) : '';
1493         my $lastname = $d->{lastname} ? PVE::Tools::encode_text($d->{lastname}) : '';
1494         my $email = $d->{email} || '';
1495         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1496         my $expire = int($d->{expire} || 0);
1497         my $enable = $d->{enable} ? 1 : 0;
1498         my $keys = $d->{keys} ? $d->{keys} : '';
1499         $data .= "user:$user:$enable:$expire:$firstname:$lastname:$email:$comment:$keys:\n";
1500
1501         my $user_tokens = $d->{tokens};
1502         foreach my $token (sort keys %$user_tokens) {
1503             my $td = $user_tokens->{$token};
1504             my $full_tokenid = join_tokenid($user, $token);
1505             my $comment = $td->{comment} ? PVE::Tools::encode_text($td->{comment}) : '';
1506             my $expire = int($td->{expire} || 0);
1507             my $privsep = $td->{privsep} ? 1 : 0;
1508             $data .= "token:$full_tokenid:$expire:$privsep:$comment:\n";
1509         }
1510     }
1511
1512     $data .= "\n";
1513
1514     foreach my $group (sort keys %{$cfg->{groups}}) {
1515         my $d = $cfg->{groups}->{$group};
1516         my $list = join (',', sort keys %{$d->{users}});
1517         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1518         $data .= "group:$group:$list:$comment:\n";
1519     }
1520
1521     $data .= "\n";
1522
1523     foreach my $pool (sort keys %{$cfg->{pools}}) {
1524         my $d = $cfg->{pools}->{$pool};
1525         my $vmlist = join (',', sort keys %{$d->{vms}});
1526         my $storelist = join (',', sort keys %{$d->{storage}});
1527         my $comment = $d->{comment} ? PVE::Tools::encode_text($d->{comment}) : '';
1528         $data .= "pool:$pool:$comment:$vmlist:$storelist:\n";
1529     }
1530
1531     $data .= "\n";
1532
1533     foreach my $role (sort keys %{$cfg->{roles}}) {
1534         next if $special_roles->{$role};
1535
1536         my $d = $cfg->{roles}->{$role};
1537         my $list = join (',', sort keys %$d);
1538         $data .= "role:$role:$list:\n";
1539     }
1540
1541     $data .= "\n";
1542
1543     my $collect_rolelist_members = sub {
1544         my ($acl_members, $result, $prefix, $exclude) = @_;
1545
1546         foreach my $member (keys %$acl_members) {
1547             next if $exclude && $member eq $exclude;
1548
1549             my $l0 = '';
1550             my $l1 = '';
1551             foreach my $role (sort keys %{$acl_members->{$member}}) {
1552                 my $propagate = $acl_members->{$member}->{$role};
1553                 if ($propagate) {
1554                     $l1 .= ',' if $l1;
1555                     $l1 .= $role;
1556                 } else {
1557                     $l0 .= ',' if $l0;
1558                     $l0 .= $role;
1559                 }
1560             }
1561             $result->{0}->{$l0}->{"${prefix}${member}"} = 1 if $l0;
1562             $result->{1}->{$l1}->{"${prefix}${member}"} = 1 if $l1;
1563         }
1564     };
1565
1566     foreach my $path (sort keys %{$cfg->{acl}}) {
1567         my $d = $cfg->{acl}->{$path};
1568
1569         my $rolelist_members = {};
1570
1571         $collect_rolelist_members->($d->{'groups'}, $rolelist_members, '@');
1572
1573         # no need to save 'root@pam', it is always 'Administrator'
1574         $collect_rolelist_members->($d->{'users'}, $rolelist_members, '', 'root@pam');
1575
1576         $collect_rolelist_members->($d->{'tokens'}, $rolelist_members, '');
1577
1578         foreach my $propagate (0,1) {
1579             my $filtered = $rolelist_members->{$propagate};
1580             foreach my $rolelist (sort keys %$filtered) {
1581                 my $uglist = join (',', sort keys %{$filtered->{$rolelist}});
1582                 $data .= "acl:$propagate:$path:$uglist:$rolelist:\n";
1583             }
1584
1585         }
1586     }
1587
1588     return $data;
1589 }
1590
1591 # Creates a `PVE::RS::TFA` instance from the raw config data.
1592 # Its contained hash will also support the legacy functionality.
1593 sub parse_priv_tfa_config {
1594     my ($filename, $raw) = @_;
1595
1596     $raw = '' if !defined($raw);
1597     my $cfg = PVE::RS::TFA->new($raw);
1598
1599     # Purge invalid users:
1600     foreach my $user ($cfg->users()->@*) {
1601         my (undef, undef, $realm) = PVE::Auth::Plugin::verify_username($user, 1);
1602         if (!$realm) {
1603             warn "user tfa config - ignore user '$user' - invalid user name\n";
1604             $cfg->remove_user($user);
1605         }
1606     }
1607
1608     return $cfg;
1609 }
1610
1611 sub write_priv_tfa_config {
1612     my ($filename, $cfg) = @_;
1613
1614     assert_new_tfa_config_available();
1615
1616     return $cfg->write();
1617 }
1618
1619 sub roles {
1620     my ($cfg, $user, $path) = @_;
1621
1622     # NOTE: we do not consider pools here.
1623     # NOTE: for privsep tokens, this does not filter roles by those that the
1624     # corresponding user has.
1625     # Use $rpcenv->permission() for any actual permission checks!
1626
1627     return 'Administrator' if $user eq 'root@pam'; # root can do anything
1628
1629     if (pve_verify_tokenid($user, 1)) {
1630         my $tokenid = $user;
1631         my ($username, $token) = split_tokenid($tokenid);
1632
1633         my $token_info = $cfg->{users}->{$username}->{tokens}->{$token};
1634         return () if !$token_info;
1635
1636         my $user_roles = roles($cfg, $username, $path);
1637
1638         # return full user privileges
1639         return $user_roles if !$token_info->{privsep};
1640     }
1641
1642     my $roles = {};
1643
1644     foreach my $p (sort keys %{$cfg->{acl}}) {
1645         my $final = ($path eq $p);
1646
1647         next if !(($p eq '/') || $final || ($path =~ m|^$p/|));
1648
1649         my $acl = $cfg->{acl}->{$p};
1650
1651         #print "CHECKACL $path $p\n";
1652         #print "ACL $path = " . Dumper ($acl);
1653         if (my $ri = $acl->{tokens}->{$user}) {
1654             my $new;
1655             foreach my $role (keys %$ri) {
1656                 my $propagate = $ri->{$role};
1657                 if ($final || $propagate) {
1658                     #print "APPLY ROLE $p $user $role\n";
1659                     $new = {} if !$new;
1660                     $new->{$role} = $propagate;
1661                 }
1662             }
1663             if ($new) {
1664                 $roles = $new; # overwrite previous settings
1665                 next;
1666             }
1667         }
1668
1669         if (my $ri = $acl->{users}->{$user}) {
1670             my $new;
1671             foreach my $role (keys %$ri) {
1672                 my $propagate = $ri->{$role};
1673                 if ($final || $propagate) {
1674                     #print "APPLY ROLE $p $user $role\n";
1675                     $new = {} if !$new;
1676                     $new->{$role} = $propagate;
1677                 }
1678             }
1679             if ($new) {
1680                 $roles = $new; # overwrite previous settings
1681                 next; # user privs always override group privs
1682             }
1683         }
1684
1685         my $new;
1686         foreach my $g (keys %{$acl->{groups}}) {
1687             next if !$cfg->{groups}->{$g}->{users}->{$user};
1688             if (my $ri = $acl->{groups}->{$g}) {
1689                 foreach my $role (keys %$ri) {
1690                     my $propagate = $ri->{$role};
1691                     if ($final || $propagate) {
1692                         #print "APPLY ROLE $p \@$g $role\n";
1693                         $new = {} if !$new;
1694                         $new->{$role} = $propagate;
1695                     }
1696                 }
1697             }
1698         }
1699         if ($new) {
1700             $roles = $new; # overwrite previous settings
1701             next;
1702         }
1703     }
1704
1705     return { 'NoAccess' => $roles->{NoAccess} } if defined ($roles->{NoAccess});
1706     #return () if defined ($roles->{NoAccess});
1707
1708     #print "permission $user $path = " . Dumper ($roles);
1709
1710     #print "roles $user $path = " . join (',', @ra) . "\n";
1711
1712     return $roles;
1713 }
1714
1715 sub remove_vm_access {
1716     my ($vmid) = @_;
1717     my $delVMaccessFn = sub {
1718         my $usercfg = cfs_read_file("user.cfg");
1719         my $modified;
1720
1721         if (my $acl = $usercfg->{acl}->{"/vms/$vmid"}) {
1722             delete $usercfg->{acl}->{"/vms/$vmid"};
1723             $modified = 1;
1724         }
1725         if (my $pool = $usercfg->{vms}->{$vmid}) {
1726             if (my $data = $usercfg->{pools}->{$pool}) {
1727                 delete $data->{vms}->{$vmid};
1728                 delete $usercfg->{vms}->{$vmid};
1729                 $modified = 1;
1730             }
1731         }
1732         cfs_write_file("user.cfg", $usercfg) if $modified;
1733     };
1734
1735     lock_user_config($delVMaccessFn, "access permissions cleanup for VM $vmid failed");
1736 }
1737
1738 sub remove_storage_access {
1739     my ($storeid) = @_;
1740
1741     my $deleteStorageAccessFn = sub {
1742         my $usercfg = cfs_read_file("user.cfg");
1743         my $modified;
1744
1745         if (my $storage = $usercfg->{acl}->{"/storage/$storeid"}) {
1746             delete $usercfg->{acl}->{"/storage/$storeid"};
1747             $modified = 1;
1748         }
1749         foreach my $pool (keys %{$usercfg->{pools}}) {
1750             delete $usercfg->{pools}->{$pool}->{storage}->{$storeid};
1751             $modified = 1;
1752         }
1753         cfs_write_file("user.cfg", $usercfg) if $modified;
1754     };
1755
1756     lock_user_config($deleteStorageAccessFn,
1757                      "access permissions cleanup for storage $storeid failed");
1758 }
1759
1760 sub add_vm_to_pool {
1761     my ($vmid, $pool) = @_;
1762
1763     my $addVMtoPoolFn = sub {
1764         my $usercfg = cfs_read_file("user.cfg");
1765         if (my $data = $usercfg->{pools}->{$pool}) {
1766             $data->{vms}->{$vmid} = 1;
1767             $usercfg->{vms}->{$vmid} = $pool;
1768             cfs_write_file("user.cfg", $usercfg);
1769         }
1770     };
1771
1772     lock_user_config($addVMtoPoolFn, "can't add VM $vmid to pool '$pool'");
1773 }
1774
1775 sub remove_vm_from_pool {
1776     my ($vmid) = @_;
1777
1778     my $delVMfromPoolFn = sub {
1779         my $usercfg = cfs_read_file("user.cfg");
1780         if (my $pool = $usercfg->{vms}->{$vmid}) {
1781             if (my $data = $usercfg->{pools}->{$pool}) {
1782                 delete $data->{vms}->{$vmid};
1783                 delete $usercfg->{vms}->{$vmid};
1784                 cfs_write_file("user.cfg", $usercfg);
1785             }
1786         }
1787     };
1788
1789     lock_user_config($delVMfromPoolFn, "pool cleanup for VM $vmid failed");
1790 }
1791
1792 my $USER_CONTROLLED_TFA_TYPES = {
1793     u2f => 1,
1794     oath => 1,
1795 };
1796
1797 sub assert_new_tfa_config_available() {
1798     PVE::Cluster::cfs_update();
1799     my $version_info = PVE::Cluster::get_node_kv('version-info');
1800     die "cannot update tfa config, please make sure all cluster nodes are up to date\n"
1801         if !$version_info;
1802     my $members = PVE::Cluster::get_members() or return; # get_members returns undef on no cluster
1803     my $old = '';
1804     foreach my $node (keys $members->%*) {
1805         my $info = $version_info->{$node};
1806         if (!$info) {
1807             $old .= "  cluster node '$node' is too old, did not broadcast its version info\n";
1808             next;
1809         }
1810         $info = from_json($info);
1811         my $ver = $info->{version};
1812         if ($ver !~ /^(\d+\.\d+)-(\d+)/) {
1813             $old .= "  cluster node '$node' provided an invalid version string: '$ver'\n";
1814             next;
1815         }
1816         my ($maj, $rel) = ($1, $2);
1817         if (!($maj > 7.0 || ($maj == 7.0 && $rel >= 15))) {
1818             $old .= "  cluster node '$node' is too old ($ver < 7.0-15)\n";
1819             next;
1820         }
1821     }
1822     die "cannot update tfa config, following nodes are not up to date:\n$old" if length($old);
1823 }
1824
1825 sub user_remove_tfa : prototype($) {
1826     my ($userid) = @_;
1827
1828     assert_new_tfa_config_available();
1829
1830     my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1831     $tfa_cfg->remove_user($userid);
1832     cfs_write_file('priv/tfa.cfg', $tfa_cfg);
1833 }
1834
1835 my sub add_old_yubico_keys : prototype($$$) {
1836     my ($userid, $tfa_cfg, $keys) = @_;
1837
1838     my $count = 0;
1839     foreach my $key (split_list($keys)) {
1840         my $description = "<old userconfig key $count>";
1841         ++$count;
1842         $tfa_cfg->add_yubico_entry($userid, $description, $key);
1843     }
1844 }
1845
1846 my sub normalize_totp_secret : prototype($) {
1847     my ($key) = @_;
1848
1849     my $binkey;
1850     # See PVE::OTP::oath_verify_otp:
1851     if ($key =~ /^v2-0x([0-9a-fA-F]+)$/) {
1852         # v2, hex
1853         $binkey = pack('H*', $1);
1854     } elsif ($key =~ /^v2-([A-Z2-7=]+)$/) {
1855         # v2, base32
1856         $binkey = MIME::Base32::decode_rfc3548($1);
1857     } elsif ($key =~ /^[A-Z2-7=]{16}$/) {
1858         $binkey = MIME::Base32::decode_rfc3548($key);
1859     } elsif ($key =~ /^[A-Fa-f0-9]{40}$/) {
1860         $binkey = pack('H*', $key);
1861     } else {
1862         return undef;
1863     }
1864
1865     return MIME::Base32::encode_rfc3548($binkey);
1866 }
1867
1868 my sub add_old_totp_keys : prototype($$$$) {
1869     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1870
1871     my $issuer = 'Proxmox%20VE';
1872     my $account = uri_escape("Old key for $userid");
1873     my $digits = $realm_tfa->{digits} || 6;
1874     my $step = $realm_tfa->{step} || 30;
1875     my $uri = "otpauth://totp/$issuer:$account?digits=$digits&period=$step&algorithm=SHA1&secret=";
1876
1877     my $count = 0;
1878     foreach my $key (split_list($keys)) {
1879         $key = normalize_totp_secret($key);
1880         # and just skip invalid keys:
1881         next if !defined($key);
1882
1883         my $description = "<old userconfig key $count>";
1884         ++$count;
1885         eval { $tfa_cfg->add_totp_entry($userid, $description, $uri . $key) };
1886         warn $@ if $@;
1887     }
1888 }
1889
1890 sub add_old_keys_to_realm_tfa : prototype($$$$) {
1891     my ($userid, $tfa_cfg, $realm_tfa, $keys) = @_;
1892
1893     # if there's no realm tfa configured, we don't know what the keys mean, so we just ignore
1894     # them...
1895     return if !$realm_tfa;
1896
1897     my $type = $realm_tfa->{type};
1898     if ($type eq 'oath') {
1899         add_old_totp_keys($userid, $tfa_cfg, $realm_tfa, $keys);
1900     } elsif ($type eq 'yubico') {
1901         add_old_yubico_keys($userid, $tfa_cfg, $keys);
1902     } else {
1903         # invalid keys, we'll just drop them now...
1904     }
1905 }
1906
1907 sub user_get_tfa : prototype($$$) {
1908     my ($username, $realm, $new_format) = @_;
1909
1910     my $user_cfg = cfs_read_file('user.cfg');
1911     my $user = $user_cfg->{users}->{$username}
1912         or die "user '$username' not found\n";
1913
1914     my $keys = $user->{keys};
1915
1916     my $domain_cfg = cfs_read_file('domains.cfg');
1917     my $realm_cfg = $domain_cfg->{ids}->{$realm};
1918     die "auth domain '$realm' does not exist\n" if !$realm_cfg;
1919
1920     my $realm_tfa = $realm_cfg->{tfa};
1921     $realm_tfa = PVE::Auth::Plugin::parse_tfa_config($realm_tfa)
1922         if $realm_tfa;
1923
1924     if (!$keys) {
1925         return if !$realm_tfa;
1926         die "missing required 2nd keys\n";
1927     }
1928
1929     if ($new_format) {
1930         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1931         if (defined($keys) && $keys !~ /^x(?:!.*)$/) {
1932             add_old_keys_to_realm_tfa($username, $tfa_cfg, $realm_tfa, $keys);
1933         }
1934         return ($tfa_cfg, $realm_tfa);
1935     }
1936
1937     # new style config starts with an 'x' and optionally contains a !<type> suffix
1938     if ($keys !~ /^x(?:!.*)?$/) {
1939         # old style config, find the type via the realm
1940         return if !$realm_tfa;
1941         return ($realm_tfa->{type}, {
1942             keys => $keys,
1943             config => $realm_tfa,
1944         });
1945     } else {
1946         my $tfa_cfg = cfs_read_file('priv/tfa.cfg');
1947         my $tfa = $tfa_cfg->{users}->{$username};
1948         return if !$tfa; # should not happen (user.cfg wasn't cleaned up?)
1949
1950         if ($realm_tfa) {
1951             # if the realm has a tfa setting we need to verify the type:
1952             die "auth domain '$realm' and user have mismatching TFA settings\n"
1953                 if $realm_tfa && $realm_tfa->{type} ne $tfa->{type};
1954         }
1955
1956         return ($tfa->{type}, $tfa->{data});
1957     }
1958 }
1959
1960 # bash completion helpers
1961
1962 register_standard_option('userid-completed',
1963     get_standard_option('userid', { completion => \&complete_username}),
1964 );
1965
1966 sub complete_username {
1967
1968     my $user_cfg = cfs_read_file('user.cfg');
1969
1970     return [ keys %{$user_cfg->{users}} ];
1971 }
1972
1973 sub complete_group {
1974
1975     my $user_cfg = cfs_read_file('user.cfg');
1976
1977     return [ keys %{$user_cfg->{groups}} ];
1978 }
1979
1980 sub complete_realm {
1981
1982     my $domain_cfg = cfs_read_file('domains.cfg');
1983
1984     return [ keys %{$domain_cfg->{ids}} ];
1985 }
1986
1987 1;