cleanup coding style
[pve-common.git] / data / PVE / Network.pm
1 package PVE::Network;
2
3 use strict;
4 use warnings;
5 use PVE::Tools qw(run_command);
6 use PVE::ProcFSTools;
7 use PVE::INotify;
8 use File::Basename;
9
10 # host network related utility functions
11
12 sub setup_tc_rate_limit {
13 my ($iface, $rate, $burst, $debug) = @_;
14
15 system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
16 system("/sbin/tc filter del dev $iface parent ffff: protocol ip prio 50 estimator 1sec 8sec >/dev/null 2>&1");
17 system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
18 system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
19
20 return if !$rate;
21
22 run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
23
24 # this does not work wit virtio - don't know why (setting "mtu 64kb" does not help)
25 #run_command("/sbin/tc filter add dev $iface parent ffff: protocol ip prio 50 u32 match ip src 0.0.0.0/0 police rate ${rate}bps burst ${burst}b drop flowid :1");
26 # so we use avrate instead
27 run_command("/sbin/tc filter add dev $iface parent ffff: " .
28 "protocol ip prio 50 estimator 1sec 8sec " .
29 "u32 match ip src 0.0.0.0/0 police avrate ${rate}bps drop flowid :1");
30
31 # tbf does not work for unknown reason
32 #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
33 # so we use htb instead
34 run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
35 run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
36 "htb rate ${rate}bps burst ${burst}b");
37
38 if ($debug) {
39 print "DEBUG tc settings\n";
40 system("/sbin/tc qdisc ls dev $iface");
41 system("/sbin/tc class ls dev $iface");
42 system("/sbin/tc filter ls dev $iface parent ffff:");
43 }
44 }
45
46 sub tap_rate_limit {
47 my ($iface, $rate) = @_;
48
49 my $debug = 0;
50 $rate = int($rate*1024*1024);
51 my $burst = 1024*1024;
52
53 setup_tc_rate_limit($iface, $rate, $burst, $debug);
54 }
55
56 sub tap_create {
57 my ($iface, $bridge) = @_;
58
59 die "unable to get bridge setting\n" if !$bridge;
60
61 my $bridgemtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
62 die "bridge '$bridge' does not exist\n" if !$bridgemtu;
63
64 eval {
65 PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
66 };
67 die "interface activation failed\n" if $@;
68 }
69
70 sub tap_plug {
71 my ($iface, $bridge, $tag) = @_;
72
73 #cleanup old port config from any openvswitch bridge
74 eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
75
76 if (-d "/sys/class/net/$bridge/bridge") {
77 my $newbridge = activate_bridge_vlan($bridge, $tag);
78 copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
79
80 system("/sbin/brctl addif $newbridge $iface") == 0 ||
81 die "can't add interface to bridge\n";
82 } else {
83 my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
84 $cmd .= " tag=$tag" if $tag;
85 system($cmd) == 0 ||
86 die "can't add interface to bridge\n";
87 }
88 }
89
90 sub tap_unplug {
91 my ($iface, $bridge, $tag) = @_;
92
93 if (-d "/sys/class/net/$bridge/bridge") {
94 $bridge .= "v$tag" if $tag;
95
96 system("/sbin/brctl delif $bridge $iface") == 0 ||
97 die "can't del interface from bridge\n";
98 } else {
99 system ("/usr/bin/ovs-vsctl del-port $iface") == 0 ||
100 die "can't del interface from bridge\n";
101 }
102 }
103
104 sub copy_bridge_config {
105 my ($br0, $br1) = @_;
106
107 return if $br0 eq $br1;
108
109 my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
110 'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
111
112 foreach my $sysname (@$br_configs) {
113 eval {
114 my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
115 my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
116 if ($v0 ne $v1) {
117 system("echo \"$v0\" > /sys/class/net/$br1/bridge/$sysname") == 0 ||
118 warn "unable to set bridge config '$sysname'\n";
119 }
120 };
121 warn $@ if $@;
122 }
123 }
124
125 sub activate_bridge_vlan {
126 my ($bridge, $tag_param) = @_;
127
128 die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
129
130 return $bridge if !defined($tag_param); # no vlan, simply return
131
132 my $tag = int($tag_param);
133
134 die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
135
136 my $bridgevlan = "${bridge}v$tag";
137
138 my $dir = "/sys/class/net/$bridge/brif";
139
140 #check if we have an only one ethX or bondX interface in the bridge
141
142 my $iface;
143 PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+)', sub {
144 my ($slave) = @_;
145
146 die "more then one physical interfaces on bridge '$bridge'\n" if $iface;
147 $iface = $slave;
148
149 });
150
151 die "no physical interface on bridge '$bridge'\n" if !$iface;
152
153 my $ifacevlan = "${iface}.$tag";
154
155 # create vlan on $iface is not already exist
156 if (! -d "/sys/class/net/$ifacevlan") {
157 system("/sbin/vconfig add $iface $tag") == 0 ||
158 die "can't add vlan tag $tag to interface $iface\n";
159 }
160
161 # be sure to have the $ifacevlan up
162 system("/sbin/ip link set $ifacevlan up") == 0 ||
163 die "can't up interface $ifacevlan\n";
164
165 # test if $vlaniface is already enslaved in another bridge
166 my $path= "/sys/class/net/$ifacevlan/brport/bridge";
167 if (-l $path) {
168 my $tbridge = basename(readlink($path));
169 if ($tbridge eq $bridgevlan) {
170 # already member of bridge - assume setup is already done
171 return $bridgevlan;
172 } else {
173 die "interface $ifacevlan already exist in bridge $tbridge\n";
174 }
175 }
176
177 # add bridgevlan if it doesn't already exist
178 if (! -d "/sys/class/net/$bridgevlan") {
179 system("/sbin/brctl addbr $bridgevlan") == 0 ||
180 die "can't add bridge $bridgevlan\n";
181 }
182
183 #fixme: set other bridge flags
184
185 # be sure to have the bridge up
186 system("/sbin/ip link set $bridgevlan up") == 0 ||
187 die "can't up bridge $bridgevlan\n";
188
189 # add $ifacevlan to the bridge
190 system("/sbin/brctl addif $bridgevlan $ifacevlan") == 0 ||
191 die "can't add interface $ifacevlan to bridge $bridgevlan\n";
192
193 return $bridgevlan;
194 }
195
196 1;