346df516813758ba3b09ec3391c3426892cba888
[pve-client.git] / PVE / APIClient / Commands / lxc.pm
1 package PVE::APIClient::Commands::lxc;
2
3 use strict;
4 use warnings;
5 use JSON;
6 use URI::Escape;
7 use IO::Select;
8 use IO::Socket::SSL;
9 use MIME::Base64;
10 use Digest::SHA;
11 use HTTP::Response;
12
13 use PVE::Tools;
14 use PVE::JSONSchema qw(get_standard_option);
15 use PVE::CLIHandler;
16 use PVE::PTY;
17
18 use base qw(PVE::CLIHandler);
19 use PVE::APIClient::Config;
20
21 my $CRLF = "\x0D\x0A";
22 my $max_payload_size = 65536;
23
24 my $build_web_socket_request = sub {
25     my ($host, $path, $ticket, $termproxy) = @_;
26
27     my $key = '';
28     $key .= chr(int(rand(256))) for 1 .. 16;
29     my $enckey = MIME::Base64::encode_base64($key, '');
30
31     my $encticket = uri_escape($ticket);
32     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
33
34     $path .= "?port=$termproxy->{port}" .
35         "&vncticket=" . uri_escape($termproxy->{ticket});
36
37     my $request = "GET $path HTTP/1.1$CRLF"
38         . "Upgrade: WebSocket$CRLF"
39         . "Connection: Upgrade$CRLF"
40         . "Host: $host$CRLF"
41         . "Sec-WebSocket-Key: $enckey$CRLF"
42         . "Sec-WebSocket-Version: 13$CRLF"
43         . "Sec-WebSocket-Protocol: binary$CRLF"
44         . "Cookie: $cookie$CRLF"
45         . "$CRLF";
46
47     return ($request, $enckey);
48 };
49
50 my $create_websockt_frame = sub {
51     my ($payload) = @_;
52
53     my $string = "\x82"; # binary frame
54     my $payload_len = length($payload);
55     if ($payload_len <= 125) {
56         $string .= pack 'C', $payload_len | 128;
57     } elsif ($payload_len <= 0xffff) {
58         $string .= pack 'C', 126 | 128;
59         $string .= pack 'n', $payload_len;
60     } else {
61         $string .= pack 'C', 127 | 128;
62         $string .= pack 'Q>', $payload_len;
63     }
64
65     $string .= pack 'N', 0; # we simply use 0 as mask
66     $string .= $payload;
67
68     return $string;
69 };
70
71 my $parse_web_socket_frame = sub  {
72     my ($wsbuf_ref) = @_;
73
74     my $wsbuf = $$wsbuf_ref;
75
76     my $payload;
77     my $req_close = 0;
78
79     while (my $len = length($wsbuf)) {
80         last if $len < 2;
81
82         my $hdr = unpack('C', substr($wsbuf, 0, 1));
83         my $opcode = $hdr & 0b00001111;
84         my $fin = $hdr & 0b10000000;
85
86         die "received fragmented websocket frame\n" if !$fin;
87
88         my $rsv = $hdr & 0b01110000;
89         die "received websocket frame with RSV flags\n" if $rsv;
90
91         my $payload_len = unpack 'C', substr($wsbuf, 1, 1);
92
93         my $masked = $payload_len & 0b10000000;
94         die "received masked websocket frame from server\n" if $masked;
95
96         my $offset = 2;
97         $payload_len = $payload_len & 0b01111111;
98         if ($payload_len == 126) {
99             last if $len < 4;
100             $payload_len = unpack('n', substr($wsbuf, $offset, 2));
101             $offset += 2;
102         } elsif ($payload_len == 127) {
103             last if $len < 10;
104             $payload_len = unpack('Q>', substr($wsbuf, $offset, 8));
105             $offset += 8;
106         }
107
108         die "received too large websocket frame (len = $payload_len)\n"
109             if ($payload_len > $max_payload_size) || ($payload_len < 0);
110
111         last if $len < ($offset + $payload_len);
112
113         my $data = substr($wsbuf, 0, $offset + $payload_len, ''); # now consume data
114
115         my $frame_data = substr($data, $offset, $payload_len);
116
117         $payload = '' if !defined($payload);
118         $payload .= $frame_data;
119
120         if ($opcode == 1 || $opcode == 2) {
121             # continue
122         } elsif ($opcode == 8) {
123             my $statuscode = unpack ("n", $frame_data);
124             $req_close = 1;
125         } else {
126             die "received unhandled websocket opcode $opcode\n";
127         }
128     }
129
130     return ($payload, $req_close);
131 };
132
133 my $client_exit = sub {
134     my ($select, $web_socket, $old_termios) = @_;
135
136     foreach my $fh ($select->handles) {
137         $select->remove($fh);
138
139         if ($fh == $web_socket) {
140             if ($fh->connected) {
141
142                 # close connection
143                 # Opcode, mask, statuscode
144                 my $msg = "\x88" . pack('N', 0) . pack('n', 0);
145                 $fh->syswrite($msg);
146                 close($fh);
147             }
148         }
149
150     }
151
152     # switch back to blocking mode (else later shell commands will fail).
153     STDIN->blocking(1);
154
155     #
156     # Reset the terminal parameters.
157     #
158     print "\e[24H\r\n";
159     PVE::PTY::tcsetattr(*STDIN, $old_termios);
160 };
161
162 __PACKAGE__->register_method ({
163     name => 'enter',
164     path => 'enter',
165     method => 'POST',
166     description => "Enter container console.",
167     parameters => {
168         additionalProperties => 0,
169         properties => {
170             remote => get_standard_option('pveclient-remote-name'),
171             vmid => {
172                 description => "The container ID",
173                 type => 'string',
174             },
175         },
176     },
177     returns => { type => 'null'},
178     code => sub {
179         my ($param) = @_;
180
181         my $config = PVE::APIClient::Config->load();
182         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
183
184         # Get the real node from the resources endpoint
185         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
186         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
187
188         die "container '$param->{vmid}' does not exist\n"
189             if !(defined($resource) && defined($resource->{node}));
190
191         my $node = $resource->{node};
192
193         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
194
195         my $termproxy = $conn->post("${api_path}/termproxy", {});
196
197         my $web_socket =  IO::Socket::SSL->new(
198             PeerHost => $conn->{host},
199             PeerPort => $conn->{port},
200             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
201             timeout => 30) ||
202             die "failed to connect: $!\n";
203
204         # WebSocket Handshake
205
206         my ($request, $wskey) = $build_web_socket_request->(
207             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
208
209         $web_socket->syswrite($request);
210
211         my $wsbuf = '';
212
213         my $wb_socket_read_available_bytes = sub {
214             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
215             die "web socket read error - $!\n" if $nr < 0;
216             return $nr;
217         };
218
219         my $raw_response = '';
220
221         while(1) {
222             my $nr = $wb_socket_read_available_bytes->();
223             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
224                 $raw_response = $1;
225                 last;
226             }
227             last if !$nr;
228         };
229
230         # Note: we keep any remaining data in $wsbuf
231
232         my $response = HTTP::Response->parse($raw_response);
233
234         # Note: Digest::SHA::sha1_base64 has wrong padding
235         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
236
237         die "got invalid websocket reponse: $raw_response\n"
238             if !(($response->code == 101) &&
239                  (lc $response->header('connection') eq 'upgrade') &&
240                  (lc $response->header('upgrade') eq 'websocket') &&
241                  ($response->header('sec-websocket-protocol') eq 'binary') &&
242                  ($response->header('sec-websocket-accept') eq $wsaccept));
243
244         # send auth again...
245         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
246         $web_socket->syswrite($frame);
247
248         # Send resize command
249         my ($columns, $rows) = PVE::PTY::tcgetsize(*STDIN);
250         $frame = $create_websockt_frame->("1:$columns:$rows:");
251         $web_socket->syswrite($frame);
252
253         # Set STDIN to "raw -echo" mode
254         my $old_termios = PVE::PTY::tcgetattr(*STDIN);
255         my $raw_termios = {%$old_termios};
256         PVE::PTY::cfmakeraw($raw_termios);
257         PVE::PTY::tcsetattr(*STDIN, $raw_termios);
258
259         # And set it to non-blocking so we can every char with IO::Select.
260         STDIN->blocking(0);
261
262         my $select = IO::Select->new;
263
264         $web_socket->blocking(0);
265         $select->add($web_socket);
266         $select->add(fileno(STDIN));
267
268         my @messages;
269         my $ctrl_a_pressed_before = 0;
270         my $next_ping = time() + 3;
271
272         eval {
273             while (1) {
274                 # Ping server every 3 seconds.
275                 my $now = time();
276                 if ($now >= $next_ping) {
277                     push(@messages, $create_websockt_frame->("2"));
278                     $next_ping = $now + 3;
279                 }
280
281                 # Write
282                 foreach my $fh ($select->can_write(0.5)) {
283                     if ($fh == $web_socket and my $msg = shift @messages) {
284                         $fh->syswrite($msg, length($msg));
285                     }
286                 }
287
288                 # Read
289                 foreach my $fh ($select->can_read(0.5)) {
290
291                     # From Web Socket
292                     if ($fh == $web_socket) {
293                         # Read from WebSocket
294                         my $nr = $wb_socket_read_available_bytes->();
295                         my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
296
297                         if ($payload ne "OK") {
298                             syswrite(\*STDOUT, $payload, length($payload));
299                         }
300                     }
301
302                     # From STDIN
303                     elsif ($fh == fileno(STDIN)) {
304
305                         # Read from STDIN
306                         my $nr = read(\*STDIN, my $buff, 4096);
307                         if (!$nr) {
308                             next;
309                         }
310
311                         my $char = ord($buff);
312
313                         if ($ctrl_a_pressed_before == 1 && $char == hex("0x71")) {
314                             $client_exit->($select, $web_socket, $old_termios);
315                             return;
316                         }
317
318                         if ($char == hex("0x01")) {
319                             if ($ctrl_a_pressed_before == 0) {
320                                 $ctrl_a_pressed_before = 1;
321                             }
322                         }
323                         else {
324                             $ctrl_a_pressed_before = 0;
325                         }
326
327                         push(@messages, $create_websockt_frame->("0:" . $nr . ":" . $buff));
328                     }
329                 }
330             }
331         };
332         print "ERROR: " . $@ . ".\n" if $@;
333
334         $client_exit->($select, $web_socket, $old_termios);
335
336         return undef
337     }});
338
339 __PACKAGE__->register_method ({
340     name => 'list',
341     path => 'list',
342     method => 'GET',
343     description => "List containers.",
344     parameters => {
345         additionalProperties => 0,
346         properties => {
347             remote => get_standard_option('pveclient-remote-name'),
348         },
349     },
350     returns => { type => 'null'},
351     code => sub {
352         my ($param) = @_;
353
354         die "implement me";
355
356     }});
357
358
359 our $cmddef = {
360     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
361     list => [ __PACKAGE__, 'list', ['remote']],
362 };
363
364 1;