websocket: set max_payload_size to 128*1024
[pve-client.git] / PVE / APIClient / Commands / lxc.pm
1 package PVE::APIClient::Commands::lxc;
2
3 use strict;
4 use warnings;
5 use JSON;
6 use URI::Escape;
7 use IO::Select;
8 use IO::Socket::SSL;
9 use MIME::Base64;
10 use Digest::SHA;
11 use HTTP::Response;
12
13 use PVE::Tools;
14 use PVE::JSONSchema qw(get_standard_option);
15 use PVE::CLIHandler;
16 use PVE::PTY;
17
18 use base qw(PVE::CLIHandler);
19 use PVE::APIClient::Config;
20
21 my $CRLF = "\x0D\x0A";
22 my $max_payload_size = 128*1024;
23
24 my $build_web_socket_request = sub {
25     my ($host, $path, $ticket, $termproxy) = @_;
26
27     my $key = '';
28     $key .= chr(int(rand(256))) for 1 .. 16;
29     my $enckey = MIME::Base64::encode_base64($key, '');
30
31     my $encticket = uri_escape($ticket);
32     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
33
34     $path .= "?port=$termproxy->{port}" .
35         "&vncticket=" . uri_escape($termproxy->{ticket});
36
37     my $request = "GET $path HTTP/1.1$CRLF"
38         . "Upgrade: WebSocket$CRLF"
39         . "Connection: Upgrade$CRLF"
40         . "Host: $host$CRLF"
41         . "Sec-WebSocket-Key: $enckey$CRLF"
42         . "Sec-WebSocket-Version: 13$CRLF"
43         . "Sec-WebSocket-Protocol: binary$CRLF"
44         . "Cookie: $cookie$CRLF"
45         . "$CRLF";
46
47     return ($request, $enckey);
48 };
49
50 my $create_websockt_frame = sub {
51     my ($payload) = @_;
52
53     my $string = "\x82"; # binary frame
54     my $payload_len = length($payload);
55     if ($payload_len <= 125) {
56         $string .= pack 'C', $payload_len | 128;
57     } elsif ($payload_len <= 0xffff) {
58         $string .= pack 'C', 126 | 128;
59         $string .= pack 'n', $payload_len;
60     } else {
61         $string .= pack 'C', 127 | 128;
62         $string .= pack 'Q>', $payload_len;
63     }
64
65     $string .= pack 'N', 0; # we simply use 0 as mask
66     $string .= $payload;
67
68     return $string;
69 };
70
71 my $parse_web_socket_frame = sub  {
72     my ($wsbuf_ref) = @_;
73
74     my $payload;
75     my $req_close = 0;
76
77     while (my $len = length($$wsbuf_ref)) {
78         last if $len < 2;
79
80         my $hdr = unpack('C', substr($$wsbuf_ref, 0, 1));
81         my $opcode = $hdr & 0b00001111;
82         my $fin = $hdr & 0b10000000;
83
84         die "received fragmented websocket frame\n" if !$fin;
85
86         my $rsv = $hdr & 0b01110000;
87         die "received websocket frame with RSV flags\n" if $rsv;
88
89         my $payload_len = unpack 'C', substr($$wsbuf_ref, 1, 1);
90
91         my $masked = $payload_len & 0b10000000;
92         die "received masked websocket frame from server\n" if $masked;
93
94         my $offset = 2;
95         $payload_len = $payload_len & 0b01111111;
96         if ($payload_len == 126) {
97             last if $len < 4;
98             $payload_len = unpack('n', substr($$wsbuf_ref, $offset, 2));
99             $offset += 2;
100         } elsif ($payload_len == 127) {
101             last if $len < 10;
102             $payload_len = unpack('Q>', substr($$wsbuf_ref, $offset, 8));
103             $offset += 8;
104         }
105
106         die "received too large websocket frame (len = $payload_len)\n"
107             if ($payload_len > $max_payload_size) || ($payload_len < 0);
108
109         last if $len < ($offset + $payload_len);
110
111         my $data = substr($$wsbuf_ref, 0, $offset + $payload_len, ''); # now consume data
112
113         my $frame_data = substr($data, $offset, $payload_len);
114
115         $payload = '' if !defined($payload);
116         $payload .= $frame_data;
117
118         if ($opcode == 1 || $opcode == 2) {
119             # continue
120         } elsif ($opcode == 8) {
121             my $statuscode = unpack ("n", $frame_data);
122             $req_close = 1;
123         } else {
124             die "received unhandled websocket opcode $opcode\n";
125         }
126     }
127
128     return ($payload, $req_close);
129 };
130
131 __PACKAGE__->register_method ({
132     name => 'enter',
133     path => 'enter',
134     method => 'POST',
135     description => "Enter container console.",
136     parameters => {
137         additionalProperties => 0,
138         properties => {
139             remote => get_standard_option('pveclient-remote-name'),
140             vmid => {
141                 description => "The container ID",
142                 type => 'string',
143             },
144         },
145     },
146     returns => { type => 'null'},
147     code => sub {
148         my ($param) = @_;
149
150         my $config = PVE::APIClient::Config->load();
151         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
152
153         # Get the real node from the resources endpoint
154         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
155         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
156
157         die "container '$param->{vmid}' does not exist\n"
158             if !(defined($resource) && defined($resource->{node}));
159
160         my $node = $resource->{node};
161
162         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
163
164         my $termproxy = $conn->post("${api_path}/termproxy", {});
165
166         my $web_socket =  IO::Socket::SSL->new(
167             PeerHost => $conn->{host},
168             PeerPort => $conn->{port},
169             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
170             timeout => 30) ||
171             die "failed to connect: $!\n";
172
173         # WebSocket Handshake
174
175         my ($request, $wskey) = $build_web_socket_request->(
176             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
177
178         $web_socket->syswrite($request);
179
180         my $wsbuf = '';
181
182         my $wb_socket_read_available_bytes = sub {
183             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
184             die "web socket read error - $!\n" if $nr < 0;
185             return $nr;
186         };
187
188         my $raw_response = '';
189
190         while(1) {
191             my $nr = $wb_socket_read_available_bytes->();
192             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
193                 $raw_response = $1;
194                 last;
195             }
196             last if !$nr;
197         };
198
199         # Note: we keep any remaining data in $wsbuf
200
201         my $response = HTTP::Response->parse($raw_response);
202
203         # Note: Digest::SHA::sha1_base64 has wrong padding
204         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
205
206         die "got invalid websocket reponse: $raw_response\n"
207             if !(($response->code == 101) &&
208                  (lc $response->header('connection') eq 'upgrade') &&
209                  (lc $response->header('upgrade') eq 'websocket') &&
210                  ($response->header('sec-websocket-protocol') eq 'binary') &&
211                  ($response->header('sec-websocket-accept') eq $wsaccept));
212
213         # send auth again...
214         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
215         $web_socket->syswrite($frame);
216
217         # Send resize command
218         my ($columns, $rows) = PVE::PTY::tcgetsize(*STDIN);
219         $frame = $create_websockt_frame->("1:$columns:$rows:");
220         $web_socket->syswrite($frame);
221
222         # Set STDIN to "raw -echo" mode
223         my $old_termios = PVE::PTY::tcgetattr(*STDIN);
224         my $raw_termios = {%$old_termios};
225
226         my $select = IO::Select->new;
227
228         eval {
229             $SIG{TERM} = $SIG{INT} = $SIG{KILL} = sub { die "received interrupt\n"; };
230
231             PVE::PTY::cfmakeraw($raw_termios);
232             PVE::PTY::tcsetattr(*STDIN, $raw_termios);
233
234             # And set it to non-blocking so we can every char with IO::Select.
235             STDIN->blocking(0);
236
237             $web_socket->blocking(1);
238             $select->add($web_socket);
239             my $input_fh = fileno(STDIN);
240             $select->add($input_fh);
241
242             my $ctrl_a_pressed_before = 0;
243
244             while (1) {
245                 while(my @ready = $select->can_read(3)) {
246                     foreach my $fh (@ready) {
247
248                         if ($fh == $web_socket) {
249                             # Read from WebSocket
250
251                             my $nr = $wb_socket_read_available_bytes->();
252                             if (!defined($nr)) {
253                                 die "web socket read error $!\n";
254                             } elsif ($nr == 0) {
255                                 return; # EOF
256                             } else {
257                                 my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
258                                 if ($payload) {
259                                     syswrite(\*STDOUT, $payload);
260                                 }
261                                 return if $req_close;
262                             }
263
264                         } elsif ($fh == $input_fh) {
265                             # Read from STDIN
266
267                             my $nr = read(\*STDIN, my $buff, 4096);
268                             return if !$nr; # EOF or error
269
270                             my $char = ord($buff);
271
272                             # check for CTRL-a-q
273                             return if $ctrl_a_pressed_before == 1 && $char == hex("0x71");
274
275                             $ctrl_a_pressed_before = ($char == hex("0x01") && $ctrl_a_pressed_before == 0) ? 1 : 0;
276
277                             my $frame = $create_websockt_frame->("0:" . $nr . ":" . $buff);
278                             syswrite($web_socket, $frame);
279                         }
280                     }
281                 }
282                 # got timeout
283                 syswrite($web_socket, $create_websockt_frame->("2")); # ping server to keep connection alive
284             }
285         };
286         my $err = $@;
287
288         eval {  # cleanup
289
290             # switch back to blocking mode (else later shell commands will fail).
291             STDIN->blocking(1);
292
293             if ($web_socket->connected) {
294                 # close connection
295                 my $msg = "\x88" . pack('N', 0) . pack('n', 0); # Opcode, mask, statuscode
296                 $web_socket->syswrite($msg);
297                 close($web_socket);
298             }
299
300             # Reset the terminal parameters.
301             syswrite(\*STDOUT, "\e[24H\r\n");
302             PVE::PTY::tcsetattr(*STDIN, $old_termios);
303         };
304         warn $@ if $@; # show cleanup errors
305
306         print STDERR "\nERROR: $err" if $err;
307
308         return undef;
309     }});
310
311 __PACKAGE__->register_method ({
312     name => 'list',
313     path => 'list',
314     method => 'GET',
315     description => "List containers.",
316     parameters => {
317         additionalProperties => 0,
318         properties => {
319             remote => get_standard_option('pveclient-remote-name'),
320         },
321     },
322     returns => { type => 'null'},
323     code => sub {
324         my ($param) = @_;
325
326         die "implement me";
327
328     }});
329
330
331 our $cmddef = {
332     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
333     list => [ __PACKAGE__, 'list', ['remote']],
334 };
335
336 1;