data/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::File;
  10 use IO::Dir;
  11 use File::stat;
  12 use File::Basename;
  13 use Fcntl qw(:DEFAULT :flock);
  14 use PVE::SafeSyslog;
  15 use PVE::Exception qw(raise_param_exc);
  16 use PVE::Tools;
  17 use Storable qw(dclone);
  18 use Linux::Inotify2;
  19 use base 'Exporter';
  20 use JSON;
  21
  22 our @EXPORT_OK = qw(read_file write_file register_file);
  23
  24 my $ccache;
  25 my $ccachemap;
  26 my $ccacheregex;
  27 my $inotify;
  28 my $inotify_pid = 0;
  29 my $versions;
  30 my $shadowfiles = {
  31     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  32 };
  33
  34 # to enable cached operation, you need to call 'inotify_init'
  35 # inotify handles are a limited resource, so use with care (only
  36 # enable the cache if you really need it)
  37
  38 # Note: please close the inotify handle after you fork
  39
  40 sub ccache_default_writer {
  41     my ($filename, $data) = @_;
  42
  43     die "undefined config writer for '$filename' :ERROR";
  44 }
  45
  46 sub ccache_default_parser {
  47     my ($filename, $srcfd) = @_;
  48
  49     die "undefined config reader for '$filename' :ERROR";
  50 }
  51
  52 sub ccache_compute_diff {
  53     my ($filename, $shadow) = @_;
  54
  55     my $diff = '';
  56
  57     open (TMP, "diff -b -N -u '$filename' '$shadow'|");
  58
  59     while (my $line = <TMP>) {
  60         $diff .= $line;
  61     }
  62
  63     close (TMP);
  64
  65     $diff = undef if !$diff;
  66
  67     return $diff;
  68 }
  69
  70 sub ccache_info {
  71     my ($filename) = @_;
  72
  73     foreach my $uid (keys %$ccacheregex) {
  74         my $ccinfo = $ccacheregex->{$uid};
  75         my $dir = $ccinfo->{dir};
  76         my $regex = $ccinfo->{regex};
  77         if ($filename =~ m|^$dir/+$regex$|) {
  78             if (!$ccache->{$filename}) {
  79                 my $cp = {};
  80                 while (my ($k, $v) = each %$ccinfo) {
  81                     $cp->{$k} = $v;
  82                 }
  83                 $ccache->{$filename} = $cp;
  84             }
  85             return ($ccache->{$filename}, $filename);
  86         }
  87     }
  88
  89     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  90
  91     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  92
  93     return ($ccache->{$filename}, $filename);
  94 }
  95
  96 sub write_file {
  97     my ($fileid, $data, $full) = @_;
  98
  99     my ($ccinfo, $filename) = ccache_info($fileid);
 100
 101     my $writer = $ccinfo->{writer};
 102
 103     my $realname = $filename;
 104
 105     my $shadow;
 106     if ($shadow = $shadowfiles->{$filename}) {
 107         $realname = $shadow;
 108     }
 109
 110     my $perm = $ccinfo->{perm} || 0644;
 111
 112     my $tmpname = "$realname.tmp.$$";
 113
 114     my $res;
 115     eval {
 116         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 117         die "unable to open file '$tmpname' - $!\n" if !$fh;
 118
 119         $res = &$writer($filename, $fh, $data);
 120
 121         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 122     };
 123     my $err = $@;
 124
 125     $ccinfo->{version} = undef;
 126
 127     if ($err) {
 128         unlink $tmpname;
 129         die $err;
 130     }
 131
 132     if (!rename($tmpname, $realname)) {
 133         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 134         unlink $tmpname;
 135         die $msg;
 136     }
 137
 138     my $diff;
 139     if ($shadow && $full) {
 140         $diff = ccache_compute_diff ($filename, $shadow);
 141     }
 142
 143     if ($full) {
 144         return { data => $res, changes => $diff };
 145     }
 146
 147     return $res;
 148 }
 149
 150 sub update_file {
 151     my ($fileid, $data, @args) = @_;
 152
 153     my ($ccinfo, $filename) = ccache_info($fileid);
 154
 155     my $update = $ccinfo->{update};
 156
 157     die "unable to update/merge data" if !$update;
 158
 159     my $lkfn = "$filename.lock";
 160
 161     my $timeout = 10;
 162
 163     my $fd;
 164
 165     my $code = sub {
 166
 167         $fd = IO::File->new ($filename, "r");
 168
 169         my $new = &$update($filename, $fd, $data, @args);
 170
 171         if (defined($new)) {
 172             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 173         } else {
 174             unlink $filename;
 175         }
 176     };
 177
 178     PVE::Tools::lock_file($lkfn, $timeout, $code);
 179     my $err = $@;
 180
 181     close($fd) if defined($fd);
 182
 183     die $err if $err;
 184
 185     return undef;
 186 }
 187
 188 sub discard_changes {
 189     my ($fileid, $full) = @_;
 190
 191     my ($ccinfo, $filename) = ccache_info($fileid);
 192
 193     if (my $copy = $shadowfiles->{$filename}) {
 194         unlink $copy;
 195     }
 196
 197     return read_file ($filename, $full);
 198 }
 199
 200 sub read_file {
 201     my ($fileid, $full) = @_;
 202
 203     my $parser;
 204
 205     my ($ccinfo, $filename) = ccache_info($fileid);
 206
 207     $parser = $ccinfo->{parser};
 208
 209     my $fd;
 210     my $shadow;
 211
 212     poll() if $inotify; # read new inotify events
 213
 214     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 215
 216     my $cver = $versions->{$filename};
 217
 218     if (my $copy = $shadowfiles->{$filename}) {
 219         if ($fd = IO::File->new ($copy, "r")) {
 220             $shadow = $copy;
 221         } else {
 222             $fd = IO::File->new ($filename, "r");
 223         }
 224     } else {
 225         $fd = IO::File->new ($filename, "r");
 226     }
 227
 228     my $acp = $ccinfo->{always_call_parser};
 229
 230     if (!$fd) {
 231         $ccinfo->{version} = undef;
 232         $ccinfo->{data} = undef;
 233         $ccinfo->{diff} = undef;
 234         return undef if !$acp;
 235     }
 236
 237     my $noclone = $ccinfo->{noclone};
 238
 239     # file unchanged?
 240     if (!$ccinfo->{nocache} &&
 241         $inotify && $versions->{$filename} &&
 242         defined ($ccinfo->{data}) &&
 243         defined ($ccinfo->{version}) &&
 244         ($ccinfo->{readonce} ||
 245          ($ccinfo->{version} == $versions->{$filename}))) {
 246
 247         my $ret;
 248         if (!$noclone && ref ($ccinfo->{data})) {
 249             $ret->{data} = dclone ($ccinfo->{data});
 250         } else {
 251             $ret->{data} = $ccinfo->{data};
 252         }
 253         $ret->{changes} = $ccinfo->{diff};
 254
 255         return $full ? $ret : $ret->{data};
 256     }
 257
 258     my $diff;
 259
 260     if ($shadow) {
 261         $diff = ccache_compute_diff ($filename, $shadow);
 262     }
 263
 264     my $res = &$parser($filename, $fd);
 265
 266     if (!$ccinfo->{nocache}) {
 267         $ccinfo->{version} = $cver;
 268     }
 269
 270     # we cache data with references, so we always need to
 271     # dclone this data. Else the original data may get
 272     # modified.
 273     $ccinfo->{data} = $res;
 274
 275     # also store diff
 276     $ccinfo->{diff} = $diff;
 277
 278     my $ret;
 279     if (!$noclone && ref ($ccinfo->{data})) {
 280         $ret->{data} = dclone ($ccinfo->{data});
 281     } else {
 282         $ret->{data} = $ccinfo->{data};
 283     }
 284     $ret->{changes} = $ccinfo->{diff};
 285
 286     return $full ? $ret : $ret->{data};
 287 }
 288
 289 sub parse_ccache_options {
 290     my ($ccinfo, %options) = @_;
 291
 292     foreach my $opt (keys %options) {
 293         my $v = $options{$opt};
 294         if ($opt eq 'readonce') {
 295             $ccinfo->{$opt} = $v;
 296         } elsif ($opt eq 'nocache') {
 297             $ccinfo->{$opt} = $v;
 298         } elsif ($opt eq 'shadow') {
 299             $ccinfo->{$opt} = $v;
 300         } elsif ($opt eq 'perm') {
 301             $ccinfo->{$opt} = $v;
 302         } elsif ($opt eq 'noclone') {
 303             # noclone flag for large read-only data chunks like aplinfo
 304             $ccinfo->{$opt} = $v;
 305         } elsif ($opt eq 'always_call_parser') {
 306             # when set, we call parser even when the file does not exists.
 307             # this allows the parser to return some default
 308             $ccinfo->{$opt} = $v;
 309         } else {
 310             die "internal error - unsupported option '$opt'";
 311         }
 312     }
 313 }
 314
 315 sub register_file {
 316     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 317
 318     die "can't register file after initify_init" if $inotify;
 319
 320     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 321     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 322
 323     my $ccinfo = {};
 324
 325     $ccinfo->{id} = $id;
 326     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 327     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 328     $ccinfo->{update} = $update;
 329
 330     parse_ccache_options($ccinfo, %options);
 331
 332     if ($options{shadow}) {
 333         $shadowfiles->{$filename} = $options{shadow};
 334     }
 335
 336     $ccachemap->{$id} = $filename;
 337     $ccache->{$filename} = $ccinfo;
 338 }
 339
 340 sub register_regex {
 341     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 342
 343     die "can't register regex after initify_init" if $inotify;
 344
 345     my $uid = "$dir/$regex";
 346     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 347
 348     my $ccinfo = {};
 349
 350     $ccinfo->{dir} = $dir;
 351     $ccinfo->{regex} = $regex;
 352     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 353     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 354     $ccinfo->{update} = $update;
 355
 356     parse_ccache_options($ccinfo, %options);
 357
 358     $ccacheregex->{$uid} = $ccinfo;
 359 }
 360
 361 sub poll {
 362     return if !$inotify;
 363
 364     if ($inotify_pid != $$) {
 365         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 366         $inotify = undef;
 367     } else {
 368         1 while $inotify && $inotify->poll;
 369     }
 370 }
 371
 372 sub flushcache {
 373     foreach my $filename (keys %$ccache) {
 374         $ccache->{$filename}->{version} = undef;
 375         $ccache->{$filename}->{data} = undef;
 376         $ccache->{$filename}->{diff} = undef;
 377     }
 378 }
 379
 380 sub inotify_close {
 381     $inotify = undef;
 382 }
 383
 384 sub inotify_init {
 385
 386     die "only one inotify instance allowed" if $inotify;
 387
 388     $inotify =  Linux::Inotify2->new()
 389         || die "Unable to create new inotify object: $!";
 390
 391     $inotify->blocking (0);
 392
 393     $versions = {};
 394
 395     my $dirhash = {};
 396     foreach my $fn (keys %$ccache) {
 397         my $dir = dirname ($fn);
 398         my $base = basename ($fn);
 399
 400         $dirhash->{$dir}->{$base} = $fn;
 401
 402         if (my $sf = $shadowfiles->{$fn}) {
 403             $base = basename ($sf);
 404             $dir = dirname ($sf);
 405             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 406         }
 407     }
 408
 409     foreach my $uid (keys %$ccacheregex) {
 410         my $ccinfo = $ccacheregex->{$uid};
 411         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 412     }
 413
 414     $inotify_pid = $$;
 415
 416     foreach my $dir (keys %$dirhash) {
 417
 418         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 419         $inotify->watch ($dir, $evlist, sub {
 420             my $e = shift;
 421             my $name = $e->name;
 422
 423             if ($inotify_pid != $$) {
 424                 syslog ('err', "got inotify event in wrong process");
 425             }
 426
 427             if ($e->IN_ISDIR || !$name) {
 428                 return;
 429             }
 430
 431             if ($e->IN_Q_OVERFLOW) {
 432                 syslog ('info', "got inotify overflow - flushing cache");
 433                 flushcache();
 434                 return;
 435             }
 436
 437             if ($e->IN_UNMOUNT) {
 438                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 439                 $inotify = undef;
 440             }
 441             if ($e->IN_IGNORED) {
 442                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 443                 $inotify = undef;
 444             }
 445
 446             if ($dirhash->{$dir}->{_regex}) {
 447                 foreach my $uid (keys %$ccacheregex) {
 448                     my $ccinfo = $ccacheregex->{$uid};
 449                     next if $dir ne $ccinfo->{dir};
 450                     my $regex = $ccinfo->{regex};
 451                     if ($regex && ($name =~ m|^$regex$|)) {
 452
 453                         my $fn = "$dir/$name";
 454                         $versions->{$fn}++;
 455                         #print "VERSION:$fn:$versions->{$fn}\n";
 456                     }
 457                 }
 458             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 459
 460                 $versions->{$fn}++;
 461                 #print "VERSION:$fn:$versions->{$fn}\n";
 462             }
 463         });
 464     }
 465
 466     foreach my $dir (keys %$dirhash) {
 467         foreach my $name (keys %{$dirhash->{$dir}}) {
 468             if ($name eq '_regex') {
 469                 foreach my $uid (keys %$ccacheregex) {
 470                     my $ccinfo = $ccacheregex->{$uid};
 471                     next if $dir ne $ccinfo->{dir};
 472                     my $re = $ccinfo->{regex};
 473                     if (my $fd = IO::Dir->new ($dir)) {
 474                         while (defined(my $de = $fd->read)) {
 475                             if ($de =~ m/^$re$/) {
 476                                 my $fn = "$dir/$de";
 477                                 $versions->{$fn}++; # init with version
 478                                 #print "init:$fn:$versions->{$fn}\n";
 479                             }
 480                         }
 481                     }
 482                 }
 483             } else {
 484                 my $fn = $dirhash->{$dir}->{$name};
 485                 $versions->{$fn}++; # init with version
 486                 #print "init:$fn:$versions->{$fn}\n";
 487             }
 488         }
 489     }
 490 }
 491
 492 my $cached_nodename;
 493
 494 sub nodename {
 495
 496     return $cached_nodename if $cached_nodename;
 497
 498     my ($sysname, $nodename) = POSIX::uname();
 499
 500     $nodename =~ s/\..*$//; # strip domain part, if any
 501
 502     die "unable to read node name\n" if !$nodename;
 503
 504     $cached_nodename = $nodename;
 505
 506     return $cached_nodename;
 507 }
 508
 509 sub read_etc_hostname {
 510     my ($filename, $fd) = @_;
 511
 512     my $hostname = <$fd>;
 513
 514     chomp $hostname;
 515
 516     $hostname =~ s/\..*$//; # strip domain part, if any
 517
 518     return $hostname;
 519 }
 520
 521 sub write_etc_hostname {
 522     my ($filename, $fh, $hostname) = @_;
 523
 524     die "write failed: $!" unless print $fh "$hostname\n";
 525
 526     return $hostname;
 527 }
 528
 529 register_file('hostname', "/etc/hostname",
 530               \&read_etc_hostname,
 531               \&write_etc_hostname);
 532
 533 sub read_etc_resolv_conf {
 534     my ($filename, $fh) = @_;
 535
 536     my $res = {};
 537
 538     my $nscount = 0;
 539     while (my $line = <$fh>) {
 540         chomp $line;
 541         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 542             $res->{search} = $2;
 543         } elsif ($line =~ m/^nameserver\s+(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\s*/) {
 544             $nscount++;
 545             if ($nscount <= 3) {
 546                 $res->{"dns$nscount"} = $1;
 547             }
 548         }
 549     }
 550
 551     return $res;
 552 }
 553
 554 sub update_etc_resolv_conf {
 555     my ($filename, $fh, $resolv, @args) = @_;
 556
 557     my $data = "";
 558
 559     $data = "search $resolv->{search}\n"
 560         if $resolv->{search};
 561
 562     my $written = {};
 563     foreach my $k ("dns1", "dns2", "dns3") {
 564         my $ns = $resolv->{$k};
 565         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 566             $written->{$ns} = 1;
 567             $data .= "nameserver $ns\n";
 568         }
 569     }
 570
 571     while (my $line = <$fh>) {
 572         next if $line =~ m/^(search|domain|nameserver)\s+/;
 573         $data .= $line
 574     }
 575
 576     return $data;
 577 }
 578
 579 register_file('resolvconf', "/etc/resolv.conf",
 580               \&read_etc_resolv_conf, undef,
 581               \&update_etc_resolv_conf);
 582
 583 sub read_etc_timezone {
 584     my ($filename, $fd) = @_;
 585
 586     my $timezone = <$fd>;
 587
 588     chomp $timezone;
 589
 590     return $timezone;
 591 }
 592
 593 sub write_etc_timezone {
 594     my ($filename, $fh, $timezone) = @_;
 595
 596     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 597
 598     raise_param_exc({ 'timezone' => "No such timezone" })
 599         if (! -f $tzinfo);
 600
 601     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 602
 603     print $fh "$timezone\n";
 604
 605     unlink ("/etc/localtime");
 606     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 607
 608 }
 609
 610 register_file('timezone', "/etc/timezone",
 611               \&read_etc_timezone,
 612               \&write_etc_timezone);
 613
 614 sub read_active_workers {
 615     my ($filename, $fh) = @_;
 616
 617     return [] if !$fh;
 618
 619     my $res = [];
 620     while (defined (my $line = <$fh>)) {
 621         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 622             my $upid = $1;
 623             my $saved = $2;
 624             my $endtime = $4;
 625             my $status = $6;
 626             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 627                 $task->{upid} = $upid;
 628                 $task->{saved} = $saved;
 629                 $task->{endtime} = hex($endtime) if $endtime;
 630                 $task->{status} = $status if $status;
 631                 push @$res, $task;
 632             }
 633         } else {
 634             warn "unable to parse line: $line";
 635         }
 636     }
 637
 638     return $res;
 639
 640 }
 641
 642 sub write_active_workers {
 643     my ($filename, $fh, $tasklist) = @_;
 644
 645     my $raw = '';
 646     foreach my $task (@$tasklist) {
 647         my $upid = $task->{upid};
 648         my $saved = $task->{saved} ? 1 : 0;
 649         if ($task->{endtime}) {
 650             if ($task->{status}) {
 651                 $raw .= sprintf("$upid $saved %08X $task->{status}\n", $task->{endtime});
 652             } else {
 653                 $raw .= sprintf("$upid $saved %08X\n", $task->{endtime});
 654             }
 655         } else {
 656             $raw .= "$upid $saved\n";
 657         }
 658     }
 659
 660     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 661 }
 662
 663 register_file('active', "/var/log/pve/tasks/active",
 664               \&read_active_workers,
 665               \&write_active_workers);
 666
 667
 668 my $bond_modes = { 'balance-rr' => 0,
 669                    'active-backup' => 1,
 670                    'balance-xor' => 2,
 671                    'broadcast' => 3,
 672                    '802.3ad' => 4,
 673                    'balance-tlb' => 5,
 674                    'balance-alb' => 6,
 675                };
 676
 677 #sub get_bond_modes {
 678 #    return $bond_modes;
 679 #}
 680
 681 sub read_etc_network_interfaces {
 682     my ($filename, $fh) = @_;
 683
 684     my $ifaces = {};
 685
 686     my $line;
 687
 688     if (my $fd2 = IO::File->new("/proc/net/dev", "r")) {
 689         while (defined ($line = <$fd2>)) {
 690             if ($line =~ m/^\s*(eth\d+):.*/) {
 691                 $ifaces->{$1}->{exists} = 1;
 692             }
 693         }
 694         close($fd2);
 695     }
 696
 697     # we try to keep order inside the file
 698     my $priority = 2; # 1 is reserved for lo
 699
 700     # always add the vmbr0 bridge device
 701     $ifaces->{vmbr0}->{exists} = 1;
 702
 703     if (my $fd2 = IO::File->new("/proc/net/if_inet6", "r")) {
 704         while (defined ($line = <$fd2>)) {
 705             if ($line =~ m/^[a-f0-9]{32}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+(lo|eth\d+|vmbr\d+|bond\d+)$/) {
 706                 $ifaces->{$1}->{active} = 1;
 707             }
 708         }
 709         close ($fd2);
 710     }
 711
 712     my $gateway = 0;
 713
 714     while (defined ($line = <$fh>)) {
 715         chomp ($line);
 716         next if $line =~ m/^#/;
 717
 718         if ($line =~ m/^auto\s+(.*)$/) {
 719             my @aa = split (/\s+/, $1);
 720
 721             foreach my $a (@aa) {
 722                 $ifaces->{$a}->{autostart} = 1;
 723             }
 724
 725         } elsif ($line =~ m/^iface\s+(\S+)\s+inet\s+(\S+)\s*$/) {
 726             my $i = $1;
 727             $ifaces->{$i}->{method} = $2;
 728             $ifaces->{$i}->{priority} = $priority++;
 729
 730             my $d = $ifaces->{$i};
 731             while (defined ($line = <$fh>)) {
 732                 if ($line =~ m/^\s*#(.*)\s*$/) {
 733                     # NOTE: we use 'comments' instead of 'comment' to
 734                     # avoid automatic utf8 conversion
 735                     $d->{comments} = '' if !$d->{comments};
 736                     $d->{comments} .= "$1\n";
 737                 } elsif ($line =~ m/^\s+((\S+)\s+(.+))$/) {
 738                     my $option = $1;
 739                     my ($id, $value) = ($2, $3);
 740                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast')) {
 741                         $d->{$id} = $value;
 742                     } elsif ($id eq 'gateway') {
 743                         $d->{$id} = $value;
 744                         $gateway = 1;
 745                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 746                         my $devs = {};
 747                         foreach my $p (split (/\s+/, $value)) {
 748                             next if $p eq 'none';
 749                             $devs->{$p} = 1;
 750                         }
 751                         my $str = join (' ', sort keys %{$devs});
 752                         $d->{$id} = $str || '';
 753                     } elsif ($id eq 'bridge_stp') {
 754                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 755                             $d->{$id} = 'on';
 756                         } else {
 757                             $d->{$id} = 'off';
 758                         }
 759                     } elsif ($id eq 'bridge_fd') {
 760                         $d->{$id} = $value;
 761                     } elsif ($id eq 'bond_miimon') {
 762                         $d->{$id} = $value;
 763                     } elsif ($id eq 'bond_mode') {
 764                         # always use names
 765                         foreach my $bm (keys %$bond_modes) {
 766                             my $id = $bond_modes->{$bm};
 767                             if ($id eq $value) {
 768                                 $value = $bm;
 769                                 last;
 770                             }
 771                         }
 772                         $d->{$id} = $value;
 773                     } else {
 774                         push @{$d->{options}}, $option;
 775                     }
 776                 } else {
 777                     last;
 778                 }
 779             }
 780         }
 781     }
 782
 783
 784     if (!$gateway) {
 785         $ifaces->{vmbr0}->{gateway} = '';
 786     }
 787
 788     if (!$ifaces->{lo}) {
 789         $ifaces->{lo}->{priority} = 1;
 790         $ifaces->{lo}->{method} = 'loopback';
 791         $ifaces->{lo}->{type} = 'loopback';
 792         $ifaces->{lo}->{autostart} = 1;
 793     }
 794
 795     foreach my $iface (keys %$ifaces) {
 796         my $d = $ifaces->{$iface};
 797         if ($iface =~ m/^bond\d+$/) {
 798             $d->{type} = 'bond';
 799         } elsif ($iface =~ m/^vmbr\d+$/) {
 800             $d->{type} = 'bridge';
 801             if (!defined ($d->{bridge_fd})) {
 802                 $d->{bridge_fd} = 0;
 803             }
 804             if (!defined ($d->{bridge_stp})) {
 805                 $d->{bridge_stp} = 'off';
 806             }
 807         } elsif ($iface =~ m/^(\S+):\d+$/) {
 808             $d->{type} = 'alias';
 809             if (defined ($ifaces->{$1})) {
 810                 $d->{exists} = $ifaces->{$1}->{exists};
 811             } else {
 812                 $ifaces->{$1}->{exists} = 0;
 813                 $d->{exists} = 0;
 814             }
 815         } elsif ($iface =~ m/^eth\d+$/) {
 816             $d->{type} = 'eth';
 817         } elsif ($iface =~ m/^lo$/) {
 818             $d->{type} = 'loopback';
 819         } else {
 820             $d->{type} = 'unknown';
 821         }
 822
 823         $d->{method} = 'manual' if !$d->{method};
 824     }
 825
 826     return $ifaces;
 827 }
 828
 829 sub __interface_to_string {
 830     my ($iface, $d) = @_;
 831
 832     return '' if !($d && $d->{method});
 833
 834     my $raw = '';
 835
 836     if ($d->{autostart}) {
 837         $raw .= "auto $iface\n";
 838     }
 839     $raw .= "iface $iface inet $d->{method}\n";
 840     $raw .= "\taddress  $d->{address}\n" if $d->{address};
 841     $raw .= "\tnetmask  $d->{netmask}\n" if $d->{netmask};
 842     $raw .= "\tgateway  $d->{gateway}\n" if $d->{gateway};
 843     $raw .= "\tbroadcast  $d->{broadcast}\n" if $d->{broadcast};
 844
 845     if ($d->{bridge_ports} || ($iface =~ m/^vmbr\d+$/)) {
 846         my $ports = $d->{bridge_ports} || 'none';
 847         $raw .= "\tbridge_ports $ports\n";
 848     }
 849
 850     if ($d->{bridge_stp} || ($iface =~ m/^vmbr\d+$/)) {
 851         my $v = $d->{bridge_stp};
 852         $v = defined ($v) ? $v : 'off';
 853         $raw .= "\tbridge_stp $v\n";
 854     }
 855
 856     if (defined ($d->{bridge_fd}) || ($iface =~ m/^vmbr\d+$/)) {
 857         my $v = $d->{bridge_fd};
 858         $v = defined ($v) ? $v : 0;
 859         $raw .= "\tbridge_fd $v\n";
 860     }
 861
 862     if ($d->{slaves} || ($iface =~ m/^bond\d+$/)) {
 863         my $slaves = $d->{slaves} || 'none';
 864         $raw .= "\tslaves $slaves\n";
 865     }
 866
 867     if (defined ($d->{'bond_miimon'}) || ($iface =~ m/^bond\d+$/)) {
 868         my $v = $d->{'bond_miimon'};
 869         $v = defined ($v) ? $v : 100;
 870         $raw .= "\tbond_miimon $v\n";
 871     }
 872
 873     if (defined ($d->{'bond_mode'}) || ($iface =~ m/^bond\d+$/)) {
 874         my $v = $d->{'bond_mode'};
 875         $v = defined ($v) ? $v : 'balance-rr';
 876         $raw .= "\tbond_mode $v\n";
 877     }
 878
 879     foreach my $option (@{$d->{options}}) {
 880         $raw .= "\t$option\n";
 881     }
 882
 883     # add comments
 884     my $comments = $d->{comments} || '';
 885     foreach my $cl (split(/\n/, $comments)) {
 886         $raw .= "#$cl\n";
 887     }
 888
 889     $raw .= "\n";
 890
 891     return $raw;
 892 }
 893
 894 sub write_etc_network_interfaces {
 895     my ($filename, $fh, $ifaces) = @_;
 896
 897     my $raw = "# network interface settings\n";
 898
 899     my $printed = {};
 900
 901     my $if_type_hash = {
 902         loopback => 10,
 903         eth => 20,
 904         bond => 30,
 905         bridge => 40,
 906     };
 907
 908     my $lookup_type_prio = sub {
 909         my $iface = shift;
 910
 911         my $alias = 0;
 912         if ($iface =~ m/^(\S+):\d+$/) {
 913             $iface = $1;
 914             $alias = 1;
 915         }
 916
 917         my $pri;
 918         if ($iface eq 'lo') {
 919             $pri = $if_type_hash->{loopback};
 920         } elsif ($iface =~ m/^eth\d+$/) {
 921             $pri = $if_type_hash->{eth} + $alias;
 922         } elsif ($iface =~ m/^bond\d+$/) {
 923             $pri = $if_type_hash->{bond} + $alias;
 924         } elsif ($iface =~ m/^vmbr\d+$/) {
 925             $pri = $if_type_hash->{bridge} + $alias;
 926         }
 927
 928         return $pri || ($if_type_hash->{unknown} + $alias);
 929     };
 930
 931     foreach my $iface (sort {
 932         my $ref1 = $ifaces->{$a};
 933         my $ref2 = $ifaces->{$b};
 934         my $p1 = &$lookup_type_prio($a);
 935         my $p2 = &$lookup_type_prio($b);
 936
 937         return $p1 <=> $p2 if $p1 != $p2;
 938
 939         $p1 = $ref1->{priority} || 100000;
 940         $p2 = $ref2->{priority} || 100000;
 941
 942         return $p1 <=> $p2 if $p1 != $p2;
 943
 944         return $a cmp $b;
 945                        } keys %$ifaces) {
 946
 947         my $d = $ifaces->{$iface};
 948
 949         next if $printed->{$iface};
 950
 951         $printed->{$iface} = 1;
 952         $raw .= __interface_to_string($iface, $d);
 953     }
 954
 955     PVE::Tools::safe_print($filename, $fh, $raw);
 956 }
 957
 958 register_file('interfaces', "/etc/network/interfaces",
 959               \&read_etc_network_interfaces,
 960               \&write_etc_network_interfaces);
 961
 962
 963 sub read_iscsi_initiatorname {
 964     my ($filename, $fd) = @_;
 965
 966     while (defined(my $line = <$fd>)) {
 967         if ($line =~ m/^InitiatorName=(\S+)$/) {
 968             return $1;
 969         }
 970     }
 971
 972     return 'undefined';
 973 }
 974
 975 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
 976               \&read_iscsi_initiatorname);
 977
 978 sub read_apt_auth {
 979     my ($filename, $fd) = @_;
 980
 981     local $/;
 982
 983     my $raw = defined($fd) ? <$fd> : '';
 984
 985     $raw =~ s/^\s+//;
 986
 987
 988     my @tokens = split(/\s+/, $raw);
 989
 990     my $data = {};
 991
 992     my $machine;
 993     while (defined(my $tok = shift @tokens)) {
 994
 995         $machine = shift @tokens if $tok eq 'machine';
 996         next if !$machine;
 997         $data->{$machine} = {} if !$data->{$machine};
 998
 999         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1000         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1001     };
1002
1003     return $data;
1004 }
1005
1006 my $format_apt_auth_data = sub {
1007     my $data = shift;
1008
1009     my $raw = '';
1010
1011     foreach my $machine (sort keys %$data) {
1012         my $d = $data->{$machine};
1013         $raw .= "machine $machine\n";
1014         $raw .= " login $d->{login}\n" if $d->{login};
1015         $raw .= " password $d->{password}\n" if $d->{password};
1016         $raw .= "\n";
1017     }
1018
1019     return $raw;
1020 };
1021
1022 sub write_apt_auth {
1023     my ($filename, $fh, $data) = @_;
1024
1025     my $raw = &$format_apt_auth_data($data);
1026
1027     die "write failed: $!" unless print $fh "$raw\n";
1028
1029     return $data;
1030 }
1031
1032 sub update_apt_auth {
1033     my ($filename, $fh, $data) = @_;
1034
1035     my $orig = read_apt_auth($filename, $fh);
1036
1037     foreach my $machine (keys %$data) {
1038         $orig->{$machine} = $data->{$machine};
1039     }
1040
1041     return &$format_apt_auth_data($orig);
1042 }
1043
1044 register_file('apt-auth', "/etc/apt/auth.conf",
1045               \&read_apt_auth, \&write_apt_auth,
1046               \&update_apt_auth, perm => 0640);
1047
1048 1;