data/PVE/RESTHandler.pm

   1 package PVE::RESTHandler;
   2
   3 use strict;
   4 no strict 'refs'; # our autoload requires this
   5 use warnings;
   6 use PVE::SafeSyslog;
   7 use PVE::Exception qw(raise raise_param_exc);
   8 use PVE::JSONSchema;
   9 use PVE::PodParser;
  10 use HTTP::Status qw(:constants :is status_message);
  11 use Text::Wrap;
  12 use Storable qw(dclone);
  13
  14 my $method_registry = {};
  15 my $method_by_name = {};
  16 my $method_path_lookup = {};
  17
  18 our $AUTOLOAD;  # it's a package global
  19
  20 sub api_clone_schema {
  21     my ($schema) = @_;
  22
  23     my $res = {};
  24     my $ref = ref($schema);
  25     die "not a HASH reference" if !($ref && $ref eq 'HASH');
  26
  27     foreach my $k (keys %$schema) {
  28         my $d = $schema->{$k};
  29         if ($k ne 'properties') {
  30             $res->{$k} = ref($d) ? dclone($d) : $d;
  31             next;
  32         }
  33         # convert indexed parameters like -net\d+ to -net[n]
  34         foreach my $p (keys %$d) {
  35             my $pd = $d->{$p};
  36             if ($p =~ m/^([a-z]+)(\d+)$/) {
  37                 if ($2 == 0) {
  38                     $p = "$1\[n\]";
  39                 } else {
  40                     next;
  41                 }
  42             }
  43             $res->{$k}->{$p} = ref($pd) ? dclone($pd) : $pd;
  44         }
  45     }
  46
  47     return $res;
  48 }
  49
  50 sub api_dump_full {
  51     my ($tree, $index, $class, $prefix) = @_;
  52
  53     $prefix = '' if !$prefix;
  54
  55     my $ma = $method_registry->{$class};
  56
  57     foreach my $info (@$ma) {
  58
  59         my $path = "$prefix/$info->{path}";
  60         $path =~ s/\/+$//;
  61
  62         if ($info->{subclass}) {
  63             api_dump_full($tree, $index, $info->{subclass}, $path);
  64         } else {
  65             next if !$path;
  66
  67             # check if method is unique
  68             my $realpath = $path;
  69             $realpath =~ s/\{[^\}]+\}/\{\}/g;
  70             my $fullpath = "$info->{method} $realpath";
  71             die "duplicate path '$realpath'" if $index->{$fullpath};
  72             $index->{$fullpath} = $info;
  73
  74             # insert into tree
  75             my $treedir = $tree;
  76             my $res;
  77             my $sp = '';
  78             foreach my $dir (split('/', $path)) {
  79                 next if !$dir;
  80                 $sp .= "/$dir";
  81                 $res = (grep { $_->{text} eq $dir } @$treedir)[0];
  82                 if ($res) {
  83                     $res->{children} = [] if !$res->{children};
  84                     $treedir = $res->{children};
  85                 } else {
  86                     $res = {
  87                         path => $sp,
  88                         text => $dir,
  89                         children => [],
  90                     };
  91                     push @$treedir, $res;
  92                     $treedir = $res->{children};
  93                 }
  94             }
  95
  96             if ($res) {
  97                 my $data = {};
  98                 foreach my $k (keys %$info) {
  99                     next if $k eq 'code' || $k eq "match_name" || $k eq "match_re" ||
 100                         $k eq "path";
 101
 102                     my $d = $info->{$k};
 103
 104                     if ($k eq 'parameters') {
 105                         $data->{$k} = api_clone_schema($d);
 106                     } else {
 107
 108                         $data->{$k} = ref($d) ? dclone($d) : $d;
 109                     }
 110                 }
 111                 $res->{info}->{$info->{method}} = $data;
 112             };
 113         }
 114     }
 115 };
 116
 117 sub api_dump_cleanup_tree {
 118     my ($tree) = @_;
 119
 120     foreach my $rec (@$tree) {
 121         delete $rec->{children} if $rec->{children} && !scalar(@{$rec->{children}});
 122         if ($rec->{children}) {
 123             $rec->{leaf} = 0;
 124             api_dump_cleanup_tree($rec->{children});
 125         } else {
 126             $rec->{leaf} = 1;
 127         }
 128     }
 129
 130 }
 131
 132 sub api_dump {
 133     my ($class, $prefix) = @_;
 134
 135     my $tree = [];
 136
 137     my $index = {};
 138     api_dump_full($tree, $index, $class);
 139     api_dump_cleanup_tree($tree);
 140     return $tree;
 141 };
 142
 143 sub validate_method_schemas {
 144
 145     foreach my $class (keys %$method_registry) {
 146         my $ma = $method_registry->{$class};
 147
 148         foreach my $info (@$ma) {
 149             PVE::JSONSchema::validate_method_info($info);
 150         }
 151     }
 152 }
 153
 154 sub register_method {
 155     my ($self, $info) = @_;
 156
 157     my $match_re = [];
 158     my $match_name = [];
 159
 160     my $errprefix;
 161
 162     my $method;
 163     if ($info->{subclass}) {
 164         $errprefix = "register subclass $info->{subclass} at ${self}/$info->{path} -";
 165         $method = 'SUBCLASS';
 166     } else {
 167         $errprefix = "register method ${self}/$info->{path} -";
 168         $info->{method} = 'GET' if !$info->{method};
 169         $method = $info->{method};
 170     }
 171
 172     $method_path_lookup->{$self} = {} if !defined($method_path_lookup->{$self});
 173     my $path_lookup = $method_path_lookup->{$self};
 174
 175     die "$errprefix no path" if !defined($info->{path});
 176
 177     foreach my $comp (split(/\/+/, $info->{path})) {
 178         die "$errprefix path compoment has zero length\n" if $comp eq '';
 179         my ($name, $regex);
 180         if ($comp =~ m/^\{(\w+)(:(.*))?\}$/) {
 181             $name = $1;
 182             $regex = $3 ? $3 : '\S+';
 183             push @$match_re, $regex;
 184             push @$match_name, $name;
 185         } else {
 186             $name = $comp;
 187             push @$match_re, $name;
 188             push @$match_name, undef;
 189         }
 190
 191         if ($regex) {
 192             $path_lookup->{regex} = {} if !defined($path_lookup->{regex});
 193
 194             my $old_name = $path_lookup->{regex}->{match_name};
 195             die "$errprefix found changed regex match name\n"
 196                 if defined($old_name) && ($old_name ne $name);
 197             my $old_re = $path_lookup->{regex}->{match_re};
 198             die "$errprefix found changed regex\n"
 199                 if defined($old_re) && ($old_re ne $regex);
 200             $path_lookup->{regex}->{match_name} = $name;
 201             $path_lookup->{regex}->{match_re} = $regex;
 202
 203             die "$errprefix path match error - regex and fixed items\n"
 204                 if defined($path_lookup->{folders});
 205
 206             $path_lookup = $path_lookup->{regex};
 207
 208         } else {
 209             $path_lookup->{folders}->{$name} = {} if !defined($path_lookup->{folders}->{$name});
 210
 211             die "$errprefix path match error - regex and fixed items\n"
 212                 if defined($path_lookup->{regex});
 213
 214             $path_lookup = $path_lookup->{folders}->{$name};
 215         }
 216     }
 217
 218     die "$errprefix duplicate method definition\n"
 219         if defined($path_lookup->{$method});
 220
 221     $path_lookup->{$method} = $info;
 222
 223     $info->{match_re} = $match_re;
 224     $info->{match_name} = $match_name;
 225
 226     $method_by_name->{$self} = {} if !defined($method_by_name->{$self});
 227
 228     if ($info->{name}) {
 229         die "$errprefix method name already defined\n"
 230             if defined($method_by_name->{$self}->{$info->{name}});
 231
 232         $method_by_name->{$self}->{$info->{name}} = $info;
 233     }
 234
 235     push @{$method_registry->{$self}}, $info;
 236 }
 237
 238 sub register_page_formatter {
 239     my ($self, %config) = @_;
 240
 241     my $format = $config{format} ||
 242         die "missing format";
 243
 244     my $path = $config{path} ||
 245         die "missing path";
 246
 247     my $method = $config{method} ||
 248         die "missing method";
 249
 250     my $code = $config{code} ||
 251         die "missing formatter code";
 252
 253     my $uri_param = {};
 254     my ($handler, $info) = $self->find_handler($method, $path, $uri_param);
 255     die "unabe to find handler for '$method: $path'" if !($handler && $info);
 256
 257     die "duplicate formatter for '$method: $path'"
 258         if $info->{formatter} && $info->{formatter}->{$format};
 259
 260     $info->{formatter}->{$format} = $code;
 261 }
 262
 263 sub AUTOLOAD {
 264     my ($this) = @_;
 265
 266     # also see "man perldiag"
 267
 268     my $sub = $AUTOLOAD;
 269     (my $method = $sub) =~ s/.*:://;
 270
 271     $method =~ s/.*:://;
 272
 273     my $info = $this->map_method_by_name($method);
 274
 275     *{$sub} = sub {
 276         my $self = shift;
 277         return $self->handle($info, @_);
 278     };
 279     goto &$AUTOLOAD;
 280 }
 281
 282 sub method_attributes {
 283     my ($self) = @_;
 284
 285     return $method_registry->{$self};
 286 }
 287
 288 sub map_method_by_name {
 289     my ($self, $name) = @_;
 290
 291     my $info = $method_by_name->{$self}->{$name};
 292     die "no such method '${self}::$name'\n" if !$info;
 293
 294     return $info;
 295 }
 296
 297 sub map_path_to_methods {
 298     my ($class, $stack, $uri_param, $pathmatchref) = @_;
 299
 300     my $path_lookup = $method_path_lookup->{$class};
 301
 302     # Note: $pathmatchref can be used to obtain path including
 303     # uri patterns like '/cluster/firewall/groups/{group}'.
 304     # Used by pvesh to display help
 305     if (defined($pathmatchref)) {
 306         $$pathmatchref = '' if !$$pathmatchref;
 307     }
 308
 309     while (defined(my $comp = shift @$stack)) {
 310         return undef if !$path_lookup; # not registerd?
 311         if ($path_lookup->{regex}) {
 312             my $name = $path_lookup->{regex}->{match_name};
 313             my $regex = $path_lookup->{regex}->{match_re};
 314
 315             return undef if $comp !~ m/^($regex)$/;
 316             $uri_param->{$name} = $1;
 317             $path_lookup = $path_lookup->{regex};
 318             $$pathmatchref .= '/{' . $name . '}' if defined($pathmatchref);
 319         } elsif ($path_lookup->{folders}) {
 320             $path_lookup = $path_lookup->{folders}->{$comp};
 321             $$pathmatchref .= '/' . $comp if defined($pathmatchref);
 322         } else {
 323             die "internal error";
 324         }
 325
 326         return undef if !$path_lookup;
 327
 328         if (my $info = $path_lookup->{SUBCLASS}) {
 329             $class = $info->{subclass};
 330
 331             my $fd = $info->{fragmentDelimiter};
 332
 333             if (defined($fd)) {
 334                 # we only support the empty string '' (match whole URI)
 335                 die "unsupported fragmentDelimiter '$fd'"
 336                     if $fd ne '';
 337
 338                 $stack = [ join ('/', @$stack) ] if scalar(@$stack) > 1;
 339             }
 340             $path_lookup = $method_path_lookup->{$class};
 341         }
 342     }
 343
 344     return undef if !$path_lookup;
 345
 346     return ($class, $path_lookup);
 347 }
 348
 349 sub find_handler {
 350     my ($class, $method, $path, $uri_param, $pathmatchref) = @_;
 351
 352     my $stack = [ grep { length($_) > 0 }  split('\/+' , $path)]; # skip empty fragments
 353
 354     my ($handler_class, $path_info);
 355     eval {
 356         ($handler_class, $path_info) = $class->map_path_to_methods($stack, $uri_param, $pathmatchref);
 357     };
 358     my $err = $@;
 359     syslog('err', $err) if $err;
 360
 361     return undef if !($handler_class && $path_info);
 362
 363     my $method_info = $path_info->{$method};
 364
 365     return undef if !$method_info;
 366
 367     return ($handler_class, $method_info);
 368 }
 369
 370 sub handle {
 371     my ($self, $info, $param) = @_;
 372
 373     my $func = $info->{code};
 374
 375     if (!($info->{name} && $func)) {
 376         raise("Method lookup failed ('$info->{name}')\n",
 377               code => HTTP_INTERNAL_SERVER_ERROR);
 378     }
 379
 380     if (my $schema = $info->{parameters}) {
 381         # warn "validate ". Dumper($param}) . "\n" . Dumper($schema);
 382         PVE::JSONSchema::validate($param, $schema);
 383         # untaint data (already validated)
 384         while (my ($key, $val) = each %$param) {
 385             ($param->{$key}) = $val =~ /^(.*)$/s;
 386         }
 387     }
 388
 389     my $result = &$func($param);
 390
 391     # todo: this is only to be safe - disable?
 392     if (my $schema = $info->{returns}) {
 393         PVE::JSONSchema::validate($result, $schema, "Result verification vailed\n");
 394     }
 395
 396     return $result;
 397 }
 398
 399 # generate usage information for command line tools
 400 #
 401 # $name        ... the name of the method
 402 # $prefix      ... usually something like "$exename $cmd" ('pvesm add')
 403 # $arg_param   ... list of parameters we want to get as ordered arguments
 404 #                  on the command line (or single parameter name for lists)
 405 # $fixed_param ... do not generate and info about those parameters
 406 # $format:
 407 #   'long'     ... default (list all options)
 408 #   'short'    ... command line only (one line)
 409 #   'full'     ... also include description
 410 # $hidepw      ... hide password option (use this if you provide a read passwork callback)
 411 sub usage_str {
 412     my ($self, $name, $prefix, $arg_param, $fixed_param, $format, $hidepw) = @_;
 413
 414     $format = 'long' if !$format;
 415
 416     my $info = $self->map_method_by_name($name);
 417     my $schema = $info->{parameters};
 418     my $prop = $schema->{properties};
 419
 420     my $out = '';
 421
 422     my $arg_hash = {};
 423
 424     my $args = '';
 425
 426     $arg_param = [ $arg_param ] if $arg_param && !ref($arg_param);
 427
 428     foreach my $p (@$arg_param) {
 429         next if !$prop->{$p}; # just to be sure
 430         my $pd = $prop->{$p};
 431
 432         $arg_hash->{$p} = 1;
 433         $args .= " " if $args;
 434         if ($pd->{format} && $pd->{format} =~ m/-list/) {
 435             $args .= "{<$p>}";
 436         } else {
 437             $args .= $pd->{optional} ? "[<$p>]" : "<$p>";
 438         }
 439     }
 440
 441     my $get_prop_descr = sub {
 442         my ($k, $display_name) = @_;
 443
 444         my $phash = $prop->{$k};
 445
 446         my $res = '';
 447
 448         my $descr = $phash->{description} || "no description available";
 449         chomp $descr;
 450
 451         my $type = PVE::PodParser::schema_get_type_text($phash);
 452
 453         if ($hidepw && $k eq 'password') {
 454             $type = '';
 455         }
 456
 457         my $defaulttxt = '';
 458         if (defined(my $dv = $phash->{default})) {
 459             $defaulttxt = "   (default=$dv)";
 460         }
 461         my $tmp = sprintf "  %-10s %s$defaulttxt\n", $display_name, "$type";
 462         my $indend = "             ";
 463
 464         $res .= Text::Wrap::wrap('', $indend, ($tmp));
 465         $res .= "\n",
 466         $res .= Text::Wrap::wrap($indend, $indend, ($descr)) . "\n\n";
 467
 468         if (my $req = $phash->{requires}) {
 469             my $tmp = "Requires option(s): ";
 470             $tmp .= ref($req) ? join(', ', @$req) : $req;
 471             $res .= Text::Wrap::wrap($indend, $indend, ($tmp)). "\n\n";
 472         }
 473
 474         return $res;
 475     };
 476
 477     my $argdescr = '';
 478     foreach my $k (@$arg_param) {
 479         next if defined($fixed_param->{$k}); # just to be sure
 480         next if !$prop->{$k}; # just to be sure
 481         $argdescr .= &$get_prop_descr($k, "<$k>");
 482     }
 483
 484     my $idx_param = {}; # -vlan\d+ -scsi\d+
 485
 486     my $opts = '';
 487     foreach my $k (sort keys %$prop) {
 488         next if $arg_hash->{$k};
 489         next if defined($fixed_param->{$k});
 490
 491         my $type = $prop->{$k}->{type} || 'string';
 492
 493         next if $hidepw && ($k eq 'password') && !$prop->{$k}->{optional};
 494
 495         my $base = $k;
 496         if ($k =~ m/^([a-z]+)(\d+)$/) {
 497             my $name = $1;
 498             next if $idx_param->{$name};
 499             $idx_param->{$name} = 1;
 500             $base = "${name}[n]";
 501         }
 502
 503         $opts .= &$get_prop_descr($k, "-$base");
 504
 505         if (!$prop->{$k}->{optional}) {
 506             $args .= " " if $args;
 507             $args .= "-$base <$type>"
 508         }
 509     }
 510
 511     $out .= "USAGE: " if $format ne 'short';
 512
 513     $out .= "$prefix $args";
 514
 515     $out .= $opts ? " [OPTIONS]\n" : "\n";
 516
 517     return $out if $format eq 'short';
 518
 519     if ($info->{description} && $format eq 'full') {
 520         my $desc = Text::Wrap::wrap('  ', '  ', ($info->{description}));
 521         $out .= "\n$desc\n\n";
 522     }
 523
 524     $out .= $argdescr if $argdescr;
 525
 526     $out .= $opts if $opts;
 527
 528     return $out;
 529 }
 530
 531 sub cli_handler {
 532     my ($self, $prefix, $name, $args, $arg_param, $fixed_param, $pwcallback) = @_;
 533
 534     my $info = $self->map_method_by_name($name);
 535
 536     my $res;
 537     eval {
 538         my $param = PVE::JSONSchema::get_options($info->{parameters}, $args, $arg_param, $fixed_param, $pwcallback);
 539         $res = $self->handle($info, $param);
 540     };
 541     if (my $err = $@) {
 542         my $ec = ref($err);
 543
 544         die $err if !$ec || $ec ne "PVE::Exception" || !$err->is_param_exc();
 545
 546         $err->{usage} = $self->usage_str($name, $prefix, $arg_param, $fixed_param, 'short', $pwcallback);
 547
 548         die $err;
 549     }
 550
 551     return $res;
 552 }
 553
 554 # utility methods
 555 # note: this modifies the original hash by adding the id property
 556 sub hash_to_array {
 557     my ($hash, $idprop) = @_;
 558
 559     my $res = [];
 560     return $res if !$hash;
 561
 562     foreach my $k (keys %$hash) {
 563         $hash->{$k}->{$idprop} = $k;
 564         push @$res, $hash->{$k};
 565     }
 566
 567     return $res;
 568 }
 569
 570 1;