src/PVE/CLIHandler.pm

   1 package PVE::CLIHandler;
   2
   3 use strict;
   4 use warnings;
   5 use JSON;
   6
   7 use PVE::SafeSyslog;
   8 use PVE::Exception qw(raise raise_param_exc);
   9 use PVE::RESTHandler;
  10 use PVE::PTY;
  11 use PVE::INotify;
  12
  13 use base qw(PVE::RESTHandler);
  14
  15 # $cmddef defines which (sub)commands are available in a specific CLI class.
  16 # A real command is always an array consisting of its class, name, array of
  17 # position fixed (required) parameters and hash of predefined parameters when
  18 # mapping a CLI command t o an API call. Optionally an output method can be
  19 # passed at the end, e.g., for formatting or transformation purpose.
  20 #
  21 # [class, name, fixed_params, API_pre-set params, output_sub ]
  22 #
  23 # In case of so called 'simple commands', the $cmddef can be also just an
  24 # array.
  25 #
  26 # Examples:
  27 # $cmddef = {
  28 #     command => [ 'PVE::API2::Class', 'command', [ 'arg1', 'arg2' ], { node => $nodename } ],
  29 #     do => {
  30 #         this => [ 'PVE::API2::OtherClass', 'method', [ 'arg1' ], undef, sub {
  31 #             my ($res) = @_;
  32 #             print "$res\n";
  33 #         }],
  34 #         that => [ 'PVE::API2::OtherClass', 'subroutine' [] ],
  35 #     },
  36 #     dothat => { alias => 'do that' },
  37 # }
  38 my $cmddef;
  39 my $exename;
  40 my $cli_handler_class;
  41
  42 my $standard_mappings = {
  43     'pve-password' => {
  44         name => 'password',
  45         desc => '<password>',
  46         interactive => 1,
  47         func => sub {
  48             my ($value) = @_;
  49             return $value if $value;
  50             return PVE::PTY::get_confirmed_password();
  51         },
  52     },
  53 };
  54 sub get_standard_mapping {
  55     my ($name, $base) = @_;
  56
  57     my $std = $standard_mappings->{$name};
  58     die "no such standard mapping '$name'\n" if !$std;
  59
  60     my $res = $base || {};
  61
  62     foreach my $opt (keys %$std) {
  63         next if defined($res->{$opt});
  64         $res->{$opt} = $std->{$opt};
  65     }
  66
  67     return $res;
  68 }
  69
  70 my $assert_initialized = sub {
  71     my @caller = caller;
  72     die "$caller[0]:$caller[2] - not initialized\n"
  73         if !($cmddef && $exename && $cli_handler_class);
  74 };
  75
  76 my $abort = sub {
  77     my ($reason, $cmd) = @_;
  78     print_usage_short (\*STDERR, $reason, $cmd);
  79     exit (-1);
  80 };
  81
  82 my $expand_command_name = sub {
  83     my ($def, $cmd) = @_;
  84
  85     return $cmd if exists $def->{$cmd}; # command is already complete
  86
  87     my $is_alias = sub { ref($_[0]) eq 'HASH' && exists($_[0]->{alias}) };
  88     my @expanded = grep { /^\Q$cmd\E/ && !$is_alias->($def->{$_}) } keys %$def;
  89
  90     return $expanded[0] if scalar(@expanded) == 1; # enforce exact match
  91
  92     return undef;
  93 };
  94
  95 my $get_commands = sub {
  96     my $def = shift // die "no command definition passed!";
  97     return [ grep { !(ref($def->{$_}) eq 'HASH' && defined($def->{$_}->{alias})) } sort keys %$def ];
  98 };
  99
 100 my $complete_command_names = sub { $get_commands->($cmddef) };
 101
 102 # traverses the command definition using the $argv array, resolving one level
 103 # of aliases.
 104 # Returns the matching (sub) command and its definition, and argument array for
 105 # this (sub) command and a hash where we marked which (sub) commands got
 106 # expanded (e.g. st => status) while traversing
 107 sub resolve_cmd {
 108     my ($argv, $is_alias) = @_;
 109
 110     my ($def, $cmd) = ($cmddef, $argv);
 111     my $cmdstr = $exename;
 112
 113     if (ref($argv) eq 'ARRAY') {
 114         my $expanded_last_arg;
 115         my $last_arg_id = scalar(@$argv) - 1;
 116
 117         for my $i (0..$last_arg_id) {
 118             $cmd = $expand_command_name->($def, $argv->[$i]);
 119             if (defined($cmd)) {
 120                 # If the argument was expanded (or was already complete) and it
 121                 # is the final argument, tell our caller about it:
 122                 $expanded_last_arg = $cmd if $i == $last_arg_id;
 123             } else {
 124                 # Otherwise continue with the unexpanded version of it.
 125                 $cmd = $argv->[$i];
 126             }
 127             $cmdstr .= " $cmd";
 128             $def = $def->{$cmd};
 129             last if !defined($def);
 130
 131             if (ref($def) eq 'ARRAY') {
 132                 # could expand to a real command, rest of $argv are its arguments
 133                 my $cmd_args = [ @$argv[$i+1..$last_arg_id] ];
 134                 return ($cmd, $def, $cmd_args, $expanded_last_arg, $cmdstr);
 135             }
 136
 137             if (defined($def->{alias})) {
 138                 die "alias loop detected for '$cmd'" if $is_alias; # avoids cycles
 139                 # replace aliased (sub)command with the expanded aliased command
 140                 splice @$argv, $i, 1, split(/ +/, $def->{alias});
 141                 return resolve_cmd($argv, 1);
 142             }
 143         }
 144         # got either a special command (bashcomplete, verifyapi) or an unknown
 145         # cmd, just return first entry as cmd and the rest of $argv as cmd_arg
 146         my $cmd_args = [ @$argv[1..$last_arg_id] ];
 147         return ($argv->[0], $def, $cmd_args, $expanded_last_arg, $cmdstr);
 148     }
 149     return ($cmd, $def, undef, undef, $cmdstr);
 150 }
 151
 152 sub generate_usage_str {
 153     my ($format, $cmd, $indent, $separator, $sortfunc) = @_;
 154
 155     $assert_initialized->();
 156     die 'format required' if !$format;
 157
 158     $sortfunc //= sub { sort keys %{$_[0]} };
 159     $separator //= '';
 160     $indent //= '';
 161
 162     my $read_password_func = $cli_handler_class->can('read_password');
 163     my $param_mapping_func = $cli_handler_class->can('param_mapping') ||
 164         $cli_handler_class->can('string_param_file_mapping');
 165
 166     my ($subcmd, $def, undef, undef, $cmdstr) = resolve_cmd($cmd);
 167     $abort->("unknown command '$cmdstr'") if !defined($def) && ref($cmd) eq 'ARRAY';
 168
 169     my $generate;
 170     $generate = sub {
 171         my ($indent, $separator, $def, $prefix) = @_;
 172
 173         my $str = '';
 174         if (ref($def) eq 'HASH') {
 175             my $oldclass = undef;
 176             foreach my $cmd (&$sortfunc($def)) {
 177
 178                 if (ref($def->{$cmd}) eq 'ARRAY') {
 179                     my ($class, $name, $arg_param, $fixed_param) = @{$def->{$cmd}};
 180
 181                     $str .= $separator if $oldclass && $oldclass ne $class;
 182                     $str .= $indent;
 183                     $str .= $class->usage_str($name, "$prefix $cmd", $arg_param,
 184                                               $fixed_param, $format,
 185                                               $read_password_func, $param_mapping_func);
 186                     $oldclass = $class;
 187
 188                 } elsif (defined($def->{$cmd}->{alias}) && ($format eq 'asciidoc')) {
 189
 190                     $str .= "*$prefix $cmd*\n\nAn alias for '$exename $def->{$cmd}->{alias}'.\n\n";
 191
 192                 } else {
 193                     next if $def->{$cmd}->{alias};
 194
 195                     my $substr = $generate->($indent, $separator, $def->{$cmd}, "$prefix $cmd");
 196                     if ($substr) {
 197                         $substr .= $separator if $substr !~ /\Q$separator\E{2}/;
 198                         $str .= $substr;
 199                     }
 200                 }
 201
 202             }
 203         } else {
 204             my ($class, $name, $arg_param, $fixed_param) = @$def;
 205             $abort->("unknown command '$cmd'") if !$class;
 206
 207             $str .= $indent;
 208             $str .= $class->usage_str($name, $prefix, $arg_param, $fixed_param, $format,
 209                                       $read_password_func, $param_mapping_func);
 210         }
 211         return $str;
 212     };
 213
 214     return $generate->($indent, $separator, $def, $cmdstr);
 215 }
 216
 217 __PACKAGE__->register_method ({
 218     name => 'help',
 219     path => 'help',
 220     method => 'GET',
 221     description => "Get help about specified command.",
 222     parameters => {
 223         additionalProperties => 0,
 224         properties => {
 225             'extra-args' => PVE::JSONSchema::get_standard_option('extra-args', {
 226                 description => 'Shows help for a specific command',
 227                 completion => $complete_command_names,
 228             }),
 229             verbose => {
 230                 description => "Verbose output format.",
 231                 type => 'boolean',
 232                 optional => 1,
 233             },
 234         },
 235     },
 236     returns => { type => 'null' },
 237
 238     code => sub {
 239         my ($param) = @_;
 240
 241         $assert_initialized->();
 242
 243         my $cmd = $param->{'extra-args'};
 244
 245         my $verbose = defined($cmd) && $cmd;
 246         $verbose = $param->{verbose} if defined($param->{verbose});
 247
 248         if (!$cmd) {
 249             if ($verbose) {
 250                 print_usage_verbose();
 251             } else {
 252                 print_usage_short(\*STDOUT);
 253             }
 254             return undef;
 255         }
 256
 257         my $str;
 258         if ($verbose) {
 259             $str = generate_usage_str('full', $cmd, '');
 260         } else {
 261             $str = generate_usage_str('short', $cmd, ' ' x 7);
 262         }
 263         $str =~ s/^\s+//;
 264
 265         if ($verbose) {
 266             print "$str\n";
 267         } else {
 268             print "USAGE: $str\n";
 269         }
 270
 271         return undef;
 272
 273     }});
 274
 275 sub print_simple_asciidoc_synopsis {
 276     $assert_initialized->();
 277
 278     my $synopsis = "*${exename}* `help`\n\n";
 279     $synopsis .= generate_usage_str('asciidoc');
 280
 281     return $synopsis;
 282 }
 283
 284 sub print_asciidoc_synopsis {
 285     $assert_initialized->();
 286
 287     my $synopsis = "";
 288
 289     $synopsis .= "*${exename}* `<COMMAND> [ARGS] [OPTIONS]`\n\n";
 290
 291     $synopsis .= generate_usage_str('asciidoc');
 292
 293     $synopsis .= "\n";
 294
 295     return $synopsis;
 296 }
 297
 298 sub print_usage_verbose {
 299     $assert_initialized->();
 300
 301     print "USAGE: $exename <COMMAND> [ARGS] [OPTIONS]\n\n";
 302
 303     my $str = generate_usage_str('full');
 304
 305     print "$str\n";
 306 }
 307
 308 sub print_usage_short {
 309     my ($fd, $msg, $cmd) = @_;
 310
 311     $assert_initialized->();
 312
 313     print $fd "ERROR: $msg\n" if $msg;
 314     print $fd "USAGE: $exename <COMMAND> [ARGS] [OPTIONS]\n";
 315
 316     print {$fd} generate_usage_str('short', $cmd, ' ' x 7, "\n", sub {
 317         my ($h) = @_;
 318         return sort {
 319             if (ref($h->{$a}) eq 'ARRAY' && ref($h->{$b}) eq 'ARRAY') {
 320                 # $a and $b are both real commands order them by their class
 321                 return $h->{$a}->[0] cmp $h->{$b}->[0] || $a cmp $b;
 322             } elsif (ref($h->{$a}) eq 'ARRAY' xor ref($h->{$b}) eq 'ARRAY') {
 323                 # real command and subcommand mixed, put sub commands first
 324                 return ref($h->{$b}) eq 'ARRAY' ? -1 : 1;
 325             } else {
 326                 # both are either from the same class or subcommands
 327                 return $a cmp $b;
 328             }
 329         } keys %$h;
 330     });
 331 }
 332
 333 my $print_bash_completion = sub {
 334     my ($simple_cmd, $bash_command, $cur, $prev) = @_;
 335
 336     my $debug = 0;
 337
 338     return if !(defined($cur) && defined($prev) && defined($bash_command));
 339     return if !defined($ENV{COMP_LINE});
 340     return if !defined($ENV{COMP_POINT});
 341
 342     my $cmdline = substr($ENV{COMP_LINE}, 0, $ENV{COMP_POINT});
 343     print STDERR "\nCMDLINE: $ENV{COMP_LINE}\n" if $debug;
 344
 345     my $args = PVE::Tools::split_args($cmdline);
 346     shift @$args; # no need for program name
 347     my $print_result = sub {
 348         foreach my $p (@_) {
 349             print "$p\n" if $p =~ m/^\Q$cur\E/;
 350         }
 351     };
 352
 353     my ($cmd, $def) = ($simple_cmd, $cmddef);
 354     if (!$simple_cmd) {
 355         ($cmd, $def, $args, my $expanded) = resolve_cmd($args);
 356
 357         if (defined($expanded) && $prev ne $expanded) {
 358             print "$expanded\n";
 359             return;
 360         }
 361
 362         if (ref($def) eq 'HASH') {
 363             &$print_result(@{$get_commands->($def)});
 364             return;
 365         }
 366     }
 367     return if !$def;
 368
 369     my $pos = scalar(@$args) - 1;
 370     $pos += 1 if $cmdline =~ m/\s+$/;
 371     print STDERR "pos: $pos\n" if $debug;
 372     return if $pos < 0;
 373
 374     my $skip_param = {};
 375
 376     my ($class, $name, $arg_param, $uri_param) = @$def;
 377     $arg_param //= [];
 378     $uri_param //= {};
 379
 380     $arg_param = [ $arg_param ] if !ref($arg_param);
 381
 382     map { $skip_param->{$_} = 1; } @$arg_param;
 383     map { $skip_param->{$_} = 1; } keys %$uri_param;
 384
 385     my $info = $class->map_method_by_name($name);
 386
 387     my $prop = $info->{parameters}->{properties};
 388
 389     my $print_parameter_completion = sub {
 390         my ($pname) = @_;
 391         my $d = $prop->{$pname};
 392         if ($d->{completion}) {
 393             my $vt = ref($d->{completion});
 394             if ($vt eq 'CODE') {
 395                 my $res = $d->{completion}->($cmd, $pname, $cur, $args);
 396                 &$print_result(@$res);
 397             }
 398         } elsif ($d->{type} eq 'boolean') {
 399             &$print_result('0', '1');
 400         } elsif ($d->{enum}) {
 401             &$print_result(@{$d->{enum}});
 402         }
 403     };
 404
 405     # positional arguments
 406     if ($pos < scalar(@$arg_param)) {
 407         my $pname = $arg_param->[$pos];
 408         &$print_parameter_completion($pname);
 409         return;
 410     }
 411
 412     my @option_list = ();
 413     foreach my $key (keys %$prop) {
 414         next if $skip_param->{$key};
 415         push @option_list, "--$key";
 416     }
 417
 418     if ($cur =~ m/^-/) {
 419         &$print_result(@option_list);
 420         return;
 421     }
 422
 423     if ($prev =~ m/^--?(.+)$/ && $prop->{$1}) {
 424         my $pname = $1;
 425         &$print_parameter_completion($pname);
 426         return;
 427     }
 428
 429     &$print_result(@option_list);
 430 };
 431
 432 sub data_to_text {
 433     my ($data) = @_;
 434
 435     return '' if !defined($data);
 436
 437     if (my $class = ref($data)) {
 438         return to_json($data, { utf8 => 1, canonical => 1 });
 439     } else {
 440         return "$data";
 441     }
 442 }
 443
 444 # prints a formatted table with a title row.
 445 # $data - the data to print (array of objects)
 446 # $returnprops -json schema property description
 447 # $props_to_print - ordered list of properties to print
 448 # $sort_key can be used to sort after a column, if it isn't set we sort
 449 #   after the leftmost column (with no undef value in $data) this can be
 450 #   turned off by passing 0 as $sort_key
 451 sub print_text_table {
 452     my ($data, $returnprops, $props_to_print, $sort_key) = @_;
 453
 454     my $autosort = 1;
 455     if (defined($sort_key) && $sort_key eq 0) {
 456         $autosort = 0;
 457         $sort_key = undef;
 458     }
 459
 460     my $colopts = {};
 461     my $formatstring = '';
 462
 463     my $column_count = scalar(@$props_to_print);
 464
 465     for (my $i = 0; $i < $column_count; $i++) {
 466         my $prop = $props_to_print->[$i];
 467         my $propinfo = $returnprops->{$prop};
 468         die "undefined property '$prop'" if !$propinfo;
 469
 470         my $title = $propinfo->{title} // $prop;
 471         my $cutoff = $propinfo->{print_width} // $propinfo->{maxLength};
 472
 473         # calculate maximal print width and cutoff
 474         my $titlelen = length($title);
 475
 476         my $longest = $titlelen;
 477         my $sortable = $autosort;
 478         foreach my $entry (@$data) {
 479             my $len = length(data_to_text($entry->{$prop})) // 0;
 480             $longest = $len if $len > $longest;
 481             $sortable = 0 if !defined($entry->{$prop});
 482         }
 483         $cutoff = (defined($cutoff) && $cutoff < $longest) ? $cutoff : $longest;
 484         $sort_key //= $prop if $sortable;
 485
 486         $colopts->{$prop} = {
 487             title => $title,
 488             default => $propinfo->{default} // '',
 489             cutoff => $cutoff,
 490         };
 491
 492         $formatstring .= ($i == ($column_count - 1)) ? "%s\n" : "%-${cutoff}s ";
 493     }
 494
 495     printf $formatstring, map { $colopts->{$_}->{title} } @$props_to_print;
 496
 497     if (defined($sort_key)) {
 498         if ($returnprops->{$sort_key}->{type} eq 'integer' ||
 499             $returnprops->{$sort_key}->{type} eq 'number') {
 500             @$data = sort { $a->{$sort_key} <=> $b->{$sort_key} } @$data;
 501         } else {
 502             @$data = sort { $a->{$sort_key} cmp $b->{$sort_key} } @$data;
 503         }
 504     }
 505
 506     foreach my $entry (@$data) {
 507         printf $formatstring, map {
 508             substr(data_to_text($entry->{$_}) // $colopts->{$_}->{default},
 509                    0, $colopts->{$_}->{cutoff});
 510         } @$props_to_print;
 511     }
 512 }
 513
 514 # prints the result of an API GET call returning an array as a table.
 515 # takes formatting information from the results property of the call
 516 # if $props_to_print is provided, prints only those columns. otherwise
 517 # takes all fields of the results property, with a fallback
 518 # to all fields occuring in items of $data.
 519 sub print_api_list {
 520     my ($data, $result_schema, $props_to_print, $sort_key) = @_;
 521
 522     die "can only print object lists\n"
 523         if !($result_schema->{type} eq 'array' && $result_schema->{items}->{type} eq 'object');
 524
 525     my $returnprops = $result_schema->{items}->{properties};
 526
 527     if (!defined($props_to_print)) {
 528         $props_to_print = [ sort keys %$returnprops ];
 529         if (!scalar(@$props_to_print)) {
 530             my $all_props = {};
 531             foreach my $obj (@{$data}) {
 532                 foreach my $key (keys %{$obj}) {
 533                     $all_props->{ $key } = 1;
 534                 }
 535             }
 536             $props_to_print = [ sort keys %{$all_props} ];
 537         }
 538         die "unable to detect list properties\n" if !scalar(@$props_to_print);
 539     }
 540
 541     print_text_table($data, $returnprops, $props_to_print, $sort_key);
 542 }
 543
 544 sub print_api_result {
 545     my ($format, $data, $result_schema, $props_to_print, $sort_key) = @_;
 546
 547     return if $result_schema->{type} eq 'null';
 548
 549     if ($format eq 'json') {
 550         print to_json($data, {utf8 => 1, allow_nonref => 1, canonical => 1, pretty => 1 });
 551     } elsif ($format eq 'text') {
 552         my $type = $result_schema->{type};
 553         if ($type eq 'object') {
 554             $props_to_print = [ sort keys %$data ] if !defined($props_to_print);
 555             foreach my $key (@$props_to_print) {
 556                 print $key . ": " .  data_to_text($data->{$key}) . "\n";
 557             }
 558         } elsif ($type eq 'array') {
 559             return if !scalar(@$data);
 560             my $item_type = $result_schema->{items}->{type};
 561             if ($item_type eq 'object') {
 562                 print_api_list($data, $result_schema, $props_to_print, $sort_key);
 563             } else {
 564                 foreach my $entry (@$data) {
 565                     print data_to_text($entry) . "\n";
 566                 }
 567             }
 568         } else {
 569             print "$data\n";
 570         }
 571     } else {
 572         die "internal error: unknown output format"; # should not happen
 573     }
 574 }
 575
 576 sub verify_api {
 577     my ($class) = @_;
 578
 579     # simply verify all registered methods
 580     PVE::RESTHandler::validate_method_schemas();
 581 }
 582
 583 my $get_exe_name = sub {
 584     my ($class) = @_;
 585
 586     my $name = $class;
 587     $name =~ s/^.*:://;
 588     $name =~ s/_/-/g;
 589
 590     return $name;
 591 };
 592
 593 sub generate_bash_completions {
 594     my ($class) = @_;
 595
 596     # generate bash completion config
 597
 598     $exename = &$get_exe_name($class);
 599
 600     print <<__EOD__;
 601 # $exename bash completion
 602
 603 # see http://tiswww.case.edu/php/chet/bash/FAQ
 604 # and __ltrim_colon_completions() in /usr/share/bash-completion/bash_completion
 605 # this modifies global var, but I found no better way
 606 COMP_WORDBREAKS=\${COMP_WORDBREAKS//:}
 607
 608 complete -o default -C '$exename bashcomplete' $exename
 609 __EOD__
 610 }
 611
 612 sub generate_asciidoc_synopsys {
 613     my ($class) = @_;
 614     $class->generate_asciidoc_synopsis();
 615 };
 616
 617 sub generate_asciidoc_synopsis {
 618     my ($class) = @_;
 619
 620     $cli_handler_class = $class;
 621
 622     $exename = &$get_exe_name($class);
 623
 624     no strict 'refs';
 625     my $def = ${"${class}::cmddef"};
 626     $cmddef = $def;
 627
 628     if (ref($def) eq 'ARRAY') {
 629         print_simple_asciidoc_synopsis();
 630     } else {
 631         $cmddef->{help} = [ __PACKAGE__, 'help', ['cmd'] ];
 632
 633         print_asciidoc_synopsis();
 634     }
 635 }
 636
 637 # overwrite this if you want to run/setup things early
 638 sub setup_environment {
 639     my ($class) = @_;
 640
 641     # do nothing by default
 642 }
 643
 644 my $handle_cmd  = sub {
 645     my ($args, $read_password_func, $preparefunc, $param_mapping_func) = @_;
 646
 647     $cmddef->{help} = [ __PACKAGE__, 'help', ['extra-args'] ];
 648
 649     my ($cmd, $def, $cmd_args, undef, $cmd_str) = resolve_cmd($args);
 650
 651     $abort->("no command specified") if !$cmd;
 652
 653     # call verifyapi before setup_environment(), don't execute any real code in
 654     # this case
 655     if ($cmd eq 'verifyapi') {
 656         PVE::RESTHandler::validate_method_schemas();
 657         return;
 658     }
 659
 660     $cli_handler_class->setup_environment();
 661
 662     if ($cmd eq 'bashcomplete') {
 663         &$print_bash_completion(undef, @$cmd_args);
 664         return;
 665     }
 666
 667     # checked special commands, if def is still a hash we got an incomplete sub command
 668     $abort->("incomplete command '$cmd_str'", $args) if ref($def) eq 'HASH';
 669
 670     &$preparefunc() if $preparefunc;
 671
 672     my ($class, $name, $arg_param, $uri_param, $outsub) = @{$def || []};
 673     $abort->("unknown command '$cmd_str'") if !$class;
 674
 675     my $res = $class->cli_handler($cmd_str, $name, $cmd_args, $arg_param, $uri_param, $read_password_func, $param_mapping_func);
 676
 677     if (defined $outsub) {
 678         my $result_schema = $class->map_method_by_name($name)->{returns};
 679         $outsub->($res, $result_schema);
 680     }
 681 };
 682
 683 my $handle_simple_cmd = sub {
 684     my ($args, $read_password_func, $preparefunc, $param_mapping_func) = @_;
 685
 686     my ($class, $name, $arg_param, $uri_param, $outsub) = @{$cmddef};
 687     die "no class specified" if !$class;
 688
 689     if (scalar(@$args) >= 1) {
 690         if ($args->[0] eq 'help') {
 691             my $str = "USAGE: $name help\n";
 692             $str .= generate_usage_str('long');
 693             print STDERR "$str\n\n";
 694             return;
 695         } elsif ($args->[0] eq 'verifyapi') {
 696             PVE::RESTHandler::validate_method_schemas();
 697             return;
 698         }
 699     }
 700
 701     $cli_handler_class->setup_environment();
 702
 703     if (scalar(@$args) >= 1) {
 704         if ($args->[0] eq 'bashcomplete') {
 705             shift @$args;
 706             &$print_bash_completion($name, @$args);
 707             return;
 708         }
 709     }
 710
 711     &$preparefunc() if $preparefunc;
 712
 713     my $res = $class->cli_handler($name, $name, \@ARGV, $arg_param, $uri_param, $read_password_func, $param_mapping_func);
 714
 715     if (defined $outsub) {
 716         my $result_schema = $class->map_method_by_name($name)->{returns};
 717         $outsub->($res, $result_schema);
 718     }
 719 };
 720
 721 sub run_cli_handler {
 722     my ($class, %params) = @_;
 723
 724     $cli_handler_class = $class;
 725
 726     $ENV{'PATH'} = '/sbin:/bin:/usr/sbin:/usr/bin';
 727
 728     foreach my $key (keys %params) {
 729         next if $key eq 'prepare';
 730         next if $key eq 'no_init'; # not used anymore
 731         next if $key eq 'no_rpcenv'; # not used anymore
 732         die "unknown parameter '$key'";
 733     }
 734
 735     my $preparefunc = $params{prepare};
 736
 737     my $read_password_func = $class->can('read_password');
 738     my $param_mapping_func = $cli_handler_class->can('param_mapping') ||
 739         $class->can('string_param_file_mapping');
 740
 741     $exename = &$get_exe_name($class);
 742
 743     initlog($exename);
 744
 745     no strict 'refs';
 746     $cmddef = ${"${class}::cmddef"};
 747
 748     if (ref($cmddef) eq 'ARRAY') {
 749         &$handle_simple_cmd(\@ARGV, $read_password_func, $preparefunc, $param_mapping_func);
 750     } else {
 751         &$handle_cmd(\@ARGV, $read_password_func, $preparefunc, $param_mapping_func);
 752     }
 753
 754     exit 0;
 755 }
 756
 757 1;