PVE/APIClient/Commands/lxc.pm

   1 package PVE::APIClient::Commands::lxc;
   2
   3 use strict;
   4 use warnings;
   5 use Errno qw(EINTR EAGAIN);
   6 use JSON;
   7 use URI::Escape;
   8 use IO::Select;
   9 use IO::Socket::SSL;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use HTTP::Response;
  13
  14 use PVE::Tools;
  15 use PVE::JSONSchema qw(get_standard_option);
  16 use PVE::CLIHandler;
  17 use PVE::PTY;
  18
  19 use base qw(PVE::CLIHandler);
  20 use PVE::APIClient::Config;
  21
  22 my $CRLF = "\x0D\x0A";
  23 my $max_payload_size = 128*1024;
  24
  25 my $build_web_socket_request = sub {
  26     my ($host, $path, $ticket, $termproxy) = @_;
  27
  28     my $key = '';
  29     $key .= chr(int(rand(256))) for 1 .. 16;
  30     my $enckey = MIME::Base64::encode_base64($key, '');
  31
  32     my $encticket = uri_escape($ticket);
  33     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
  34
  35     $path .= "?port=$termproxy->{port}" .
  36         "&vncticket=" . uri_escape($termproxy->{ticket});
  37
  38     my $request = "GET $path HTTP/1.1$CRLF"
  39         . "Upgrade: WebSocket$CRLF"
  40         . "Connection: Upgrade$CRLF"
  41         . "Host: $host$CRLF"
  42         . "Sec-WebSocket-Key: $enckey$CRLF"
  43         . "Sec-WebSocket-Version: 13$CRLF"
  44         . "Sec-WebSocket-Protocol: binary$CRLF"
  45         . "Cookie: $cookie$CRLF"
  46         . "$CRLF";
  47
  48     return ($request, $enckey);
  49 };
  50
  51 my $create_websockt_frame = sub {
  52     my ($payload) = @_;
  53
  54     my $string = "\x82"; # binary frame
  55     my $payload_len = length($payload);
  56     if ($payload_len <= 125) {
  57         $string .= pack 'C', $payload_len | 128;
  58     } elsif ($payload_len <= 0xffff) {
  59         $string .= pack 'C', 126 | 128;
  60         $string .= pack 'n', $payload_len;
  61     } else {
  62         $string .= pack 'C', 127 | 128;
  63         $string .= pack 'Q>', $payload_len;
  64     }
  65
  66     $string .= pack 'N', 0; # we simply use 0 as mask
  67     $string .= $payload;
  68
  69     return $string;
  70 };
  71
  72 my $parse_web_socket_frame = sub  {
  73     my ($wsbuf_ref) = @_;
  74
  75     my $payload;
  76     my $req_close = 0;
  77
  78     while (my $len = length($$wsbuf_ref)) {
  79         last if $len < 2;
  80
  81         my $hdr = unpack('C', substr($$wsbuf_ref, 0, 1));
  82         my $opcode = $hdr & 0b00001111;
  83         my $fin = $hdr & 0b10000000;
  84
  85         die "received fragmented websocket frame\n" if !$fin;
  86
  87         my $rsv = $hdr & 0b01110000;
  88         die "received websocket frame with RSV flags\n" if $rsv;
  89
  90         my $payload_len = unpack 'C', substr($$wsbuf_ref, 1, 1);
  91
  92         my $masked = $payload_len & 0b10000000;
  93         die "received masked websocket frame from server\n" if $masked;
  94
  95         my $offset = 2;
  96         $payload_len = $payload_len & 0b01111111;
  97         if ($payload_len == 126) {
  98             last if $len < 4;
  99             $payload_len = unpack('n', substr($$wsbuf_ref, $offset, 2));
 100             $offset += 2;
 101         } elsif ($payload_len == 127) {
 102             last if $len < 10;
 103             $payload_len = unpack('Q>', substr($$wsbuf_ref, $offset, 8));
 104             $offset += 8;
 105         }
 106
 107         die "received too large websocket frame (len = $payload_len)\n"
 108             if ($payload_len > $max_payload_size) || ($payload_len < 0);
 109
 110         last if $len < ($offset + $payload_len);
 111
 112         my $data = substr($$wsbuf_ref, 0, $offset + $payload_len, ''); # now consume data
 113
 114         my $frame_data = substr($data, $offset, $payload_len);
 115
 116         $payload = '' if !defined($payload);
 117         $payload .= $frame_data;
 118
 119         if ($opcode == 1 || $opcode == 2) {
 120             # continue
 121         } elsif ($opcode == 8) {
 122             my $statuscode = unpack ("n", $frame_data);
 123             $req_close = 1;
 124         } else {
 125             die "received unhandled websocket opcode $opcode\n";
 126         }
 127     }
 128
 129     return ($payload, $req_close);
 130 };
 131
 132 my $full_write = sub {
 133     my ($fh, $data) = @_;
 134
 135     my $len = length($data);
 136     my $todo = $len;
 137     my $offset = 0;
 138     while(1) {
 139         my $nr = syswrite($fh, $data, $todo, $offset);
 140         if (!defined($nr)) {
 141             next if $! == EINTR || $! == EAGAIN;
 142             die "console write error - $!\n"
 143         }
 144         $offset += $nr;
 145         $todo -= $nr;
 146         last if $todo <= 0;
 147     }
 148
 149     return $len;
 150 };
 151
 152 # Takes an escape character with an optional '^' prefix and returns an escape
 153 # character code.
 154 my $escapekey_to_char = sub {
 155     my ($def) = @_;
 156     if ($def =~ /^\^?([a-zA-Z])$/) {
 157         return 1 + ord(lc($1)) - ord('a');
 158     }
 159     die "bad escape key definition: $def\n";
 160 };
 161
 162 __PACKAGE__->register_method ({
 163     name => 'enter',
 164     path => 'enter',
 165     method => 'POST',
 166     description => "Enter container console.",
 167     parameters => {
 168         additionalProperties => 0,
 169         properties => {
 170             remote => get_standard_option('pveclient-remote-name'),
 171             vmid => get_standard_option('pve-vmid')
 172         },
 173     },
 174     returns => { type => 'null'},
 175     code => sub {
 176         my ($param) = @_;
 177
 178         my $config = PVE::APIClient::Config->load();
 179         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
 180
 181         # FIXME: This should come from $config
 182         my $escape_char = $escapekey_to_char->('a');
 183
 184         # Get the real node from the resources endpoint
 185         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
 186         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
 187
 188         die "container '$param->{vmid}' does not exist\n"
 189             if !(defined($resource) && defined($resource->{node}));
 190
 191         my $node = $resource->{node};
 192
 193         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
 194
 195         my $termproxy = $conn->post("${api_path}/termproxy", {});
 196
 197         my $web_socket =  IO::Socket::SSL->new(
 198             PeerHost => $conn->{host},
 199             PeerPort => $conn->{port},
 200             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
 201             timeout => 30) ||
 202             die "failed to connect: $!\n";
 203
 204         # WebSocket Handshake
 205
 206         my ($request, $wskey) = $build_web_socket_request->(
 207             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
 208
 209         $full_write->($web_socket, $request);
 210
 211         my $wsbuf = '';
 212
 213         my $wb_socket_read_available_bytes = sub {
 214             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
 215             if (!defined($nr) && !($! == EINTR || $! == EAGAIN)) {
 216                 die "web socket read error - $!\n";
 217             }
 218             return $nr;
 219         };
 220
 221         my $raw_response = '';
 222
 223         while(1) {
 224             my $nr = $wb_socket_read_available_bytes->();
 225             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
 226                 $raw_response = $1;
 227                 last;
 228             }
 229             last if !$nr;
 230         };
 231
 232         # Note: we keep any remaining data in $wsbuf
 233
 234         my $response = HTTP::Response->parse($raw_response);
 235
 236         # Note: Digest::SHA::sha1_base64 has wrong padding
 237         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 238
 239         die "got invalid websocket reponse: $raw_response\n"
 240             if !(($response->code == 101) &&
 241                  (lc $response->header('connection') eq 'upgrade') &&
 242                  (lc $response->header('upgrade') eq 'websocket') &&
 243                  ($response->header('sec-websocket-protocol') eq 'binary') &&
 244                  ($response->header('sec-websocket-accept') eq $wsaccept));
 245
 246         # send auth again...
 247         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
 248         $full_write->($web_socket, $frame);
 249
 250         # Send resize command
 251         my ($columns, $rows) = PVE::PTY::tcgetsize(*STDIN);
 252         $frame = $create_websockt_frame->("1:$columns:$rows:");
 253         $full_write->($web_socket, $frame);
 254
 255         # Set STDIN to "raw -echo" mode
 256         my $old_termios = PVE::PTY::tcgetattr(*STDIN);
 257         my $raw_termios = {%$old_termios};
 258
 259         my $read_select = IO::Select->new;
 260         my $write_select = IO::Select->new;
 261
 262         my $output_buffer = ''; # write buffer for STDOUT
 263         my $websock_buffer = ''; # write buffer for $web_socket
 264
 265         eval {
 266             $SIG{TERM} = $SIG{INT} = $SIG{KILL} = sub { die "received interrupt\n"; };
 267
 268             PVE::PTY::cfmakeraw($raw_termios);
 269             PVE::PTY::tcsetattr(*STDIN, $raw_termios);
 270
 271             # And set it to non-blocking so we can every char with IO::Select.
 272             STDIN->blocking(0);
 273             STDOUT->blocking(0);
 274             $web_socket->blocking(0);
 275             $read_select->add($web_socket);
 276             my $input_fh = \*STDIN;
 277             $read_select->add($input_fh);
 278
 279             my $output_fh = \*STDOUT;
 280
 281             my $in_escape_sequence;
 282
 283             my $winch_received = 0;
 284             $SIG{WINCH} = sub { $winch_received = 1; };
 285
 286             my $check_terminal_size = sub {
 287                 my ($ncols, $nrows) = PVE::PTY::tcgetsize(*STDIN);
 288                 if ($ncols != $columns or $nrows != $rows) {
 289                     $columns = $ncols;
 290                     $rows = $nrows;
 291                     $websock_buffer .= $create_websockt_frame->("1:$columns:$rows:");
 292                     $write_select->add($web_socket);
 293                 }
 294                 $winch_received = 0;
 295             };
 296
 297             my $max_buffer_len = 256*1024;
 298
 299             my $drain_buffer = sub {
 300                 my ($fh, $buffer_ref) = @_;
 301
 302                 my $len = length($$buffer_ref);
 303                 my $nr = syswrite($fh, $$buffer_ref);
 304                 if (!defined($nr)) {
 305                     return if $! == EINTR || $! == EAGAIN;
 306                     die "drain buffer - write error - $!\n";
 307                 }
 308                 return $nr if !$nr;
 309                 substr($$buffer_ref, 0, $nr, '');
 310                 $len = length($$buffer_ref);
 311                 $write_select->remove($fh) if !$len;
 312             };
 313
 314             while (1) {
 315                 while(my ($readable, $writable) = IO::Select->select($read_select, $write_select, undef, 3)) {
 316                     $check_terminal_size->() if $winch_received;
 317
 318                     foreach my $fh (@$writable) {
 319                         if ($fh == $output_fh) {
 320                             $drain_buffer->($output_fh, \$output_buffer);
 321                             $read_select->add($web_socket) if length($output_buffer) <= $max_buffer_len;
 322                         } elsif ($fh == $web_socket) {
 323                             $drain_buffer->($web_socket, \$websock_buffer);
 324                         }
 325                     }
 326
 327                     foreach my $fh (@$readable) {
 328
 329                         if ($fh == $web_socket) {
 330                             # Read from WebSocket
 331
 332                             my $nr = $wb_socket_read_available_bytes->();
 333                             if (!defined($nr)) {
 334                                 # wait
 335                             } elsif ($nr == 0) {
 336                                 return; # EOF
 337                             } else {
 338                                 my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
 339                                 if (defined($payload) && length($payload)) {
 340                                     $output_buffer .= $payload;
 341                                     $write_select->add($output_fh);
 342                                     if (length($output_buffer) > $max_buffer_len) {
 343                                         $read_select->remove($web_socket);
 344                                     }
 345                                 }
 346                                 return if $req_close;
 347                             }
 348
 349                         } elsif ($fh == $input_fh) {
 350                             # Read from STDIN
 351
 352                             my $nr = sysread($input_fh, my $buff, 4096);
 353                             return if !$nr; # EOF or error
 354
 355                             my $char = ord($buff);
 356
 357                             # Handle escape sequences:
 358                             if ($in_escape_sequence) {
 359                                 $in_escape_sequence = 0;
 360                                 if ($char == 0x71) {
 361                                     # (escape, 'q')
 362                                     return;
 363                                 } elsif ($char == $escape_char) {
 364                                     # (escape, escape)
 365                                     # Pass this one through as a single escapekey
 366                                 } else {
 367                                     # Unknown escape sequence
 368                                     # We could generate a bell or something...
 369                                     # but for now just skip it
 370                                     next;
 371                                 }
 372                             } elsif ($char == $escape_char) {
 373                                 $in_escape_sequence = 1;
 374                                 next;
 375                             }
 376
 377                             # Pass the key through:
 378                             $websock_buffer .= $create_websockt_frame->("0:" . $nr . ":" . $buff);
 379                             $write_select->add($web_socket);
 380                         }
 381                     }
 382                 }
 383                 $check_terminal_size->() if $winch_received;
 384
 385                 # got timeout
 386                 $websock_buffer .= $create_websockt_frame->("2"); # ping server to keep connection alive
 387                 $write_select->add($web_socket);
 388             }
 389         };
 390         my $err = $@;
 391
 392         eval {  # cleanup
 393
 394             # switch back to blocking mode (else later shell commands will fail).
 395             STDIN->blocking(1);
 396
 397             if ($web_socket->connected) {
 398                 # close connection
 399                 $websock_buffer .= "\x88" . pack('N', 0) . pack('n', 0); # Opcode, mask, statuscode
 400                 $full_write->($web_socket, $websock_buffer);
 401                 $websock_buffer = '';
 402                 close($web_socket);
 403             }
 404
 405             # Reset the terminal parameters.
 406             $output_buffer .= "\e[24H\r\n";
 407             $full_write->(\*STDOUT, $output_buffer);
 408             $output_buffer = '';
 409
 410             PVE::PTY::tcsetattr(*STDIN, $old_termios);
 411         };
 412         warn $@ if $@; # show cleanup errors
 413
 414         print STDERR "\nERROR: $err" if $err;
 415
 416         return undef;
 417     }});
 418
 419 our $cmddef = {
 420     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
 421 };
 422
 423 1;