add openvswitch support to tap_plug / tap_unplug
[pve-common.git] / data / PVE / Network.pm
1 package PVE::Network;
2
3 use strict;
4 use warnings;
5 use PVE::Tools qw(run_command);
6 use PVE::ProcFSTools;
7 use PVE::INotify;
8 use File::Basename;
9
10 # host network related utility functions
11
12 sub setup_tc_rate_limit {
13     my ($iface, $rate, $burst, $debug) = @_;
14
15     system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
16     system("/sbin/tc filter del dev $iface parent ffff: protocol ip prio 50 estimator 1sec 8sec >/dev/null 2>&1");
17     system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
18     system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
19
20     return if !$rate;
21
22     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
23
24     # this does not work wit virtio - don't know why (setting "mtu 64kb" does not help)
25     #run_command("/sbin/tc filter add dev $iface parent ffff: protocol ip prio 50 u32 match ip src 0.0.0.0/0 police rate ${rate}bps burst ${burst}b drop flowid :1");
26     # so we use avrate instead
27     run_command("/sbin/tc filter add dev $iface parent ffff: " .
28                 "protocol ip prio 50 estimator 1sec 8sec " .
29                 "u32 match ip src 0.0.0.0/0 police avrate ${rate}bps drop flowid :1");
30
31     # tbf does not work for unknown reason
32     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
33     # so we use htb instead
34     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
35     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
36                 "htb rate ${rate}bps burst ${burst}b");
37
38     if ($debug) {
39         print "DEBUG tc settings\n";
40         system("/sbin/tc qdisc ls dev $iface");
41         system("/sbin/tc class ls dev $iface");
42         system("/sbin/tc filter ls dev $iface parent ffff:");
43     }
44 }
45
46 sub tap_rate_limit {
47     my ($iface, $rate) = @_;
48
49     my $debug = 0;
50     $rate = int($rate*1024*1024);
51     my $burst = 1024*1024;
52
53     setup_tc_rate_limit($iface, $rate, $burst, $debug);
54 }
55
56 sub tap_create {
57     my ($iface, $bridge) = @_;
58
59     die "unable to get bridge setting\n" if !$bridge;
60
61     my $bridgemtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
62         die "bridge '$bridge' does not exist\n" if !$bridgemtu;
63
64     eval{ PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");};
65         die "interface activation failed\n" if $@;
66 }
67
68 sub tap_plug {
69     my ($iface, $bridge, $tag) = @_;
70
71     #cleanup old port config from any openvswitch bridge
72     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
73
74     if (-d "/sys/class/net/$bridge/bridge"){
75             my $newbridge = activate_bridge_vlan($bridge, $tag);
76             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
77
78             system ("/sbin/brctl addif $newbridge $iface") == 0 ||
79                 die "can't add interface to bridge\n";
80     }else{
81             my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
82             $cmd .= " tag=$tag" if $tag;
83             system ($cmd) == 0 ||
84                 die "can't add interface to bridge\n";
85     }
86 }
87
88 sub tap_unplug {
89     my ($iface, $bridge, $tag) = @_;
90
91     if (-d "/sys/class/net/$bridge/bridge"){
92
93         $bridge .= "v$tag" if $tag;
94
95             system ("/sbin/brctl delif $bridge $iface") == 0 ||
96                 die "can't del interface from bridge\n";
97     }else{
98             system ("/usr/bin/ovs-vsctl del-port $iface") == 0 ||
99                 die "can't del interface from bridge\n";
100     }
101 }
102
103 sub copy_bridge_config {
104     my ($br0, $br1) = @_;
105
106     return if $br0 eq $br1;
107
108     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay', 
109                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
110
111     foreach my $sysname (@$br_configs) {
112         eval {
113             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
114             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
115             if ($v0 ne $v1) {
116                 system("echo \"$v0\" > /sys/class/net/$br1/bridge/$sysname") == 0 ||
117                     warn "unable to set bridge config '$sysname'\n";
118             }
119         };
120         warn $@ if $@;
121     }
122 }
123
124 sub activate_bridge_vlan {
125     my ($bridge, $tag_param) = @_;
126
127     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
128
129     return $bridge if !defined($tag_param); # no vlan, simply return
130
131     my $tag = int($tag_param);
132
133     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
134
135     my $bridgevlan = "${bridge}v$tag";
136
137     my $dir = "/sys/class/net/$bridge/brif";
138
139     #check if we have an only one ethX or bondX interface in the bridge
140     
141     my $iface;
142     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+)', sub {
143         my ($slave) = @_;
144
145         die "more then one physical interfaces on bridge '$bridge'\n" if $iface;
146         $iface = $slave;
147
148     });
149
150     die "no physical interface on bridge '$bridge'\n" if !$iface;
151
152     my $ifacevlan = "${iface}.$tag";
153
154     # create vlan on $iface is not already exist
155     if (! -d "/sys/class/net/$ifacevlan") {
156         system("/sbin/vconfig add $iface $tag") == 0 ||
157             die "can't add vlan tag $tag to interface $iface\n";
158     }
159
160     # be sure to have the $ifacevlan up
161     system("/sbin/ip link set $ifacevlan up") == 0 ||
162         die "can't up interface $ifacevlan\n";
163
164     # test if $vlaniface is already enslaved in another bridge
165     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
166     if (-l $path) {
167         my $tbridge = basename(readlink($path));
168         if ($tbridge eq $bridgevlan) {
169             # already member of bridge - assume setup is already done
170             return $bridgevlan;
171         } else {
172             die "interface $ifacevlan already exist in bridge $tbridge\n";
173         }
174     }
175
176     # add bridgevlan if it doesn't already exist
177     if (! -d "/sys/class/net/$bridgevlan") {
178         system("/sbin/brctl addbr $bridgevlan") == 0 ||
179             die "can't add bridge $bridgevlan\n";
180     }
181
182     #fixme: set other bridge flags
183
184     # be sure to have the bridge up
185     system("/sbin/ip link set $bridgevlan up") == 0 ||
186         die "can't up bridge $bridgevlan\n";
187
188     # add $ifacevlan to the bridge
189     system("/sbin/brctl addif $bridgevlan $ifacevlan") == 0 ||
190         die "can't add interface $ifacevlan to bridge $bridgevlan\n";
191     
192     return $bridgevlan;
193 }
194
195 1;