src/PVE/CLIFormatter.pm

   1 package PVE::CLIFormatter;
   2
   3 use strict;
   4 use warnings;
   5 use I18N::Langinfo;
   6 use POSIX qw(strftime);
   7 use CPAN::Meta::YAML; # comes with perl-modules
   8
   9 use PVE::JSONSchema;
  10 use PVE::PTY;
  11 use JSON;
  12 use utf8;
  13 use Encode;
  14
  15 sub render_timestamp {
  16     my ($epoch) = @_;
  17
  18     # ISO 8601 date format
  19     return strftime("%F %H:%M:%S", localtime($epoch));
  20 }
  21
  22 PVE::JSONSchema::register_renderer('timestamp', \&render_timestamp);
  23
  24 sub render_timestamp_gmt {
  25     my ($epoch) = @_;
  26
  27     # ISO 8601 date format, standard Greenwich time zone
  28     return strftime("%F %H:%M:%S", gmtime($epoch));
  29 }
  30
  31 PVE::JSONSchema::register_renderer('timestamp_gmt', \&render_timestamp_gmt);
  32
  33 sub render_duration {
  34     my ($duration_in_seconds) = @_;
  35
  36     my $text = '';
  37     my $rest = $duration_in_seconds;
  38
  39     my $step = sub {
  40         my ($unit, $unitlength) = @_;
  41
  42         if ((my $v = int($rest/$unitlength)) > 0) {
  43             $text .= " " if length($text);
  44             $text .= "${v}${unit}";
  45             $rest -= $v * $unitlength;
  46         }
  47     };
  48
  49     $step->('w', 7*24*3600);
  50     $step->('d', 24*3600);
  51     $step->('h', 3600);
  52     $step->('m', 60);
  53     $step->('s', 1);
  54
  55     return $text;
  56 }
  57
  58 PVE::JSONSchema::register_renderer('duration', \&render_duration);
  59
  60 sub render_fraction_as_percentage {
  61     my ($fraction) = @_;
  62
  63     return sprintf("%.2f%%", $fraction*100);
  64 }
  65
  66 PVE::JSONSchema::register_renderer(
  67     'fraction_as_percentage', \&render_fraction_as_percentage);
  68
  69 sub render_bytes {
  70     my ($value) = @_;
  71
  72     my @units = qw(B KiB MiB GiB TiB PiB);
  73
  74     my $max_unit = 0;
  75     if ($value > 1023) {
  76         $max_unit = int(log($value)/log(1024));
  77         $value /= 1024**($max_unit);
  78     }
  79
  80     return sprintf "%.2f $units[$max_unit]", $value;
  81 }
  82
  83 PVE::JSONSchema::register_renderer('bytes', \&render_bytes);
  84
  85 sub render_yaml {
  86     my ($value) = @_;
  87
  88     my $data = CPAN::Meta::YAML::Dump($value);
  89     $data =~ s/^---[\n\s]//; # remove yaml marker
  90
  91     return $data;
  92 }
  93
  94 PVE::JSONSchema::register_renderer('yaml', \&render_yaml);
  95
  96 sub query_terminal_options {
  97     my ($options) = @_;
  98
  99     $options //= {};
 100
 101     if (-t STDOUT) {
 102         ($options->{columns}) = PVE::PTY::tcgetsize(*STDOUT);
 103     }
 104
 105     $options->{encoding} = I18N::Langinfo::langinfo(I18N::Langinfo::CODESET());
 106
 107     $options->{utf8} = 1 if $options->{encoding} eq 'UTF-8';
 108
 109     return $options;
 110 }
 111
 112 sub data_to_text {
 113     my ($data, $propdef, $options, $terminal_opts) = @_;
 114
 115     return '' if !defined($data);
 116
 117     $terminal_opts //= {};
 118
 119     my $human_readable = $options->{'human-readable'} // 1;
 120
 121      if ($human_readable && defined($propdef)) {
 122         if (my $type = $propdef->{type}) {
 123             if ($type eq 'boolean') {
 124                 return $data ? 1 : 0;
 125             }
 126         }
 127         if (!defined($data) && defined($propdef->{default})) {
 128             return "($propdef->{default})";
 129         }
 130         if (defined(my $renderer = $propdef->{renderer})) {
 131             my $code = PVE::JSONSchema::get_renderer($renderer);
 132             die "internal error: unknown renderer '$renderer'" if !$code;
 133             return $code->($data, $options, $terminal_opts);
 134         }
 135     }
 136
 137     if (my $class = ref($data)) {
 138         return to_json($data, { canonical => 1 });
 139     } else {
 140         return "$data";
 141     }
 142 }
 143
 144 # prints a formatted table with a title row.
 145 # $data - the data to print (array of objects)
 146 # $returnprops -json schema property description
 147 # $props_to_print - ordered list of properties to print
 148 # $options
 149 # - sort_key: can be used to sort after a specific column, if it isn't set we sort
 150 #   after the leftmost column (with no undef value in $data) this can be
 151 #   turned off by passing 0 as sort_key
 152 # - noborder: print without asciiart border
 153 # - noheader: print without table header
 154 # - columns: limit output width (if > 0)
 155 # - utf8: use utf8 characters for table delimiters
 156
 157 sub print_text_table {
 158     my ($data, $returnprops, $props_to_print, $options, $terminal_opts) = @_;
 159
 160     $terminal_opts //= query_terminal_options({});
 161
 162     my $sort_key = $options->{sort_key};
 163     my $border = !$options->{noborder};
 164     my $header = !$options->{noheader};
 165
 166     my $columns = $terminal_opts->{columns};
 167     my $utf8 = $terminal_opts->{utf8};
 168     my $encoding = $terminal_opts->{encoding} // 'UTF-8';
 169
 170     $sort_key //= $props_to_print->[0];
 171
 172     if (defined($sort_key) && $sort_key ne 0) {
 173         my $type = $returnprops->{$sort_key}->{type} // 'string';
 174         if ($type eq 'integer' || $type eq 'number') {
 175             @$data = sort { $a->{$sort_key} <=> $b->{$sort_key} } @$data;
 176         } else {
 177             @$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
 178         }
 179     }
 180
 181     my $colopts = {};
 182
 183     my $borderstring_m = '';
 184     my $borderstring_b = '';
 185     my $borderstring_t = '';
 186     my $formatstring = '';
 187
 188     my $column_count = scalar(@$props_to_print);
 189
 190     my $tabledata = [];
 191
 192     foreach my $entry (@$data) {
 193
 194         my $height = 1;
 195         my $rowdata = {};
 196
 197         for (my $i = 0; $i < $column_count; $i++) {
 198             my $prop = $props_to_print->[$i];
 199             my $propinfo = $returnprops->{$prop} // {};
 200
 201             my $text = data_to_text($entry->{$prop}, $propinfo, $options, $terminal_opts);
 202             my $lines = [ split(/\n/, $text) ];
 203             my $linecount = scalar(@$lines);
 204             $height = $linecount if $linecount > $height;
 205
 206             my $width = 0;
 207             foreach my $line (@$lines) {
 208                 my $len = length($line);
 209                 $width = $len if $len > $width;
 210             }
 211
 212             $width = ($width =~ m/^(\d+)$/) ? int($1) : 0; # untaint int
 213
 214             $rowdata->{$prop} = {
 215                 lines => $lines,
 216                 width => $width,
 217             };
 218         }
 219
 220         push @$tabledata, {
 221             height => $height,
 222             rowdata => $rowdata,
 223         };
 224     }
 225
 226     for (my $i = 0; $i < $column_count; $i++) {
 227         my $prop = $props_to_print->[$i];
 228         my $propinfo = $returnprops->{$prop} // {};
 229         my $type = $propinfo->{type} // 'string';
 230         my $alignstr = ($type eq 'integer' || $type eq 'number') ? '' : '-';
 231
 232         my $title = $propinfo->{title} // $prop;
 233         my $cutoff = $propinfo->{print_width} // $propinfo->{maxLength};
 234
 235         # calculate maximal print width and cutoff
 236         my $titlelen = length($title);
 237
 238         my $longest = $titlelen;
 239         foreach my $coldata (@$tabledata) {
 240             my $rowdata = $coldata->{rowdata}->{$prop};
 241             $longest = $rowdata->{width} if $rowdata->{width} > $longest;
 242         }
 243         $cutoff = $longest if !defined($cutoff) || $cutoff > $longest;
 244
 245         $colopts->{$prop} = {
 246             title => $title,
 247             cutoff => $cutoff,
 248         };
 249
 250         if ($border) {
 251             if ($i == 0 && ($column_count == 1)) {
 252                 if ($utf8) {
 253                     $formatstring .= "│ %$alignstr${cutoff}s │";
 254                     $borderstring_t .= "┌─" . ('─' x $cutoff) . "─┐";
 255                     $borderstring_m .= "├─" . ('─' x $cutoff) . "─┤";
 256                     $borderstring_b .= "└─" . ('─' x $cutoff) . "─┘";
 257                 } else {
 258                     $formatstring .= "| %$alignstr${cutoff}s |";
 259                     $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
 260                 }
 261             } elsif ($i == 0) {
 262                 if ($utf8) {
 263                     $formatstring .= "│ %$alignstr${cutoff}s ";
 264                     $borderstring_t .= "┌─" . ('─' x $cutoff) . '─';
 265                     $borderstring_m .= "├─" . ('─' x $cutoff) . '─';
 266                     $borderstring_b .= "└─" . ('─' x $cutoff) . '─';
 267                 } else {
 268                     $formatstring .= "| %$alignstr${cutoff}s ";
 269                     $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
 270                 }
 271             } elsif ($i == ($column_count - 1)) {
 272                 if ($utf8) {
 273                     $formatstring .= "│ %$alignstr${cutoff}s │";
 274                     $borderstring_t .= "┬─" . ('─' x $cutoff) . "─┐";
 275                     $borderstring_m .= "┼─" . ('─' x $cutoff) . "─┤";
 276                     $borderstring_b .= "┴─" . ('─' x $cutoff) . "─┘";
 277                 } else {
 278                     $formatstring .= "| %$alignstr${cutoff}s |";
 279                     $borderstring_m .= "+-" . ('-' x $cutoff) . "-+";
 280                 }
 281             } else {
 282                 if ($utf8) {
 283                     $formatstring .= "│ %$alignstr${cutoff}s ";
 284                     $borderstring_t .= "┬─" . ('─' x $cutoff) . '─';
 285                     $borderstring_m .= "┼─" . ('─' x $cutoff) . '─';
 286                     $borderstring_b .= "┴─" . ('─' x $cutoff) . '─';
 287                 } else {
 288                     $formatstring .= "| %$alignstr${cutoff}s ";
 289                     $borderstring_m .= "+-" . ('-' x $cutoff) . '-';
 290                 }
 291             }
 292         } else {
 293             # skip alignment and cutoff on last column
 294             $formatstring .= ($i == ($column_count - 1)) ? "%s" : "%$alignstr${cutoff}s ";
 295         }
 296     }
 297
 298     $borderstring_t = $borderstring_m if !length($borderstring_t);
 299     $borderstring_b = $borderstring_m if !length($borderstring_b);
 300
 301     my $writeln = sub {
 302         my ($text) = @_;
 303
 304         if ($columns) {
 305             print encode($encoding, substr($text, 0, $columns) . "\n");
 306         } else {
 307             print encode($encoding, $text) . "\n";
 308         }
 309     };
 310
 311     $writeln->($borderstring_t) if $border;
 312
 313     if ($header) {
 314         my $text = sprintf $formatstring, map { $colopts->{$_}->{title} } @$props_to_print;
 315         $writeln->($text);
 316     }
 317
 318     for (my $i = 0; $i < scalar(@$tabledata); $i++) {
 319         my $coldata = $tabledata->[$i];
 320
 321         $writeln->($borderstring_m) if $border && ($i != 0 || $header);
 322
 323         for (my $i = 0; $i < $coldata->{height}; $i++) {
 324
 325             my $text = sprintf $formatstring, map {
 326                 substr($coldata->{rowdata}->{$_}->{lines}->[$i] // '', 0, $colopts->{$_}->{cutoff});
 327             } @$props_to_print;
 328
 329             $writeln->($text);
 330         }
 331     }
 332
 333     $writeln->($borderstring_b) if $border;
 334 }
 335
 336 sub extract_properties_to_print {
 337     my ($propdef) = @_;
 338
 339     my $required = [];
 340     my $optional = [];
 341
 342     foreach my $key (keys %$propdef) {
 343         my $prop = $propdef->{$key};
 344         if ($prop->{optional}) {
 345             push @$optional, $key;
 346         } else {
 347             push @$required, $key;
 348         }
 349     }
 350
 351     return [ sort(@$required), sort(@$optional) ];
 352 }
 353
 354 # prints the result of an API GET call returning an array as a table.
 355 # takes formatting information from the results property of the call
 356 # if $props_to_print is provided, prints only those columns. otherwise
 357 # takes all fields of the results property, with a fallback
 358 # to all fields occuring in items of $data.
 359 sub print_api_list {
 360     my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
 361
 362     die "can only print object lists\n"
 363         if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');
 364
 365     my $returnprops = $result_schema->{items}->{properties};
 366
 367     $props_to_print = extract_properties_to_print($returnprops)
 368         if !defined($props_to_print);
 369
 370     if (!scalar(@$props_to_print)) {
 371         my $all_props = {};
 372         foreach my $obj (@$data) {
 373             foreach my $key (keys %$obj) {
 374                 $all_props->{$key} = 1;
 375             }
 376         }
 377         $props_to_print = [ sort keys %{$all_props} ];
 378     }
 379
 380     die "unable to detect list properties\n" if !scalar(@$props_to_print);
 381
 382     print_text_table($data, $returnprops, $props_to_print, $options, $terminal_opts);
 383 }
 384
 385 sub print_api_result {
 386     my ($data, $result_schema, $props_to_print, $options, $terminal_opts) = @_;
 387
 388     return if $options->{quiet};
 389
 390     $terminal_opts //= query_terminal_options({});
 391
 392     my $format = $options->{'output-format'} // 'text';
 393
 394     return if $result_schema->{type} eq 'null';
 395
 396     if ($format eq 'yaml') {
 397         print encode('UTF-8', CPAN::Meta::YAML::Dump($data));
 398     } elsif ($format eq 'json') {
 399         # Note: we always use utf8 encoding for json format
 400         print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1 }) . "\n";
 401     } elsif ($format eq 'json-pretty') {
 402         # Note: we always use utf8 encoding for json format
 403         print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
 404     } elsif ($format eq 'text') {
 405         my $encoding = $options->{encoding} // 'UTF-8';
 406         my $type = $result_schema->{type};
 407         if ($type eq 'object') {
 408             $props_to_print = extract_properties_to_print($result_schema->{properties})
 409                 if !defined($props_to_print);
 410             $props_to_print = [ sort keys %$data ] if !scalar(@$props_to_print);
 411             my $kvstore = [];
 412             foreach my $key (@$props_to_print) {
 413                 next if !defined($data->{$key});
 414                 push @$kvstore, { key => $key, value => data_to_text($data->{$key}, $result_schema->{properties}->{$key}, $options, $terminal_opts) };
 415             }
 416             my $schema = { type => 'array', items => { type => 'object' }};
 417             print_api_list($kvstore, $schema, ['key', 'value'], $options, $terminal_opts);
 418         } elsif ($type eq 'array') {
 419             return if !scalar(@$data);
 420             my $item_type = $result_schema->{items}->{type};
 421             if ($item_type eq 'object') {
 422                 print_api_list($data, $result_schema, $props_to_print, $options, $terminal_opts);
 423             } else {
 424                 my $kvstore = [];
 425                 foreach my $value (@$data) {
 426                     push @$kvstore, { value => $value };
 427                 }
 428                 my $schema = { type => 'array', items => { type => 'object', properties => { value => $result_schema->{items} }}};
 429                 print_api_list($kvstore, $schema, ['value'], { %$options, noheader => 1 },  $terminal_opts);
 430             }
 431         } else {
 432             print encode($encoding, "$data\n");
 433         }
 434     } else {
 435         die "internal error: unknown output format"; # should not happen
 436     }
 437 }
 438
 439 sub print_api_result_plain {
 440     my ($data, $result_schema, $props_to_print, $options) = @_;
 441
 442     # avoid borders and header, ignore terminal width
 443     $options = $options ? { %$options } : {}; # copy
 444
 445     $options->{noheader} //= 1;
 446     $options->{noborder} //= 1;
 447
 448     print_api_result($data, $result_schema, $props_to_print, $options, {});
 449 }
 450
 451 1;