PVE/APIClient/Commands/lxc.pm

   1 package PVE::APIClient::Commands::lxc;
   2
   3 use strict;
   4 use warnings;
   5 use Errno qw(EINTR EAGAIN);
   6 use JSON;
   7 use URI::Escape;
   8 use IO::Select;
   9 use IO::Socket::SSL;
  10 use MIME::Base64;
  11 use Digest::SHA;
  12 use HTTP::Response;
  13
  14 use PVE::APIClient::JSONSchema qw(get_standard_option);
  15 use PVE::APIClient::CLIHandler;
  16 use PVE::APIClient::PTY;
  17
  18 use base qw(PVE::APIClient::CLIHandler);
  19 use PVE::APIClient::Config;
  20
  21 my $CRLF = "\x0D\x0A";
  22 my $max_payload_size = 128*1024;
  23
  24 my $build_web_socket_request = sub {
  25     my ($host, $path, $ticket, $termproxy) = @_;
  26
  27     my $key = '';
  28     $key .= chr(int(rand(256))) for 1 .. 16;
  29     my $enckey = MIME::Base64::encode_base64($key, '');
  30
  31     my $encticket = uri_escape($ticket);
  32     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
  33
  34     $path .= "?port=$termproxy->{port}" .
  35         "&vncticket=" . uri_escape($termproxy->{ticket});
  36
  37     my $request = "GET $path HTTP/1.1$CRLF"
  38         . "Upgrade: WebSocket$CRLF"
  39         . "Connection: Upgrade$CRLF"
  40         . "Host: $host$CRLF"
  41         . "Sec-WebSocket-Key: $enckey$CRLF"
  42         . "Sec-WebSocket-Version: 13$CRLF"
  43         . "Sec-WebSocket-Protocol: binary$CRLF"
  44         . "Cookie: $cookie$CRLF"
  45         . "$CRLF";
  46
  47     return ($request, $enckey);
  48 };
  49
  50 my $create_websockt_frame = sub {
  51     my ($payload) = @_;
  52
  53     my $string = "\x82"; # binary frame
  54     my $payload_len = length($payload);
  55     if ($payload_len <= 125) {
  56         $string .= pack 'C', $payload_len | 128;
  57     } elsif ($payload_len <= 0xffff) {
  58         $string .= pack 'C', 126 | 128;
  59         $string .= pack 'n', $payload_len;
  60     } else {
  61         $string .= pack 'C', 127 | 128;
  62         $string .= pack 'Q>', $payload_len;
  63     }
  64
  65     $string .= pack 'N', 0; # we simply use 0 as mask
  66     $string .= $payload;
  67
  68     return $string;
  69 };
  70
  71 my $parse_web_socket_frame = sub  {
  72     my ($wsbuf_ref) = @_;
  73
  74     my $payload;
  75     my $req_close = 0;
  76
  77     while (my $len = length($$wsbuf_ref)) {
  78         last if $len < 2;
  79
  80         my $hdr = unpack('C', substr($$wsbuf_ref, 0, 1));
  81         my $opcode = $hdr & 0b00001111;
  82         my $fin = $hdr & 0b10000000;
  83
  84         die "received fragmented websocket frame\n" if !$fin;
  85
  86         my $rsv = $hdr & 0b01110000;
  87         die "received websocket frame with RSV flags\n" if $rsv;
  88
  89         my $payload_len = unpack 'C', substr($$wsbuf_ref, 1, 1);
  90
  91         my $masked = $payload_len & 0b10000000;
  92         die "received masked websocket frame from server\n" if $masked;
  93
  94         my $offset = 2;
  95         $payload_len = $payload_len & 0b01111111;
  96         if ($payload_len == 126) {
  97             last if $len < 4;
  98             $payload_len = unpack('n', substr($$wsbuf_ref, $offset, 2));
  99             $offset += 2;
 100         } elsif ($payload_len == 127) {
 101             last if $len < 10;
 102             $payload_len = unpack('Q>', substr($$wsbuf_ref, $offset, 8));
 103             $offset += 8;
 104         }
 105
 106         die "received too large websocket frame (len = $payload_len)\n"
 107             if ($payload_len > $max_payload_size) || ($payload_len < 0);
 108
 109         last if $len < ($offset + $payload_len);
 110
 111         my $data = substr($$wsbuf_ref, 0, $offset + $payload_len, ''); # now consume data
 112
 113         my $frame_data = substr($data, $offset, $payload_len);
 114
 115         $payload = '' if !defined($payload);
 116         $payload .= $frame_data;
 117
 118         if ($opcode == 1 || $opcode == 2) {
 119             # continue
 120         } elsif ($opcode == 8) {
 121             my $statuscode = unpack ("n", $frame_data);
 122             $req_close = 1;
 123         } else {
 124             die "received unhandled websocket opcode $opcode\n";
 125         }
 126     }
 127
 128     return ($payload, $req_close);
 129 };
 130
 131 my $full_write = sub {
 132     my ($fh, $data) = @_;
 133
 134     my $len = length($data);
 135     my $todo = $len;
 136     my $offset = 0;
 137     while(1) {
 138         my $nr = syswrite($fh, $data, $todo, $offset);
 139         if (!defined($nr)) {
 140             next if $! == EINTR || $! == EAGAIN;
 141             die "console write error - $!\n"
 142         }
 143         $offset += $nr;
 144         $todo -= $nr;
 145         last if $todo <= 0;
 146     }
 147
 148     return $len;
 149 };
 150
 151 # Takes an escape character with an optional '^' prefix and returns an escape
 152 # character code.
 153 my $escapekey_to_char = sub {
 154     my ($def) = @_;
 155     if ($def =~ /^\^?([a-zA-Z])$/) {
 156         return 1 + ord(lc($1)) - ord('a');
 157     }
 158     die "bad escape key definition: $def\n";
 159 };
 160
 161 __PACKAGE__->register_method ({
 162     name => 'enter',
 163     path => 'enter',
 164     method => 'POST',
 165     description => "Enter container console.",
 166     parameters => {
 167         additionalProperties => 0,
 168         properties => {
 169             remote => get_standard_option('pveclient-remote-name'),
 170             vmid => get_standard_option('pve-vmid')
 171         },
 172     },
 173     returns => { type => 'null'},
 174     code => sub {
 175         my ($param) = @_;
 176
 177         my $config = PVE::APIClient::Config->load();
 178         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
 179
 180         # FIXME: This should come from $config
 181         my $escape_char = $escapekey_to_char->('a');
 182
 183         # Get the real node from the resources endpoint
 184         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
 185         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
 186
 187         die "container '$param->{vmid}' does not exist\n"
 188             if !(defined($resource) && defined($resource->{node}));
 189
 190         my $node = $resource->{node};
 191
 192         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
 193
 194         my $termproxy = $conn->post("${api_path}/termproxy", {});
 195
 196         my $web_socket =  IO::Socket::SSL->new(
 197             PeerHost => $conn->{host},
 198             PeerPort => $conn->{port},
 199             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
 200             timeout => 30) ||
 201             die "failed to connect: $!\n";
 202
 203         # WebSocket Handshake
 204
 205         my ($request, $wskey) = $build_web_socket_request->(
 206             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
 207
 208         $full_write->($web_socket, $request);
 209
 210         my $wsbuf = '';
 211
 212         my $wb_socket_read_available_bytes = sub {
 213             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
 214             if (!defined($nr) && !($! == EINTR || $! == EAGAIN)) {
 215                 die "web socket read error - $!\n";
 216             }
 217             return $nr;
 218         };
 219
 220         my $raw_response = '';
 221
 222         while(1) {
 223             my $nr = $wb_socket_read_available_bytes->();
 224             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
 225                 $raw_response = $1;
 226                 last;
 227             }
 228             last if !$nr;
 229         };
 230
 231         # Note: we keep any remaining data in $wsbuf
 232
 233         my $response = HTTP::Response->parse($raw_response);
 234
 235         # Note: Digest::SHA::sha1_base64 has wrong padding
 236         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
 237
 238         die "got invalid websocket reponse: $raw_response\n"
 239             if !(($response->code == 101) &&
 240                  (lc $response->header('connection') eq 'upgrade') &&
 241                  (lc $response->header('upgrade') eq 'websocket') &&
 242                  ($response->header('sec-websocket-protocol') eq 'binary') &&
 243                  ($response->header('sec-websocket-accept') eq $wsaccept));
 244
 245         # send auth again...
 246         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
 247         $full_write->($web_socket, $frame);
 248
 249         # Send resize command
 250         my ($columns, $rows) = PVE::APIClient::PTY::tcgetsize(*STDIN);
 251         $frame = $create_websockt_frame->("1:$columns:$rows:");
 252         $full_write->($web_socket, $frame);
 253
 254         # Set STDIN to "raw -echo" mode
 255         my $old_termios = PVE::APIClient::PTY::tcgetattr(*STDIN);
 256         my $raw_termios = {%$old_termios};
 257
 258         my $read_select = IO::Select->new;
 259         my $write_select = IO::Select->new;
 260
 261         my $output_buffer = ''; # write buffer for STDOUT
 262         my $websock_buffer = ''; # write buffer for $web_socket
 263
 264         eval {
 265             $SIG{TERM} = $SIG{INT} = $SIG{KILL} = sub { die "received interrupt\n"; };
 266
 267             PVE::APIClient::PTY::cfmakeraw($raw_termios);
 268             PVE::APIClient::PTY::tcsetattr(*STDIN, $raw_termios);
 269
 270             # And set it to non-blocking so we can every char with IO::Select.
 271             STDIN->blocking(0);
 272             STDOUT->blocking(0);
 273             $web_socket->blocking(0);
 274             $read_select->add($web_socket);
 275             my $input_fh = \*STDIN;
 276             $read_select->add($input_fh);
 277
 278             my $output_fh = \*STDOUT;
 279
 280             my $in_escape_sequence;
 281
 282             my $winch_received = 0;
 283             $SIG{WINCH} = sub { $winch_received = 1; };
 284
 285             my $check_terminal_size = sub {
 286                 my ($ncols, $nrows) = PVE::APIClient::PTY::tcgetsize(*STDIN);
 287                 if ($ncols != $columns or $nrows != $rows) {
 288                     $columns = $ncols;
 289                     $rows = $nrows;
 290                     $websock_buffer .= $create_websockt_frame->("1:$columns:$rows:");
 291                     $write_select->add($web_socket);
 292                 }
 293                 $winch_received = 0;
 294             };
 295
 296             my $max_buffer_len = 256*1024;
 297
 298             my $drain_buffer = sub {
 299                 my ($fh, $buffer_ref) = @_;
 300
 301                 my $len = length($$buffer_ref);
 302                 my $nr = syswrite($fh, $$buffer_ref);
 303                 if (!defined($nr)) {
 304                     return if $! == EINTR || $! == EAGAIN;
 305                     die "drain buffer - write error - $!\n";
 306                 }
 307                 return $nr if !$nr;
 308                 substr($$buffer_ref, 0, $nr, '');
 309                 $len = length($$buffer_ref);
 310                 $write_select->remove($fh) if !$len;
 311             };
 312
 313             while (1) {
 314                 while(my ($readable, $writable) = IO::Select->select($read_select, $write_select, undef, 3)) {
 315                     $check_terminal_size->() if $winch_received;
 316
 317                     foreach my $fh (@$writable) {
 318                         if ($fh == $output_fh) {
 319                             $drain_buffer->($output_fh, \$output_buffer);
 320                             $read_select->add($web_socket) if length($output_buffer) <= $max_buffer_len;
 321                         } elsif ($fh == $web_socket) {
 322                             $drain_buffer->($web_socket, \$websock_buffer);
 323                         }
 324                     }
 325
 326                     foreach my $fh (@$readable) {
 327
 328                         if ($fh == $web_socket) {
 329                             # Read from WebSocket
 330
 331                             my $nr = $wb_socket_read_available_bytes->();
 332                             if (!defined($nr)) {
 333                                 # wait
 334                             } elsif ($nr == 0) {
 335                                 return; # EOF
 336                             } else {
 337                                 my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
 338                                 if (defined($payload) && length($payload)) {
 339                                     $output_buffer .= $payload;
 340                                     $write_select->add($output_fh);
 341                                     if (length($output_buffer) > $max_buffer_len) {
 342                                         $read_select->remove($web_socket);
 343                                     }
 344                                 }
 345                                 return if $req_close;
 346                             }
 347
 348                         } elsif ($fh == $input_fh) {
 349                             # Read from STDIN
 350
 351                             my $nr = sysread($input_fh, my $buff, 4096);
 352                             return if !$nr; # EOF or error
 353
 354                             my $char = ord($buff);
 355
 356                             # Handle escape sequences:
 357                             if ($in_escape_sequence) {
 358                                 $in_escape_sequence = 0;
 359                                 if ($char == 0x71) {
 360                                     # (escape, 'q')
 361                                     return;
 362                                 } elsif ($char == $escape_char) {
 363                                     # (escape, escape)
 364                                     # Pass this one through as a single escapekey
 365                                 } else {
 366                                     # Unknown escape sequence
 367                                     # We could generate a bell or something...
 368                                     # but for now just skip it
 369                                     next;
 370                                 }
 371                             } elsif ($char == $escape_char) {
 372                                 $in_escape_sequence = 1;
 373                                 next;
 374                             }
 375
 376                             # Pass the key through:
 377                             $websock_buffer .= $create_websockt_frame->("0:" . $nr . ":" . $buff);
 378                             $write_select->add($web_socket);
 379                         }
 380                     }
 381                 }
 382                 $check_terminal_size->() if $winch_received;
 383
 384                 # got timeout
 385                 $websock_buffer .= $create_websockt_frame->("2"); # ping server to keep connection alive
 386                 $write_select->add($web_socket);
 387             }
 388         };
 389         my $err = $@;
 390
 391         eval {  # cleanup
 392
 393             # switch back to blocking mode (else later shell commands will fail).
 394             STDIN->blocking(1);
 395
 396             if ($web_socket->connected) {
 397                 # close connection
 398                 $websock_buffer .= "\x88" . pack('N', 0) . pack('n', 0); # Opcode, mask, statuscode
 399                 $full_write->($web_socket, $websock_buffer);
 400                 $websock_buffer = '';
 401                 close($web_socket);
 402             }
 403
 404             # Reset the terminal parameters.
 405             $output_buffer .= "\e[24H\r\n";
 406             $full_write->(\*STDOUT, $output_buffer);
 407             $output_buffer = '';
 408
 409             PVE::APIClient::PTY::tcsetattr(*STDIN, $old_termios);
 410         };
 411         warn $@ if $@; # show cleanup errors
 412
 413         print STDERR "\nERROR: $err" if $err;
 414
 415         return undef;
 416     }});
 417
 418 our $cmddef = {
 419     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
 420 };
 421
 422 1;