PVE/APIClient/Commands/lxc.pm

   1 package PVE::APIClient::Commands::lxc;
   2
   3 use strict;
   4 use warnings;
   5 use Errno qw(EINTR EAGAIN);
   6 use JSON;
   7 use URI::Escape;
   8 use IO::Select;
   9 use IO::Socket::SSL;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use HTTP::Response;
  13
  14 use PVE::Tools;
  15 use PVE::JSONSchema qw(get_standard_option);
  16 use PVE::CLIHandler;
  17 use PVE::PTY;
  18
  19 use base qw(PVE::CLIHandler);
  20 use PVE::APIClient::Config;
  21
  22 my $CRLF = "\x0D\x0A";
  23 my $max_payload_size = 128*1024;
  24
  25 my $build_web_socket_request = sub {
  26     my ($host, $path, $ticket, $termproxy) = @_;
  27
  28     my $key = '';
  29     $key .= chr(int(rand(256))) for 1 .. 16;
  30     my $enckey = MIME::Base64::encode_base64($key, '');
  31
  32     my $encticket = uri_escape($ticket);
  33     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
  34
  35     $path .= "?port=$termproxy->{port}" .
  36         "&vncticket=" . uri_escape($termproxy->{ticket});
  37
  38     my $request = "GET $path HTTP/1.1$CRLF"
  39         . "Upgrade: WebSocket$CRLF"
  40         . "Connection: Upgrade$CRLF"
  41         . "Host: $host$CRLF"
  42         . "Sec-WebSocket-Key: $enckey$CRLF"
  43         . "Sec-WebSocket-Version: 13$CRLF"
  44         . "Sec-WebSocket-Protocol: binary$CRLF"
  45         . "Cookie: $cookie$CRLF"
  46         . "$CRLF";
  47
  48     return ($request, $enckey);
  49 };
  50
  51 my $create_websockt_frame = sub {
  52     my ($payload) = @_;
  53
  54     my $string = "\x82"; # binary frame
  55     my $payload_len = length($payload);
  56     if ($payload_len <= 125) {
  57         $string .= pack 'C', $payload_len | 128;
  58     } elsif ($payload_len <= 0xffff) {
  59         $string .= pack 'C', 126 | 128;
  60         $string .= pack 'n', $payload_len;
  61     } else {
  62         $string .= pack 'C', 127 | 128;
  63         $string .= pack 'Q>', $payload_len;
  64     }
  65
  66     $string .= pack 'N', 0; # we simply use 0 as mask
  67     $string .= $payload;
  68
  69     return $string;
  70 };
  71
  72 my $parse_web_socket_frame = sub  {
  73     my ($wsbuf_ref) = @_;
  74
  75     my $payload;
  76     my $req_close = 0;
  77
  78     while (my $len = length($$wsbuf_ref)) {
  79         last if $len < 2;
  80
  81         my $hdr = unpack('C', substr($$wsbuf_ref, 0, 1));
  82         my $opcode = $hdr & 0b00001111;
  83         my $fin = $hdr & 0b10000000;
  84
  85         die "received fragmented websocket frame\n" if !$fin;
  86
  87         my $rsv = $hdr & 0b01110000;
  88         die "received websocket frame with RSV flags\n" if $rsv;
  89
  90         my $payload_len = unpack 'C', substr($$wsbuf_ref, 1, 1);
  91
  92         my $masked = $payload_len & 0b10000000;
  93         die "received masked websocket frame from server\n" if $masked;
  94
  95         my $offset = 2;
  96         $payload_len = $payload_len & 0b01111111;
  97         if ($payload_len == 126) {
  98             last if $len < 4;
  99             $payload_len = unpack('n', substr($$wsbuf_ref, $offset, 2));
 100             $offset += 2;
 101         } elsif ($payload_len == 127) {
 102             last if $len < 10;
 103             $payload_len = unpack('Q>', substr($$wsbuf_ref, $offset, 8));
 104             $offset += 8;
 105         }
 106
 107         die "received too large websocket frame (len = $payload_len)\n"
 108             if ($payload_len > $max_payload_size) || ($payload_len < 0);
 109
 110         last if $len < ($offset + $payload_len);
 111
 112         my $data = substr($$wsbuf_ref, 0, $offset + $payload_len, ''); # now consume data
 113
 114         my $frame_data = substr($data, $offset, $payload_len);
 115
 116         $payload = '' if !defined($payload);
 117         $payload .= $frame_data;
 118
 119         if ($opcode == 1 || $opcode == 2) {
 120             # continue
 121         } elsif ($opcode == 8) {
 122             my $statuscode = unpack ("n", $frame_data);
 123             $req_close = 1;
 124         } else {
 125             die "received unhandled websocket opcode $opcode\n";
 126         }
 127     }
 128
 129     return ($payload, $req_close);
 130 };
 131
 132 my $full_write = sub {
 133     my ($fh, $data) = @_;
 134
 135     my $len = length($data);
 136     my $todo = $len;
 137     my $offset = 0;
 138     while(1) {
 139         my $nr = syswrite($fh, $data, $todo, $offset);
 140         if (!defined($nr)) {
 141             next if $! == EINTR || $! == EAGAIN;
 142             die "console write error - $!\n"
 143         }
 144         $offset += $nr;
 145         $todo -= $nr;
 146         last if $todo <= 0;
 147     }
 148
 149     return $len;
 150 };
 151
 152 # Takes an escape character with an optional '^' prefix and returns an escape
 153 # character code.
 154 my $escapekey_to_char = sub {
 155     my ($def) = @_;
 156     if ($def =~ /^\^?([a-zA-Z])$/) {
 157         return 1 + ord(lc($1)) - ord('a');
 158     }
 159     die "bad escape key definition: $def\n";
 160 };
 161
 162 __PACKAGE__->register_method ({
 163     name => 'enter',
 164     path => 'enter',
 165     method => 'POST',
 166     description => "Enter container console.",
 167     parameters => {
 168         additionalProperties => 0,
 169         properties => {
 170             remote => get_standard_option('pveclient-remote-name'),
 171             vmid => {
 172                 description => "The container ID",
 173                 type => 'string',
 174             },
 175         },
 176     },
 177     returns => { type => 'null'},
 178     code => sub {
 179         my ($param) = @_;
 180
 181         my $config = PVE::APIClient::Config->load();
 182         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
 183
 184         # FIXME: This should come from $config
 185         my $escape_char = $escapekey_to_char->('a');
 186
 187         # Get the real node from the resources endpoint
 188         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
 189         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
 190
 191         die "container '$param->{vmid}' does not exist\n"
 192             if !(defined($resource) && defined($resource->{node}));
 193
 194         my $node = $resource->{node};
 195
 196         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
 197
 198         my $termproxy = $conn->post("${api_path}/termproxy", {});
 199
 200         my $web_socket =  IO::Socket::SSL->new(
 201             PeerHost => $conn->{host},
 202             PeerPort => $conn->{port},
 203             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
 204             timeout => 30) ||
 205             die "failed to connect: $!\n";
 206
 207         # WebSocket Handshake
 208
 209         my ($request, $wskey) = $build_web_socket_request->(
 210             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
 211
 212         $full_write->($web_socket, $request);
 213
 214         my $wsbuf = '';
 215
 216         my $wb_socket_read_available_bytes = sub {
 217             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
 218             if (!defined($nr) && !($! == EINTR || $! == EAGAIN)) {
 219                 die "web socket read error - $!\n";
 220             }
 221             return $nr;
 222         };
 223
 224         my $raw_response = '';
 225
 226         while(1) {
 227             my $nr = $wb_socket_read_available_bytes->();
 228             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
 229                 $raw_response = $1;
 230                 last;
 231             }
 232             last if !$nr;
 233         };
 234
 235         # Note: we keep any remaining data in $wsbuf
 236
 237         my $response = HTTP::Response->parse($raw_response);
 238
 239         # Note: Digest::SHA::sha1_base64 has wrong padding
 240         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 241
 242         die "got invalid websocket reponse: $raw_response\n"
 243             if !(($response->code == 101) &&
 244                  (lc $response->header('connection') eq 'upgrade') &&
 245                  (lc $response->header('upgrade') eq 'websocket') &&
 246                  ($response->header('sec-websocket-protocol') eq 'binary') &&
 247                  ($response->header('sec-websocket-accept') eq $wsaccept));
 248
 249         # send auth again...
 250         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
 251         $full_write->($web_socket, $frame);
 252
 253         # Send resize command
 254         my ($columns, $rows) = PVE::PTY::tcgetsize(*STDIN);
 255         $frame = $create_websockt_frame->("1:$columns:$rows:");
 256         $full_write->($web_socket, $frame);
 257
 258         # Set STDIN to "raw -echo" mode
 259         my $old_termios = PVE::PTY::tcgetattr(*STDIN);
 260         my $raw_termios = {%$old_termios};
 261
 262         my $read_select = IO::Select->new;
 263         my $write_select = IO::Select->new;
 264
 265         my $output_buffer = ''; # write buffer for STDOUT
 266         my $websock_buffer = ''; # write buffer for $web_socket
 267
 268         eval {
 269             $SIG{TERM} = $SIG{INT} = $SIG{KILL} = sub { die "received interrupt\n"; };
 270
 271             PVE::PTY::cfmakeraw($raw_termios);
 272             PVE::PTY::tcsetattr(*STDIN, $raw_termios);
 273
 274             # And set it to non-blocking so we can every char with IO::Select.
 275             STDIN->blocking(0);
 276             STDOUT->blocking(0);
 277             $web_socket->blocking(0);
 278             $read_select->add($web_socket);
 279             my $input_fh = \*STDIN;
 280             $read_select->add($input_fh);
 281
 282             my $output_fh = \*STDOUT;
 283
 284             my $in_escape_sequence;
 285
 286             my $winch_received = 0;
 287             $SIG{WINCH} = sub { $winch_received = 1; };
 288
 289             my $check_terminal_size = sub {
 290                 my ($ncols, $nrows) = PVE::PTY::tcgetsize(*STDIN);
 291                 if ($ncols != $columns or $nrows != $rows) {
 292                     $columns = $ncols;
 293                     $rows = $nrows;
 294                     $websock_buffer .= $create_websockt_frame->("1:$columns:$rows:");
 295                     $write_select->add($web_socket);
 296                 }
 297                 $winch_received = 0;
 298             };
 299
 300             my $max_buffer_len = 256*1024;
 301
 302             my $drain_buffer = sub {
 303                 my ($fh, $buffer_ref) = @_;
 304
 305                 my $len = length($$buffer_ref);
 306                 my $nr = syswrite($fh, $$buffer_ref);
 307                 if (!defined($nr)) {
 308                     return if $! == EINTR || $! == EAGAIN;
 309                     die "drain buffer - write error - $!\n";
 310                 }
 311                 return $nr if !$nr;
 312                 substr($$buffer_ref, 0, $nr, '');
 313                 $len = length($$buffer_ref);
 314                 $write_select->remove($fh) if !$len;
 315             };
 316
 317             while (1) {
 318                 while(my ($readable, $writable) = IO::Select->select($read_select, $write_select, undef, 3)) {
 319                     $check_terminal_size->() if $winch_received;
 320
 321                     foreach my $fh (@$writable) {
 322                         if ($fh == $output_fh) {
 323                             $drain_buffer->($output_fh, \$output_buffer);
 324                             $read_select->add($web_socket) if length($output_buffer) <= $max_buffer_len;
 325                         } elsif ($fh == $web_socket) {
 326                             $drain_buffer->($web_socket, \$websock_buffer);
 327                         }
 328                     }
 329
 330                     foreach my $fh (@$readable) {
 331
 332                         if ($fh == $web_socket) {
 333                             # Read from WebSocket
 334
 335                             my $nr = $wb_socket_read_available_bytes->();
 336                             if (!defined($nr)) {
 337                                 # wait
 338                             } elsif ($nr == 0) {
 339                                 return; # EOF
 340                             } else {
 341                                 my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
 342                                 if (defined($payload) && length($payload)) {
 343                                     $output_buffer .= $payload;
 344                                     $write_select->add($output_fh);
 345                                     if (length($output_buffer) > $max_buffer_len) {
 346                                         $read_select->remove($web_socket);
 347                                     }
 348                                 }
 349                                 return if $req_close;
 350                             }
 351
 352                         } elsif ($fh == $input_fh) {
 353                             # Read from STDIN
 354
 355                             my $nr = sysread($input_fh, my $buff, 4096);
 356                             return if !$nr; # EOF or error
 357
 358                             my $char = ord($buff);
 359
 360                             # Handle escape sequences:
 361                             if ($in_escape_sequence) {
 362                                 $in_escape_sequence = 0;
 363                                 if ($char == 0x71) {
 364                                     # (escape, 'q')
 365                                     return;
 366                                 } elsif ($char == $escape_char) {
 367                                     # (escape, escape)
 368                                     # Pass this one through as a single escapekey
 369                                 } else {
 370                                     # Unknown escape sequence
 371                                     # We could generate a bell or something...
 372                                     # but for now just skip it
 373                                     next;
 374                                 }
 375                             } elsif ($char == $escape_char) {
 376                                 $in_escape_sequence = 1;
 377                                 next;
 378                             }
 379
 380                             # Pass the key through:
 381                             $websock_buffer .= $create_websockt_frame->("0:" . $nr . ":" . $buff);
 382                             $write_select->add($web_socket);
 383                         }
 384                     }
 385                 }
 386                 $check_terminal_size->() if $winch_received;
 387
 388                 # got timeout
 389                 $websock_buffer .= $create_websockt_frame->("2"); # ping server to keep connection alive
 390                 $write_select->add($web_socket);
 391             }
 392         };
 393         my $err = $@;
 394
 395         eval {  # cleanup
 396
 397             # switch back to blocking mode (else later shell commands will fail).
 398             STDIN->blocking(1);
 399
 400             if ($web_socket->connected) {
 401                 # close connection
 402                 $websock_buffer .= "\x88" . pack('N', 0) . pack('n', 0); # Opcode, mask, statuscode
 403                 $full_write->($web_socket, $websock_buffer);
 404                 $websock_buffer = '';
 405                 close($web_socket);
 406             }
 407
 408             # Reset the terminal parameters.
 409             $output_buffer .= "\e[24H\r\n";
 410             $full_write->(\*STDOUT, $output_buffer);
 411             $output_buffer = '';
 412
 413             PVE::PTY::tcsetattr(*STDIN, $old_termios);
 414         };
 415         warn $@ if $@; # show cleanup errors
 416
 417         print STDERR "\nERROR: $err" if $err;
 418
 419         return undef;
 420     }});
 421
 422 our $cmddef = {
 423     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
 424 };
 425
 426 1;