read_etc_network_interfaces: less strict parsing
[pve-common.git] / src / PVE / INotify.pm
1 package PVE::INotify;
2
3 # todo: maybe we do not need update_file() ?
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::File;
10 use IO::Dir;
11 use File::stat;
12 use File::Basename;
13 use Fcntl qw(:DEFAULT :flock);
14 use PVE::SafeSyslog;
15 use PVE::Exception qw(raise_param_exc);
16 use PVE::Tools;
17 use Storable qw(dclone);            
18 use Linux::Inotify2;
19 use base 'Exporter';
20 use JSON; 
21
22 our @EXPORT_OK = qw(read_file write_file register_file);
23
24 my $ccache;
25 my $ccachemap;
26 my $ccacheregex;
27 my $inotify;
28 my $inotify_pid = 0;
29 my $versions;
30 my $shadowfiles = {
31     '/etc/network/interfaces' => '/etc/network/interfaces.new',
32 };
33
34 # to enable cached operation, you need to call 'inotify_init'
35 # inotify handles are a limited resource, so use with care (only
36 # enable the cache if you really need it)
37
38 # Note: please close the inotify handle after you fork
39
40 sub ccache_default_writer {
41     my ($filename, $data) = @_;
42
43     die "undefined config writer for '$filename' :ERROR";
44 }
45
46 sub ccache_default_parser {
47     my ($filename, $srcfd) = @_;
48
49     die "undefined config reader for '$filename' :ERROR";
50 }
51
52 sub ccache_compute_diff {
53     my ($filename, $shadow) = @_;
54
55     my $diff = '';
56
57     open (TMP, "diff -b -N -u '$filename' '$shadow'|");
58         
59     while (my $line = <TMP>) {
60         $diff .= $line;
61     }
62
63     close (TMP);
64
65     $diff = undef if !$diff;
66
67     return $diff;
68 }
69
70 sub ccache_info {
71     my ($filename) = @_;
72
73     foreach my $uid (keys %$ccacheregex) {
74         my $ccinfo = $ccacheregex->{$uid};
75         my $dir = $ccinfo->{dir};
76         my $regex = $ccinfo->{regex};
77         if ($filename =~ m|^$dir/+$regex$|) {
78             if (!$ccache->{$filename}) {
79                 my $cp = {};
80                 while (my ($k, $v) = each %$ccinfo) {
81                     $cp->{$k} = $v;
82                 }
83                 $ccache->{$filename} = $cp;
84             } 
85             return ($ccache->{$filename}, $filename);
86         }
87     }
88  
89     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
90
91     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
92    
93     return ($ccache->{$filename}, $filename);
94 }
95
96 sub write_file {
97     my ($fileid, $data, $full) = @_;
98
99     my ($ccinfo, $filename) = ccache_info($fileid);
100
101     my $writer = $ccinfo->{writer};
102
103     my $realname = $filename;
104
105     my $shadow;
106     if ($shadow = $shadowfiles->{$filename}) {
107         $realname = $shadow;
108     }
109
110     my $perm = $ccinfo->{perm} || 0644;
111
112     my $tmpname = "$realname.tmp.$$";
113
114     my $res;
115     eval {
116         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
117         die "unable to open file '$tmpname' - $!\n" if !$fh;
118
119         $res = &$writer($filename, $fh, $data);
120
121         die "closing file '$tmpname' failed - $!\n" unless close $fh;
122     };
123     my $err = $@;
124
125     $ccinfo->{version} = undef;
126
127     if ($err) {
128         unlink $tmpname;
129         die $err;
130     }
131
132     if (!rename($tmpname, $realname)) {
133         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
134         unlink $tmpname;
135         die $msg;       
136     }
137
138     my $diff;
139     if ($shadow && $full) {
140         $diff = ccache_compute_diff ($filename, $shadow);
141     }
142
143     if ($full) {
144         return { data => $res, changes => $diff };
145     }
146
147     return $res;
148 }
149
150 sub update_file {
151     my ($fileid, $data, @args) = @_;
152
153     my ($ccinfo, $filename) = ccache_info($fileid);
154
155     my $update = $ccinfo->{update};
156
157     die "unable to update/merge data" if !$update;
158
159     my $lkfn = "$filename.lock";
160
161     my $timeout = 10;
162
163     my $fd;
164
165     my $code = sub {
166
167         $fd = IO::File->new ($filename, "r");
168         
169         my $new = &$update($filename, $fd, $data, @args);
170
171         if (defined($new)) {
172             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
173         } else {
174             unlink $filename;
175         }
176     };
177
178     PVE::Tools::lock_file($lkfn, $timeout, $code);
179     my $err = $@;
180
181     close($fd) if defined($fd);
182
183     die $err if $err;
184
185     return undef;
186 }
187
188 sub discard_changes {
189     my ($fileid, $full) = @_;
190
191     my ($ccinfo, $filename) = ccache_info($fileid);
192
193     if (my $copy = $shadowfiles->{$filename}) {
194         unlink $copy;
195     }
196
197     return read_file ($filename, $full);
198 }
199
200 sub read_file {
201     my ($fileid, $full) = @_;
202
203     my $parser;
204
205     my ($ccinfo, $filename) = ccache_info($fileid);
206      
207     $parser = $ccinfo->{parser};
208  
209     my $fd;
210     my $shadow;
211
212     poll() if $inotify; # read new inotify events
213
214     $versions->{$filename} = 0 if !defined ($versions->{$filename});
215
216     my $cver = $versions->{$filename};
217
218     if (my $copy = $shadowfiles->{$filename}) {
219         if ($fd = IO::File->new ($copy, "r")) {
220             $shadow = $copy;
221         } else {
222             $fd = IO::File->new ($filename, "r");
223         }
224     } else {
225         $fd = IO::File->new ($filename, "r");
226     }
227
228     my $acp = $ccinfo->{always_call_parser};
229
230     if (!$fd) {
231         $ccinfo->{version} = undef;
232         $ccinfo->{data} = undef; 
233         $ccinfo->{diff} = undef;
234         return undef if !$acp;
235     }
236
237     my $noclone = $ccinfo->{noclone};
238
239     # file unchanged?
240     if (!$ccinfo->{nocache} &&
241         $inotify && $versions->{$filename} &&
242         defined ($ccinfo->{data}) &&
243         defined ($ccinfo->{version}) &&
244         ($ccinfo->{readonce} ||
245          ($ccinfo->{version} == $versions->{$filename}))) {
246
247         my $ret;
248         if (!$noclone && ref ($ccinfo->{data})) {
249             $ret->{data} = dclone ($ccinfo->{data});
250         } else {
251             $ret->{data} = $ccinfo->{data};
252         }
253         $ret->{changes} = $ccinfo->{diff};
254         
255         return $full ? $ret : $ret->{data};
256     }
257
258     my $diff;
259
260     if ($shadow) {
261         $diff = ccache_compute_diff ($filename, $shadow);
262     }
263
264     my $res = &$parser($filename, $fd);
265
266     if (!$ccinfo->{nocache}) {
267         $ccinfo->{version} = $cver;
268     }
269
270     # we cache data with references, so we always need to
271     # dclone this data. Else the original data may get
272     # modified.
273     $ccinfo->{data} = $res;
274
275     # also store diff
276     $ccinfo->{diff} = $diff;
277
278     my $ret;
279     if (!$noclone && ref ($ccinfo->{data})) {
280         $ret->{data} = dclone ($ccinfo->{data});
281     } else {
282         $ret->{data} = $ccinfo->{data};
283     }
284     $ret->{changes} = $ccinfo->{diff};
285
286     return $full ? $ret : $ret->{data};
287 }    
288
289 sub parse_ccache_options {
290     my ($ccinfo, %options) = @_;
291
292     foreach my $opt (keys %options) {
293         my $v = $options{$opt};
294         if ($opt eq 'readonce') {
295             $ccinfo->{$opt} = $v;
296         } elsif ($opt eq 'nocache') {
297             $ccinfo->{$opt} = $v;
298         } elsif ($opt eq 'shadow') {
299             $ccinfo->{$opt} = $v;
300         } elsif ($opt eq 'perm') {
301             $ccinfo->{$opt} = $v;
302         } elsif ($opt eq 'noclone') {
303             # noclone flag for large read-only data chunks like aplinfo
304             $ccinfo->{$opt} = $v;
305         } elsif ($opt eq 'always_call_parser') {
306             # when set, we call parser even when the file does not exists.
307             # this allows the parser to return some default
308             $ccinfo->{$opt} = $v;
309         } else {
310             die "internal error - unsupported option '$opt'";
311         }
312     }
313 }
314
315 sub register_file {
316     my ($id, $filename, $parser, $writer, $update, %options) = @_;
317
318     die "can't register file '$filename' after inotify_init" if $inotify;
319
320     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
321     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
322
323     my $ccinfo = {};
324
325     $ccinfo->{id} = $id;
326     $ccinfo->{parser} = $parser || \&ccache_default_parser;
327     $ccinfo->{writer} = $writer || \&ccache_default_writer;
328     $ccinfo->{update} = $update;
329
330     parse_ccache_options($ccinfo, %options);
331     
332     if ($options{shadow}) {
333         $shadowfiles->{$filename} = $options{shadow};
334     }
335
336     $ccachemap->{$id} = $filename;
337     $ccache->{$filename} = $ccinfo;
338 }
339
340 sub register_regex {
341     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
342
343     die "can't register regex after initify_init" if $inotify;
344
345     my $uid = "$dir/$regex";
346     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
347  
348     my $ccinfo = {};
349
350     $ccinfo->{dir} = $dir;
351     $ccinfo->{regex} = $regex;
352     $ccinfo->{parser} = $parser || \&ccache_default_parser;
353     $ccinfo->{writer} = $writer || \&ccache_default_writer;
354     $ccinfo->{update} = $update;
355
356     parse_ccache_options($ccinfo, %options);
357
358     $ccacheregex->{$uid} = $ccinfo;
359 }
360
361 sub poll {
362     return if !$inotify;
363
364     if ($inotify_pid != $$) {
365         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
366         $inotify = undef;
367     } else {
368         1 while $inotify && $inotify->poll;
369     }
370 }
371
372 sub flushcache {
373     foreach my $filename (keys %$ccache) {
374         $ccache->{$filename}->{version} = undef;
375         $ccache->{$filename}->{data} = undef;
376         $ccache->{$filename}->{diff} = undef;
377     }
378 }
379
380 sub inotify_close {
381     $inotify = undef;
382 }
383
384 sub inotify_init {
385
386     die "only one inotify instance allowed" if $inotify;
387
388     $inotify =  Linux::Inotify2->new()
389         || die "Unable to create new inotify object: $!";
390
391     $inotify->blocking (0);
392
393     $versions = {};
394
395     my $dirhash = {};
396     foreach my $fn (keys %$ccache) {
397         my $dir = dirname ($fn);
398         my $base = basename ($fn);
399
400         $dirhash->{$dir}->{$base} = $fn;
401
402         if (my $sf = $shadowfiles->{$fn}) {
403             $base = basename ($sf);
404             $dir = dirname ($sf);
405             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
406         }
407     }
408
409     foreach my $uid (keys %$ccacheregex) {
410         my $ccinfo = $ccacheregex->{$uid};
411         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;       
412     }
413
414     $inotify_pid = $$;
415
416     foreach my $dir (keys %$dirhash) {
417
418         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
419         $inotify->watch ($dir, $evlist, sub {
420             my $e = shift;
421             my $name = $e->name;
422
423             if ($inotify_pid != $$) {
424                 syslog ('err', "got inotify event in wrong process");
425             }
426
427             if ($e->IN_ISDIR || !$name) {
428                 return;
429             }
430
431             if ($e->IN_Q_OVERFLOW) {
432                 syslog ('info', "got inotify overflow - flushing cache");
433                 flushcache();
434                 return;
435             }
436
437             if ($e->IN_UNMOUNT) {
438                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
439                 $inotify = undef;
440             }
441             if ($e->IN_IGNORED) { 
442                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
443                 $inotify = undef;
444             }
445
446             if ($dirhash->{$dir}->{_regex}) {
447                 foreach my $uid (keys %$ccacheregex) {
448                     my $ccinfo = $ccacheregex->{$uid};
449                     next if $dir ne $ccinfo->{dir};
450                     my $regex = $ccinfo->{regex};
451                     if ($regex && ($name =~ m|^$regex$|)) {
452
453                         my $fn = "$dir/$name";
454                         $versions->{$fn}++;
455                         #print "VERSION:$fn:$versions->{$fn}\n";
456                     }
457                 }
458             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
459
460                 $versions->{$fn}++;
461                 #print "VERSION:$fn:$versions->{$fn}\n";
462             }
463         });
464     }
465
466     foreach my $dir (keys %$dirhash) {
467         foreach my $name (keys %{$dirhash->{$dir}}) {
468             if ($name eq '_regex') {
469                 foreach my $uid (keys %$ccacheregex) {
470                     my $ccinfo = $ccacheregex->{$uid};
471                     next if $dir ne $ccinfo->{dir};
472                     my $re = $ccinfo->{regex};
473                     if (my $fd = IO::Dir->new ($dir)) {
474                         while (defined(my $de = $fd->read)) { 
475                             if ($de =~ m/^$re$/) {
476                                 my $fn = "$dir/$de";
477                                 $versions->{$fn}++; # init with version
478                                 #print "init:$fn:$versions->{$fn}\n";
479                             }
480                         }
481                     }
482                 }
483             } else {
484                 my $fn = $dirhash->{$dir}->{$name};
485                 $versions->{$fn}++; # init with version
486                 #print "init:$fn:$versions->{$fn}\n";
487             }
488         }
489     }
490 }
491
492 my $cached_nodename;
493
494 sub nodename {
495
496     return $cached_nodename if $cached_nodename;
497
498     my ($sysname, $nodename) = POSIX::uname();
499
500     $nodename =~ s/\..*$//; # strip domain part, if any
501
502     die "unable to read node name\n" if !$nodename;
503
504     $cached_nodename = $nodename;
505
506     return $cached_nodename;
507 }
508
509 sub read_etc_hostname {
510     my ($filename, $fd) = @_;
511
512     my $hostname = <$fd>;
513
514     chomp $hostname;
515
516     $hostname =~ s/\..*$//; # strip domain part, if any
517
518     return $hostname;
519 }
520
521 sub write_etc_hostname {
522     my ($filename, $fh, $hostname) = @_;
523
524     die "write failed: $!" unless print $fh "$hostname\n";
525
526     return $hostname;
527 }
528
529 register_file('hostname', "/etc/hostname",  
530               \&read_etc_hostname, 
531               \&write_etc_hostname);
532
533 sub read_etc_resolv_conf {
534     my ($filename, $fh) = @_;
535
536     my $res = {};
537
538     my $nscount = 0;
539     while (my $line = <$fh>) {
540         chomp $line;
541         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
542             $res->{search} = $2;
543         } elsif ($line =~ m/^nameserver\s+(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\s*/) {
544             $nscount++;
545             if ($nscount <= 3) {
546                 $res->{"dns$nscount"} = $1;
547             }
548         }
549     }
550
551     return $res;
552 }
553
554 sub update_etc_resolv_conf {
555     my ($filename, $fh, $resolv, @args) = @_;
556
557     my $data = "";
558
559     $data = "search $resolv->{search}\n"
560         if $resolv->{search};
561
562     my $written = {};
563     foreach my $k ("dns1", "dns2", "dns3") {
564         my $ns = $resolv->{$k};
565         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
566             $written->{$ns} = 1;
567             $data .= "nameserver $ns\n";
568         }
569     }
570
571     while (my $line = <$fh>) {
572         next if $line =~ m/^(search|domain|nameserver)\s+/;
573         $data .= $line
574     }
575     
576     return $data;
577 }
578
579 register_file('resolvconf', "/etc/resolv.conf", 
580               \&read_etc_resolv_conf, undef, 
581               \&update_etc_resolv_conf);
582
583 sub read_etc_timezone {
584     my ($filename, $fd) = @_;
585
586     my $timezone = <$fd>;
587
588     chomp $timezone;
589
590     return $timezone;
591 }
592
593 sub write_etc_timezone {
594     my ($filename, $fh, $timezone) = @_;
595
596     my $tzinfo = "/usr/share/zoneinfo/$timezone";
597
598     raise_param_exc({ 'timezone' => "No such timezone" })
599         if (! -f $tzinfo);
600
601     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
602
603     print $fh "$timezone\n";
604
605     unlink ("/etc/localtime");
606     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
607
608 }
609
610 register_file('timezone', "/etc/timezone", 
611               \&read_etc_timezone, 
612               \&write_etc_timezone);
613
614 sub read_active_workers {
615     my ($filename, $fh) = @_;
616
617     return [] if !$fh;
618
619     my $res = []; 
620     while (defined (my $line = <$fh>)) {
621         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
622             my $upid = $1;
623             my $saved = $2;
624             my $endtime = $4;
625             my $status = $6;
626             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
627                 $task->{upid} = $upid;
628                 $task->{saved} = $saved;
629                 $task->{endtime} = hex($endtime) if $endtime;
630                 $task->{status} = $status if $status;
631                 push @$res, $task;
632             }
633         } else {
634             warn "unable to parse line: $line";
635         }
636     }
637
638     return $res;
639
640 }
641
642 sub write_active_workers {
643     my ($filename, $fh, $tasklist) = @_;
644
645     my $raw = '';
646     foreach my $task (@$tasklist) {
647         my $upid = $task->{upid};
648         my $saved = $task->{saved} ? 1 : 0;
649         if ($task->{endtime}) {
650             if ($task->{status}) {
651                 $raw .= sprintf("$upid $saved %08X $task->{status}\n", $task->{endtime});
652             } else {
653                 $raw .= sprintf("$upid $saved %08X\n", $task->{endtime});
654             }
655         } else {
656             $raw .= "$upid $saved\n";
657         }
658     }
659
660     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
661 }
662
663 register_file('active', "/var/log/pve/tasks/active", 
664               \&read_active_workers,
665               \&write_active_workers);
666
667
668 my $bond_modes = { 'balance-rr' => 0,
669                    'active-backup' => 1,
670                    'balance-xor' => 2,
671                    'broadcast' => 3,
672                    '802.3ad' => 4,
673                    'balance-tlb' => 5,
674                    'balance-alb' => 6,
675                };
676
677 my $ovs_bond_modes = {
678     'active-backup' => 1,
679     'balance-slb' => 1,
680     'lacp-balance-slb' => 1,
681     'lacp-balance-tcp' => 1, 
682 };
683
684 #sub get_bond_modes {
685 #    return $bond_modes;
686 #}
687
688 my $parse_ovs_option = sub {
689     my ($data) = @_;
690
691     my $opts = {};
692     foreach my $kv (split (/\s+/, $data || '')) {
693         my ($k, $v) = split('=', $kv, 2);
694         $opts->{$k} = $v if $k && $v;
695     }
696     return $opts;
697 };
698
699 my $set_ovs_option = sub {
700     my ($d, %params) = @_;
701
702     my $opts = &$parse_ovs_option($d->{ovs_options});
703
704     foreach my $k (keys %params) {
705         my $v = $params{$k};
706         if ($v) {
707             $opts->{$k} = $v;
708         } else {
709             delete $opts->{$k};
710         }
711     }
712
713     my $res = [];
714     foreach my $k (keys %$opts) {
715         push @$res, "$k=$opts->{$k}";
716     }
717
718     if (my $new = join(' ', @$res)) {
719         $d->{ovs_options} = $new;
720         return $d->{ovs_options};
721     } else {
722         delete $d->{ovs_options};
723         return undef;
724     }
725 };
726
727 my $extract_ovs_option = sub {
728     my ($d, $name) = @_;
729
730     my $opts = &$parse_ovs_option($d->{ovs_options});
731
732     my $v = delete $opts->{$name};
733
734     my $res = [];
735     foreach my $k (keys %$opts) {
736         push @$res, "$k=$opts->{$k}";
737     }
738
739     if (my $new = join(' ', @$res)) {
740         $d->{ovs_options} = $new;
741     } else {
742         delete $d->{ovs_options};
743     }
744
745     return $v;
746 };
747
748 sub read_etc_network_interfaces {
749     my ($filename, $fh) = @_;
750
751     my $ifaces = {};
752
753     my $line;
754
755     if (my $fd2 = IO::File->new("/proc/net/dev", "r")) {
756         while (defined ($line = <$fd2>)) {
757             if ($line =~ m/^\s*(eth\d+):.*/) {
758                 $ifaces->{$1}->{exists} = 1;
759             }
760         }
761         close($fd2);
762     }
763
764     # we try to keep order inside the file
765     my $priority = 2; # 1 is reserved for lo 
766
767     my $gateway = 0;
768
769     SECTION: while (defined ($line = <$fh>)) {
770         chomp ($line);
771         next if $line =~ m/^\s*#/;
772  
773         if ($line =~ m/^\s*auto\s+(.*)$/) {
774             my @aa = split (/\s+/, $1);
775
776             foreach my $a (@aa) {
777                 $ifaces->{$a}->{autostart} = 1;
778             }
779
780         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+inet\s+(\S+)\s*$/) {
781             my $i = $1;
782             $ifaces->{$i}->{method} = $2;
783             $ifaces->{$i}->{priority} = $priority++;
784
785             my $d = $ifaces->{$i};
786             while (defined ($line = <$fh>)) {
787                 chomp $line;
788                 if ($line =~ m/^\s*#(.*?)\s*$/) {
789                     # NOTE: we use 'comments' instead of 'comment' to 
790                     # avoid automatic utf8 conversion
791                     $d->{comments} = '' if !$d->{comments};
792                     $d->{comments} .= "$1\n";
793                 } elsif ($line =~ m/^\s*(?:iface\s
794                                           |mapping\s
795                                           |auto\s
796                                           |allow-
797                                           |source\s
798                                           |source-directory\s
799                                         )/x) {
800                     last;
801                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
802                     my $option = $1;
803                     my ($id, $value) = ($2, $3);
804                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast')) {
805                         $d->{$id} = $value;
806                     } elsif ($id eq 'gateway') {
807                         $d->{$id} = $value;
808                         $gateway = 1;
809                     } elsif ($id eq 'ovs_type' || $id eq 'ovs_options'|| $id eq 'ovs_bridge' ||
810                              $id eq 'ovs_bonds' || $id eq 'ovs_ports') {
811                         $d->{$id} = $value;
812                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
813                         my $devs = {};
814                         foreach my $p (split (/\s+/, $value)) {
815                             next if $p eq 'none';
816                             $devs->{$p} = 1;
817                         }
818                         my $str = join (' ', sort keys %{$devs});
819                         $d->{$id} = $str || '';
820                     } elsif ($id eq 'bridge_stp') {
821                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
822                             $d->{$id} = 'on';
823                         } else {
824                             $d->{$id} = 'off';
825                         }
826                     } elsif ($id eq 'bridge_fd') {
827                         $d->{$id} = $value;
828                     } elsif ($id eq 'bond_miimon') {
829                         $d->{$id} = $value;
830                     } elsif ($id eq 'bond_xmit_hash_policy') {
831                         $d->{$id} = $value;
832                     } elsif ($id eq 'bond_mode') {
833                         # always use names
834                         foreach my $bm (keys %$bond_modes) {
835                             my $id = $bond_modes->{$bm};
836                             if ($id eq $value) {
837                                 $value = $bm;
838                                 last;
839                             }
840                         }
841                         $d->{$id} = $value;
842                     } else {
843                         push @{$d->{options}}, $option;
844                     }
845                 } else {
846                     last;
847                 }
848             }
849             last SECTION if !defined($line);
850             redo SECTION;
851         }
852     }
853
854
855
856     if (!$ifaces->{lo}) {
857         $ifaces->{lo}->{priority} = 1;
858         $ifaces->{lo}->{method} = 'loopback';
859         $ifaces->{lo}->{type} = 'loopback';
860         $ifaces->{lo}->{autostart} = 1;
861     }
862
863     foreach my $iface (keys %$ifaces) {
864         my $d = $ifaces->{$iface};
865         if ($iface =~ m/^bond\d+$/) {
866             if (!$d->{ovs_type}) {
867                 $d->{type} = 'bond';
868             } elsif ($d->{ovs_type} eq 'OVSBond') {
869                 $d->{type} = $d->{ovs_type};
870                 # translate: ovs_options => bond_mode
871                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
872                 my $lacp = &$extract_ovs_option($d, 'lacp');
873                 if ($lacp && $lacp eq 'active') {
874                     if ($d->{'bond_mode'} eq 'balance-slb') {
875                         $d->{'bond_mode'} = 'lacp-balance-slb';
876                     }
877                 }
878                 # Note: balance-tcp needs lacp
879                 if ($d->{'bond_mode'} eq 'balance-tcp') {
880                     $d->{'bond_mode'} = 'lacp-balance-tcp';
881                 }
882                 my $tag = &$extract_ovs_option($d, 'tag');
883                 $d->{ovs_tag} = $tag if defined($tag);
884             } else {
885                 $d->{type} = 'unknown';
886             }
887         } elsif ($iface =~ m/^vmbr\d+$/) {
888             if (!$d->{ovs_type}) {
889                 $d->{type} = 'bridge';
890
891                 if (!defined ($d->{bridge_fd})) {
892                     $d->{bridge_fd} = 0;
893                 }
894                 if (!defined ($d->{bridge_stp})) {
895                     $d->{bridge_stp} = 'off';
896                 }
897             } elsif ($d->{ovs_type} eq 'OVSBridge') {
898                 $d->{type} = $d->{ovs_type};
899             } else {
900                 $d->{type} = 'unknown';
901             }
902         } elsif ($iface =~ m/^(\S+):\d+$/) {
903             $d->{type} = 'alias';
904             if (defined ($ifaces->{$1})) {
905                 $d->{exists} = $ifaces->{$1}->{exists};
906             } else {
907                 $ifaces->{$1}->{exists} = 0;
908                 $d->{exists} = 0;
909             }
910         } elsif ($iface =~ m/^eth\d+$/) {
911             if (!$d->{ovs_type}) {
912                 $d->{type} = 'eth';
913             } elsif ($d->{ovs_type} eq 'OVSPort') {
914                 $d->{type} = $d->{ovs_type};
915                 my $tag = &$extract_ovs_option($d, 'tag');
916                 $d->{ovs_tag} = $tag if defined($tag);
917             } else {
918                 $d->{type} = 'unknown';
919             }
920         } elsif ($iface =~ m/^lo$/) {
921             $d->{type} = 'loopback';
922         } else {
923             if (!$d->{ovs_type}) {
924                 $d->{type} = 'unknown';
925             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
926                 $d->{type} = $d->{ovs_type};
927                 my $tag = &$extract_ovs_option($d, 'tag');
928                 $d->{ovs_tag} = $tag if defined($tag);
929             }
930         }
931
932         $d->{method} = 'manual' if !$d->{method};
933     }
934
935     if (my $fd2 = IO::File->new("/proc/net/if_inet6", "r")) {
936         while (defined ($line = <$fd2>)) {
937             if ($line =~ m/^[a-f0-9]{32}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+(\S+)$/) {
938                 $ifaces->{$1}->{active} = 1 if defined($ifaces->{$1});
939             }
940         }
941         close ($fd2);
942     }
943
944     return $ifaces;
945 }
946
947 sub __interface_to_string {
948     my ($iface, $d) = @_;
949
950     return '' if !($d && $d->{method});
951
952     my $raw = '';
953
954     $raw .= "iface $iface inet $d->{method}\n";
955     $raw .= "\taddress  $d->{address}\n" if $d->{address};
956     $raw .= "\tnetmask  $d->{netmask}\n" if $d->{netmask};
957     $raw .= "\tgateway  $d->{gateway}\n" if $d->{gateway};
958     $raw .= "\tbroadcast  $d->{broadcast}\n" if $d->{broadcast};
959
960     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
961                  comments => 1, autostart => 1, options => 1,
962                  address => 1, netmask => 1, gateway => 1, broadcast => 1 };
963  
964     if ($d->{type} eq 'bridge') {
965
966         my $ports = $d->{bridge_ports} || 'none';
967         $raw .= "\tbridge_ports $ports\n";
968         $done->{bridge_ports} = 1;
969
970         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
971         $raw .= "\tbridge_stp $v\n";
972         $done->{bridge_stp} = 1;
973
974         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
975         $raw .= "\tbridge_fd $v\n";
976         $done->{bridge_fd} = 1;
977     
978     } elsif ($d->{type} eq 'bond') {
979
980         my $slaves = $d->{slaves} || 'none';
981         $raw .= "\tslaves $slaves\n";
982         $done->{slaves} = 1;
983
984         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
985         $raw .= "\tbond_miimon $v\n";
986         $done->{'bond_miimon'} = 1;
987
988         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
989         $raw .= "\tbond_mode $v\n";
990         $done->{'bond_mode'} = 1;
991
992         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
993             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
994             $raw .= "\tbond_xmit_hash_policy $d->{'bond_xmit_hash_policy'}\n";
995         }
996         $done->{'bond_xmit_hash_policy'} = 1;
997
998     } elsif ($d->{type} eq 'OVSBridge') {
999
1000         $raw .= "\tovs_type $d->{type}\n";
1001         $done->{ovs_type} = 1;
1002
1003         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1004         $done->{ovs_ports} = 1;
1005
1006     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1007              $d->{type} eq 'OVSBond') {
1008
1009         $d->{autostart} = 0; # started by the bridge
1010
1011         if (defined($d->{ovs_tag})) {
1012             &$set_ovs_option($d, tag => $d->{ovs_tag});
1013         }
1014         $done->{ovs_tag} = 1;
1015
1016         if ($d->{type} eq 'OVSBond') {
1017
1018             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1019
1020             $ovs_bond_modes->{$d->{bond_mode}} ||
1021                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1022
1023             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1024                 &$set_ovs_option($d, lacp => 'active');
1025                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1026             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1027                 &$set_ovs_option($d, lacp => 'active');
1028                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1029             } else {
1030                 &$set_ovs_option($d, lacp => undef);
1031                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1032             }
1033             $done->{bond_mode} = 1;
1034
1035             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1036             $done->{ovs_bonds} = 1;
1037         }
1038
1039         if ($d->{ovs_bridge}) {
1040             $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1041         }
1042
1043         $raw .= "\tovs_type $d->{type}\n";
1044         $done->{ovs_type} = 1;
1045
1046         if ($d->{ovs_bridge}) {
1047             $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1048             $done->{ovs_bridge} = 1;
1049         }
1050         # fixme: use Data::Dumper; print Dumper($d);
1051     }
1052
1053     # print other settings
1054     foreach my $k (keys %$d) {
1055         next if $done->{$k};
1056         next if !$d->{$k};
1057         $raw .= "\t$k $d->{$k}\n";
1058     }
1059
1060     foreach my $option (@{$d->{options}}) {
1061         $raw .= "\t$option\n";
1062     }
1063
1064     # add comments
1065     my $comments = $d->{comments} || '';
1066     foreach my $cl (split(/\n/, $comments)) {
1067         $raw .= "#$cl\n";
1068     }
1069
1070     if ($d->{autostart}) {
1071         $raw = "auto $iface\n$raw";
1072     }
1073
1074     $raw .= "\n";
1075
1076     return $raw;
1077 }
1078
1079 sub write_etc_network_interfaces {
1080     my ($filename, $fh, $ifaces) = @_;
1081
1082     my $used_ports = {};
1083
1084     foreach my $iface (keys %$ifaces) {
1085         my $d = $ifaces->{$iface};
1086
1087         my $ports = '';
1088         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1089             $ports .= " $d->{$k}" if $d->{$k};
1090         }
1091
1092         foreach my $p (PVE::Tools::split_list($ports)) {
1093             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1094                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1095             $used_ports->{$p} = $iface;
1096         }
1097     }
1098
1099     # delete unused OVS ports
1100     foreach my $iface (keys %$ifaces) {
1101         my $d = $ifaces->{$iface};
1102         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || 
1103             $d->{type} eq 'OVSBond') {
1104             my $brname = $used_ports->{$iface};
1105             if (!$brname || !$ifaces->{$brname}) { 
1106                 delete $ifaces->{$iface}; 
1107                 next;
1108             }
1109             my $bd = $ifaces->{$brname};
1110             if ($bd->{type} ne 'OVSBridge') {
1111                 delete $ifaces->{$iface};
1112                 next;
1113             }
1114         }
1115     }
1116
1117     # create OVS bridge ports
1118     foreach my $iface (keys %$ifaces) {
1119         my $d = $ifaces->{$iface};
1120         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1121             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1122                 my $n = $ifaces->{$p};
1123                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1124                     if !$n;
1125                 if ($n->{type} eq 'eth') {
1126                     $n->{type} = 'OVSPort';
1127                     $n->{ovs_bridge} = $iface;              
1128                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1129                     $n->{type} eq 'OVSIntPort') {
1130                     $n->{ovs_bridge} = $iface;
1131                 } else {
1132                     die "interface '$p' is not defined as OVS port/bond\n";
1133                 }
1134             }
1135         }
1136     }
1137
1138     # check OVS bond ports
1139     foreach my $iface (keys %$ifaces) {
1140         my $d = $ifaces->{$iface};
1141         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1142             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1143                 my $n = $ifaces->{$p};
1144                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1145                     if !$n;
1146                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1147                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1148             }
1149         }
1150     }
1151
1152     my $raw = "# network interface settings\n";
1153
1154     my $printed = {};
1155
1156     my $if_type_hash = {
1157         unknown => 0,
1158         loopback => 10,
1159         eth => 20,
1160         bond => 30,
1161         bridge => 40,
1162    };
1163
1164     my $lookup_type_prio = sub {
1165         my $iface = shift;
1166
1167         my $alias = 0;
1168         if ($iface =~ m/^(\S+):\d+$/) {
1169             $iface = $1;
1170             $alias = 1;
1171         }
1172
1173         my $pri;
1174         if ($iface eq 'lo') {
1175             $pri = $if_type_hash->{loopback};
1176         } elsif ($iface =~ m/^eth\d+$/) {
1177             $pri = $if_type_hash->{eth} + $alias;
1178         } elsif ($iface =~ m/^bond\d+$/) {
1179             $pri = $if_type_hash->{bond} + $alias;
1180         } elsif ($iface =~ m/^vmbr\d+$/) {
1181             $pri = $if_type_hash->{bridge} + $alias;
1182         }
1183
1184         return $pri || ($if_type_hash->{unknown} + $alias);
1185     };
1186
1187     foreach my $iface (sort {
1188         my $ref1 = $ifaces->{$a};
1189         my $ref2 = $ifaces->{$b};
1190         my $p1 = &$lookup_type_prio($a);
1191         my $p2 = &$lookup_type_prio($b);
1192
1193         return $p1 <=> $p2 if $p1 != $p2;
1194
1195         $p1 = $ref1->{priority} || 100000;
1196         $p2 = $ref2->{priority} || 100000;
1197
1198         return $p1 <=> $p2 if $p1 != $p2;
1199
1200         return $a cmp $b;
1201                        } keys %$ifaces) {
1202
1203         my $d = $ifaces->{$iface};
1204
1205         next if $printed->{$iface};
1206
1207         $printed->{$iface} = 1;
1208         $raw .= __interface_to_string($iface, $d);
1209     }
1210     
1211     PVE::Tools::safe_print($filename, $fh, $raw);
1212 }
1213
1214 register_file('interfaces', "/etc/network/interfaces",
1215               \&read_etc_network_interfaces,
1216               \&write_etc_network_interfaces);
1217
1218
1219 sub read_iscsi_initiatorname {
1220     my ($filename, $fd) = @_;
1221
1222     while (defined(my $line = <$fd>)) {
1223         if ($line =~ m/^InitiatorName=(\S+)$/) {
1224             return $1;
1225         }
1226     }
1227
1228     return 'undefined';
1229 }
1230
1231 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",  
1232               \&read_iscsi_initiatorname);
1233
1234 sub read_apt_auth {
1235     my ($filename, $fd) = @_;
1236
1237     local $/;
1238
1239     my $raw = defined($fd) ? <$fd> : '';
1240
1241     $raw =~ s/^\s+//;
1242
1243  
1244     my @tokens = split(/\s+/, $raw);
1245
1246     my $data = {};
1247
1248     my $machine;
1249     while (defined(my $tok = shift @tokens)) {
1250
1251         $machine = shift @tokens if $tok eq 'machine';
1252         next if !$machine;
1253         $data->{$machine} = {} if !$data->{$machine};
1254
1255         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1256         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1257     };
1258
1259     return $data;
1260 }
1261
1262 my $format_apt_auth_data = sub {
1263     my $data = shift;
1264
1265     my $raw = '';
1266
1267     foreach my $machine (sort keys %$data) {
1268         my $d = $data->{$machine};
1269         $raw .= "machine $machine\n";
1270         $raw .= " login $d->{login}\n" if $d->{login};
1271         $raw .= " password $d->{password}\n" if $d->{password};
1272         $raw .= "\n";
1273     }
1274
1275     return $raw;
1276 };
1277
1278 sub write_apt_auth {
1279     my ($filename, $fh, $data) = @_;
1280
1281     my $raw = &$format_apt_auth_data($data);
1282
1283     die "write failed: $!" unless print $fh "$raw\n";
1284    
1285     return $data;
1286 }
1287
1288 sub update_apt_auth {
1289     my ($filename, $fh, $data) = @_;
1290
1291     my $orig = read_apt_auth($filename, $fh);
1292
1293     foreach my $machine (keys %$data) {
1294         $orig->{$machine} = $data->{$machine};
1295     }
1296
1297     return &$format_apt_auth_data($orig);
1298 }
1299
1300 register_file('apt-auth', "/etc/apt/auth.conf",  
1301               \&read_apt_auth, \&write_apt_auth,
1302               \&update_apt_auth, perm => 0640);
1303
1304 1;