src/PVE/CLIFormatter.pm

   1 package PVE::CLIFormatter;
   2
   3 use strict;
   4 use warnings;
   5 use I18N::Langinfo;
   6 use POSIX qw(strftime);
   7 use CPAN::Meta::YAML; # comes with perl-modules
   8
   9 use PVE::JSONSchema;
  10 use PVE::PTY;
  11 use JSON;
  12 use utf8;
  13 use Encode;
  14
  15 sub render_timestamp {
  16     my ($epoch) = @_;
  17
  18     # ISO 8601 date format
  19     return strftime("%F %H:%M:%S", localtime($epoch));
  20 }
  21
  22 PVE::JSONSchema::register_renderer('timestamp', \&render_timestamp);
  23
  24 sub render_timestamp_gmt {
  25     my ($epoch) = @_;
  26
  27     # ISO 8601 date format, standard Greenwich time zone
  28     return strftime("%F %H:%M:%S", gmtime($epoch));
  29 }
  30
  31 PVE::JSONSchema::register_renderer('timestamp_gmt', \&render_timestamp_gmt);
  32
  33 sub render_duration {
  34     my ($duration_in_seconds) = @_;
  35
  36     my $text = '';
  37     my $rest = $duration_in_seconds;
  38
  39     my $step = sub {
  40         my ($unit, $unitlength) = @_;
  41
  42         if ((my $v = int($rest/$unitlength)) > 0) {
  43             $text .= " " if length($text);
  44             $text .= "${v}${unit}";
  45             $rest -= $v * $unitlength;
  46         }
  47     };
  48
  49     $step->('w', 7*24*3600);
  50     $step->('d', 24*3600);
  51     $step->('h', 3600);
  52     $step->('m', 60);
  53     $step->('s', 1);
  54
  55     return $text;
  56 }
  57
  58 PVE::JSONSchema::register_renderer('duration', \&render_duration);
  59
  60 sub render_fraction_as_percentage {
  61     my ($fraction) = @_;
  62
  63     return sprintf("%.2f%%", $fraction*100);
  64 }
  65
  66 PVE::JSONSchema::register_renderer(
  67     'fraction_as_percentage', \&render_fraction_as_percentage);
  68
  69 sub render_bytes {
  70     my ($value) = @_;
  71
  72     my @units = qw(B KiB MiB GiB TiB PiB);
  73
  74     my $max_unit = 0;
  75     if ($value > 1023) {
  76         $max_unit = int(log($value)/log(1024));
  77         $value /= 1024**($max_unit);
  78     }
  79
  80     return sprintf "%.2f $units[$max_unit]", $value;
  81 }
  82
  83 PVE::JSONSchema::register_renderer('bytes', \&render_bytes);
  84
  85 sub render_yaml {
  86     my ($value) = @_;
  87
  88     my $data = CPAN::Meta::YAML::Dump($value);
  89     $data =~ s/^---[\n\s]//; # remove yaml marker
  90
  91     return $data;
  92 }
  93
  94 PVE::JSONSchema::register_renderer('yaml', \&render_yaml);
  95
  96 sub query_terminal_options {
  97     my ($options) = @_;
  98
  99     $options //= {};
 100
 101     if (-t STDOUT) {
 102         ($options->{columns}) = PVE::PTY::tcgetsize(*STDOUT);
 103     }
 104
 105     $options->{encoding} = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET());
 106
 107     $options->{utf8} = 1 if $options->{encoding} eq 'UTF-8';
 108
 109     return $options;
 110 }
 111
 112 sub data_to_text {
 113     my ($data, $propdef, $options, $terminal_opts) = @_;
 114
 115     return '' if !defined($data);
 116
 117     $terminal_opts //= {};
 118
 119     my $human_readable = $options->{'human-readable'} // 1;
 120
 121      if ($human_readable && defined($propdef)) {
 122         if (my $type = $propdef->{type}) {
 123             if ($type eq 'boolean') {
 124                 return $data ? 1 : 0;
 125             }
 126         }
 127         if (!defined($data) && defined($propdef->{default})) {
 128             return "($propdef->{default})";
 129         }
 130         if (defined(my $renderer = $propdef->{renderer})) {
 131             my $code = PVE::JSONSchema::get_renderer($renderer);
 132             die "internal error: unknown renderer '$renderer'" if !$code;
 133             return $code->($data, $options, $terminal_opts);
 134         }
 135     }
 136
 137     if (my $class = ref($data)) {
 138         return to_json($data, { canonical => 1 });
 139     } else {
 140         return "$data";
 141     }
 142 }
 143
 144 # prints a formatted table with a title row.
 145 # $data - the data to print (array of objects)
 146 # $returnprops -json schema property description
 147 # $props_to_print - ordered list of properties to print
 148 # $options
 149 # - sort_key: can be used to sort after a specific column, if it isn't set we sort
 150 #   after the leftmost column (with no undef value in $data) this can be
 151 #   turned off by passing 0 as sort_key
 152 # - noborder: print without asciiart border
 153 # - noheader: print without table header
 154 # - columns: limit output width (if > 0)
 155 # - utf8: use utf8 characters for table delimiters
 156
 157 sub print_text_table {
 158     my ($data, $returnprops, $props_to_print, $options, $terminal_opts) = @_;
 159
 160     $terminal_opts //= query_terminal_options({});
 161
 162     my $sort_key = $options->{sort_key};
 163     my $border = !$options->{noborder};
 164     my $header = !$options->{noheader};
 165
 166     my $columns = $terminal_opts->{columns};
 167     my $utf8 = $terminal_opts->{utf8};
 168     my $encoding = $terminal_opts->{encoding} // 'UTF-8';
 169
 170     $sort_key //= $props_to_print->[0];
 171
 172     if (defined($sort_key) && $sort_key ne 0) {
 173         my $type = $returnprops->{$sort_key}->{type} // 'string';
 174         if ($type eq 'integer' || $type eq 'number') {
 175             @$data = sort { $a->{$sort_key} <=> $b->{$sort_key} } @$data;
 176         } else {
 177             @$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
 178         }
 179     }
 180
 181     my $colopts = {};
 182
 183     my $borderstring_m = '';
 184     my $borderstring_b = '';
 185     my $borderstring_t = '';
 186     my $formatstring = '';
 187
 188     my $column_count = scalar(@$props_to_print);
 189
 190     my $tabledata = [];
 191
 192     foreach my $entry (@$data) {
 193
 194         my $height = 1;
 195         my $rowdata = {};
 196
 197         for (my $i = 0; $i < $column_count; $i++) {
 198             my $prop = $props_to_print->[$i];
 199             my $propinfo = $returnprops->{$prop} // {};
 200
 201             my $text = data_to_text($entry->{$prop}, $propinfo, $options, $terminal_opts);
 202             my $lines = [ split(/\n/, $text) ];
 203             my $linecount = scalar(@$lines);
 204             $height = $linecount if $linecount > $height;
 205
 206             my $width = 0;
 207             foreach my $line (@$lines) {
 208                 my $len = length($line);
 209                 $width = $len if $len > $width;
 210             }
 211
 212             $width = ($width =~ m/^(\d+)$/) ? int($1) : 0; # untaint int
 213
 214             $rowdata->{$prop} = {
 215                 lines => $lines,
 216                 width => $width,
 217             };
 218         }
 219
 220         push @$tabledata, {
 221             height => $height,
 222             rowdata => $rowdata,
 223         };
 224     }
 225
 226     for (my $i = 0; $i < $column_count; $i++) {
 227         my $prop = $props_to_print->[$i];
 228         my $propinfo = $returnprops->{$prop} // {};
 229
 230         my $title = $propinfo->{title} // $prop;
 231         my $cutoff = $propinfo->{print_width} // $propinfo->{maxLength};
 232
 233         # calculate maximal print width and cutoff
 234         my $titlelen = length($title);
 235
 236         my $longest = $titlelen;
 237         foreach my $coldata (@$tabledata) {
 238             my $rowdata = $coldata->{rowdata}->{$prop};
 239             $longest = $rowdata->{width} if $rowdata->{width} > $longest;
 240         }
 241         $cutoff = $longest if !defined($cutoff) || $cutoff > $longest;
 242
 243         $colopts->{$prop} = {
 244             title => $title,
 245             cutoff => $cutoff,
 246         };
 247
 248         if ($border) {
 249             if ($i == 0 && ($column_count == 1)) {
 250                 if ($utf8) {
 251                     $formatstring .= "│ %-${cutoff}s │";
 252                     $borderstring_t .= "┌─" . ('─' x $cutoff) . "─┐";
 253                     $borderstring_m .= "├─" . ('─' x $cutoff) . "─┤";
 254                     $borderstring_b .= "└─" . ('─' x $cutoff) . "─┘";
 255                 } else {
 256                     $formatstring .= "| %-${cutoff}s |";
 257                     $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
 258                 }
 259             } elsif ($i == 0) {
 260                 if ($utf8) {
 261                     $formatstring .= "│ %-${cutoff}s ";
 262                     $borderstring_t .= "┌─" . ('─' x $cutoff) . '─';
 263                     $borderstring_m .= "├─" . ('─' x $cutoff) . '─';
 264                     $borderstring_b .= "└─" . ('─' x $cutoff) . '─';
 265                 } else {
 266                     $formatstring .= "| %-${cutoff}s ";
 267                     $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
 268                 }
 269             } elsif ($i == ($column_count - 1)) {
 270                 if ($utf8) {
 271                     $formatstring .= "│ %-${cutoff}s │";
 272                     $borderstring_t .= "┬─" . ('─' x $cutoff) . "─┐";
 273                     $borderstring_m .= "┼─" . ('─' x $cutoff) . "─┤";
 274                     $borderstring_b .= "┴─" . ('─' x $cutoff) . "─┘";
 275                 } else {
 276                     $formatstring .= "| %-${cutoff}s |";
 277                     $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
 278                 }
 279             } else {
 280                 if ($utf8) {
 281                     $formatstring .= "│ %-${cutoff}s ";
 282                     $borderstring_t .= "┬─" . ('─' x $cutoff) . '─';
 283                     $borderstring_m .= "┼─" . ('─' x $cutoff) . '─';
 284                     $borderstring_b .= "┴─" . ('─' x $cutoff) . '─';
 285                 } else {
 286                     $formatstring .= "| %-${cutoff}s ";
 287                     $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
 288                 }
 289             }
 290         } else {
 291             # skip alignment and cutoff on last column
 292             $formatstring .= ($i == ($column_count - 1)) ? "%s" : "%-${cutoff}s ";
 293         }
 294     }
 295
 296     $borderstring_t = $borderstring_m if !length($borderstring_t);
 297     $borderstring_b = $borderstring_m if !length($borderstring_b);
 298
 299     my $writeln = sub {
 300         my ($text) = @_;
 301
 302         if ($columns) {
 303             print encode($encoding, substr($text, 0, $columns) . "\n");
 304         } else {
 305             print encode($encoding, $text) . "\n";
 306         }
 307     };
 308
 309     $writeln->($borderstring_t) if $border;
 310
 311     if ($header) {
 312         my $text = sprintf $formatstring, map { $colopts->{$_}->{title} } @$props_to_print;
 313         $writeln->($text);
 314     }
 315
 316     for (my $i = 0; $i < scalar(@$tabledata); $i++) {
 317         my $coldata = $tabledata->[$i];
 318
 319         $writeln->($borderstring_m) if $border && ($i != 0 || $header);
 320
 321         for (my $i = 0; $i < $coldata->{height}; $i++) {
 322
 323             my $text = sprintf $formatstring, map {
 324                 substr($coldata->{rowdata}->{$_}->{lines}->[$i] // '', 0, $colopts->{$_}->{cutoff});
 325             } @$props_to_print;
 326
 327             $writeln->($text);
 328         }
 329     }
 330
 331     $writeln->($borderstring_b) if $border;
 332 }
 333
 334 sub extract_properties_to_print {
 335     my ($propdef) = @_;
 336
 337     my $required = [];
 338     my $optional = [];
 339
 340     foreach my $key (keys %$propdef) {
 341         my $prop = $propdef->{$key};
 342         if ($prop->{optional}) {
 343             push @$optional, $key;
 344         } else {
 345             push @$required, $key;
 346         }
 347     }
 348
 349     return [ sort(@$required), sort(@$optional) ];
 350 }
 351
 352 # prints the result of an API GET call returning an array as a table.
 353 # takes formatting information from the results property of the call
 354 # if $props_to_print is provided, prints only those columns. otherwise
 355 # takes all fields of the results property, with a fallback
 356 # to all fields occuring in items of $data.
 357 sub print_api_list {
 358     my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
 359
 360     die "can only print object lists\n"
 361         if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');
 362
 363     my $returnprops = $result_schema->{items}->{properties};
 364
 365     $props_to_print = extract_properties_to_print($returnprops)
 366         if !defined($props_to_print);
 367
 368     if (!scalar(@$props_to_print)) {
 369         my $all_props = {};
 370         foreach my $obj (@$data) {
 371             foreach my $key (keys %$obj) {
 372                 $all_props->{$key} = 1;
 373             }
 374         }
 375         $props_to_print = [ sort keys %{$all_props} ];
 376     }
 377
 378     die "unable to detect list properties\n" if !scalar(@$props_to_print);
 379
 380     print_text_table($data, $returnprops, $props_to_print, $options, $terminal_opts);
 381 }
 382
 383 sub print_api_result {
 384     my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
 385
 386     return if $options->{quiet};
 387
 388     $terminal_opts //= query_terminal_options({});
 389
 390     my $format = $options->{'output-format'} // 'text';
 391
 392     return if $result_schema->{type} eq 'null';
 393
 394     if ($format eq 'yaml') {
 395         print encode('UTF-8', CPAN::Meta::YAML::Dump($data));
 396     } elsif ($format eq 'json') {
 397         # Note: we always use utf8 encoding for json format
 398         print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1 }) . "\n";
 399     } elsif ($format eq 'json-pretty') {
 400         # Note: we always use utf8 encoding for json format
 401         print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
 402     } elsif ($format eq 'text') {
 403         my $encoding = $options->{encoding} // 'UTF-8';
 404         my $type = $result_schema->{type};
 405         if ($type eq 'object') {
 406             $props_to_print = extract_properties_to_print($result_schema->{properties})
 407                 if !defined($props_to_print);
 408             $props_to_print = [ sort keys %$data ] if !scalar(@$props_to_print);
 409             my $kvstore = [];
 410             foreach my $key (@$props_to_print) {
 411                 next if !defined($data->{$key});
 412                 push @$kvstore, { key => $key, value => data_to_text($data->{$key}, $result_schema->{properties}->{$key}, $options, $terminal_opts) };
 413             }
 414             my $schema = { type => 'array', items => { type => 'object' }};
 415             print_api_list($kvstore, $schema, ['key', 'value'], $options, $terminal_opts);
 416         } elsif ($type eq 'array') {
 417             return if !scalar(@$data);
 418             my $item_type = $result_schema->{items}->{type};
 419             if ($item_type eq 'object') {
 420                 print_api_list($data, $result_schema, $props_to_print, $options, $terminal_opts);
 421             } else {
 422                 my $kvstore = [];
 423                 foreach my $value (@$data) {
 424                     push @$kvstore, { value => $value };
 425                 }
 426                 my $schema = { type => 'array', items => { type => 'object', properties => { value => $result_schema->{items} }}};
 427                 print_api_list($kvstore, $schema, ['value'], { %$options, noheader => 1 },  $terminal_opts);
 428             }
 429         } else {
 430             print encode($encoding, "$data\n");
 431         }
 432     } else {
 433         die "internal error: unknown output format"; # should not happen
 434     }
 435 }
 436
 437 1;