c60017b551ebd750236568807d4b62d21e4c7024
[pve-client.git] / PVE / APIClient / Commands / lxc.pm
1 package PVE::APIClient::Commands::lxc;
2
3 use strict;
4 use warnings;
5 use Errno qw(EINTR EAGAIN);
6 use JSON;
7 use URI::Escape;
8 use IO::Select;
9 use IO::Socket::SSL;
10 use MIME::Base64;
11 use Digest::SHA;
12 use HTTP::Response;
13
14 use PVE::Tools;
15 use PVE::JSONSchema qw(get_standard_option);
16 use PVE::CLIHandler;
17 use PVE::PTY;
18
19 use base qw(PVE::CLIHandler);
20 use PVE::APIClient::Config;
21
22 my $CRLF = "\x0D\x0A";
23 my $max_payload_size = 128*1024;
24
25 my $build_web_socket_request = sub {
26     my ($host, $path, $ticket, $termproxy) = @_;
27
28     my $key = '';
29     $key .= chr(int(rand(256))) for 1 .. 16;
30     my $enckey = MIME::Base64::encode_base64($key, '');
31
32     my $encticket = uri_escape($ticket);
33     my $cookie = "PVEAuthCookie=$encticket; path=/; secure;";
34
35     $path .= "?port=$termproxy->{port}" .
36         "&vncticket=" . uri_escape($termproxy->{ticket});
37
38     my $request = "GET $path HTTP/1.1$CRLF"
39         . "Upgrade: WebSocket$CRLF"
40         . "Connection: Upgrade$CRLF"
41         . "Host: $host$CRLF"
42         . "Sec-WebSocket-Key: $enckey$CRLF"
43         . "Sec-WebSocket-Version: 13$CRLF"
44         . "Sec-WebSocket-Protocol: binary$CRLF"
45         . "Cookie: $cookie$CRLF"
46         . "$CRLF";
47
48     return ($request, $enckey);
49 };
50
51 my $create_websockt_frame = sub {
52     my ($payload) = @_;
53
54     my $string = "\x82"; # binary frame
55     my $payload_len = length($payload);
56     if ($payload_len <= 125) {
57         $string .= pack 'C', $payload_len | 128;
58     } elsif ($payload_len <= 0xffff) {
59         $string .= pack 'C', 126 | 128;
60         $string .= pack 'n', $payload_len;
61     } else {
62         $string .= pack 'C', 127 | 128;
63         $string .= pack 'Q>', $payload_len;
64     }
65
66     $string .= pack 'N', 0; # we simply use 0 as mask
67     $string .= $payload;
68
69     return $string;
70 };
71
72 my $parse_web_socket_frame = sub  {
73     my ($wsbuf_ref) = @_;
74
75     my $payload;
76     my $req_close = 0;
77
78     while (my $len = length($$wsbuf_ref)) {
79         last if $len < 2;
80
81         my $hdr = unpack('C', substr($$wsbuf_ref, 0, 1));
82         my $opcode = $hdr & 0b00001111;
83         my $fin = $hdr & 0b10000000;
84
85         die "received fragmented websocket frame\n" if !$fin;
86
87         my $rsv = $hdr & 0b01110000;
88         die "received websocket frame with RSV flags\n" if $rsv;
89
90         my $payload_len = unpack 'C', substr($$wsbuf_ref, 1, 1);
91
92         my $masked = $payload_len & 0b10000000;
93         die "received masked websocket frame from server\n" if $masked;
94
95         my $offset = 2;
96         $payload_len = $payload_len & 0b01111111;
97         if ($payload_len == 126) {
98             last if $len < 4;
99             $payload_len = unpack('n', substr($$wsbuf_ref, $offset, 2));
100             $offset += 2;
101         } elsif ($payload_len == 127) {
102             last if $len < 10;
103             $payload_len = unpack('Q>', substr($$wsbuf_ref, $offset, 8));
104             $offset += 8;
105         }
106
107         die "received too large websocket frame (len = $payload_len)\n"
108             if ($payload_len > $max_payload_size) || ($payload_len < 0);
109
110         last if $len < ($offset + $payload_len);
111
112         my $data = substr($$wsbuf_ref, 0, $offset + $payload_len, ''); # now consume data
113
114         my $frame_data = substr($data, $offset, $payload_len);
115
116         $payload = '' if !defined($payload);
117         $payload .= $frame_data;
118
119         if ($opcode == 1 || $opcode == 2) {
120             # continue
121         } elsif ($opcode == 8) {
122             my $statuscode = unpack ("n", $frame_data);
123             $req_close = 1;
124         } else {
125             die "received unhandled websocket opcode $opcode\n";
126         }
127     }
128
129     return ($payload, $req_close);
130 };
131
132 my $full_write = sub {
133     my ($fh, $data) = @_;
134
135     my $len = length($data);
136     my $todo = $len;
137     my $offset = 0;
138     while(1) {
139         my $nr = syswrite($fh, $data, $todo, $offset);
140         if (!defined($nr)) {
141             next if $! == EINTR || $! == EAGAIN;
142             die "console write error - $!\n"
143         }
144         $offset += $nr;
145         $todo -= $nr;
146         last if $todo <= 0;
147     }
148
149     return $len;
150 };
151
152 __PACKAGE__->register_method ({
153     name => 'enter',
154     path => 'enter',
155     method => 'POST',
156     description => "Enter container console.",
157     parameters => {
158         additionalProperties => 0,
159         properties => {
160             remote => get_standard_option('pveclient-remote-name'),
161             vmid => {
162                 description => "The container ID",
163                 type => 'string',
164             },
165         },
166     },
167     returns => { type => 'null'},
168     code => sub {
169         my ($param) = @_;
170
171         my $config = PVE::APIClient::Config->load();
172         my $conn = PVE::APIClient::Config->remote_conn($config, $param->{remote});
173
174         # Get the real node from the resources endpoint
175         my $resource_list = $conn->get("api2/json/cluster/resources", { type => 'vm'});
176         my ($resource) = grep { $_->{type} eq "lxc" && $_->{vmid} eq $param->{vmid}} @$resource_list;
177
178         die "container '$param->{vmid}' does not exist\n"
179             if !(defined($resource) && defined($resource->{node}));
180
181         my $node = $resource->{node};
182
183         my $api_path = "api2/json/nodes/$node/lxc/$param->{vmid}";
184
185         my $termproxy = $conn->post("${api_path}/termproxy", {});
186
187         my $web_socket =  IO::Socket::SSL->new(
188             PeerHost => $conn->{host},
189             PeerPort => $conn->{port},
190             SSL_verify_mode => SSL_VERIFY_NONE, # fixme: ???
191             timeout => 30) ||
192             die "failed to connect: $!\n";
193
194         # WebSocket Handshake
195
196         my ($request, $wskey) = $build_web_socket_request->(
197             $conn->{host}, "/$api_path/vncwebsocket", $conn->{ticket}, $termproxy);
198
199         $full_write->($web_socket, $request);
200
201         my $wsbuf = '';
202
203         my $wb_socket_read_available_bytes = sub {
204             my $nr = $web_socket->sysread($wsbuf, $max_payload_size, length($wsbuf));
205             if (!defined($nr) && !($! == EINTR || $! == EAGAIN)) {
206                 die "web socket read error - $!\n";
207             }
208             return $nr;
209         };
210
211         my $raw_response = '';
212
213         while(1) {
214             my $nr = $wb_socket_read_available_bytes->();
215             if ($wsbuf =~ s/^(.*?)$CRLF$CRLF//s) {
216                 $raw_response = $1;
217                 last;
218             }
219             last if !$nr;
220         };
221
222         # Note: we keep any remaining data in $wsbuf
223
224         my $response = HTTP::Response->parse($raw_response);
225
226         # Note: Digest::SHA::sha1_base64 has wrong padding
227         my $wsaccept = Digest::SHA::sha1_base64("${wskey}258EAFA5-E914-47DA-95CA-C5AB0DC85B11") . "=";
228
229         die "got invalid websocket reponse: $raw_response\n"
230             if !(($response->code == 101) &&
231                  (lc $response->header('connection') eq 'upgrade') &&
232                  (lc $response->header('upgrade') eq 'websocket') &&
233                  ($response->header('sec-websocket-protocol') eq 'binary') &&
234                  ($response->header('sec-websocket-accept') eq $wsaccept));
235
236         # send auth again...
237         my $frame = $create_websockt_frame->($termproxy->{user} . ":" . $termproxy->{ticket} . "\n");
238         $full_write->($web_socket, $frame);
239
240         # Send resize command
241         my ($columns, $rows) = PVE::PTY::tcgetsize(*STDIN);
242         $frame = $create_websockt_frame->("1:$columns:$rows:");
243         $full_write->($web_socket, $frame);
244
245         # Set STDIN to "raw -echo" mode
246         my $old_termios = PVE::PTY::tcgetattr(*STDIN);
247         my $raw_termios = {%$old_termios};
248
249         my $read_select = IO::Select->new;
250         my $write_select = IO::Select->new;
251
252         my $output_buffer = ''; # write buffer for STDOUT
253         my $websock_buffer = ''; # write buffer for $web_socket
254
255         eval {
256             $SIG{TERM} = $SIG{INT} = $SIG{KILL} = sub { die "received interrupt\n"; };
257
258             PVE::PTY::cfmakeraw($raw_termios);
259             PVE::PTY::tcsetattr(*STDIN, $raw_termios);
260
261             # And set it to non-blocking so we can every char with IO::Select.
262             STDIN->blocking(0);
263             STDOUT->blocking(0);
264             $web_socket->blocking(0);
265             $read_select->add($web_socket);
266             my $input_fh = \*STDIN;
267             $read_select->add($input_fh);
268
269             my $output_fh = \*STDOUT;
270
271             my $ctrl_a_pressed_before = 0;
272
273             my $winch_received = 0;
274             $SIG{WINCH} = sub { $winch_received = 1; };
275
276             my $check_terminal_size = sub {
277                 my ($ncols, $nrows) = PVE::PTY::tcgetsize(*STDIN);
278                 if ($ncols != $columns or $nrows != $rows) {
279                     $columns = $ncols;
280                     $rows = $nrows;
281                     $websock_buffer .= $create_websockt_frame->("1:$columns:$rows:");
282                     $write_select->add($web_socket);
283                 }
284                 $winch_received = 0;
285             };
286
287             my $max_buffer_len = 256*1024;
288
289             my $drain_buffer = sub {
290                 my ($fh, $buffer_ref) = @_;
291
292                 my $len = length($$buffer_ref);
293                 my $nr = syswrite($fh, $$buffer_ref);
294                 if (!defined($nr)) {
295                     next if $! == EINTR || $! == EAGAIN;
296                     die "drain buffer - write error - $!\n";
297                 }
298                 return $nr if !$nr;
299                 substr($$buffer_ref, 0, $nr, '');
300                 $len = length($$buffer_ref);
301                 $write_select->remove($fh) if !$len;
302             };
303
304             while (1) {
305                 while(my ($readable, $writable) = IO::Select->select($read_select, $write_select, undef, 3)) {
306                     $check_terminal_size->() if $winch_received;
307
308                     foreach my $fh (@$writable) {
309                         if ($fh == $output_fh) {
310                             $drain_buffer->($output_fh, \$output_buffer);
311                             $read_select->add($web_socket) if length($output_buffer) <= $max_buffer_len;
312                         } elsif ($fh == $web_socket) {
313                             $drain_buffer->($web_socket, \$websock_buffer);
314                         }
315                     }
316
317                     foreach my $fh (@$readable) {
318
319                         if ($fh == $web_socket) {
320                             # Read from WebSocket
321
322                             my $nr = $wb_socket_read_available_bytes->();
323                             if (!defined($nr)) {
324                                 # wait
325                             } elsif ($nr == 0) {
326                                 return; # EOF
327                             } else {
328                                 my ($payload, $req_close) = $parse_web_socket_frame->(\$wsbuf);
329                                 if (defined($payload) && length($payload)) {
330                                     $output_buffer .= $payload;
331                                     $write_select->add($output_fh);
332                                     if (length($output_buffer) > $max_buffer_len) {
333                                         $read_select->remove($web_socket);
334                                     }
335                                 }
336                                 return if $req_close;
337                             }
338
339                         } elsif ($fh == $input_fh) {
340                             # Read from STDIN
341
342                             my $nr = sysread($input_fh, my $buff, 4096);
343                             return if !$nr; # EOF or error
344
345                             my $char = ord($buff);
346
347                             # check for CTRL-a-q
348                             return if $ctrl_a_pressed_before == 1 && $char == hex("0x71");
349
350                             $ctrl_a_pressed_before = ($char == hex("0x01") && $ctrl_a_pressed_before == 0) ? 1 : 0;
351
352                             $websock_buffer .= $create_websockt_frame->("0:" . $nr . ":" . $buff);
353                             $write_select->add($web_socket);
354                         }
355                     }
356                 }
357                 $check_terminal_size->() if $winch_received;
358
359                 # got timeout
360                 $websock_buffer .= $create_websockt_frame->("2"); # ping server to keep connection alive
361                 $write_select->add($web_socket);
362             }
363         };
364         my $err = $@;
365
366         eval {  # cleanup
367
368             # switch back to blocking mode (else later shell commands will fail).
369             STDIN->blocking(1);
370
371             if ($web_socket->connected) {
372                 # close connection
373                 $websock_buffer .= "\x88" . pack('N', 0) . pack('n', 0); # Opcode, mask, statuscode
374                 $full_write->($web_socket, $websock_buffer);
375                 $websock_buffer = '';
376                 close($web_socket);
377             }
378
379             # Reset the terminal parameters.
380             $output_buffer .= "\e[24H\r\n";
381             $full_write->(\*STDOUT, $output_buffer);
382             $output_buffer = '';
383
384             PVE::PTY::tcsetattr(*STDIN, $old_termios);
385         };
386         warn $@ if $@; # show cleanup errors
387
388         print STDERR "\nERROR: $err" if $err;
389
390         return undef;
391     }});
392
393 __PACKAGE__->register_method ({
394     name => 'list',
395     path => 'list',
396     method => 'GET',
397     description => "List containers.",
398     parameters => {
399         additionalProperties => 0,
400         properties => {
401             remote => get_standard_option('pveclient-remote-name'),
402         },
403     },
404     returns => { type => 'null'},
405     code => sub {
406         my ($param) = @_;
407
408         die "implement me";
409
410     }});
411
412
413 our $cmddef = {
414     enter => [ __PACKAGE__, 'enter', ['remote', 'vmid']],
415     list => [ __PACKAGE__, 'list', ['remote']],
416 };
417
418 1;