PVE/APIClient/Commands/lxc.pm

   1 package PVE::APIClient::Commands::lxc;
   2
   3 use strict;
   4 use warnings;
   5 use JSON;
   6 use URI::Escape;
   7 use IO::Select;
   8 use IO::Socket::SSL;
   9 use MIME::Base64;
  10 use Digest::SHA;
  11
  12 use PVE::Tools;
  13 use PVE::JSONSchema qw(get_standard_option);
  14 use PVE::CLIHandler;
  15
  16 use base qw(PVE::CLIHandler);
  17 use PVE::APIClient::Config;
  18
  19 my $CRLF = "\x0D\x0A";
  20 my $max_payload_size = 65536;
  21
  22 my $build_web_socket_request = sub {
  23     my ($path, $ticket, $termproxy) = @_;
  24
  25     my $key = '';
  26     $key .= chr(int(rand(256))) for 1 .. 16;
  27     my $enckey = MIME::Base64::encode_base64($key, '');
  28
  29     my $encticket = uri_escape($ticket);
  30     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
  31
  32     $path .= "?port=$termproxy->{port}" .
  33         "&vncticket=" . uri_escape($termproxy->{ticket});
  34
  35     my $request = "GET $path HTTP/1.1$CRLF"
  36         . "Upgrade: WebSocket$CRLF"
  37         . "Connection: Upgrade$CRLF"
  38         . "Sec-WebSocket-Key: $enckey$CRLF"
  39         . "Sec-WebSocket-Version: 13$CRLF"
  40         . "Sec-WebSocket-Protocol: binary$CRLF"
  41         . "Cookie: $cookie$CRLF"
  42         . "$CRLF";
  43
  44     return ($request, $enckey);
  45 };
  46
  47 my $create_websockt_frame = sub {
  48     my ($payload) = @_;
  49
  50     my $string = "\x82"; # binary frame
  51     my $payload_len = length($payload);
  52     if ($payload_len <= 125) {
  53         $string .= pack 'C', $payload_len | 128;
  54     } elsif ($payload_len <= 0xffff) {
  55         $string .= pack 'C', 126 | 128;
  56         $string .= pack 'n', $payload_len;
  57     } else {
  58         $string .= pack 'C', 127 | 128;
  59         $string .= pack 'Q>', $payload_len;
  60     }
  61
  62     $string .= pack 'N', 0; # we simply use 0 as mask
  63     $string .= $payload;
  64
  65     return $string;
  66 };
  67
  68 my $parse_web_socket_frame = sub  {
  69     my ($wsbuf_ref) = @_;
  70
  71     my $wsbuf = $$wsbuf_ref;
  72
  73     my $payload;
  74     my $req_close = 0;
  75
  76     while (my $len = length($wsbuf)) {
  77         last if $len < 2;
  78
  79         my $hdr = unpack('C', substr($wsbuf, 0, 1));
  80         my $opcode = $hdr & 0b00001111;
  81         my $fin = $hdr & 0b10000000;
  82
  83         die "received fragmented websocket frame\n" if !$fin;
  84
  85         my $rsv = $hdr & 0b01110000;
  86         die "received websocket frame with RSV flags\n" if $rsv;
  87
  88         my $payload_len = unpack 'C', substr($wsbuf, 1, 1);
  89
  90         my $masked = $payload_len & 0b10000000;
  91         die "received masked websocket frame from server\n" if $masked;
  92
  93         my $offset = 2;
  94         $payload_len = $payload_len & 0b01111111;
  95         if ($payload_len == 126) {
  96             last if $len < 4;
  97             $payload_len = unpack('n', substr($wsbuf, $offset, 2));
  98             $offset += 2;
  99         } elsif ($payload_len == 127) {
 100             last if $len < 10;
 101             $payload_len = unpack('Q>', substr($wsbuf, $offset, 8));
 102             $offset += 8;
 103         }
 104
 105         die "received too large websocket frame (len = $payload_len)\n"
 106             if ($payload_len > $max_payload_size) || ($payload_len < 0);
 107
 108         last if $len < ($offset + $payload_len);
 109
 110         my $data = substr($wsbuf, 0, $offset + $payload_len, ''); # now consume data
 111
 112         my $frame_data = substr($data, $offset, $payload_len);
 113
 114         $payload = '' if !defined($payload);
 115         $payload .= $frame_data;
 116
 117         if ($opcode == 1 || $opcode == 2) {
 118             # continue
 119         } elsif ($opcode == 8) {
 120             my $statuscode = unpack ("n", $frame_data);
 121             $req_close = 1;
 122         } else {
 123             die "received unhandled websocket opcode $opcode\n";
 124         }
 125     }
 126
 127     return ($payload, $req_close);
 128 };
 129
 130 __PACKAGE__->register_method ({
 131     name => 'enter',
 132     path => 'enter',
 133     method => 'POST',
 134     description => "Enter container console.",
 135     parameters => {
 136         additionalProperties => 0,
 137         properties => {
 138             remote => get_standard_option('pveclient-remote-name'),
 139             vmid => {
 140                 description => "The container ID",
 141                 type => 'string',
 142             },
 143         },
 144     },
 145     returns => { type => 'null'},
 146     code => sub {
 147         my ($param) = @_;
 148
 149         my $conn = PVE::APIClient::Config::get_remote_connection($param->{remote});
 150
 151         # Get the real node from the resources endpoint
 152         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
 153         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
 154
 155         die "container '$param->{vmid}' does not exist\n"
 156             if !(defined($resource) && defined($resource->{node}));
 157
 158         my $node = $resource->{node};
 159
 160         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
 161
 162         my $termproxy = $conn->post("${api_path}/termproxy", {});
 163
 164         my $web_socket =  IO::Socket::SSL->new(
 165             PeerHost => $conn->{host},
 166             PeerPort => $conn->{port},
 167             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
 168             timeout => 30) ||
 169             die "failed to connect: $!\n";
 170
 171         # WebSocket Handshake
 172
 173         my ($request, $wskey) = $build_web_socket_request->(
 174             "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
 175
 176         $web_socket->syswrite($request);
 177
 178         my $wsbuf = '';
 179
 180         my $wb_socket_read_available_bytes = sub {
 181             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
 182             die "web socket read error - $!\n" if $nr < 0;
 183             return $nr;
 184         };
 185
 186         my $raw_response = '';
 187
 188         while(1) {
 189             my $nr = $wb_socket_read_available_bytes->();
 190             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
 191                 $raw_response = $1;
 192                 last;
 193             }
 194             last if !$nr;
 195         };
 196
 197         # Note: we keep any remaining data in $wsbuf
 198
 199         my $response = HTTP::Response->parse($raw_response);
 200
 201         # Note: Digest::SHA::sha1_base64 has wrong padding
 202         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 203
 204         die "got invalid websocket reponse: $raw_response\n"
 205             if !(($response->code == 101) &&
 206                  ($response->header('connection') eq 'upgrade') &&
 207                  ($response->header('upgrade') eq 'websocket') &&
 208                  ($response->header('sec-websocket-protocol') eq 'binary') &&
 209                  ($response->header('sec-websocket-accept') eq $wsaccept));
 210
 211         # send auth again...
 212         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
 213         $web_socket->syswrite($frame);
 214
 215         my $select = IO::Select->new;
 216
 217         $web_socket->blocking(0);
 218         $select->add($web_socket);
 219
 220         while(my @ready = $select->can_read) {
 221             foreach my $fh (@ready) {
 222                 if ($fh == $web_socket) {
 223                     my $nr = $wb_socket_read_available_bytes->();
 224                     my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
 225                     print "GOT: $payload\n" if defined($payload);
 226                     last if $req_close;
 227                     last if !$nr; # eos
 228                 } else {
 229                     die "internal error - unknown handle";
 230                 }
 231             }
 232         }
 233
 234     }});
 235
 236 __PACKAGE__->register_method ({
 237     name => 'list',
 238     path => 'list',
 239     method => 'GET',
 240     description => "List containers.",
 241     parameters => {
 242         additionalProperties => 0,
 243         properties => {
 244             remote => get_standard_option('pveclient-remote-name'),
 245         },
 246     },
 247     returns => { type => 'null'},
 248     code => sub {
 249         my ($param) = @_;
 250
 251         die "implement me";
 252
 253     }});
 254
 255
 256 our $cmddef = {
 257     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
 258     list => [ __PACKAGE__, 'list', ['remote']],
 259 };
 260
 261 1;