INotify: map address/netmask to cidr while parsing interfaces
[pve-common.git] / src / PVE / INotify.pm
1 package PVE::INotify;
2
3 # todo: maybe we do not need update_file() ?
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::File;
10 use IO::Dir;
11 use File::stat;
12 use File::Basename;
13 use Fcntl qw(:DEFAULT :flock);
14 use PVE::SafeSyslog;
15 use PVE::Exception qw(raise_param_exc);
16 use PVE::Network;
17 use PVE::Tools;
18 use PVE::ProcFSTools;
19 use PVE::JSONSchema;
20 use Clone qw(clone);
21 use Linux::Inotify2;
22 use base 'Exporter';
23 use JSON;
24 use Digest::SHA;
25 use Encode qw(encode decode);
26
27 our @EXPORT_OK = qw(read_file write_file register_file);
28
29 my $ccache;
30 my $ccachemap;
31 my $ccacheregex;
32 my $inotify;
33 my $inotify_pid = 0;
34 my $versions;
35 my $shadowfiles = {
36     '/etc/network/interfaces' => '/etc/network/interfaces.new',
37 };
38
39 # to enable cached operation, you need to call 'inotify_init'
40 # inotify handles are a limited resource, so use with care (only
41 # enable the cache if you really need it)
42
43 # Note: please close the inotify handle after you fork
44
45 sub ccache_default_writer {
46     my ($filename, $data) = @_;
47
48     die "undefined config writer for '$filename' :ERROR";
49 }
50
51 sub ccache_default_parser {
52     my ($filename, $srcfd) = @_;
53
54     die "undefined config reader for '$filename' :ERROR";
55 }
56
57 sub ccache_compute_diff {
58     my ($filename, $shadow) = @_;
59
60     my $diff = '';
61
62     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
63     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
64         my ($line) = @_;
65         $diff .= decode('UTF-8', $line) . "\n";
66     });
67
68     $diff = undef if !$diff;
69
70     return $diff;
71 }
72
73 sub ccache_info {
74     my ($filename) = @_;
75
76     foreach my $uid (keys %$ccacheregex) {
77         my $ccinfo = $ccacheregex->{$uid};
78         my $dir = $ccinfo->{dir};
79         my $regex = $ccinfo->{regex};
80         if ($filename =~ m|^$dir/+$regex$|) {
81             if (!$ccache->{$filename}) {
82                 my $cp = {};
83                 while (my ($k, $v) = each %$ccinfo) {
84                     $cp->{$k} = $v;
85                 }
86                 $ccache->{$filename} = $cp;
87             } 
88             return ($ccache->{$filename}, $filename);
89         }
90     }
91  
92     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
93
94     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
95    
96     return ($ccache->{$filename}, $filename);
97 }
98
99 sub write_file {
100     my ($fileid, $data, $full) = @_;
101
102     my ($ccinfo, $filename) = ccache_info($fileid);
103
104     my $writer = $ccinfo->{writer};
105
106     my $realname = $filename;
107
108     my $shadow;
109     if ($shadow = $shadowfiles->{$filename}) {
110         $realname = $shadow;
111     }
112
113     my $perm = $ccinfo->{perm} || 0644;
114
115     my $tmpname = "$realname.tmp.$$";
116
117     my $res;
118     eval {
119         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
120         die "unable to open file '$tmpname' - $!\n" if !$fh;
121
122         $res = &$writer($filename, $fh, $data);
123
124         die "closing file '$tmpname' failed - $!\n" unless close $fh;
125     };
126     my $err = $@;
127
128     $ccinfo->{version} = undef;
129
130     if ($err) {
131         unlink $tmpname;
132         die $err;
133     }
134
135     if (!rename($tmpname, $realname)) {
136         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
137         unlink $tmpname;
138         die $msg;       
139     }
140
141     my $diff;
142     if ($shadow && $full) {
143         $diff = ccache_compute_diff ($filename, $shadow);
144     }
145
146     if ($full) {
147         return { data => $res, changes => $diff };
148     }
149
150     return $res;
151 }
152
153 sub update_file {
154     my ($fileid, $data, @args) = @_;
155
156     my ($ccinfo, $filename) = ccache_info($fileid);
157
158     my $update = $ccinfo->{update};
159
160     die "unable to update/merge data" if !$update;
161
162     my $lkfn = "$filename.lock";
163
164     my $timeout = 10;
165
166     my $fd;
167
168     my $code = sub {
169
170         $fd = IO::File->new ($filename, "r");
171         
172         my $new = &$update($filename, $fd, $data, @args);
173
174         if (defined($new)) {
175             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
176         } else {
177             unlink $filename;
178         }
179     };
180
181     PVE::Tools::lock_file($lkfn, $timeout, $code);
182     my $err = $@;
183
184     close($fd) if defined($fd);
185
186     die $err if $err;
187
188     return undef;
189 }
190
191 sub discard_changes {
192     my ($fileid, $full) = @_;
193
194     my ($ccinfo, $filename) = ccache_info($fileid);
195
196     if (my $copy = $shadowfiles->{$filename}) {
197         unlink $copy;
198     }
199
200     return read_file ($filename, $full);
201 }
202
203 sub poll_changes {
204     my ($filename) = @_;
205
206     poll() if $inotify; # read new inotify events
207
208     $versions->{$filename} = 0 if !defined ($versions->{$filename});
209
210     return $versions->{$filename};
211 }
212
213 sub read_file {
214     my ($fileid, $full) = @_;
215
216     my $parser;
217
218     my ($ccinfo, $filename) = ccache_info($fileid);
219      
220     $parser = $ccinfo->{parser};
221  
222     my $fd;
223     my $shadow;
224
225     my $cver = poll_changes($filename);
226
227     if (my $copy = $shadowfiles->{$filename}) {
228         if ($fd = IO::File->new ($copy, "r")) {
229             $shadow = $copy;
230         } else {
231             $fd = IO::File->new ($filename, "r");
232         }
233     } else {
234         $fd = IO::File->new ($filename, "r");
235     }
236
237     my $acp = $ccinfo->{always_call_parser};
238
239     if (!$fd) {
240         $ccinfo->{version} = undef;
241         $ccinfo->{data} = undef; 
242         $ccinfo->{diff} = undef;
243         return undef if !$acp;
244     }
245
246     my $noclone = $ccinfo->{noclone};
247
248     # file unchanged?
249     if (!$ccinfo->{nocache} &&
250         $inotify && $cver &&
251         defined ($ccinfo->{data}) &&
252         defined ($ccinfo->{version}) &&
253         ($ccinfo->{readonce} ||
254          ($ccinfo->{version} == $cver))) {
255
256         my $ret;
257         if (!$noclone && ref ($ccinfo->{data})) {
258             $ret->{data} = clone ($ccinfo->{data});
259         } else {
260             $ret->{data} = $ccinfo->{data};
261         }
262         $ret->{changes} = $ccinfo->{diff};
263         
264         return $full ? $ret : $ret->{data};
265     }
266
267     my $diff;
268
269     if ($shadow) {
270         $diff = ccache_compute_diff ($filename, $shadow);
271     }
272
273     my $res = &$parser($filename, $fd);
274
275     if (!$ccinfo->{nocache}) {
276         $ccinfo->{version} = $cver;
277     }
278
279     # we cache data with references, so we always need to
280     # clone this data. Else the original data may get
281     # modified.
282     $ccinfo->{data} = $res;
283
284     # also store diff
285     $ccinfo->{diff} = $diff;
286
287     my $ret;
288     if (!$noclone && ref ($ccinfo->{data})) {
289         $ret->{data} = clone ($ccinfo->{data});
290     } else {
291         $ret->{data} = $ccinfo->{data};
292     }
293     $ret->{changes} = $ccinfo->{diff};
294
295     return $full ? $ret : $ret->{data};
296 }    
297
298 sub parse_ccache_options {
299     my ($ccinfo, %options) = @_;
300
301     foreach my $opt (keys %options) {
302         my $v = $options{$opt};
303         if ($opt eq 'readonce') {
304             $ccinfo->{$opt} = $v;
305         } elsif ($opt eq 'nocache') {
306             $ccinfo->{$opt} = $v;
307         } elsif ($opt eq 'shadow') {
308             $ccinfo->{$opt} = $v;
309         } elsif ($opt eq 'perm') {
310             $ccinfo->{$opt} = $v;
311         } elsif ($opt eq 'noclone') {
312             # noclone flag for large read-only data chunks like aplinfo
313             $ccinfo->{$opt} = $v;
314         } elsif ($opt eq 'always_call_parser') {
315             # when set, we call parser even when the file does not exists.
316             # this allows the parser to return some default
317             $ccinfo->{$opt} = $v;
318         } else {
319             die "internal error - unsupported option '$opt'";
320         }
321     }
322 }
323
324 sub register_file {
325     my ($id, $filename, $parser, $writer, $update, %options) = @_;
326
327     die "can't register file '$filename' after inotify_init" if $inotify;
328
329     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
330     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
331
332     my $ccinfo = {};
333
334     $ccinfo->{id} = $id;
335     $ccinfo->{parser} = $parser || \&ccache_default_parser;
336     $ccinfo->{writer} = $writer || \&ccache_default_writer;
337     $ccinfo->{update} = $update;
338
339     parse_ccache_options($ccinfo, %options);
340     
341     if ($options{shadow}) {
342         $shadowfiles->{$filename} = $options{shadow};
343     }
344
345     $ccachemap->{$id} = $filename;
346     $ccache->{$filename} = $ccinfo;
347 }
348
349 sub register_regex {
350     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
351
352     die "can't register regex after inotify_init" if $inotify;
353
354     my $uid = "$dir/$regex";
355     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
356  
357     my $ccinfo = {};
358
359     $ccinfo->{dir} = $dir;
360     $ccinfo->{regex} = $regex;
361     $ccinfo->{parser} = $parser || \&ccache_default_parser;
362     $ccinfo->{writer} = $writer || \&ccache_default_writer;
363     $ccinfo->{update} = $update;
364
365     parse_ccache_options($ccinfo, %options);
366
367     $ccacheregex->{$uid} = $ccinfo;
368 }
369
370 sub poll {
371     return if !$inotify;
372
373     if ($inotify_pid != $$) {
374         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
375         $inotify = undef;
376     } else {
377         1 while $inotify && $inotify->poll;
378     }
379 }
380
381 sub flushcache {
382     foreach my $filename (keys %$ccache) {
383         $ccache->{$filename}->{version} = undef;
384         $ccache->{$filename}->{data} = undef;
385         $ccache->{$filename}->{diff} = undef;
386     }
387 }
388
389 sub inotify_close {
390     $inotify = undef;
391 }
392
393 sub inotify_init {
394
395     die "only one inotify instance allowed" if $inotify;
396
397     $inotify =  Linux::Inotify2->new()
398         || die "Unable to create new inotify object: $!";
399
400     $inotify->blocking (0);
401
402     $versions = {};
403
404     my $dirhash = {};
405     foreach my $fn (keys %$ccache) {
406         my $dir = dirname ($fn);
407         my $base = basename ($fn);
408
409         $dirhash->{$dir}->{$base} = $fn;
410
411         if (my $sf = $shadowfiles->{$fn}) {
412             $base = basename ($sf);
413             $dir = dirname ($sf);
414             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
415         }
416     }
417
418     foreach my $uid (keys %$ccacheregex) {
419         my $ccinfo = $ccacheregex->{$uid};
420         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;       
421     }
422
423     $inotify_pid = $$;
424
425     foreach my $dir (keys %$dirhash) {
426
427         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
428         $inotify->watch ($dir, $evlist, sub {
429             my $e = shift;
430             my $name = $e->name;
431
432             if ($inotify_pid != $$) {
433                 syslog ('err', "got inotify event in wrong process");
434             }
435
436             if ($e->IN_ISDIR || !$name) {
437                 return;
438             }
439
440             if ($e->IN_Q_OVERFLOW) {
441                 syslog ('info', "got inotify overflow - flushing cache");
442                 flushcache();
443                 return;
444             }
445
446             if ($e->IN_UNMOUNT) {
447                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
448                 $inotify = undef;
449             }
450             if ($e->IN_IGNORED) { 
451                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
452                 $inotify = undef;
453             }
454
455             if ($dirhash->{$dir}->{_regex}) {
456                 foreach my $uid (keys %$ccacheregex) {
457                     my $ccinfo = $ccacheregex->{$uid};
458                     next if $dir ne $ccinfo->{dir};
459                     my $regex = $ccinfo->{regex};
460                     if ($regex && ($name =~ m|^$regex$|)) {
461
462                         my $fn = "$dir/$name";
463                         $versions->{$fn}++;
464                         #print "VERSION:$fn:$versions->{$fn}\n";
465                     }
466                 }
467             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
468
469                 $versions->{$fn}++;
470                 #print "VERSION:$fn:$versions->{$fn}\n";
471             }
472         });
473     }
474
475     foreach my $dir (keys %$dirhash) {
476         foreach my $name (keys %{$dirhash->{$dir}}) {
477             if ($name eq '_regex') {
478                 foreach my $uid (keys %$ccacheregex) {
479                     my $ccinfo = $ccacheregex->{$uid};
480                     next if $dir ne $ccinfo->{dir};
481                     my $re = $ccinfo->{regex};
482                     if (my $fd = IO::Dir->new ($dir)) {
483                         while (defined(my $de = $fd->read)) { 
484                             if ($de =~ m/^$re$/) {
485                                 my $fn = "$dir/$de";
486                                 $versions->{$fn}++; # init with version
487                                 #print "init:$fn:$versions->{$fn}\n";
488                             }
489                         }
490                     }
491                 }
492             } else {
493                 my $fn = $dirhash->{$dir}->{$name};
494                 $versions->{$fn}++; # init with version
495                 #print "init:$fn:$versions->{$fn}\n";
496             }
497         }
498     }
499 }
500
501 my $cached_nodename;
502
503 sub nodename {
504
505     return $cached_nodename if $cached_nodename;
506
507     my ($sysname, $nodename) = POSIX::uname();
508
509     $nodename =~ s/\..*$//; # strip domain part, if any
510
511     die "unable to read node name\n" if !$nodename;
512
513     $cached_nodename = $nodename;
514
515     return $cached_nodename;
516 }
517
518 sub read_etc_hostname {
519     my ($filename, $fd) = @_;
520
521     my $hostname = <$fd>;
522
523     chomp $hostname;
524
525     $hostname =~ s/\..*$//; # strip domain part, if any
526
527     return $hostname;
528 }
529
530 sub write_etc_hostname {
531     my ($filename, $fh, $hostname) = @_;
532
533     die "write failed: $!" unless print $fh "$hostname\n";
534
535     return $hostname;
536 }
537
538 register_file('hostname', "/etc/hostname",  
539               \&read_etc_hostname, 
540               \&write_etc_hostname);
541
542 sub read_etc_hosts {
543     my ($filename, $fh) = @_;
544
545     my $raw = '';
546     my $data = '';
547
548     while (my $line = <$fh>) {
549         $raw .= $line;
550         if ($line =~ m/^\s*#/) {
551             $line = decode('UTF-8', $line);
552         }
553         $data .= $line;
554     }
555
556     return {
557         digest => Digest::SHA::sha1_hex($raw),
558         data => $data,
559     }
560 }
561
562 sub write_etc_hosts {
563     my ($filename, $fh, $hosts, @args) = @_;
564
565     # check validity of ips/names
566     for my $line (split("\n", $hosts)) {
567         next if $line =~ m/^\s*#/; # comments
568         next if $line =~ m/^\s*$/; # whitespace/empty lines
569
570         my ($ip, @names) = split(/\s+/, $line);
571
572         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
573             if $ip !~ m/^$PVE::Tools::IPRE$/;
574
575         for my $name (@names) {
576             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
577                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
578         }
579     }
580
581     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
582
583     return $hosts;
584 }
585
586 register_file('etchosts', "/etc/hosts",
587               \&read_etc_hosts,
588               \&write_etc_hosts);
589
590 sub read_etc_resolv_conf {
591     my ($filename, $fh) = @_;
592
593     my $res = {};
594
595     my $nscount = 0;
596     while (my $line = <$fh>) {
597         chomp $line;
598         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
599             $res->{search} = $2;
600         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
601             $nscount++;
602             if ($nscount <= 3) {
603                 $res->{"dns$nscount"} = $1;
604             }
605         }
606     }
607
608     return $res;
609 }
610
611 sub update_etc_resolv_conf {
612     my ($filename, $fh, $resolv, @args) = @_;
613
614     my $data = "";
615
616     $data = "search $resolv->{search}\n"
617         if $resolv->{search};
618
619     my $written = {};
620     foreach my $k ("dns1", "dns2", "dns3") {
621         my $ns = $resolv->{$k};
622         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
623             $written->{$ns} = 1;
624             $data .= "nameserver $ns\n";
625         }
626     }
627
628     while (my $line = <$fh>) {
629         next if $line =~ m/^(search|domain|nameserver)\s+/;
630         $data .= $line
631     }
632     
633     return $data;
634 }
635
636 register_file('resolvconf', "/etc/resolv.conf", 
637               \&read_etc_resolv_conf, undef, 
638               \&update_etc_resolv_conf);
639
640 sub read_etc_timezone {
641     my ($filename, $fd) = @_;
642
643     my $timezone = <$fd>;
644
645     chomp $timezone;
646
647     return $timezone;
648 }
649
650 sub write_etc_timezone {
651     my ($filename, $fh, $timezone) = @_;
652
653     my $tzinfo = "/usr/share/zoneinfo/$timezone";
654
655     raise_param_exc({ 'timezone' => "No such timezone" })
656         if (! -f $tzinfo);
657
658     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
659
660     print $fh "$timezone\n";
661
662     unlink ("/etc/localtime");
663     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
664
665 }
666
667 register_file('timezone', "/etc/timezone", 
668               \&read_etc_timezone, 
669               \&write_etc_timezone);
670
671 sub read_active_workers {
672     my ($filename, $fh) = @_;
673
674     return [] if !$fh;
675
676     my $res = []; 
677     while (defined (my $line = <$fh>)) {
678         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
679             my $upid = $1;
680             my $saved = $2;
681             my $endtime = $4;
682             my $status = $6;
683             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
684                 $task->{upid} = $upid;
685                 $task->{saved} = $saved;
686                 $task->{endtime} = hex($endtime) if $endtime;
687                 $task->{status} = $status if $status;
688                 push @$res, $task;
689             }
690         } else {
691             warn "unable to parse line: $line";
692         }
693     }
694
695     return $res;
696
697 }
698
699 sub write_active_workers {
700     my ($filename, $fh, $tasklist) = @_;
701
702     my $raw = '';
703     foreach my $task (@$tasklist) {
704         my $upid = $task->{upid};
705         my $saved = $task->{saved} ? 1 : 0;
706         if ($task->{endtime}) {
707             if ($task->{status}) {
708                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
709             } else {
710                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
711             }
712         } else {
713             $raw .= "$upid $saved\n";
714         }
715     }
716
717     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
718 }
719
720 register_file('active', "/var/log/pve/tasks/active", 
721               \&read_active_workers,
722               \&write_active_workers);
723
724
725 our $bond_modes = { 'balance-rr' => 0,
726                    'active-backup' => 1,
727                    'balance-xor' => 2,
728                    'broadcast' => 3,
729                    '802.3ad' => 4,
730                    'balance-tlb' => 5,
731                    'balance-alb' => 6,
732                };
733
734 my $ovs_bond_modes = {
735     'active-backup' => 1,
736     'balance-slb' => 1,
737     'lacp-balance-slb' => 1,
738     'lacp-balance-tcp' => 1, 
739 };
740
741 #sub get_bond_modes {
742 #    return $bond_modes;
743 #}
744
745 my $parse_ovs_option = sub {
746     my ($data) = @_;
747
748     my $opts = {};
749     foreach my $kv (split (/\s+/, $data || '')) {
750         my ($k, $v) = split('=', $kv, 2);
751         $opts->{$k} = $v if $k && $v;
752     }
753     return $opts;
754 };
755
756 my $set_ovs_option = sub {
757     my ($d, %params) = @_;
758
759     my $opts = &$parse_ovs_option($d->{ovs_options});
760
761     foreach my $k (keys %params) {
762         my $v = $params{$k};
763         if ($v) {
764             $opts->{$k} = $v;
765         } else {
766             delete $opts->{$k};
767         }
768     }
769
770     my $res = [];
771     foreach my $k (keys %$opts) {
772         push @$res, "$k=$opts->{$k}";
773     }
774
775     if (my $new = join(' ', @$res)) {
776         $d->{ovs_options} = $new;
777         return $d->{ovs_options};
778     } else {
779         delete $d->{ovs_options};
780         return undef;
781     }
782 };
783
784 my $extract_ovs_option = sub {
785     my ($d, $name) = @_;
786
787     my $opts = &$parse_ovs_option($d->{ovs_options});
788
789     my $v = delete $opts->{$name};
790
791     my $res = [];
792     foreach my $k (keys %$opts) {
793         push @$res, "$k=$opts->{$k}";
794     }
795
796     if (my $new = join(' ', @$res)) {
797         $d->{ovs_options} = $new;
798     } else {
799         delete $d->{ovs_options};
800     }
801
802     return $v;
803 };
804
805 my $check_mtu = sub {
806     my ($ifaces, $parent, $child) = @_;
807
808     die "check mtu - missing parent interface\n" if !$parent;
809     die "check mtu - missing child interface\n" if !$child;
810
811     my $cmtu = $ifaces->{$child}->{mtu};
812     return if !$cmtu;
813
814     my $parentdata = $ifaces->{$parent};
815     my $pmtu = $parentdata->{mtu};
816     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
817     $pmtu = 1500 if !$pmtu;
818
819     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
820         if $pmtu < $cmtu;
821 };
822
823 # config => {
824 #   ifaces => {
825 #     $ifname => {
826 #       <optional> exists => BOOL,
827 #       <optional> active => BOOL,
828 #       <optional> autostart => BOOL,
829 #       <auto> priority => INT,
830 #
831 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
832 #
833 #       families => ["inet", "inet6", ...],
834 #
835 #       method => "manual" | "static" | "dhcp" | ... ,
836 #       address => IP,
837 #       netmask => SUBNET,
838 #       broadcast => IP,
839 #       gateway => IP,
840 #       comments => [ "..." ],
841 #
842 #       method6 => "manual" | "static" | "dhcp" | ... ,
843 #       address6 => IP,
844 #       netmask6 => SUBNET,
845 #       gateway6 => IP,
846 #       comments6 => [ "..." ],
847 #
848 #       <known options>, # like bridge_ports, ovs_*
849 #
850 #       # extra/unknown options stored by-family:
851 #       options => { <inet options>... }
852 #       options6 => { <inet6 options>... }
853 #     }
854 #   },
855 #   options => [
856 #     # mappings end up here as well, as we don't need to understand them
857 #     [priority,line]
858 #   ]
859 # }
860 sub read_etc_network_interfaces {
861     my ($filename, $fh) = @_;
862     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
863     my $active = PVE::ProcFSTools::get_active_network_interfaces();
864     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
865 }
866
867 sub __read_etc_network_interfaces {
868     my ($fh, $proc_net_dev, $active_ifaces) = @_;
869
870     my $config = {};
871     my $ifaces = $config->{ifaces} = {};
872     my $options = $config->{options} = [];
873
874     my $options_alternatives = {
875         'bond-slaves' => 'slaves',
876         'bond_slaves' => 'slaves',
877         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
878         'bond-mode' => 'bond_mode',
879         'bond-miimon' =>'bond_miimon',
880         'bridge-vlan-aware' => 'bridge_vlan_aware',
881         'bridge-fd' => 'bridge_fd',
882         'bridge-stp' => 'bridge_stp',
883         'bridge-ports' => 'bridge_ports',
884         'bridge-vids' => 'bridge_vids'
885     };
886
887     my $line;
888
889     if ($proc_net_dev) {
890         while (defined ($line = <$proc_net_dev>)) {
891             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
892                 $ifaces->{$1}->{exists} = 1;
893             }
894         }
895         close($proc_net_dev);
896     }
897
898     # we try to keep order inside the file
899     my $priority = 2; # 1 is reserved for lo 
900
901     SECTION: while (defined ($line = <$fh>)) {
902         chomp ($line);
903         next if $line =~ m/^\s*#/;
904  
905         if ($line =~ m/^\s*auto\s+(.*)$/) {
906             my @aa = split (/\s+/, $1);
907
908             foreach my $a (@aa) {
909                 $ifaces->{$a}->{autostart} = 1;
910             }
911
912         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
913             my $i = $1;
914             my $family = $2;
915             my $f = { method => $3 }; # by family, merged to $d with a $suffix
916             (my $suffix = $family) =~ s/^inet//;
917
918             my $d = $ifaces->{$i} ||= {};
919             $d->{priority} = $priority++ if !$d->{priority};
920             push @{$d->{families}}, $family;
921
922             while (defined ($line = <$fh>)) {
923                 chomp $line;
924                 if ($line =~ m/^\s*#(.*?)\s*$/) {
925                     $f->{comments} = '' if !$f->{comments};
926                     my $comment = decode('UTF-8', $1);
927                     $f->{comments} .= "$comment\n";
928                 } elsif ($line =~ m/^\s*(?:iface\s
929                                           |mapping\s
930                                           |auto\s
931                                           |allow-
932                                           |source\s
933                                           |source-directory\s
934                                         )/x) {
935                     last;
936                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
937                     my $option = $1;
938                     my ($id, $value) = ($2, $3);
939
940                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
941
942                     my $simple_options = {
943                         'mtu' => 1,
944                         'ovs_type' => 1,
945                         'ovs_options' => 1,
946                         'ovs_bridge' => 1,
947                         'ovs_bonds' => 1,
948                         'ovs_ports' => 1,
949                         'bridge_fd' => 1,
950                         'bridge_vids' => 1,
951                         'bridge-access' => 1,
952                         'bridge-learning' => 1,
953                         'bridge-arp-nd-suppress' => 1,
954                         'bridge-unicast-flood' => 1,
955                         'bridge-multicast-flood' => 1,
956                         'bond_miimon' => 1,
957                         'bond_xmit_hash_policy' => 1,
958                         'vlan-protocol' => 1,
959                         'vxlan-id' => 1,
960                         'vxlan-svcnodeip' => 1,
961                         'vxlan-physdev' => 1,
962                         'vxlan-local-tunnelip' => 1 };
963
964                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
965                         $f->{$id} = $value;
966                     } elsif ($simple_options->{$id}) {
967                         $d->{$id} = $value;
968                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
969                         my $devs = {};
970                         foreach my $p (split (/\s+/, $value)) {
971                             next if $p eq 'none';
972                             $devs->{$p} = 1;
973                         }
974                         my $str = join (' ', sort keys %{$devs});
975                         if ($d->{$id}) {
976                             $d->{$id} .= ' ' . $str if $str;
977                         } else {
978                             $d->{$id} = $str || '';
979                         }
980                     } elsif ($id eq 'bridge_stp') {
981                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
982                             $d->{$id} = 'on';
983                         } else {
984                             $d->{$id} = 'off';
985                         }
986                     } elsif ($id eq 'bridge_vlan_aware') {
987                         $d->{$id} = 1;
988                     } elsif ($id eq 'bond_mode') {
989                         # always use names
990                         foreach my $bm (keys %$bond_modes) {
991                             my $id = $bond_modes->{$bm};
992                             if ($id eq $value) {
993                                 $value = $bm;
994                                 last;
995                             }
996                         }
997                         $d->{$id} = $value;
998                     } elsif ($id eq 'vxlan-remoteip') {
999                         push @{$d->{$id}}, $value;
1000                     } else {
1001                         push @{$f->{options}}, $option;
1002                     }
1003                 } else {
1004                     last;
1005                 }
1006             }
1007             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
1008             last SECTION if !defined($line);
1009             redo SECTION;
1010         } elsif ($line =~ /\w/) {
1011             push @$options, [$priority++, $line];
1012         }
1013     }
1014
1015     foreach my $ifname (@$active_ifaces) {
1016         if (my $iface = $ifaces->{$ifname}) {
1017             $iface->{active} = 1;
1018         }
1019     }
1020
1021     if (!$ifaces->{lo}) {
1022         $ifaces->{lo}->{priority} = 1;
1023         $ifaces->{lo}->{method} = 'loopback';
1024         $ifaces->{lo}->{type} = 'loopback';
1025         $ifaces->{lo}->{autostart} = 1;
1026     }
1027
1028     foreach my $iface (keys %$ifaces) {
1029         my $d = $ifaces->{$iface};
1030         if ($iface =~ m/^bond\d+$/) {
1031             if (!$d->{ovs_type}) {
1032                 $d->{type} = 'bond';
1033             } elsif ($d->{ovs_type} eq 'OVSBond') {
1034                 $d->{type} = $d->{ovs_type};
1035                 # translate: ovs_options => bond_mode
1036                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1037                 my $lacp = &$extract_ovs_option($d, 'lacp');
1038                 if ($lacp && $lacp eq 'active') {
1039                     if ($d->{'bond_mode'} eq 'balance-slb') {
1040                         $d->{'bond_mode'} = 'lacp-balance-slb';
1041                     }
1042                 }
1043                 # Note: balance-tcp needs lacp
1044                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1045                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1046                 }
1047                 my $tag = &$extract_ovs_option($d, 'tag');
1048                 $d->{ovs_tag} = $tag if defined($tag);
1049             } else {
1050                 $d->{type} = 'unknown';
1051             }
1052         } elsif ($iface =~ m/^vmbr\d+$/) {
1053             if (!$d->{ovs_type}) {
1054                 $d->{type} = 'bridge';
1055
1056                 if (!defined ($d->{bridge_fd})) {
1057                     $d->{bridge_fd} = 0;
1058                 }
1059                 if (!defined ($d->{bridge_stp})) {
1060                     $d->{bridge_stp} = 'off';
1061                 }
1062             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1063                 $d->{type} = $d->{ovs_type};
1064             } else {
1065                 $d->{type} = 'unknown';
1066             }
1067         } elsif ($iface =~ m/^(\S+):\d+$/) {
1068             $d->{type} = 'alias';
1069             if (defined ($ifaces->{$1})) {
1070                 $d->{exists} = $ifaces->{$1}->{exists};
1071             } else {
1072                 $ifaces->{$1}->{exists} = 0;
1073                 $d->{exists} = 0;
1074             }
1075         } elsif ($iface =~ m/^(\S+)\.\d+$/) {
1076             $d->{type} = 'vlan';
1077             if (defined ($ifaces->{$1})) {
1078                 $d->{exists} = $ifaces->{$1}->{exists};
1079             } else {
1080                 $ifaces->{$1}->{exists} = 0;
1081                 $d->{exists} = 0;
1082             }
1083         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1084             if (!$d->{ovs_type}) {
1085                 $d->{type} = 'eth';
1086             } elsif ($d->{ovs_type} eq 'OVSPort') {
1087                 $d->{type} = $d->{ovs_type};
1088                 my $tag = &$extract_ovs_option($d, 'tag');
1089                 $d->{ovs_tag} = $tag if defined($tag);
1090             } else {
1091                 $d->{type} = 'unknown';
1092             }
1093         } elsif ($iface =~ m/^lo$/) {
1094             $d->{type} = 'loopback';
1095         } else {
1096             if ($d->{'vxlan-id'}) {
1097                 $d->{type} = 'vxlan';
1098             } elsif (!$d->{ovs_type}) {
1099                 $d->{type} = 'unknown';
1100             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
1101                 $d->{type} = $d->{ovs_type};
1102                 my $tag = &$extract_ovs_option($d, 'tag');
1103                 $d->{ovs_tag} = $tag if defined($tag);
1104             }
1105         }
1106
1107         # map address and netmask to cidr
1108         if ($d->{address}) {
1109             if ($d->{netmask} =~ m/^\d+$/) { # e.g. netmask 20
1110                 $d->{cidr} = $d->{address} . "/" . $d->{netmask};
1111             } elsif ($d->{netmask} &&
1112                      (my $cidr = PVE::JSONSchema::get_netmask_bits($d->{netmask}))) { # e.g. netmask 255.255.255.0
1113                 $d->{cidr} = $d->{address} . "/" . $cidr;
1114             } elsif ($d->{address} =~ m!^(.*)/(\d+)$!) {
1115                 $d->{cidr} = $d->{address};
1116                 $d->{address} = $1;
1117                 $d->{netmask} = $2;
1118             } else {
1119                 $d->{cidr} = $d->{address};
1120             }
1121         }
1122
1123         # map address6 and netmask6 to cidr6
1124         if ($d->{address6}) {
1125             $d->{cidr6} = $d->{address6};
1126             if ($d->{netmask6}) {
1127                 $d->{cidr6} .= "/" . $d->{netmask6} if $d->{netmask6};
1128             } elsif ($d->{address6} =~ m!^(.*)/(\d+)$!) {
1129                 $d->{cidr6} = $d->{address6};
1130                 $d->{address6} = $1;
1131                 $d->{netmask6} = $2;
1132             }
1133         }
1134
1135         $d->{method} = 'manual' if !$d->{method};
1136         $d->{method6} = 'manual' if !$d->{method6};
1137
1138         $d->{families} ||= ['inet'];
1139     }
1140
1141     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1142     # from the {options} hash for them to be removed correctly.
1143     @$options = grep {defined($_)} map {
1144         my ($pri, $line) = @$_;
1145         if ($line =~ /^allow-(\S+)\s+(.*)$/) {
1146             my $bridge = $1;
1147             my @ports = split(/\s+/, $2);
1148             if (defined(my $br = $ifaces->{$bridge})) {
1149                 # if this port is part of a bridge, remove it
1150                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1151                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1152             }
1153             # create the allow line for the remaining ports, or delete if empty
1154             if (@ports) {
1155                 [$pri, "allow-$bridge " . join(' ', @ports)];
1156             } else {
1157                 undef;
1158             }
1159         } else {
1160             # don't modify other lines
1161             $_;
1162         }
1163     } @$options;
1164
1165     return $config;
1166 }
1167
1168 sub __interface_to_string {
1169     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1170
1171     (my $suffix = $family) =~ s/^inet//;
1172
1173     return '' if !($d && $d->{"method$suffix"});
1174
1175     my $raw = '';
1176
1177     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1178     $raw .= "\taddress  " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1179     $raw .= "\tnetmask  " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1180     $raw .= "\tgateway  " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1181     $raw .= "\tbroadcast  " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1182
1183     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1184                  comments => 1, autostart => 1, options => 1,
1185                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1186                  method6 => 1, families => 1, options6 => 1,
1187                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1 };
1188
1189     if (!$first_block) {
1190         # not printing out options
1191     } elsif ($d->{type} eq 'bridge') {
1192
1193         $d->{bridge_ports} =~ s/[;,\s]+/ /g;
1194         my $ports = $d->{bridge_ports} || 'none';
1195         $raw .= "\tbridge-ports $ports\n";
1196         $done->{bridge_ports} = 1;
1197
1198         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1199         $raw .= "\tbridge-stp $v\n";
1200         $done->{bridge_stp} = 1;
1201
1202         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1203         $raw .= "\tbridge-fd $v\n";
1204         $done->{bridge_fd} = 1;
1205
1206         if( defined($d->{bridge_vlan_aware})) {
1207             $raw .= "\tbridge-vlan-aware yes\n";
1208             $v = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1209             $raw .= "\tbridge-vids $v\n";
1210         }
1211         $done->{bridge_vlan_aware} = 1;
1212         $done->{bridge_vids} = 1;
1213     
1214     } elsif ($d->{type} eq 'bond') {
1215
1216         $d->{slaves} =~ s/[;,\s]+/ /g;
1217         my $slaves = $d->{slaves} || 'none';
1218         $raw .= "\tbond-slaves $slaves\n";
1219         $done->{slaves} = 1;
1220
1221         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1222         $raw .= "\tbond-miimon $v\n";
1223         $done->{'bond_miimon'} = 1;
1224
1225         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1226         $raw .= "\tbond-mode $v\n";
1227         $done->{'bond_mode'} = 1;
1228
1229         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1230             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1231             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1232         }
1233         $done->{'bond_xmit_hash_policy'} = 1;
1234     } elsif ($d->{type} eq 'vlan') {
1235         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n" 
1236             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1237         
1238     } elsif ($d->{type} eq 'vxlan') {
1239
1240         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1241             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1242             $done->{$k} = 1;
1243         }
1244
1245         if ($d->{'vxlan-remoteip'}) {
1246             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1247                 $raw .= "\tvxlan-remoteip $remoteip\n";
1248             }
1249             $done->{'vxlan-remoteip'} = 1;
1250         }
1251     } elsif ($d->{type} eq 'OVSBridge') {
1252
1253         $raw .= "\tovs_type $d->{type}\n";
1254         $done->{ovs_type} = 1;
1255
1256         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1257         $done->{ovs_ports} = 1;
1258     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1259              $d->{type} eq 'OVSBond') {
1260
1261         $d->{autostart} = 0; # started by the bridge
1262
1263         if (defined($d->{ovs_tag})) {
1264             &$set_ovs_option($d, tag => $d->{ovs_tag});
1265         }
1266         $done->{ovs_tag} = 1;
1267
1268         if ($d->{type} eq 'OVSBond') {
1269
1270             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1271
1272             $ovs_bond_modes->{$d->{bond_mode}} ||
1273                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1274
1275             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1276                 &$set_ovs_option($d, lacp => 'active');
1277                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1278             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1279                 &$set_ovs_option($d, lacp => 'active');
1280                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1281             } else {
1282                 &$set_ovs_option($d, lacp => undef);
1283                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1284             }
1285             $done->{bond_mode} = 1;
1286
1287             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1288             $done->{ovs_bonds} = 1;
1289         }
1290
1291         $raw .= "\tovs_type $d->{type}\n";
1292         $done->{ovs_type} = 1;
1293
1294         if ($d->{ovs_bridge}) {
1295
1296             if ($ifupdown2) {
1297                 $raw = "auto $iface\n$raw";
1298             } else {
1299                 $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1300             }
1301
1302             $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1303             $done->{ovs_bridge} = 1;
1304         }
1305     }
1306
1307     if ($first_block) {
1308         # print other settings
1309         foreach my $k (sort keys %$d) {
1310            next if $done->{$k};
1311            next if !$d->{$k};
1312            $raw .= "\t$k $d->{$k}\n";
1313         }
1314     }
1315
1316     foreach my $option (@{$d->{"options$suffix"}}) {
1317         $raw .= "\t$option\n";
1318     }
1319
1320     # add comments
1321     my $comments = $d->{"comments$suffix"} || '';
1322     foreach my $cl (split(/\n/, $comments)) {
1323         $raw .= "#$cl\n";
1324     }
1325
1326     $raw .= "\n";
1327
1328     return $raw;
1329 }
1330
1331
1332 sub write_etc_network_interfaces {
1333     my ($filename, $fh, $config) = @_;
1334     my $ifupdown2 = -e '/usr/share/ifupdown2';
1335     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1336     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1337 }
1338 sub __write_etc_network_interfaces {
1339     my ($config, $ifupdown2) = @_;
1340
1341     my $ifaces = $config->{ifaces};
1342     my @options = @{$config->{options}};
1343
1344     my $used_ports = {};
1345
1346     foreach my $iface (keys %$ifaces) {
1347         my $d = $ifaces->{$iface};
1348
1349         delete $d->{cidr};
1350         delete $d->{cidr6};
1351
1352         my $ports = '';
1353         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1354             $ports .= " $d->{$k}" if $d->{$k};
1355         }
1356
1357         foreach my $p (PVE::Tools::split_list($ports)) {
1358             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1359                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1360             $used_ports->{$p} = $iface;
1361         }
1362     }
1363
1364     # delete unused OVS ports
1365     foreach my $iface (keys %$ifaces) {
1366         my $d = $ifaces->{$iface};
1367         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1368             $d->{type} eq 'OVSBond') {
1369             my $brname = $used_ports->{$iface};
1370             if (!$brname || !$ifaces->{$brname}) {
1371                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1372                     $ifaces->{$iface} = { type => 'eth',
1373                                           exists => 1,
1374                                           method => 'manual',
1375                                           families => ['inet'] };
1376                 } else {
1377                     delete $ifaces->{$iface};
1378                 }
1379                 next;
1380             }
1381             my $bd = $ifaces->{$brname};
1382             if ($bd->{type} ne 'OVSBridge') {
1383                 delete $ifaces->{$iface};
1384                 next;
1385             }
1386         }
1387     }
1388
1389     # create OVS bridge ports
1390     foreach my $iface (keys %$ifaces) {
1391         my $d = $ifaces->{$iface};
1392         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1393             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1394                 my $n = $ifaces->{$p};
1395                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1396                     if !$n;
1397                 $n->{autostart} = 0;
1398                 if ($n->{type} eq 'eth') {
1399                     $n->{type} = 'OVSPort';
1400                     $n->{ovs_bridge} = $iface;
1401                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1402                     $n->{type} eq 'OVSIntPort') {
1403                     $n->{ovs_bridge} = $iface;
1404                 } else {
1405                     die "interface '$p' is not defined as OVS port/bond\n";
1406                 }
1407
1408                 &$check_mtu($ifaces, $iface, $p);
1409             }
1410         }
1411     }
1412
1413     # check OVS bond ports
1414     foreach my $iface (keys %$ifaces) {
1415         my $d = $ifaces->{$iface};
1416         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1417             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1418                 my $n = $ifaces->{$p};
1419                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1420                     if !$n;
1421                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1422                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1423                 &$check_mtu($ifaces, $iface, $p);
1424             }
1425         }
1426     }
1427
1428     # check bond
1429     foreach my $iface (keys %$ifaces) {
1430         my $d = $ifaces->{$iface};
1431         if ($d->{type} eq 'bond' && $d->{slaves}) {
1432             foreach my $p (split (/\s+/, $d->{slaves})) {
1433                 my $n = $ifaces->{$p};
1434
1435                 die "bond '$iface' - unable to find slave '$p'\n"
1436                     if !$n;
1437                 die "bond '$iface' - wrong interface type on slave '$p' " .
1438                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1439                 &$check_mtu($ifaces, $iface, $p);
1440             }
1441         }
1442     }
1443
1444     # check vxlan
1445     my $vxlans = {};
1446     foreach my $iface (keys %$ifaces) {
1447         my $d = $ifaces->{$iface};
1448
1449         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1450             my $vxlanid = $d->{'vxlan-id'};
1451             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1452             $vxlans->{$vxlanid} = $iface;
1453         }
1454
1455         my $ips = 0;
1456         ++$ips if defined $d->{'vxlan-svcnodeip'};
1457         ++$ips if defined $d->{'vxlan-remoteip'};
1458         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1459         if ($ips > 1) {
1460             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1461         }
1462
1463         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1464             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1465         }
1466         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1467     }
1468
1469     # check vlan
1470     foreach my $iface (keys %$ifaces) {
1471         my $d = $ifaces->{$iface};
1472         if ($d->{type} eq 'vlan' && $iface =~ m/^(\S+)\.\d+$/) {
1473             my $p = $1;
1474             my $n = $ifaces->{$p};
1475
1476             die "vlan '$iface' - unable to find parent '$p'\n"
1477                 if !$n;
1478
1479             if ($n->{type} eq 'bridge' && !$n->{bridge_vlan_aware}) {
1480                 die "vlan '$iface' - bridge vlan aware is not enabled on parent '$p'\n";
1481             } elsif ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1482                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1483                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1484             }
1485
1486             &$check_mtu($ifaces, $p, $iface);
1487
1488         }
1489     }
1490
1491     # check bridgeport option
1492     my $bridgeports = {};
1493     my $bridges = {};
1494     foreach my $iface (keys %$ifaces) {
1495         my $d = $ifaces->{$iface};
1496         if ($d->{type} eq 'bridge') {
1497             foreach my $p (split (/\s+/, $d->{bridge_ports})) {
1498                 $p =~ s/\.\d+$//;
1499                 my $n = $ifaces->{$p};
1500                 die "bridge '$iface' - unable to find bridge port '$p'\n"
1501                     if !$n;
1502                 &$check_mtu($ifaces, $iface, $p);
1503                 $bridgeports->{$p} = $iface;
1504             }
1505             $bridges->{$iface} = $d;
1506         }
1507     }
1508
1509     foreach my $iface (keys %$ifaces) {
1510         my $d = $ifaces->{$iface};
1511
1512         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1513             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1514                 if $d->{$k} && !$bridgeports->{$iface};
1515         }
1516
1517         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1518             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1519         }
1520     }
1521
1522     my $raw = <<'NETWORKDOC';
1523 # network interface settings; autogenerated
1524 # Please do NOT modify this file directly, unless you know what
1525 # you're doing.
1526 #
1527 # If you want to manage parts of the network configuration manually,
1528 # please utilize the 'source' or 'source-directory' directives to do
1529 # so.
1530 # PVE will preserve these directives, but will NOT read its network
1531 # configuration from sourced files, so do not attempt to move any of
1532 # the PVE managed interfaces into external files!
1533
1534 NETWORKDOC
1535
1536     my $printed = {};
1537
1538     my $if_type_hash = {
1539         loopback => 100000,
1540         eth => 200000,
1541         OVSPort => 200000,
1542         OVSIntPort => 200000,
1543         bond => 300000,
1544         bridge => 400000,
1545         OVSBridge => 400000,
1546         vxlan => 500000,
1547    };
1548
1549     my $lookup_type_prio = sub {
1550         my ($iface, $ifaces) = @_;
1551
1552         my ($rootiface, @rest) = split(/[.:]/, $iface);
1553         my $childlevel = scalar(@rest);
1554         my $n = $ifaces->{$rootiface};
1555
1556         my $pri = $if_type_hash->{$n->{type}} + $childlevel
1557             if $n->{type} && $n->{type} ne 'unknown';
1558
1559         return $pri;
1560     };
1561
1562     foreach my $iface (sort {
1563         my $ref1 = $ifaces->{$a};
1564         my $ref2 = $ifaces->{$b};
1565         my $tp1 = &$lookup_type_prio($a, $ifaces);
1566         my $tp2 = &$lookup_type_prio($b, $ifaces);
1567
1568         # Only recognized types are in relation to each other. If one type
1569         # is unknown then only consider the interfaces' priority attributes.
1570         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1571
1572         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1573         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1574
1575         return $p1 <=> $p2 if $p1 != $p2;
1576
1577         return $a cmp $b;
1578     } keys %$ifaces) {
1579         next if $printed->{$iface};
1580
1581         my $d = $ifaces->{$iface};
1582         my $pri = $d->{priority} // 0;
1583         if (@options && $options[0]->[0] < $pri) {
1584             do {
1585                 $raw .= (shift @options)->[1] . "\n";
1586             } while (@options && $options[0]->[0] < $pri);
1587             $raw .= "\n";
1588         }
1589
1590         $printed->{$iface} = 1;
1591         $raw .= "auto $iface\n" if $d->{autostart};
1592         my $i = 0; # some options should be printed only once
1593         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1594     }
1595
1596     $raw .= $_->[1] . "\n" foreach @options;
1597     return $raw;
1598 }
1599
1600 register_file('interfaces', "/etc/network/interfaces",
1601               \&read_etc_network_interfaces,
1602               \&write_etc_network_interfaces);
1603
1604
1605 sub read_iscsi_initiatorname {
1606     my ($filename, $fd) = @_;
1607
1608     while (defined(my $line = <$fd>)) {
1609         if ($line =~ m/^InitiatorName=(\S+)$/) {
1610             return $1;
1611         }
1612     }
1613
1614     return 'undefined';
1615 }
1616
1617 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",  
1618               \&read_iscsi_initiatorname);
1619
1620 sub read_apt_auth {
1621     my ($filename, $fd) = @_;
1622
1623     local $/;
1624
1625     my $raw = defined($fd) ? <$fd> : '';
1626
1627     $raw =~ s/^\s+//;
1628
1629  
1630     my @tokens = split(/\s+/, $raw);
1631
1632     my $data = {};
1633
1634     my $machine;
1635     while (defined(my $tok = shift @tokens)) {
1636
1637         $machine = shift @tokens if $tok eq 'machine';
1638         next if !$machine;
1639         $data->{$machine} = {} if !$data->{$machine};
1640
1641         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1642         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1643     };
1644
1645     return $data;
1646 }
1647
1648 my $format_apt_auth_data = sub {
1649     my $data = shift;
1650
1651     my $raw = '';
1652
1653     foreach my $machine (sort keys %$data) {
1654         my $d = $data->{$machine};
1655         $raw .= "machine $machine\n";
1656         $raw .= " login $d->{login}\n" if $d->{login};
1657         $raw .= " password $d->{password}\n" if $d->{password};
1658         $raw .= "\n";
1659     }
1660
1661     return $raw;
1662 };
1663
1664 sub write_apt_auth {
1665     my ($filename, $fh, $data) = @_;
1666
1667     my $raw = &$format_apt_auth_data($data);
1668
1669     die "write failed: $!" unless print $fh "$raw\n";
1670    
1671     return $data;
1672 }
1673
1674 sub update_apt_auth {
1675     my ($filename, $fh, $data) = @_;
1676
1677     my $orig = read_apt_auth($filename, $fh);
1678
1679     foreach my $machine (keys %$data) {
1680         $orig->{$machine} = $data->{$machine};
1681     }
1682
1683     return &$format_apt_auth_data($orig);
1684 }
1685
1686 register_file('apt-auth', "/etc/apt/auth.conf",  
1687               \&read_apt_auth, \&write_apt_auth,
1688               \&update_apt_auth, perm => 0640);
1689
1690 1;