data/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Tools qw(run_command);
   6 use PVE::ProcFSTools;
   7 use PVE::INotify;
   8 use File::Basename;
   9
  10 # host network related utility functions
  11
  12 sub setup_tc_rate_limit {
  13     my ($iface, $rate, $burst, $debug) = @_;
  14
  15     system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
  16     system("/sbin/tc filter del dev $iface parent ffff: protocol ip prio 50 estimator 1sec 8sec >/dev/null 2>&1");
  17     system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
  18     system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
  19
  20     return if !$rate;
  21
  22     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
  23
  24     # this does not work wit virtio - don't know why (setting "mtu 64kb" does not help)
  25     #run_command("/sbin/tc filter add dev $iface parent ffff: protocol ip prio 50 u32 match ip src 0.0.0.0/0 police rate ${rate}bps burst ${burst}b drop flowid :1");
  26     # so we use avrate instead
  27     run_command("/sbin/tc filter add dev $iface parent ffff: " .
  28                 "protocol ip prio 50 estimator 1sec 8sec " .
  29                 "u32 match ip src 0.0.0.0/0 police avrate ${rate}bps drop flowid :1");
  30
  31     # tbf does not work for unknown reason
  32     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  33     # so we use htb instead
  34     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  35     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
  36                 "htb rate ${rate}bps burst ${burst}b");
  37
  38     if ($debug) {
  39         print "DEBUG tc settings\n";
  40         system("/sbin/tc qdisc ls dev $iface");
  41         system("/sbin/tc class ls dev $iface");
  42         system("/sbin/tc filter ls dev $iface parent ffff:");
  43     }
  44 }
  45
  46 sub tap_rate_limit {
  47     my ($iface, $rate) = @_;
  48
  49     my $debug = 0;
  50     $rate = int($rate*1024*1024);
  51     my $burst = 1024*1024;
  52
  53     setup_tc_rate_limit($iface, $rate, $burst, $debug);
  54 }
  55
  56 my $read_bridge_mtu = sub {
  57     my ($bridge) = @_;
  58
  59     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
  60     die "bridge '$bridge' does not exist\n" if !$mtu;
  61     # avoid insecure dependency;
  62     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
  63     $mtu = int($1);
  64
  65     return $mtu;
  66 };
  67
  68 my $parse_tap_devive_name = sub {
  69     my ($iface) = @_;
  70
  71     my ($vmid, $devid);
  72
  73     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
  74         $vmid = $1;
  75         $devid = $2;
  76     } elsif ($iface =~ m/^veth(\d+)\.(\d+)$/) {
  77         $vmid = $1;
  78         $devid = $2;
  79     } else {
  80         die "wrong interface name $iface";
  81     }
  82
  83     return ($vmid, $devid);
  84 };
  85
  86 my $compute_fwbr_names = sub {
  87     my ($vmid, $devid) = @_;
  88
  89     my $fwbr = "fwbr${vmid}i${devid}";
  90     # Note: the firewall use 'fwln+' to filter traffic to VMs
  91     my $vethfw = "fwln${vmid}i${devid}";
  92     my $vethfwpeer = "fwpr${vmid}p${devid}";
  93     my $ovsintport = "fwln${vmid}o${devid}";
  94
  95     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
  96 };
  97
  98 my $cond_create_bridge = sub {
  99     my ($bridge) = @_;
 100
 101     if (! -d "/sys/class/net/$bridge") {
 102         system("/sbin/brctl addbr $bridge") == 0 ||
 103             die "can't add bridge '$bridge'\n";
 104     }
 105 };
 106
 107 my $bridge_add_interface = sub {
 108     my ($bridge, $iface) = @_;
 109
 110     system("/sbin/brctl addif $bridge $iface") == 0 ||
 111         die "can't add interface 'iface' to bridge '$bridge'\n";
 112 };
 113
 114 my $ovs_bridge_add_port = sub {
 115     my ($bridge, $iface, $tag, $internal) = @_;
 116
 117     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 118     $cmd .= " tag=$tag" if $tag;
 119     $cmd .= " -- set Interface $iface type=internal" if $internal;
 120     system($cmd) == 0 ||
 121         die "can't add ovs port '$iface'\n";
 122 };
 123
 124 my $activate_interface = sub {
 125     my ($iface) = @_;
 126
 127     system("/sbin/ip link set $iface up") == 0 ||
 128         die "can't activate interface '$iface'\n";
 129 };
 130
 131 sub tap_create {
 132     my ($iface, $bridge) = @_;
 133
 134     die "unable to get bridge setting\n" if !$bridge;
 135
 136     my $bridgemtu = &$read_bridge_mtu($bridge);
 137
 138     eval {
 139         PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
 140     };
 141     die "interface activation failed\n" if $@;
 142 }
 143
 144 my $create_firewall_bridge_linux = sub {
 145     my ($iface, $bridge) = @_;
 146
 147     my ($vmid, $devid) = &$parse_tap_devive_name($iface);
 148     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 149
 150     my $bridgemtu = &$read_bridge_mtu($bridge);
 151
 152     &$cond_create_bridge($fwbr);
 153     &$activate_interface($fwbr);
 154
 155     copy_bridge_config($bridge, $fwbr);
 156     # create veth pair
 157     if (! -d "/sys/class/net/$vethfw") {
 158         system("/sbin/ip link add name $vethfw type veth peer name $vethfwpeer mtu $bridgemtu") == 0 ||
 159             die "can't create interface $vethfw\n";
 160     }
 161
 162     # up vethpair
 163     &$activate_interface($vethfw);
 164     &$activate_interface($vethfwpeer);
 165
 166     &$bridge_add_interface($fwbr, $vethfw);
 167     &$bridge_add_interface($bridge, $vethfwpeer);
 168
 169     return $fwbr;
 170 };
 171
 172 my $create_firewall_bridge_ovs = sub {
 173     my ($iface, $bridge, $tag) = @_;
 174
 175     my ($vmid, $devid) = &$parse_tap_devive_name($iface);
 176     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 177
 178     my $bridgemtu = &$read_bridge_mtu($bridge);
 179
 180     &$cond_create_bridge($fwbr);
 181     &$activate_interface($fwbr);
 182
 183     &$bridge_add_interface($fwbr, $iface);
 184
 185     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1);
 186
 187     # set the same mtu for ovs int port
 188     PVE::Tools::run_command("/sbin/ifconfig $ovsintport mtu $bridgemtu");
 189
 190     &$bridge_add_interface($fwbr, $ovsintport);
 191 };
 192
 193 my $cleanup_firewall_bridge = sub {
 194     my ($iface) = @_;
 195
 196     my ($vmid, $devid) = &$parse_tap_devive_name($iface);
 197     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 198
 199     # cleanup old port config from any openvswitch bridge
 200     if (-d "/sys/class/net/$ovsintport") {
 201         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 202     }
 203
 204     # delete old vethfw interface
 205     if (-d "/sys/class/net/$vethfw") {
 206         run_command("/sbin/ip link delete dev $vethfw", outfunc => sub {}, errfunc => sub {});
 207     }
 208
 209     # cleanup fwbr bridge
 210     if (-d "/sys/class/net/$fwbr") {
 211         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
 212         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
 213     }
 214 };
 215
 216 sub tap_plug {
 217     my ($iface, $bridge, $tag, $firewall) = @_;
 218
 219     #cleanup old port config from any openvswitch bridge
 220     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 221
 222     if (-d "/sys/class/net/$bridge/bridge") {
 223         &$cleanup_firewall_bridge($iface); # remove stale devices
 224
 225         my $newbridge = activate_bridge_vlan($bridge, $tag);
 226         copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 227
 228         $newbridge = &$create_firewall_bridge_linux($iface, $newbridge) if $firewall;
 229
 230         &$bridge_add_interface($newbridge, $iface);
 231     } else {
 232         &$cleanup_firewall_bridge($iface); # remove stale devices
 233
 234         if ($firewall) {
 235             &$create_firewall_bridge_ovs($iface, $bridge, $tag);
 236         } else {
 237             &$ovs_bridge_add_port($bridge, $iface, $tag);
 238         }
 239     }
 240 }
 241
 242 sub tap_unplug {
 243     my ($iface) = @_;
 244
 245     my $path= "/sys/class/net/$iface/brport/bridge";
 246     if (-l $path) {
 247         my $bridge = basename(readlink($path));
 248         #avoid insecure dependency;
 249         ($bridge) = $bridge =~ /(\S+)/;
 250
 251         system("/sbin/brctl delif $bridge $iface") == 0 ||
 252             die "can't del interface '$iface' from bridge '$bridge'\n";
 253
 254     }
 255
 256     &$cleanup_firewall_bridge($iface);
 257 }
 258
 259 sub copy_bridge_config {
 260     my ($br0, $br1) = @_;
 261
 262     return if $br0 eq $br1;
 263
 264     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 265                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 266
 267     foreach my $sysname (@$br_configs) {
 268         eval {
 269             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 270             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 271             if ($v0 ne $v1) {
 272                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 273             }
 274         };
 275         warn $@ if $@;
 276     }
 277 }
 278
 279 sub activate_bridge_vlan_slave {
 280     my ($bridgevlan, $iface, $tag) = @_;
 281     my $ifacevlan = "${iface}.$tag";
 282
 283     # create vlan on $iface is not already exist
 284     if (! -d "/sys/class/net/$ifacevlan") {
 285         system("/sbin/vconfig add $iface $tag") == 0 ||
 286             die "can't add vlan tag $tag to interface $iface\n";
 287     }
 288
 289     # be sure to have the $ifacevlan up
 290     &$activate_interface($ifacevlan);
 291
 292     # test if $vlaniface is already enslaved in another bridge
 293     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 294     if (-l $path) {
 295         my $tbridge = basename(readlink($path));
 296         if ($tbridge ne $bridgevlan) {
 297             die "interface $ifacevlan already exist in bridge $tbridge\n";
 298         } else {
 299             # Port already attached to bridge: do nothing.
 300             return;
 301         }
 302     }
 303
 304     # add $ifacevlan to the bridge
 305     &$bridge_add_interface($bridgevlan, $ifacevlan);
 306 }
 307
 308 sub activate_bridge_vlan {
 309     my ($bridge, $tag_param) = @_;
 310
 311     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 312
 313     return $bridge if !defined($tag_param); # no vlan, simply return
 314
 315     my $tag = int($tag_param);
 316
 317     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 318
 319     my $bridgevlan = "${bridge}v$tag";
 320
 321     my @ifaces = ();
 322     my $dir = "/sys/class/net/$bridge/brif";
 323     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+)', sub {
 324         push @ifaces, $_[0];
 325     });
 326
 327     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 328
 329     # add bridgevlan if it doesn't already exist
 330     if (! -d "/sys/class/net/$bridgevlan") {
 331         system("/sbin/brctl addbr $bridgevlan") == 0 ||
 332             die "can't add bridge $bridgevlan\n";
 333     }
 334
 335     # for each physical interface (eth or bridge) bind them to bridge vlan
 336     foreach my $iface (@ifaces) {
 337         activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 338     }
 339
 340     #fixme: set other bridge flags
 341
 342     # be sure to have the bridge up
 343     system("/sbin/ip link set $bridgevlan up") == 0 ||
 344         die "can't up bridge $bridgevlan\n";
 345
 346     return $bridgevlan;
 347 }
 348
 349 1;