data/PVE/RESTHandler.pm

   1 package PVE::RESTHandler;
   2
   3 use strict;
   4 no strict 'refs'; # our autoload requires this
   5 use warnings;
   6 use PVE::SafeSyslog;
   7 use PVE::Exception qw(raise raise_param_exc);
   8 use PVE::JSONSchema;
   9 use PVE::PodParser;
  10 use HTTP::Status qw(:constants :is status_message);
  11 use Text::Wrap;
  12 use Storable qw(dclone);
  13
  14 my $method_registry = {};
  15 my $method_by_name = {};
  16 my $method_path_lookup = {};
  17
  18 our $AUTOLOAD;  # it's a package global
  19
  20 sub api_clone_schema {
  21     my ($schema) = @_;
  22
  23     my $res = {};
  24     my $ref = ref($schema);
  25     die "not a HASH reference" if !($ref && $ref eq 'HASH');
  26
  27     foreach my $k (keys %$schema) {
  28         my $d = $schema->{$k};
  29         if ($k ne 'properties') {
  30             $res->{$k} = ref($d) ? dclone($d) : $d;
  31             next;
  32         }
  33         # convert indexed parameters like -net\d+ to -net[n]
  34         foreach my $p (keys %$d) {
  35             my $pd = $d->{$p};
  36             if ($p =~ m/^([a-z]+)(\d+)$/) {
  37                 if ($2 == 0) {
  38                     $p = "$1\[n\]";
  39                 } else {
  40                     next;
  41                 }
  42             }
  43             $res->{$k}->{$p} = ref($pd) ? dclone($pd) : $pd;
  44         }
  45     }
  46
  47     return $res;
  48 }
  49
  50 sub api_dump_full {
  51     my ($tree, $index, $class, $prefix) = @_;
  52
  53     $prefix = '' if !$prefix;
  54
  55     my $ma = $method_registry->{$class};
  56
  57     foreach my $info (@$ma) {
  58
  59         my $path = "$prefix/$info->{path}";
  60         $path =~ s/\/+$//;
  61
  62         if ($info->{subclass}) {
  63             api_dump_full($tree, $index, $info->{subclass}, $path);
  64         } else {
  65             next if !$path;
  66
  67             # check if method is unique
  68             my $realpath = $path;
  69             $realpath =~ s/\{[^\}]+\}/\{\}/g;
  70             my $fullpath = "$info->{method} $realpath";
  71             die "duplicate path '$realpath'" if $index->{$fullpath};
  72             $index->{$fullpath} = $info;
  73
  74             # insert into tree
  75             my $treedir = $tree;
  76             my $res;
  77             my $sp = '';
  78             foreach my $dir (split('/', $path)) {
  79                 next if !$dir;
  80                 $sp .= "/$dir";
  81                 $res = (grep { $_->{text} eq $dir } @$treedir)[0];
  82                 if ($res) {
  83                     $res->{children} = [] if !$res->{children};
  84                     $treedir = $res->{children};
  85                 } else {
  86                     $res = {
  87                         path => $sp,
  88                         text => $dir,
  89                         children => [],
  90                     };
  91                     push @$treedir, $res;
  92                     $treedir = $res->{children};
  93                 }
  94             }
  95
  96             if ($res) {
  97                 my $data = {};
  98                 foreach my $k (keys %$info) {
  99                     next if $k eq 'code' || $k eq "match_name" || $k eq "match_re" ||
 100                         $k eq "path";
 101
 102                     my $d = $info->{$k};
 103
 104                     if ($k eq 'parameters') {
 105                         $data->{$k} = api_clone_schema($d);
 106                     } else {
 107
 108                         $data->{$k} = ref($d) ? dclone($d) : $d;
 109                     }
 110                 }
 111                 $res->{info}->{$info->{method}} = $data;
 112             };
 113         }
 114     }
 115 };
 116
 117 sub api_dump_cleanup_tree {
 118     my ($tree) = @_;
 119
 120     foreach my $rec (@$tree) {
 121         delete $rec->{children} if $rec->{children} && !scalar(@{$rec->{children}});
 122         if ($rec->{children}) {
 123             $rec->{leaf} = 0;
 124             api_dump_cleanup_tree($rec->{children});
 125         } else {
 126             $rec->{leaf} = 1;
 127         }
 128     }
 129
 130 }
 131
 132 sub api_dump {
 133     my ($class, $prefix) = @_;
 134
 135     my $tree = [];
 136
 137     my $index = {};
 138     api_dump_full($tree, $index, $class);
 139     api_dump_cleanup_tree($tree);
 140     return $tree;
 141 };
 142
 143 sub validate_method_schemas {
 144
 145     foreach my $class (keys %$method_registry) {
 146         my $ma = $method_registry->{$class};
 147
 148         foreach my $info (@$ma) {
 149             PVE::JSONSchema::validate_method_info($info);
 150         }
 151     }
 152 }
 153
 154 sub register_method {
 155     my ($self, $info) = @_;
 156
 157     my $match_re = [];
 158     my $match_name = [];
 159
 160     my $errprefix;
 161
 162     my $method;
 163     if ($info->{subclass}) {
 164         $errprefix = "register subclass $info->{subclass} at ${self}/$info->{path} -";
 165         $method = 'SUBCLASS';
 166     } else {
 167         $errprefix = "register method ${self}/$info->{path} -";
 168         $info->{method} = 'GET' if !$info->{method};
 169         $method = $info->{method};
 170     }
 171
 172     $method_path_lookup->{$self} = {} if !defined($method_path_lookup->{$self});
 173     my $path_lookup = $method_path_lookup->{$self};
 174
 175     die "$errprefix no path" if !defined($info->{path});
 176
 177     foreach my $comp (split(/\/+/, $info->{path})) {
 178         die "$errprefix path compoment has zero length\n" if $comp eq '';
 179         my ($name, $regex);
 180         if ($comp =~ m/^\{(\w+)(:(.*))?\}$/) {
 181             $name = $1;
 182             $regex = $3 ? $3 : '\S+';
 183             push @$match_re, $regex;
 184             push @$match_name, $name;
 185         } else {
 186             $name = $comp;
 187             push @$match_re, $name;
 188             push @$match_name, undef;
 189         }
 190
 191         if ($regex) {
 192             $path_lookup->{regex} = {} if !defined($path_lookup->{regex});
 193
 194             my $old_name = $path_lookup->{regex}->{match_name};
 195             die "$errprefix found changed regex match name\n"
 196                 if defined($old_name) && ($old_name ne $name);
 197             my $old_re = $path_lookup->{regex}->{match_re};
 198             die "$errprefix found changed regex\n"
 199                 if defined($old_re) && ($old_re ne $regex);
 200             $path_lookup->{regex}->{match_name} = $name;
 201             $path_lookup->{regex}->{match_re} = $regex;
 202
 203             die "$errprefix path match error - regex and fixed items\n"
 204                 if defined($path_lookup->{folders});
 205
 206             $path_lookup = $path_lookup->{regex};
 207
 208         } else {
 209             $path_lookup->{folders}->{$name} = {} if !defined($path_lookup->{folders}->{$name});
 210
 211             die "$errprefix path match error - regex and fixed items\n"
 212                 if defined($path_lookup->{regex});
 213
 214             $path_lookup = $path_lookup->{folders}->{$name};
 215         }
 216     }
 217
 218     die "$errprefix duplicate method definition\n"
 219         if defined($path_lookup->{$method});
 220
 221     $path_lookup->{$method} = $info;
 222
 223     $info->{match_re} = $match_re;
 224     $info->{match_name} = $match_name;
 225
 226     $method_by_name->{$self} = {} if !defined($method_by_name->{$self});
 227
 228     if ($info->{name}) {
 229         die "$errprefix method name already defined\n"
 230             if defined($method_by_name->{$self}->{$info->{name}});
 231
 232         $method_by_name->{$self}->{$info->{name}} = $info;
 233     }
 234
 235     push @{$method_registry->{$self}}, $info;
 236 }
 237
 238 sub AUTOLOAD {
 239     my ($this) = @_;
 240
 241     # also see "man perldiag"
 242
 243     my $sub = $AUTOLOAD;
 244     (my $method = $sub) =~ s/.*:://;
 245
 246     $method =~ s/.*:://;
 247
 248     my $info = $this->map_method_by_name($method);
 249
 250     *{$sub} = sub {
 251         my $self = shift;
 252         return $self->handle($info, @_);
 253     };
 254     goto &$AUTOLOAD;
 255 }
 256
 257 sub method_attributes {
 258     my ($self) = @_;
 259
 260     return $method_registry->{$self};
 261 }
 262
 263 sub map_method_by_name {
 264     my ($self, $name) = @_;
 265
 266     my $info = $method_by_name->{$self}->{$name};
 267     die "no such method '${self}::$name'\n" if !$info;
 268
 269     return $info;
 270 }
 271
 272 sub map_path_to_methods {
 273     my ($class, $stack, $uri_param) = @_;
 274
 275     my $path_lookup = $method_path_lookup->{$class};
 276
 277     while (my $comp = shift @$stack) {
 278         return undef if !$path_lookup; # not registerd?
 279         if ($path_lookup->{regex}) {
 280             my $name = $path_lookup->{regex}->{match_name};
 281             my $regex = $path_lookup->{regex}->{match_re};
 282
 283             return undef if $comp !~ m/^($regex)$/;
 284             $uri_param->{$name} = $1;
 285             $path_lookup = $path_lookup->{regex};
 286         } elsif ($path_lookup->{folders}) {
 287             $path_lookup = $path_lookup->{folders}->{$comp};
 288         } else {
 289             die "internal error";
 290         }
 291
 292         return undef if !$path_lookup;
 293
 294         if (my $info = $path_lookup->{SUBCLASS}) {
 295             $class = $info->{subclass};
 296
 297             my $fd = $info->{fragmentDelimiter};
 298
 299             if (defined($fd)) {
 300                 # we only support the empty string '' (match whole URI)
 301                 die "unsupported fragmentDelimiter '$fd'"
 302                     if $fd ne '';
 303
 304                 $stack = [ join ('/', @$stack) ] if scalar(@$stack) > 1;
 305             }
 306             $path_lookup = $method_path_lookup->{$class};
 307         }
 308     }
 309
 310     return undef if !$path_lookup;
 311
 312     return ($class, $path_lookup);
 313 }
 314
 315 sub find_handler {
 316     my ($class, $method, $path, $uri_param) = @_;
 317
 318     my $stack = [ grep { length($_) > 0 }  split('\/+' , $path)]; # skip empty fragments
 319
 320     my ($handler_class, $path_info);
 321     eval {
 322         ($handler_class, $path_info) = $class->map_path_to_methods($stack, $uri_param);
 323     };
 324     my $err = $@;
 325     syslog('err', $err) if $err;
 326
 327     return undef if !($handler_class && $path_info);
 328
 329     my $method_info = $path_info->{$method};
 330
 331     return undef if !$method_info;
 332
 333     return ($handler_class, $method_info);
 334 }
 335
 336 sub handle {
 337     my ($self, $info, $param) = @_;
 338
 339     my $func = $info->{code};
 340
 341     if (!($info->{name} && $func)) {
 342         raise("Method lookup failed ('$info->{name}')\n",
 343               code => HTTP_INTERNAL_SERVER_ERROR);
 344     }
 345
 346     if (my $schema = $info->{parameters}) {
 347         # warn "validate ". Dumper($param}) . "\n" . Dumper($schema);
 348         PVE::JSONSchema::validate($param, $schema);
 349         # untaint data (already validated)
 350         while (my ($key, $val) = each %$param) {
 351             ($param->{$key}) = $val =~ /^(.*)$/s;
 352         }
 353     }
 354
 355     my $result = &$func($param);
 356
 357     # todo: this is only to be safe - disable?
 358     if (my $schema = $info->{returns}) {
 359         PVE::JSONSchema::validate($result, $schema, "Result verification vailed\n");
 360     }
 361
 362     return $result;
 363 }
 364
 365 # generate usage information for command line tools
 366 #
 367 # $name        ... the name of the method
 368 # $prefix      ... usually something like "$exename $cmd" ('pvesm add')
 369 # $arg_param   ... list of parameters we want to get as ordered arguments
 370 #                  on the command line (or single parameter name for lists)
 371 # $fixed_param ... do not generate and info about those parameters
 372 # $format:
 373 #   'long'     ... default (list all options)
 374 #   'short'    ... command line only (one line)
 375 #   'full'     ... also include description
 376 # $hidepw      ... hide password option (use this if you provide a read passwork callback)
 377 sub usage_str {
 378     my ($self, $name, $prefix, $arg_param, $fixed_param, $format, $hidepw) = @_;
 379
 380     $format = 'long' if !$format;
 381
 382     my $info = $self->map_method_by_name($name);
 383     my $schema = $info->{parameters};
 384     my $prop = $schema->{properties};
 385
 386     my $out = '';
 387
 388     my $arg_hash = {};
 389
 390     my $args = '';
 391
 392     $arg_param = [ $arg_param ] if $arg_param && !ref($arg_param);
 393
 394     foreach my $p (@$arg_param) {
 395         next if !$prop->{$p}; # just to be sure
 396         my $pd = $prop->{$p};
 397
 398         $arg_hash->{$p} = 1;
 399         $args .= " " if $args;
 400         if ($pd->{format} && $pd->{format} =~ m/-list/) {
 401             $args .= "{<$p>}";
 402         } else {
 403             $args .= $pd->{optional} ? "[<$p>]" : "<$p>";
 404         }
 405     }
 406
 407     my $get_prop_descr = sub {
 408         my ($k, $display_name) = @_;
 409
 410         my $phash = $prop->{$k};
 411
 412         my $res = '';
 413
 414         my $descr = $phash->{description} || "no description available";
 415         chomp $descr;
 416
 417         my $type = PVE::PodParser::schema_get_type_text($phash);
 418
 419         if ($hidepw && $k eq 'password') {
 420             $type = '';
 421         }
 422
 423         my $defaulttxt = '';
 424         if (defined(my $dv = $phash->{default})) {
 425             $defaulttxt = "   (default=$dv)";
 426         }
 427         my $tmp = sprintf "  %-10s %s$defaulttxt\n", $display_name, "$type";
 428         my $indend = "             ";
 429
 430         $res .= Text::Wrap::wrap('', $indend, ($tmp));
 431         $res .= "\n",
 432         $res .= Text::Wrap::wrap($indend, $indend, ($descr)) . "\n\n";
 433
 434         if (my $req = $phash->{requires}) {
 435             my $tmp = "Requires option(s): ";
 436             $tmp .= ref($req) ? join(', ', @$req) : $req;
 437             $res .= Text::Wrap::wrap($indend, $indend, ($tmp)). "\n\n";
 438         }
 439
 440         return $res;
 441     };
 442
 443     my $argdescr = '';
 444     foreach my $k (@$arg_param) {
 445         next if defined($fixed_param->{$k}); # just to be sure
 446         next if !$prop->{$k}; # just to be sure
 447         $argdescr .= &$get_prop_descr($k, "<$k>");
 448     }
 449
 450     my $idx_param = {}; # -vlan\d+ -scsi\d+
 451
 452     my $opts = '';
 453     foreach my $k (sort keys %$prop) {
 454         next if $arg_hash->{$k};
 455         next if defined($fixed_param->{$k});
 456
 457         my $type = $prop->{$k}->{type} || 'string';
 458
 459         next if $hidepw && ($k eq 'password') && !$prop->{$k}->{optional};
 460
 461         my $base = $k;
 462         if ($k =~ m/^([a-z]+)(\d+)$/) {
 463             my $name = $1;
 464             next if $idx_param->{$name};
 465             $idx_param->{$name} = 1;
 466             $base = "${name}[n]";
 467         }
 468
 469         $opts .= &$get_prop_descr($k, "-$base");
 470
 471         if (!$prop->{$k}->{optional}) {
 472             $args .= " " if $args;
 473             $args .= "-$base <$type>"
 474         }
 475     }
 476
 477     $out .= "USAGE: " if $format ne 'short';
 478
 479     $out .= "$prefix $args";
 480
 481     $out .= $opts ? " [OPTIONS]\n" : "\n";
 482
 483     return $out if $format eq 'short';
 484
 485     if ($info->{description} && $format eq 'full') {
 486         my $desc = Text::Wrap::wrap('  ', '  ', ($info->{description}));
 487         $out .= "\n$desc\n\n";
 488     }
 489
 490     $out .= $argdescr if $argdescr;
 491
 492     $out .= $opts if $opts;
 493
 494     return $out;
 495 }
 496
 497 sub cli_handler {
 498     my ($self, $prefix, $name, $args, $arg_param, $fixed_param, $pwcallback) = @_;
 499
 500     my $info = $self->map_method_by_name($name);
 501
 502     my $res;
 503     eval {
 504         my $param = PVE::JSONSchema::get_options($info->{parameters}, $args, $arg_param, $fixed_param, $pwcallback);
 505         $res = $self->handle($info, $param);
 506     };
 507     if (my $err = $@) {
 508         my $ec = ref($err);
 509
 510         die $err if !$ec || $ec ne "PVE::Exception" || !$err->is_param_exc();
 511
 512         $err->{usage} = $self->usage_str($name, $prefix, $arg_param, $fixed_param, 'short', $pwcallback);
 513
 514         die $err;
 515     }
 516
 517     return $res;
 518 }
 519
 520 # utility methods
 521 # note: this modifies the original hash by adding the id property
 522 sub hash_to_array {
 523     my ($hash, $idprop) = @_;
 524
 525     my $res = [];
 526     return $res if !$hash;
 527
 528     foreach my $k (keys %$hash) {
 529         $hash->{$k}->{$idprop} = $k;
 530         push @$res, $hash->{$k};
 531     }
 532
 533     return $res;
 534 }
 535
 536 1;