createSchema: include type property
[pve-common.git] / src / PVE / INotify.pm
1 package PVE::INotify;
2
3 # todo: maybe we do not need update_file() ?
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::File;
10 use IO::Dir;
11 use File::stat;
12 use File::Basename;
13 use Fcntl qw(:DEFAULT :flock);
14 use PVE::SafeSyslog;
15 use PVE::Exception qw(raise_param_exc);
16 use PVE::Tools;
17 use Storable qw(dclone);
18 use Linux::Inotify2;
19 use base 'Exporter';
20 use JSON;
21
22 our @EXPORT_OK = qw(read_file write_file register_file);
23
24 my $ccache;
25 my $ccachemap;
26 my $ccacheregex;
27 my $inotify;
28 my $inotify_pid = 0;
29 my $versions;
30 my $shadowfiles = {
31 '/etc/network/interfaces' => '/etc/network/interfaces.new',
32 };
33
34 # to enable cached operation, you need to call 'inotify_init'
35 # inotify handles are a limited resource, so use with care (only
36 # enable the cache if you really need it)
37
38 # Note: please close the inotify handle after you fork
39
40 sub ccache_default_writer {
41 my ($filename, $data) = @_;
42
43 die "undefined config writer for '$filename' :ERROR";
44 }
45
46 sub ccache_default_parser {
47 my ($filename, $srcfd) = @_;
48
49 die "undefined config reader for '$filename' :ERROR";
50 }
51
52 sub ccache_compute_diff {
53 my ($filename, $shadow) = @_;
54
55 my $diff = '';
56
57 open (TMP, "diff -b -N -u '$filename' '$shadow'|");
58
59 while (my $line = <TMP>) {
60 $diff .= $line;
61 }
62
63 close (TMP);
64
65 $diff = undef if !$diff;
66
67 return $diff;
68 }
69
70 sub ccache_info {
71 my ($filename) = @_;
72
73 foreach my $uid (keys %$ccacheregex) {
74 my $ccinfo = $ccacheregex->{$uid};
75 my $dir = $ccinfo->{dir};
76 my $regex = $ccinfo->{regex};
77 if ($filename =~ m|^$dir/+$regex$|) {
78 if (!$ccache->{$filename}) {
79 my $cp = {};
80 while (my ($k, $v) = each %$ccinfo) {
81 $cp->{$k} = $v;
82 }
83 $ccache->{$filename} = $cp;
84 }
85 return ($ccache->{$filename}, $filename);
86 }
87 }
88
89 $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
90
91 die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
92
93 return ($ccache->{$filename}, $filename);
94 }
95
96 sub write_file {
97 my ($fileid, $data, $full) = @_;
98
99 my ($ccinfo, $filename) = ccache_info($fileid);
100
101 my $writer = $ccinfo->{writer};
102
103 my $realname = $filename;
104
105 my $shadow;
106 if ($shadow = $shadowfiles->{$filename}) {
107 $realname = $shadow;
108 }
109
110 my $perm = $ccinfo->{perm} || 0644;
111
112 my $tmpname = "$realname.tmp.$$";
113
114 my $res;
115 eval {
116 my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
117 die "unable to open file '$tmpname' - $!\n" if !$fh;
118
119 $res = &$writer($filename, $fh, $data);
120
121 die "closing file '$tmpname' failed - $!\n" unless close $fh;
122 };
123 my $err = $@;
124
125 $ccinfo->{version} = undef;
126
127 if ($err) {
128 unlink $tmpname;
129 die $err;
130 }
131
132 if (!rename($tmpname, $realname)) {
133 my $msg = "close (rename) atomic file '$filename' failed: $!\n";
134 unlink $tmpname;
135 die $msg;
136 }
137
138 my $diff;
139 if ($shadow && $full) {
140 $diff = ccache_compute_diff ($filename, $shadow);
141 }
142
143 if ($full) {
144 return { data => $res, changes => $diff };
145 }
146
147 return $res;
148 }
149
150 sub update_file {
151 my ($fileid, $data, @args) = @_;
152
153 my ($ccinfo, $filename) = ccache_info($fileid);
154
155 my $update = $ccinfo->{update};
156
157 die "unable to update/merge data" if !$update;
158
159 my $lkfn = "$filename.lock";
160
161 my $timeout = 10;
162
163 my $fd;
164
165 my $code = sub {
166
167 $fd = IO::File->new ($filename, "r");
168
169 my $new = &$update($filename, $fd, $data, @args);
170
171 if (defined($new)) {
172 PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
173 } else {
174 unlink $filename;
175 }
176 };
177
178 PVE::Tools::lock_file($lkfn, $timeout, $code);
179 my $err = $@;
180
181 close($fd) if defined($fd);
182
183 die $err if $err;
184
185 return undef;
186 }
187
188 sub discard_changes {
189 my ($fileid, $full) = @_;
190
191 my ($ccinfo, $filename) = ccache_info($fileid);
192
193 if (my $copy = $shadowfiles->{$filename}) {
194 unlink $copy;
195 }
196
197 return read_file ($filename, $full);
198 }
199
200 sub read_file {
201 my ($fileid, $full) = @_;
202
203 my $parser;
204
205 my ($ccinfo, $filename) = ccache_info($fileid);
206
207 $parser = $ccinfo->{parser};
208
209 my $fd;
210 my $shadow;
211
212 poll() if $inotify; # read new inotify events
213
214 $versions->{$filename} = 0 if !defined ($versions->{$filename});
215
216 my $cver = $versions->{$filename};
217
218 if (my $copy = $shadowfiles->{$filename}) {
219 if ($fd = IO::File->new ($copy, "r")) {
220 $shadow = $copy;
221 } else {
222 $fd = IO::File->new ($filename, "r");
223 }
224 } else {
225 $fd = IO::File->new ($filename, "r");
226 }
227
228 my $acp = $ccinfo->{always_call_parser};
229
230 if (!$fd) {
231 $ccinfo->{version} = undef;
232 $ccinfo->{data} = undef;
233 $ccinfo->{diff} = undef;
234 return undef if !$acp;
235 }
236
237 my $noclone = $ccinfo->{noclone};
238
239 # file unchanged?
240 if (!$ccinfo->{nocache} &&
241 $inotify && $versions->{$filename} &&
242 defined ($ccinfo->{data}) &&
243 defined ($ccinfo->{version}) &&
244 ($ccinfo->{readonce} ||
245 ($ccinfo->{version} == $versions->{$filename}))) {
246
247 my $ret;
248 if (!$noclone && ref ($ccinfo->{data})) {
249 $ret->{data} = dclone ($ccinfo->{data});
250 } else {
251 $ret->{data} = $ccinfo->{data};
252 }
253 $ret->{changes} = $ccinfo->{diff};
254
255 return $full ? $ret : $ret->{data};
256 }
257
258 my $diff;
259
260 if ($shadow) {
261 $diff = ccache_compute_diff ($filename, $shadow);
262 }
263
264 my $res = &$parser($filename, $fd);
265
266 if (!$ccinfo->{nocache}) {
267 $ccinfo->{version} = $cver;
268 }
269
270 # we cache data with references, so we always need to
271 # dclone this data. Else the original data may get
272 # modified.
273 $ccinfo->{data} = $res;
274
275 # also store diff
276 $ccinfo->{diff} = $diff;
277
278 my $ret;
279 if (!$noclone && ref ($ccinfo->{data})) {
280 $ret->{data} = dclone ($ccinfo->{data});
281 } else {
282 $ret->{data} = $ccinfo->{data};
283 }
284 $ret->{changes} = $ccinfo->{diff};
285
286 return $full ? $ret : $ret->{data};
287 }
288
289 sub parse_ccache_options {
290 my ($ccinfo, %options) = @_;
291
292 foreach my $opt (keys %options) {
293 my $v = $options{$opt};
294 if ($opt eq 'readonce') {
295 $ccinfo->{$opt} = $v;
296 } elsif ($opt eq 'nocache') {
297 $ccinfo->{$opt} = $v;
298 } elsif ($opt eq 'shadow') {
299 $ccinfo->{$opt} = $v;
300 } elsif ($opt eq 'perm') {
301 $ccinfo->{$opt} = $v;
302 } elsif ($opt eq 'noclone') {
303 # noclone flag for large read-only data chunks like aplinfo
304 $ccinfo->{$opt} = $v;
305 } elsif ($opt eq 'always_call_parser') {
306 # when set, we call parser even when the file does not exists.
307 # this allows the parser to return some default
308 $ccinfo->{$opt} = $v;
309 } else {
310 die "internal error - unsupported option '$opt'";
311 }
312 }
313 }
314
315 sub register_file {
316 my ($id, $filename, $parser, $writer, $update, %options) = @_;
317
318 die "can't register file '$filename' after inotify_init" if $inotify;
319
320 die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
321 die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
322
323 my $ccinfo = {};
324
325 $ccinfo->{id} = $id;
326 $ccinfo->{parser} = $parser || \&ccache_default_parser;
327 $ccinfo->{writer} = $writer || \&ccache_default_writer;
328 $ccinfo->{update} = $update;
329
330 parse_ccache_options($ccinfo, %options);
331
332 if ($options{shadow}) {
333 $shadowfiles->{$filename} = $options{shadow};
334 }
335
336 $ccachemap->{$id} = $filename;
337 $ccache->{$filename} = $ccinfo;
338 }
339
340 sub register_regex {
341 my ($dir, $regex, $parser, $writer, $update, %options) = @_;
342
343 die "can't register regex after initify_init" if $inotify;
344
345 my $uid = "$dir/$regex";
346 die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
347
348 my $ccinfo = {};
349
350 $ccinfo->{dir} = $dir;
351 $ccinfo->{regex} = $regex;
352 $ccinfo->{parser} = $parser || \&ccache_default_parser;
353 $ccinfo->{writer} = $writer || \&ccache_default_writer;
354 $ccinfo->{update} = $update;
355
356 parse_ccache_options($ccinfo, %options);
357
358 $ccacheregex->{$uid} = $ccinfo;
359 }
360
361 sub poll {
362 return if !$inotify;
363
364 if ($inotify_pid != $$) {
365 syslog ('err', "got inotify poll request in wrong process - disabling inotify");
366 $inotify = undef;
367 } else {
368 1 while $inotify && $inotify->poll;
369 }
370 }
371
372 sub flushcache {
373 foreach my $filename (keys %$ccache) {
374 $ccache->{$filename}->{version} = undef;
375 $ccache->{$filename}->{data} = undef;
376 $ccache->{$filename}->{diff} = undef;
377 }
378 }
379
380 sub inotify_close {
381 $inotify = undef;
382 }
383
384 sub inotify_init {
385
386 die "only one inotify instance allowed" if $inotify;
387
388 $inotify = Linux::Inotify2->new()
389 || die "Unable to create new inotify object: $!";
390
391 $inotify->blocking (0);
392
393 $versions = {};
394
395 my $dirhash = {};
396 foreach my $fn (keys %$ccache) {
397 my $dir = dirname ($fn);
398 my $base = basename ($fn);
399
400 $dirhash->{$dir}->{$base} = $fn;
401
402 if (my $sf = $shadowfiles->{$fn}) {
403 $base = basename ($sf);
404 $dir = dirname ($sf);
405 $dirhash->{$dir}->{$base} = $fn; # change version of original file!
406 }
407 }
408
409 foreach my $uid (keys %$ccacheregex) {
410 my $ccinfo = $ccacheregex->{$uid};
411 $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
412 }
413
414 $inotify_pid = $$;
415
416 foreach my $dir (keys %$dirhash) {
417
418 my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
419 $inotify->watch ($dir, $evlist, sub {
420 my $e = shift;
421 my $name = $e->name;
422
423 if ($inotify_pid != $$) {
424 syslog ('err', "got inotify event in wrong process");
425 }
426
427 if ($e->IN_ISDIR || !$name) {
428 return;
429 }
430
431 if ($e->IN_Q_OVERFLOW) {
432 syslog ('info', "got inotify overflow - flushing cache");
433 flushcache();
434 return;
435 }
436
437 if ($e->IN_UNMOUNT) {
438 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
439 $inotify = undef;
440 }
441 if ($e->IN_IGNORED) {
442 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
443 $inotify = undef;
444 }
445
446 if ($dirhash->{$dir}->{_regex}) {
447 foreach my $uid (keys %$ccacheregex) {
448 my $ccinfo = $ccacheregex->{$uid};
449 next if $dir ne $ccinfo->{dir};
450 my $regex = $ccinfo->{regex};
451 if ($regex && ($name =~ m|^$regex$|)) {
452
453 my $fn = "$dir/$name";
454 $versions->{$fn}++;
455 #print "VERSION:$fn:$versions->{$fn}\n";
456 }
457 }
458 } elsif (my $fn = $dirhash->{$dir}->{$name}) {
459
460 $versions->{$fn}++;
461 #print "VERSION:$fn:$versions->{$fn}\n";
462 }
463 });
464 }
465
466 foreach my $dir (keys %$dirhash) {
467 foreach my $name (keys %{$dirhash->{$dir}}) {
468 if ($name eq '_regex') {
469 foreach my $uid (keys %$ccacheregex) {
470 my $ccinfo = $ccacheregex->{$uid};
471 next if $dir ne $ccinfo->{dir};
472 my $re = $ccinfo->{regex};
473 if (my $fd = IO::Dir->new ($dir)) {
474 while (defined(my $de = $fd->read)) {
475 if ($de =~ m/^$re$/) {
476 my $fn = "$dir/$de";
477 $versions->{$fn}++; # init with version
478 #print "init:$fn:$versions->{$fn}\n";
479 }
480 }
481 }
482 }
483 } else {
484 my $fn = $dirhash->{$dir}->{$name};
485 $versions->{$fn}++; # init with version
486 #print "init:$fn:$versions->{$fn}\n";
487 }
488 }
489 }
490 }
491
492 my $cached_nodename;
493
494 sub nodename {
495
496 return $cached_nodename if $cached_nodename;
497
498 my ($sysname, $nodename) = POSIX::uname();
499
500 $nodename =~ s/\..*$//; # strip domain part, if any
501
502 die "unable to read node name\n" if !$nodename;
503
504 $cached_nodename = $nodename;
505
506 return $cached_nodename;
507 }
508
509 sub read_etc_hostname {
510 my ($filename, $fd) = @_;
511
512 my $hostname = <$fd>;
513
514 chomp $hostname;
515
516 $hostname =~ s/\..*$//; # strip domain part, if any
517
518 return $hostname;
519 }
520
521 sub write_etc_hostname {
522 my ($filename, $fh, $hostname) = @_;
523
524 die "write failed: $!" unless print $fh "$hostname\n";
525
526 return $hostname;
527 }
528
529 register_file('hostname', "/etc/hostname",
530 \&read_etc_hostname,
531 \&write_etc_hostname);
532
533 sub read_etc_resolv_conf {
534 my ($filename, $fh) = @_;
535
536 my $res = {};
537
538 my $nscount = 0;
539 while (my $line = <$fh>) {
540 chomp $line;
541 if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
542 $res->{search} = $2;
543 } elsif ($line =~ m/^nameserver\s+(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\s*/) {
544 $nscount++;
545 if ($nscount <= 3) {
546 $res->{"dns$nscount"} = $1;
547 }
548 }
549 }
550
551 return $res;
552 }
553
554 sub update_etc_resolv_conf {
555 my ($filename, $fh, $resolv, @args) = @_;
556
557 my $data = "";
558
559 $data = "search $resolv->{search}\n"
560 if $resolv->{search};
561
562 my $written = {};
563 foreach my $k ("dns1", "dns2", "dns3") {
564 my $ns = $resolv->{$k};
565 if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
566 $written->{$ns} = 1;
567 $data .= "nameserver $ns\n";
568 }
569 }
570
571 while (my $line = <$fh>) {
572 next if $line =~ m/^(search|domain|nameserver)\s+/;
573 $data .= $line
574 }
575
576 return $data;
577 }
578
579 register_file('resolvconf', "/etc/resolv.conf",
580 \&read_etc_resolv_conf, undef,
581 \&update_etc_resolv_conf);
582
583 sub read_etc_timezone {
584 my ($filename, $fd) = @_;
585
586 my $timezone = <$fd>;
587
588 chomp $timezone;
589
590 return $timezone;
591 }
592
593 sub write_etc_timezone {
594 my ($filename, $fh, $timezone) = @_;
595
596 my $tzinfo = "/usr/share/zoneinfo/$timezone";
597
598 raise_param_exc({ 'timezone' => "No such timezone" })
599 if (! -f $tzinfo);
600
601 ($timezone) = $timezone =~ m/^(.*)$/; # untaint
602
603 print $fh "$timezone\n";
604
605 unlink ("/etc/localtime");
606 symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
607
608 }
609
610 register_file('timezone', "/etc/timezone",
611 \&read_etc_timezone,
612 \&write_etc_timezone);
613
614 sub read_active_workers {
615 my ($filename, $fh) = @_;
616
617 return [] if !$fh;
618
619 my $res = [];
620 while (defined (my $line = <$fh>)) {
621 if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
622 my $upid = $1;
623 my $saved = $2;
624 my $endtime = $4;
625 my $status = $6;
626 if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
627 $task->{upid} = $upid;
628 $task->{saved} = $saved;
629 $task->{endtime} = hex($endtime) if $endtime;
630 $task->{status} = $status if $status;
631 push @$res, $task;
632 }
633 } else {
634 warn "unable to parse line: $line";
635 }
636 }
637
638 return $res;
639
640 }
641
642 sub write_active_workers {
643 my ($filename, $fh, $tasklist) = @_;
644
645 my $raw = '';
646 foreach my $task (@$tasklist) {
647 my $upid = $task->{upid};
648 my $saved = $task->{saved} ? 1 : 0;
649 if ($task->{endtime}) {
650 if ($task->{status}) {
651 $raw .= sprintf("$upid $saved %08X $task->{status}\n", $task->{endtime});
652 } else {
653 $raw .= sprintf("$upid $saved %08X\n", $task->{endtime});
654 }
655 } else {
656 $raw .= "$upid $saved\n";
657 }
658 }
659
660 PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
661 }
662
663 register_file('active', "/var/log/pve/tasks/active",
664 \&read_active_workers,
665 \&write_active_workers);
666
667
668 my $bond_modes = { 'balance-rr' => 0,
669 'active-backup' => 1,
670 'balance-xor' => 2,
671 'broadcast' => 3,
672 '802.3ad' => 4,
673 'balance-tlb' => 5,
674 'balance-alb' => 6,
675 };
676
677 my $ovs_bond_modes = {
678 'active-backup' => 1,
679 'balance-slb' => 1,
680 'lacp-balance-slb' => 1,
681 'lacp-balance-tcp' => 1,
682 };
683
684 #sub get_bond_modes {
685 # return $bond_modes;
686 #}
687
688 my $parse_ovs_option = sub {
689 my ($data) = @_;
690
691 my $opts = {};
692 foreach my $kv (split (/\s+/, $data || '')) {
693 my ($k, $v) = split('=', $kv, 2);
694 $opts->{$k} = $v if $k && $v;
695 }
696 return $opts;
697 };
698
699 my $set_ovs_option = sub {
700 my ($d, %params) = @_;
701
702 my $opts = &$parse_ovs_option($d->{ovs_options});
703
704 foreach my $k (keys %params) {
705 my $v = $params{$k};
706 if ($v) {
707 $opts->{$k} = $v;
708 } else {
709 delete $opts->{$k};
710 }
711 }
712
713 my $res = [];
714 foreach my $k (keys %$opts) {
715 push @$res, "$k=$opts->{$k}";
716 }
717
718 if (my $new = join(' ', @$res)) {
719 $d->{ovs_options} = $new;
720 return $d->{ovs_options};
721 } else {
722 delete $d->{ovs_options};
723 return undef;
724 }
725 };
726
727 my $extract_ovs_option = sub {
728 my ($d, $name) = @_;
729
730 my $opts = &$parse_ovs_option($d->{ovs_options});
731
732 my $v = delete $opts->{$name};
733
734 my $res = [];
735 foreach my $k (keys %$opts) {
736 push @$res, "$k=$opts->{$k}";
737 }
738
739 if (my $new = join(' ', @$res)) {
740 $d->{ovs_options} = $new;
741 } else {
742 delete $d->{ovs_options};
743 }
744
745 return $v;
746 };
747
748 # config => {
749 # ifaces => {
750 # $ifname => {
751 # <optional> exists => BOOL,
752 # <optional> active => BOOL,
753 # <optional> autostart => BOOL,
754 # <auto> priority => INT,
755 #
756 # type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
757 #
758 # families => ["inet", "inet6", ...],
759 #
760 # method => "manual" | "static" | "dhcp" | ... ,
761 # address => IP,
762 # netmask => SUBNET,
763 # broadcast => IP,
764 # gateway => IP,
765 # comments => [ "..." ],
766 #
767 # method6 => "manual" | "static" | "dhcp" | ... ,
768 # address6 => IP,
769 # netmask6 => SUBNET,
770 # gateway6 => IP,
771 # comments6 => [ "..." ],
772 #
773 # <known options>, # like bridge_ports, ovs_*
774 #
775 # # extra/unknown options stored by-family:
776 # options => { <inet options>... }
777 # options6 => { <inet6 options>... }
778 # }
779 # },
780 # options => [
781 # # mappings end up here as well, as we don't need to understand them
782 # [priority,line]
783 # ]
784 # }
785 sub read_etc_network_interfaces {
786 my ($filename, $fh) = @_;
787 my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
788 my $proc_net_if_inet6 = IO::File->new('/proc/net/if_inet6', 'r');
789 return __read_etc_network_interfaces($fh, $proc_net_dev, $proc_net_if_inet6);
790 }
791
792 sub __read_etc_network_interfaces {
793 my ($fh, $proc_net_dev, $proc_net_if_inet6) = @_;
794
795 my $config = {};
796 my $ifaces = $config->{ifaces} = {};
797 my $options = $config->{options} = [];
798
799 my $line;
800
801 if ($proc_net_dev) {
802 while (defined ($line = <$proc_net_dev>)) {
803 if ($line =~ m/^\s*(eth\d+):.*/) {
804 $ifaces->{$1}->{exists} = 1;
805 }
806 }
807 close($proc_net_dev);
808 }
809
810 # we try to keep order inside the file
811 my $priority = 2; # 1 is reserved for lo
812
813 SECTION: while (defined ($line = <$fh>)) {
814 chomp ($line);
815 next if $line =~ m/^\s*#/;
816
817 if ($line =~ m/^\s*auto\s+(.*)$/) {
818 my @aa = split (/\s+/, $1);
819
820 foreach my $a (@aa) {
821 $ifaces->{$a}->{autostart} = 1;
822 }
823
824 } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
825 my $i = $1;
826 my $family = $2;
827 my $f = { method => $3 }; # by family, merged to $d with a $suffix
828 (my $suffix = $family) =~ s/^inet//;
829
830 my $d = $ifaces->{$i} ||= {};
831 $d->{priority} = $priority++ if !$d->{priority};
832 push @{$d->{families}}, $family;
833
834 while (defined ($line = <$fh>)) {
835 chomp $line;
836 if ($line =~ m/^\s*#(.*?)\s*$/) {
837 # NOTE: we use 'comments' instead of 'comment' to
838 # avoid automatic utf8 conversion
839 $f->{comments} = '' if !$f->{comments};
840 $f->{comments} .= "$1\n";
841 } elsif ($line =~ m/^\s*(?:iface\s
842 |mapping\s
843 |auto\s
844 |allow-
845 |source\s
846 |source-directory\s
847 )/x) {
848 last;
849 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
850 my $option = $1;
851 my ($id, $value) = ($2, $3);
852 if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
853 $f->{$id} = $value;
854 } elsif ($id eq 'ovs_type' || $id eq 'ovs_options'|| $id eq 'ovs_bridge' ||
855 $id eq 'ovs_bonds' || $id eq 'ovs_ports') {
856 $d->{$id} = $value;
857 } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
858 my $devs = {};
859 foreach my $p (split (/\s+/, $value)) {
860 next if $p eq 'none';
861 $devs->{$p} = 1;
862 }
863 my $str = join (' ', sort keys %{$devs});
864 if ($d->{$id}) {
865 $d->{$id} .= ' ' . $str if $str;
866 } else {
867 $d->{$id} = $str || '';
868 }
869 } elsif ($id eq 'bridge_stp') {
870 if ($value =~ m/^\s*(on|yes)\s*$/i) {
871 $d->{$id} = 'on';
872 } else {
873 $d->{$id} = 'off';
874 }
875 } elsif ($id eq 'bridge_fd') {
876 $d->{$id} = $value;
877 } elsif ($id eq 'bridge_vlan_aware') {
878 $d->{$id} = 1;
879 } elsif ($id eq 'bond_miimon') {
880 $d->{$id} = $value;
881 } elsif ($id eq 'bond_xmit_hash_policy') {
882 $d->{$id} = $value;
883 } elsif ($id eq 'bond_mode') {
884 # always use names
885 foreach my $bm (keys %$bond_modes) {
886 my $id = $bond_modes->{$bm};
887 if ($id eq $value) {
888 $value = $bm;
889 last;
890 }
891 }
892 $d->{$id} = $value;
893 } else {
894 push @{$f->{options}}, $option;
895 }
896 } else {
897 last;
898 }
899 }
900 $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
901 last SECTION if !defined($line);
902 redo SECTION;
903 } elsif ($line =~ /\w/) {
904 push @$options, [$priority++, $line];
905 }
906 }
907
908
909
910 if (!$ifaces->{lo}) {
911 $ifaces->{lo}->{priority} = 1;
912 $ifaces->{lo}->{method} = 'loopback';
913 $ifaces->{lo}->{type} = 'loopback';
914 $ifaces->{lo}->{autostart} = 1;
915 }
916
917 foreach my $iface (keys %$ifaces) {
918 my $d = $ifaces->{$iface};
919 if ($iface =~ m/^bond\d+$/) {
920 if (!$d->{ovs_type}) {
921 $d->{type} = 'bond';
922 } elsif ($d->{ovs_type} eq 'OVSBond') {
923 $d->{type} = $d->{ovs_type};
924 # translate: ovs_options => bond_mode
925 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
926 my $lacp = &$extract_ovs_option($d, 'lacp');
927 if ($lacp && $lacp eq 'active') {
928 if ($d->{'bond_mode'} eq 'balance-slb') {
929 $d->{'bond_mode'} = 'lacp-balance-slb';
930 }
931 }
932 # Note: balance-tcp needs lacp
933 if ($d->{'bond_mode'} eq 'balance-tcp') {
934 $d->{'bond_mode'} = 'lacp-balance-tcp';
935 }
936 my $tag = &$extract_ovs_option($d, 'tag');
937 $d->{ovs_tag} = $tag if defined($tag);
938 } else {
939 $d->{type} = 'unknown';
940 }
941 } elsif ($iface =~ m/^vmbr\d+$/) {
942 if (!$d->{ovs_type}) {
943 $d->{type} = 'bridge';
944
945 if (!defined ($d->{bridge_fd})) {
946 $d->{bridge_fd} = 0;
947 }
948 if (!defined ($d->{bridge_stp})) {
949 $d->{bridge_stp} = 'off';
950 }
951 } elsif ($d->{ovs_type} eq 'OVSBridge') {
952 $d->{type} = $d->{ovs_type};
953 } else {
954 $d->{type} = 'unknown';
955 }
956 } elsif ($iface =~ m/^(\S+):\d+$/) {
957 $d->{type} = 'alias';
958 if (defined ($ifaces->{$1})) {
959 $d->{exists} = $ifaces->{$1}->{exists};
960 } else {
961 $ifaces->{$1}->{exists} = 0;
962 $d->{exists} = 0;
963 }
964 } elsif ($iface =~ m/^eth\d+$/) {
965 if (!$d->{ovs_type}) {
966 $d->{type} = 'eth';
967 } elsif ($d->{ovs_type} eq 'OVSPort') {
968 $d->{type} = $d->{ovs_type};
969 my $tag = &$extract_ovs_option($d, 'tag');
970 $d->{ovs_tag} = $tag if defined($tag);
971 } else {
972 $d->{type} = 'unknown';
973 }
974 } elsif ($iface =~ m/^lo$/) {
975 $d->{type} = 'loopback';
976 } else {
977 if (!$d->{ovs_type}) {
978 $d->{type} = 'unknown';
979 } elsif ($d->{ovs_type} eq 'OVSIntPort') {
980 $d->{type} = $d->{ovs_type};
981 my $tag = &$extract_ovs_option($d, 'tag');
982 $d->{ovs_tag} = $tag if defined($tag);
983 }
984 }
985
986 $d->{method} = 'manual' if !$d->{method};
987 $d->{method6} = 'manual' if !$d->{method6};
988
989 $d->{families} ||= ['inet'];
990 }
991
992 if ($proc_net_if_inet6) {
993 while (defined ($line = <$proc_net_if_inet6>)) {
994 if ($line =~ m/^[a-f0-9]{32}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+(\S+)$/) {
995 $ifaces->{$1}->{active} = 1 if defined($ifaces->{$1});
996 }
997 }
998 close ($proc_net_if_inet6);
999 }
1000
1001 # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1002 # from the {options} hash for them to be removed correctly.
1003 @$options = grep {defined($_)} map {
1004 my ($pri, $line) = @$_;
1005 if ($line =~ /^allow-(\S+)\s+(.*)$/) {
1006 my $bridge = $1;
1007 my @ports = split(/\s+/, $2);
1008 if (defined(my $br = $ifaces->{$bridge})) {
1009 # if this port is part of a bridge, remove it
1010 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1011 @ports = grep { not $in_ovs_ports{$_} } @ports;
1012 }
1013 # create the allow line for the remaining ports, or delete if empty
1014 if (@ports) {
1015 [$pri, "allow-$bridge " . join(' ', @ports)];
1016 } else {
1017 undef;
1018 }
1019 } else {
1020 # don't modify other lines
1021 $_;
1022 }
1023 } @$options;
1024
1025 return $config;
1026 }
1027
1028 sub __interface_to_string {
1029 my ($iface, $d, $family, $first_block) = @_;
1030
1031 (my $suffix = $family) =~ s/^inet//;
1032
1033 return '' if !($d && $d->{"method$suffix"});
1034
1035 my $raw = '';
1036
1037 $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1038 $raw .= "\taddress " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1039 $raw .= "\tnetmask " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1040 $raw .= "\tgateway " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1041 $raw .= "\tbroadcast " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1042
1043 my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1044 comments => 1, autostart => 1, options => 1,
1045 address => 1, netmask => 1, gateway => 1, broadcast => 1,
1046 method6 => 1, families => 1, options6 => 1,
1047 address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1 };
1048
1049 if (!$first_block) {
1050 # not printing out options
1051 } elsif ($d->{type} eq 'bridge') {
1052
1053 my $ports = $d->{bridge_ports} || 'none';
1054 $raw .= "\tbridge_ports $ports\n";
1055 $done->{bridge_ports} = 1;
1056
1057 my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1058 $raw .= "\tbridge_stp $v\n";
1059 $done->{bridge_stp} = 1;
1060
1061 $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1062 $raw .= "\tbridge_fd $v\n";
1063 $done->{bridge_fd} = 1;
1064
1065 if( defined($d->{bridge_vlan_aware})) {
1066 $raw .= "\tbridge_vlan_aware yes\n";
1067 }
1068 $done->{bridge_vlan_aware} = 1;
1069
1070 } elsif ($d->{type} eq 'bond') {
1071
1072 my $slaves = $d->{slaves} || 'none';
1073 $raw .= "\tslaves $slaves\n";
1074 $done->{slaves} = 1;
1075
1076 my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1077 $raw .= "\tbond_miimon $v\n";
1078 $done->{'bond_miimon'} = 1;
1079
1080 $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1081 $raw .= "\tbond_mode $v\n";
1082 $done->{'bond_mode'} = 1;
1083
1084 if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1085 ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1086 $raw .= "\tbond_xmit_hash_policy $d->{'bond_xmit_hash_policy'}\n";
1087 }
1088 $done->{'bond_xmit_hash_policy'} = 1;
1089
1090 } elsif ($d->{type} eq 'OVSBridge') {
1091
1092 $raw .= "\tovs_type $d->{type}\n";
1093 $done->{ovs_type} = 1;
1094
1095 $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1096 $done->{ovs_ports} = 1;
1097 } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1098 $d->{type} eq 'OVSBond') {
1099
1100 $d->{autostart} = 0; # started by the bridge
1101
1102 if (defined($d->{ovs_tag})) {
1103 &$set_ovs_option($d, tag => $d->{ovs_tag});
1104 }
1105 $done->{ovs_tag} = 1;
1106
1107 if ($d->{type} eq 'OVSBond') {
1108
1109 $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1110
1111 $ovs_bond_modes->{$d->{bond_mode}} ||
1112 die "OVS does not support bond mode '$d->{bond_mode}\n";
1113
1114 if ($d->{bond_mode} eq 'lacp-balance-slb') {
1115 &$set_ovs_option($d, lacp => 'active');
1116 &$set_ovs_option($d, bond_mode => 'balance-slb');
1117 } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1118 &$set_ovs_option($d, lacp => 'active');
1119 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1120 } else {
1121 &$set_ovs_option($d, lacp => undef);
1122 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1123 }
1124 $done->{bond_mode} = 1;
1125
1126 $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1127 $done->{ovs_bonds} = 1;
1128 }
1129
1130 $raw .= "\tovs_type $d->{type}\n";
1131 $done->{ovs_type} = 1;
1132
1133 if ($d->{ovs_bridge}) {
1134 $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1135 $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1136 $done->{ovs_bridge} = 1;
1137 }
1138 }
1139
1140 if ($first_block) {
1141 # print other settings
1142 foreach my $k (keys %$d) {
1143 next if $done->{$k};
1144 next if !$d->{$k};
1145 $raw .= "\t$k $d->{$k}\n";
1146 }
1147 }
1148
1149 foreach my $option (@{$d->{"options$suffix"}}) {
1150 $raw .= "\t$option\n";
1151 }
1152
1153 # add comments
1154 my $comments = $d->{"comments$suffix"} || '';
1155 foreach my $cl (split(/\n/, $comments)) {
1156 $raw .= "#$cl\n";
1157 }
1158
1159 $raw .= "\n";
1160
1161 return $raw;
1162 }
1163
1164
1165 sub write_etc_network_interfaces {
1166 my ($filename, $fh, $config) = @_;
1167 my $raw = __write_etc_network_interfaces($config);
1168 PVE::Tools::safe_print($filename, $fh, $raw);
1169 }
1170 sub __write_etc_network_interfaces {
1171 my ($config) = @_;
1172
1173 my $ifaces = $config->{ifaces};
1174 my @options = @{$config->{options}};
1175
1176 my $used_ports = {};
1177
1178 foreach my $iface (keys %$ifaces) {
1179 my $d = $ifaces->{$iface};
1180
1181 my $ports = '';
1182 foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1183 $ports .= " $d->{$k}" if $d->{$k};
1184 }
1185
1186 foreach my $p (PVE::Tools::split_list($ports)) {
1187 die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1188 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1189 $used_ports->{$p} = $iface;
1190 }
1191 }
1192
1193 # delete unused OVS ports
1194 foreach my $iface (keys %$ifaces) {
1195 my $d = $ifaces->{$iface};
1196 if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1197 $d->{type} eq 'OVSBond') {
1198 my $brname = $used_ports->{$iface};
1199 if (!$brname || !$ifaces->{$brname}) {
1200 if ($iface =~ /^eth/) {
1201 $ifaces->{$iface} = { type => 'eth',
1202 exists => 1,
1203 method => 'manual',
1204 families => ['inet'] };
1205 } else {
1206 delete $ifaces->{$iface};
1207 }
1208 next;
1209 }
1210 my $bd = $ifaces->{$brname};
1211 if ($bd->{type} ne 'OVSBridge') {
1212 delete $ifaces->{$iface};
1213 next;
1214 }
1215 }
1216 }
1217
1218 # create OVS bridge ports
1219 foreach my $iface (keys %$ifaces) {
1220 my $d = $ifaces->{$iface};
1221 if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1222 foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1223 my $n = $ifaces->{$p};
1224 die "OVS bridge '$iface' - unable to find port '$p'\n"
1225 if !$n;
1226 $n->{autostart} = 0;
1227 if ($n->{type} eq 'eth') {
1228 $n->{type} = 'OVSPort';
1229 $n->{ovs_bridge} = $iface;
1230 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1231 $n->{type} eq 'OVSIntPort') {
1232 $n->{ovs_bridge} = $iface;
1233 } else {
1234 die "interface '$p' is not defined as OVS port/bond\n";
1235 }
1236 }
1237 }
1238 }
1239
1240 # Remove autostart from linux bridge ports
1241 foreach my $iface (keys %$ifaces) {
1242 my $d = $ifaces->{$iface};
1243 if ($d->{type} eq 'bridge' && $d->{bridge_ports}) {
1244 foreach my $p (split (/\s+/, $d->{bridge_ports})) {
1245 my $n = $ifaces->{$p};
1246 die "bridge '$iface' - unable to find port '$p'\n"
1247 if !$n;
1248 $n->{autostart} = 0;
1249 }
1250 }
1251 }
1252
1253 # check OVS bond ports
1254 foreach my $iface (keys %$ifaces) {
1255 my $d = $ifaces->{$iface};
1256 if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1257 foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1258 my $n = $ifaces->{$p};
1259 die "OVS bond '$iface' - unable to find slave '$p'\n"
1260 if !$n;
1261 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1262 "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1263 }
1264 }
1265 }
1266
1267 my $raw = <<'NETWORKDOC';
1268 # network interface settings; autogenerated
1269 # Please do NOT modify this file directly, unless you know what
1270 # you're doing.
1271 #
1272 # If you want to manage part of the network configuration manually,
1273 # please utilize the 'source' or 'source-directory' directives to do
1274 # so.
1275 # PVE will preserve these directives, but will NOT its network
1276 # configuration from sourced files, so do not attempt to move any of
1277 # the PVE managed interfaces into external files!
1278
1279 NETWORKDOC
1280
1281 my $printed = {};
1282
1283 my $if_type_hash = {
1284 unknown => 0,
1285 loopback => 100000,
1286 eth => 200000,
1287 bond => 300000,
1288 bridge => 400000,
1289 };
1290
1291 my $lookup_type_prio = sub {
1292 my $iface = shift;
1293
1294 my $alias = 0;
1295 if ($iface =~ m/^(\S+):\d+$/) {
1296 $iface = $1;
1297 $alias = 1;
1298 }
1299
1300 my $pri;
1301 if ($iface eq 'lo') {
1302 $pri = $if_type_hash->{loopback};
1303 } elsif ($iface =~ m/^eth\d+$/) {
1304 $pri = $if_type_hash->{eth} + $alias;
1305 } elsif ($iface =~ m/^bond\d+$/) {
1306 $pri = $if_type_hash->{bond} + $alias;
1307 } elsif ($iface =~ m/^vmbr\d+$/) {
1308 $pri = $if_type_hash->{bridge} + $alias;
1309 }
1310
1311 return $pri || ($if_type_hash->{unknown} + $alias);
1312 };
1313
1314 foreach my $iface (sort {
1315 my $ref1 = $ifaces->{$a};
1316 my $ref2 = $ifaces->{$b};
1317 my $p1 = &$lookup_type_prio($a);
1318 my $p2 = &$lookup_type_prio($b);
1319
1320 $p1 += $ref1->{priority} // 50000;
1321 $p2 += $ref2->{priority} // 50000;
1322
1323 return $p1 <=> $p2 if $p1 != $p2;
1324
1325 return $a cmp $b;
1326 } keys %$ifaces) {
1327 next if $printed->{$iface};
1328
1329 my $d = $ifaces->{$iface};
1330 my $pri = $d->{priority} // 0;
1331 if (@options && $options[0]->[0] < $pri) {
1332 do {
1333 $raw .= (shift @options)->[1] . "\n";
1334 } while (@options && $options[0]->[0] < $pri);
1335 $raw .= "\n";
1336 }
1337
1338 $printed->{$iface} = 1;
1339 $raw .= "auto $iface\n" if $d->{autostart};
1340 my $i = 0; # some options should be printed only once
1341 $raw .= __interface_to_string($iface, $d, $_, !$i++) foreach @{$d->{families}};
1342 }
1343
1344 $raw .= $_->[1] . "\n" foreach @options;
1345 return $raw;
1346 }
1347
1348 register_file('interfaces', "/etc/network/interfaces",
1349 \&read_etc_network_interfaces,
1350 \&write_etc_network_interfaces);
1351
1352
1353 sub read_iscsi_initiatorname {
1354 my ($filename, $fd) = @_;
1355
1356 while (defined(my $line = <$fd>)) {
1357 if ($line =~ m/^InitiatorName=(\S+)$/) {
1358 return $1;
1359 }
1360 }
1361
1362 return 'undefined';
1363 }
1364
1365 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1366 \&read_iscsi_initiatorname);
1367
1368 sub read_apt_auth {
1369 my ($filename, $fd) = @_;
1370
1371 local $/;
1372
1373 my $raw = defined($fd) ? <$fd> : '';
1374
1375 $raw =~ s/^\s+//;
1376
1377
1378 my @tokens = split(/\s+/, $raw);
1379
1380 my $data = {};
1381
1382 my $machine;
1383 while (defined(my $tok = shift @tokens)) {
1384
1385 $machine = shift @tokens if $tok eq 'machine';
1386 next if !$machine;
1387 $data->{$machine} = {} if !$data->{$machine};
1388
1389 $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1390 $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1391 };
1392
1393 return $data;
1394 }
1395
1396 my $format_apt_auth_data = sub {
1397 my $data = shift;
1398
1399 my $raw = '';
1400
1401 foreach my $machine (sort keys %$data) {
1402 my $d = $data->{$machine};
1403 $raw .= "machine $machine\n";
1404 $raw .= " login $d->{login}\n" if $d->{login};
1405 $raw .= " password $d->{password}\n" if $d->{password};
1406 $raw .= "\n";
1407 }
1408
1409 return $raw;
1410 };
1411
1412 sub write_apt_auth {
1413 my ($filename, $fh, $data) = @_;
1414
1415 my $raw = &$format_apt_auth_data($data);
1416
1417 die "write failed: $!" unless print $fh "$raw\n";
1418
1419 return $data;
1420 }
1421
1422 sub update_apt_auth {
1423 my ($filename, $fh, $data) = @_;
1424
1425 my $orig = read_apt_auth($filename, $fh);
1426
1427 foreach my $machine (keys %$data) {
1428 $orig->{$machine} = $data->{$machine};
1429 }
1430
1431 return &$format_apt_auth_data($orig);
1432 }
1433
1434 register_file('apt-auth', "/etc/apt/auth.conf",
1435 \&read_apt_auth, \&write_apt_auth,
1436 \&update_apt_auth, perm => 0640);
1437
1438 1;