e773cf4d93649b56c5fc93775abf01a151d4ac84
[pve-common.git] / src / PVE / INotify.pm
1 package PVE::INotify;
2
3 # todo: maybe we do not need update_file() ?
4
5 use strict;
6 use warnings;
7
8 use POSIX;
9 use IO::File;
10 use IO::Dir;
11 use File::stat;
12 use File::Basename;
13 use Fcntl qw(:DEFAULT :flock);
14 use PVE::SafeSyslog;
15 use PVE::Exception qw(raise_param_exc);
16 use PVE::Tools;
17 use Storable qw(dclone);            
18 use Linux::Inotify2;
19 use base 'Exporter';
20 use JSON; 
21
22 our @EXPORT_OK = qw(read_file write_file register_file);
23
24 my $ccache;
25 my $ccachemap;
26 my $ccacheregex;
27 my $inotify;
28 my $inotify_pid = 0;
29 my $versions;
30 my $shadowfiles = {
31     '/etc/network/interfaces' => '/etc/network/interfaces.new',
32 };
33
34 # to enable cached operation, you need to call 'inotify_init'
35 # inotify handles are a limited resource, so use with care (only
36 # enable the cache if you really need it)
37
38 # Note: please close the inotify handle after you fork
39
40 sub ccache_default_writer {
41     my ($filename, $data) = @_;
42
43     die "undefined config writer for '$filename' :ERROR";
44 }
45
46 sub ccache_default_parser {
47     my ($filename, $srcfd) = @_;
48
49     die "undefined config reader for '$filename' :ERROR";
50 }
51
52 sub ccache_compute_diff {
53     my ($filename, $shadow) = @_;
54
55     my $diff = '';
56
57     open (TMP, "diff -b -N -u '$filename' '$shadow'|");
58         
59     while (my $line = <TMP>) {
60         $diff .= $line;
61     }
62
63     close (TMP);
64
65     $diff = undef if !$diff;
66
67     return $diff;
68 }
69
70 sub ccache_info {
71     my ($filename) = @_;
72
73     foreach my $uid (keys %$ccacheregex) {
74         my $ccinfo = $ccacheregex->{$uid};
75         my $dir = $ccinfo->{dir};
76         my $regex = $ccinfo->{regex};
77         if ($filename =~ m|^$dir/+$regex$|) {
78             if (!$ccache->{$filename}) {
79                 my $cp = {};
80                 while (my ($k, $v) = each %$ccinfo) {
81                     $cp->{$k} = $v;
82                 }
83                 $ccache->{$filename} = $cp;
84             } 
85             return ($ccache->{$filename}, $filename);
86         }
87     }
88  
89     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
90
91     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
92    
93     return ($ccache->{$filename}, $filename);
94 }
95
96 sub write_file {
97     my ($fileid, $data, $full) = @_;
98
99     my ($ccinfo, $filename) = ccache_info($fileid);
100
101     my $writer = $ccinfo->{writer};
102
103     my $realname = $filename;
104
105     my $shadow;
106     if ($shadow = $shadowfiles->{$filename}) {
107         $realname = $shadow;
108     }
109
110     my $perm = $ccinfo->{perm} || 0644;
111
112     my $tmpname = "$realname.tmp.$$";
113
114     my $res;
115     eval {
116         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
117         die "unable to open file '$tmpname' - $!\n" if !$fh;
118
119         $res = &$writer($filename, $fh, $data);
120
121         die "closing file '$tmpname' failed - $!\n" unless close $fh;
122     };
123     my $err = $@;
124
125     $ccinfo->{version} = undef;
126
127     if ($err) {
128         unlink $tmpname;
129         die $err;
130     }
131
132     if (!rename($tmpname, $realname)) {
133         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
134         unlink $tmpname;
135         die $msg;       
136     }
137
138     my $diff;
139     if ($shadow && $full) {
140         $diff = ccache_compute_diff ($filename, $shadow);
141     }
142
143     if ($full) {
144         return { data => $res, changes => $diff };
145     }
146
147     return $res;
148 }
149
150 sub update_file {
151     my ($fileid, $data, @args) = @_;
152
153     my ($ccinfo, $filename) = ccache_info($fileid);
154
155     my $update = $ccinfo->{update};
156
157     die "unable to update/merge data" if !$update;
158
159     my $lkfn = "$filename.lock";
160
161     my $timeout = 10;
162
163     my $fd;
164
165     my $code = sub {
166
167         $fd = IO::File->new ($filename, "r");
168         
169         my $new = &$update($filename, $fd, $data, @args);
170
171         if (defined($new)) {
172             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
173         } else {
174             unlink $filename;
175         }
176     };
177
178     PVE::Tools::lock_file($lkfn, $timeout, $code);
179     my $err = $@;
180
181     close($fd) if defined($fd);
182
183     die $err if $err;
184
185     return undef;
186 }
187
188 sub discard_changes {
189     my ($fileid, $full) = @_;
190
191     my ($ccinfo, $filename) = ccache_info($fileid);
192
193     if (my $copy = $shadowfiles->{$filename}) {
194         unlink $copy;
195     }
196
197     return read_file ($filename, $full);
198 }
199
200 sub read_file {
201     my ($fileid, $full) = @_;
202
203     my $parser;
204
205     my ($ccinfo, $filename) = ccache_info($fileid);
206      
207     $parser = $ccinfo->{parser};
208  
209     my $fd;
210     my $shadow;
211
212     poll() if $inotify; # read new inotify events
213
214     $versions->{$filename} = 0 if !defined ($versions->{$filename});
215
216     my $cver = $versions->{$filename};
217
218     if (my $copy = $shadowfiles->{$filename}) {
219         if ($fd = IO::File->new ($copy, "r")) {
220             $shadow = $copy;
221         } else {
222             $fd = IO::File->new ($filename, "r");
223         }
224     } else {
225         $fd = IO::File->new ($filename, "r");
226     }
227
228     my $acp = $ccinfo->{always_call_parser};
229
230     if (!$fd) {
231         $ccinfo->{version} = undef;
232         $ccinfo->{data} = undef; 
233         $ccinfo->{diff} = undef;
234         return undef if !$acp;
235     }
236
237     my $noclone = $ccinfo->{noclone};
238
239     # file unchanged?
240     if (!$ccinfo->{nocache} &&
241         $inotify && $versions->{$filename} &&
242         defined ($ccinfo->{data}) &&
243         defined ($ccinfo->{version}) &&
244         ($ccinfo->{readonce} ||
245          ($ccinfo->{version} == $versions->{$filename}))) {
246
247         my $ret;
248         if (!$noclone && ref ($ccinfo->{data})) {
249             $ret->{data} = dclone ($ccinfo->{data});
250         } else {
251             $ret->{data} = $ccinfo->{data};
252         }
253         $ret->{changes} = $ccinfo->{diff};
254         
255         return $full ? $ret : $ret->{data};
256     }
257
258     my $diff;
259
260     if ($shadow) {
261         $diff = ccache_compute_diff ($filename, $shadow);
262     }
263
264     my $res = &$parser($filename, $fd);
265
266     if (!$ccinfo->{nocache}) {
267         $ccinfo->{version} = $cver;
268     }
269
270     # we cache data with references, so we always need to
271     # dclone this data. Else the original data may get
272     # modified.
273     $ccinfo->{data} = $res;
274
275     # also store diff
276     $ccinfo->{diff} = $diff;
277
278     my $ret;
279     if (!$noclone && ref ($ccinfo->{data})) {
280         $ret->{data} = dclone ($ccinfo->{data});
281     } else {
282         $ret->{data} = $ccinfo->{data};
283     }
284     $ret->{changes} = $ccinfo->{diff};
285
286     return $full ? $ret : $ret->{data};
287 }    
288
289 sub parse_ccache_options {
290     my ($ccinfo, %options) = @_;
291
292     foreach my $opt (keys %options) {
293         my $v = $options{$opt};
294         if ($opt eq 'readonce') {
295             $ccinfo->{$opt} = $v;
296         } elsif ($opt eq 'nocache') {
297             $ccinfo->{$opt} = $v;
298         } elsif ($opt eq 'shadow') {
299             $ccinfo->{$opt} = $v;
300         } elsif ($opt eq 'perm') {
301             $ccinfo->{$opt} = $v;
302         } elsif ($opt eq 'noclone') {
303             # noclone flag for large read-only data chunks like aplinfo
304             $ccinfo->{$opt} = $v;
305         } elsif ($opt eq 'always_call_parser') {
306             # when set, we call parser even when the file does not exists.
307             # this allows the parser to return some default
308             $ccinfo->{$opt} = $v;
309         } else {
310             die "internal error - unsupported option '$opt'";
311         }
312     }
313 }
314
315 sub register_file {
316     my ($id, $filename, $parser, $writer, $update, %options) = @_;
317
318     die "can't register file '$filename' after inotify_init" if $inotify;
319
320     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
321     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
322
323     my $ccinfo = {};
324
325     $ccinfo->{id} = $id;
326     $ccinfo->{parser} = $parser || \&ccache_default_parser;
327     $ccinfo->{writer} = $writer || \&ccache_default_writer;
328     $ccinfo->{update} = $update;
329
330     parse_ccache_options($ccinfo, %options);
331     
332     if ($options{shadow}) {
333         $shadowfiles->{$filename} = $options{shadow};
334     }
335
336     $ccachemap->{$id} = $filename;
337     $ccache->{$filename} = $ccinfo;
338 }
339
340 sub register_regex {
341     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
342
343     die "can't register regex after initify_init" if $inotify;
344
345     my $uid = "$dir/$regex";
346     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
347  
348     my $ccinfo = {};
349
350     $ccinfo->{dir} = $dir;
351     $ccinfo->{regex} = $regex;
352     $ccinfo->{parser} = $parser || \&ccache_default_parser;
353     $ccinfo->{writer} = $writer || \&ccache_default_writer;
354     $ccinfo->{update} = $update;
355
356     parse_ccache_options($ccinfo, %options);
357
358     $ccacheregex->{$uid} = $ccinfo;
359 }
360
361 sub poll {
362     return if !$inotify;
363
364     if ($inotify_pid != $$) {
365         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
366         $inotify = undef;
367     } else {
368         1 while $inotify && $inotify->poll;
369     }
370 }
371
372 sub flushcache {
373     foreach my $filename (keys %$ccache) {
374         $ccache->{$filename}->{version} = undef;
375         $ccache->{$filename}->{data} = undef;
376         $ccache->{$filename}->{diff} = undef;
377     }
378 }
379
380 sub inotify_close {
381     $inotify = undef;
382 }
383
384 sub inotify_init {
385
386     die "only one inotify instance allowed" if $inotify;
387
388     $inotify =  Linux::Inotify2->new()
389         || die "Unable to create new inotify object: $!";
390
391     $inotify->blocking (0);
392
393     $versions = {};
394
395     my $dirhash = {};
396     foreach my $fn (keys %$ccache) {
397         my $dir = dirname ($fn);
398         my $base = basename ($fn);
399
400         $dirhash->{$dir}->{$base} = $fn;
401
402         if (my $sf = $shadowfiles->{$fn}) {
403             $base = basename ($sf);
404             $dir = dirname ($sf);
405             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
406         }
407     }
408
409     foreach my $uid (keys %$ccacheregex) {
410         my $ccinfo = $ccacheregex->{$uid};
411         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;       
412     }
413
414     $inotify_pid = $$;
415
416     foreach my $dir (keys %$dirhash) {
417
418         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
419         $inotify->watch ($dir, $evlist, sub {
420             my $e = shift;
421             my $name = $e->name;
422
423             if ($inotify_pid != $$) {
424                 syslog ('err', "got inotify event in wrong process");
425             }
426
427             if ($e->IN_ISDIR || !$name) {
428                 return;
429             }
430
431             if ($e->IN_Q_OVERFLOW) {
432                 syslog ('info', "got inotify overflow - flushing cache");
433                 flushcache();
434                 return;
435             }
436
437             if ($e->IN_UNMOUNT) {
438                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
439                 $inotify = undef;
440             }
441             if ($e->IN_IGNORED) { 
442                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
443                 $inotify = undef;
444             }
445
446             if ($dirhash->{$dir}->{_regex}) {
447                 foreach my $uid (keys %$ccacheregex) {
448                     my $ccinfo = $ccacheregex->{$uid};
449                     next if $dir ne $ccinfo->{dir};
450                     my $regex = $ccinfo->{regex};
451                     if ($regex && ($name =~ m|^$regex$|)) {
452
453                         my $fn = "$dir/$name";
454                         $versions->{$fn}++;
455                         #print "VERSION:$fn:$versions->{$fn}\n";
456                     }
457                 }
458             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
459
460                 $versions->{$fn}++;
461                 #print "VERSION:$fn:$versions->{$fn}\n";
462             }
463         });
464     }
465
466     foreach my $dir (keys %$dirhash) {
467         foreach my $name (keys %{$dirhash->{$dir}}) {
468             if ($name eq '_regex') {
469                 foreach my $uid (keys %$ccacheregex) {
470                     my $ccinfo = $ccacheregex->{$uid};
471                     next if $dir ne $ccinfo->{dir};
472                     my $re = $ccinfo->{regex};
473                     if (my $fd = IO::Dir->new ($dir)) {
474                         while (defined(my $de = $fd->read)) { 
475                             if ($de =~ m/^$re$/) {
476                                 my $fn = "$dir/$de";
477                                 $versions->{$fn}++; # init with version
478                                 #print "init:$fn:$versions->{$fn}\n";
479                             }
480                         }
481                     }
482                 }
483             } else {
484                 my $fn = $dirhash->{$dir}->{$name};
485                 $versions->{$fn}++; # init with version
486                 #print "init:$fn:$versions->{$fn}\n";
487             }
488         }
489     }
490 }
491
492 my $cached_nodename;
493
494 sub nodename {
495
496     return $cached_nodename if $cached_nodename;
497
498     my ($sysname, $nodename) = POSIX::uname();
499
500     $nodename =~ s/\..*$//; # strip domain part, if any
501
502     die "unable to read node name\n" if !$nodename;
503
504     $cached_nodename = $nodename;
505
506     return $cached_nodename;
507 }
508
509 sub read_etc_hostname {
510     my ($filename, $fd) = @_;
511
512     my $hostname = <$fd>;
513
514     chomp $hostname;
515
516     $hostname =~ s/\..*$//; # strip domain part, if any
517
518     return $hostname;
519 }
520
521 sub write_etc_hostname {
522     my ($filename, $fh, $hostname) = @_;
523
524     die "write failed: $!" unless print $fh "$hostname\n";
525
526     return $hostname;
527 }
528
529 register_file('hostname', "/etc/hostname",  
530               \&read_etc_hostname, 
531               \&write_etc_hostname);
532
533 sub read_etc_resolv_conf {
534     my ($filename, $fh) = @_;
535
536     my $res = {};
537
538     my $nscount = 0;
539     while (my $line = <$fh>) {
540         chomp $line;
541         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
542             $res->{search} = $2;
543         } elsif ($line =~ m/^nameserver\s+(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})\s*/) {
544             $nscount++;
545             if ($nscount <= 3) {
546                 $res->{"dns$nscount"} = $1;
547             }
548         }
549     }
550
551     return $res;
552 }
553
554 sub update_etc_resolv_conf {
555     my ($filename, $fh, $resolv, @args) = @_;
556
557     my $data = "";
558
559     $data = "search $resolv->{search}\n"
560         if $resolv->{search};
561
562     my $written = {};
563     foreach my $k ("dns1", "dns2", "dns3") {
564         my $ns = $resolv->{$k};
565         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
566             $written->{$ns} = 1;
567             $data .= "nameserver $ns\n";
568         }
569     }
570
571     while (my $line = <$fh>) {
572         next if $line =~ m/^(search|domain|nameserver)\s+/;
573         $data .= $line
574     }
575     
576     return $data;
577 }
578
579 register_file('resolvconf', "/etc/resolv.conf", 
580               \&read_etc_resolv_conf, undef, 
581               \&update_etc_resolv_conf);
582
583 sub read_etc_timezone {
584     my ($filename, $fd) = @_;
585
586     my $timezone = <$fd>;
587
588     chomp $timezone;
589
590     return $timezone;
591 }
592
593 sub write_etc_timezone {
594     my ($filename, $fh, $timezone) = @_;
595
596     my $tzinfo = "/usr/share/zoneinfo/$timezone";
597
598     raise_param_exc({ 'timezone' => "No such timezone" })
599         if (! -f $tzinfo);
600
601     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
602
603     print $fh "$timezone\n";
604
605     unlink ("/etc/localtime");
606     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
607
608 }
609
610 register_file('timezone', "/etc/timezone", 
611               \&read_etc_timezone, 
612               \&write_etc_timezone);
613
614 sub read_active_workers {
615     my ($filename, $fh) = @_;
616
617     return [] if !$fh;
618
619     my $res = []; 
620     while (defined (my $line = <$fh>)) {
621         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
622             my $upid = $1;
623             my $saved = $2;
624             my $endtime = $4;
625             my $status = $6;
626             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
627                 $task->{upid} = $upid;
628                 $task->{saved} = $saved;
629                 $task->{endtime} = hex($endtime) if $endtime;
630                 $task->{status} = $status if $status;
631                 push @$res, $task;
632             }
633         } else {
634             warn "unable to parse line: $line";
635         }
636     }
637
638     return $res;
639
640 }
641
642 sub write_active_workers {
643     my ($filename, $fh, $tasklist) = @_;
644
645     my $raw = '';
646     foreach my $task (@$tasklist) {
647         my $upid = $task->{upid};
648         my $saved = $task->{saved} ? 1 : 0;
649         if ($task->{endtime}) {
650             if ($task->{status}) {
651                 $raw .= sprintf("$upid $saved %08X $task->{status}\n", $task->{endtime});
652             } else {
653                 $raw .= sprintf("$upid $saved %08X\n", $task->{endtime});
654             }
655         } else {
656             $raw .= "$upid $saved\n";
657         }
658     }
659
660     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
661 }
662
663 register_file('active', "/var/log/pve/tasks/active", 
664               \&read_active_workers,
665               \&write_active_workers);
666
667
668 my $bond_modes = { 'balance-rr' => 0,
669                    'active-backup' => 1,
670                    'balance-xor' => 2,
671                    'broadcast' => 3,
672                    '802.3ad' => 4,
673                    'balance-tlb' => 5,
674                    'balance-alb' => 6,
675                };
676
677 my $ovs_bond_modes = {
678     'active-backup' => 1,
679     'balance-slb' => 1,
680     'lacp-balance-slb' => 1,
681     'lacp-balance-tcp' => 1, 
682 };
683
684 #sub get_bond_modes {
685 #    return $bond_modes;
686 #}
687
688 my $parse_ovs_option = sub {
689     my ($data) = @_;
690
691     my $opts = {};
692     foreach my $kv (split (/\s+/, $data || '')) {
693         my ($k, $v) = split('=', $kv, 2);
694         $opts->{$k} = $v if $k && $v;
695     }
696     return $opts;
697 };
698
699 my $set_ovs_option = sub {
700     my ($d, %params) = @_;
701
702     my $opts = &$parse_ovs_option($d->{ovs_options});
703
704     foreach my $k (keys %params) {
705         my $v = $params{$k};
706         if ($v) {
707             $opts->{$k} = $v;
708         } else {
709             delete $opts->{$k};
710         }
711     }
712
713     my $res = [];
714     foreach my $k (keys %$opts) {
715         push @$res, "$k=$opts->{$k}";
716     }
717
718     if (my $new = join(' ', @$res)) {
719         $d->{ovs_options} = $new;
720         return $d->{ovs_options};
721     } else {
722         delete $d->{ovs_options};
723         return undef;
724     }
725 };
726
727 my $extract_ovs_option = sub {
728     my ($d, $name) = @_;
729
730     my $opts = &$parse_ovs_option($d->{ovs_options});
731
732     my $v = delete $opts->{$name};
733
734     my $res = [];
735     foreach my $k (keys %$opts) {
736         push @$res, "$k=$opts->{$k}";
737     }
738
739     if (my $new = join(' ', @$res)) {
740         $d->{ovs_options} = $new;
741     } else {
742         delete $d->{ovs_options};
743     }
744
745     return $v;
746 };
747
748 # config => {
749 #   ifaces => {
750 #     $ifname => {
751 #       <optional> exists => BOOL,
752 #       <optional> active => BOOL,
753 #       <optional> autostart => BOOL,
754 #       <auto> priority => INT,
755 #
756 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
757 #
758 #       families => ["inet", "inet6", ...],
759 #
760 #       method => "manual" | "static" | "dhcp" | ... ,
761 #       address => IP,
762 #       netmask => SUBNET,
763 #       broadcast => IP,
764 #       gateway => IP,
765 #       comments => [ "..." ],
766 #
767 #       method6 => "manual" | "static" | "dhcp" | ... ,
768 #       address6 => IP,
769 #       netmask6 => SUBNET,
770 #       gateway6 => IP,
771 #       comments6 => [ "..." ],
772 #
773 #       <known options>, # like bridge_ports, ovs_*
774 #
775 #       # extra/unknown options stored by-family:
776 #       options => { <inet options>... }
777 #       options6 => { <inet6 options>... }
778 #     }
779 #   },
780 #   options => [
781 #     # mappings end up here as well, as we don't need to understand them
782 #     [priority,line]
783 #   ]
784 # }
785 sub read_etc_network_interfaces {
786     my ($filename, $fh) = @_;
787
788     my $config = {};
789     my $ifaces = $config->{ifaces} = {};
790     my $options = $config->{options} = [];
791
792     my $line;
793
794     if (my $fd2 = IO::File->new("/proc/net/dev", "r")) {
795         while (defined ($line = <$fd2>)) {
796             if ($line =~ m/^\s*(eth\d+):.*/) {
797                 $ifaces->{$1}->{exists} = 1;
798             }
799         }
800         close($fd2);
801     }
802
803     # we try to keep order inside the file
804     my $priority = 2; # 1 is reserved for lo 
805
806     SECTION: while (defined ($line = <$fh>)) {
807         chomp ($line);
808         next if $line =~ m/^\s*#/;
809  
810         if ($line =~ m/^\s*auto\s+(.*)$/) {
811             my @aa = split (/\s+/, $1);
812
813             foreach my $a (@aa) {
814                 $ifaces->{$a}->{autostart} = 1;
815             }
816
817         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
818             my $i = $1;
819             my $family = $2;
820             my $f = { method => $3 }; # by family, merged to $d with a $suffix
821             (my $suffix = $family) =~ s/^inet//;
822
823             my $d = $ifaces->{$i};
824             $d->{priority} = $priority++ if !$d->{priority};
825             push @{$d->{families}}, $family;
826
827             while (defined ($line = <$fh>)) {
828                 chomp $line;
829                 if ($line =~ m/^\s*#(.*?)\s*$/) {
830                     # NOTE: we use 'comments' instead of 'comment' to 
831                     # avoid automatic utf8 conversion
832                     $f->{comments} = '' if !$f->{comments};
833                     $f->{comments} .= "$1\n";
834                 } elsif ($line =~ m/^\s*(?:iface\s
835                                           |mapping\s
836                                           |auto\s
837                                           |allow-
838                                           |source\s
839                                           |source-directory\s
840                                         )/x) {
841                     last;
842                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
843                     my $option = $1;
844                     my ($id, $value) = ($2, $3);
845                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
846                         $f->{$id} = $value;
847                     } elsif ($id eq 'ovs_type' || $id eq 'ovs_options'|| $id eq 'ovs_bridge' ||
848                              $id eq 'ovs_bonds' || $id eq 'ovs_ports') {
849                         $d->{$id} = $value;
850                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
851                         my $devs = {};
852                         foreach my $p (split (/\s+/, $value)) {
853                             next if $p eq 'none';
854                             $devs->{$p} = 1;
855                         }
856                         my $str = join (' ', sort keys %{$devs});
857                         if ($d->{$id}) {
858                             $d->{$id} .= ' ' . $str if $str;
859                         } else {
860                             $d->{$id} = $str || '';
861                         }
862                     } elsif ($id eq 'bridge_stp') {
863                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
864                             $d->{$id} = 'on';
865                         } else {
866                             $d->{$id} = 'off';
867                         }
868                     } elsif ($id eq 'bridge_fd') {
869                         $d->{$id} = $value;
870                     } elsif ($id eq 'bond_miimon') {
871                         $d->{$id} = $value;
872                     } elsif ($id eq 'bond_xmit_hash_policy') {
873                         $d->{$id} = $value;
874                     } elsif ($id eq 'bond_mode') {
875                         # always use names
876                         foreach my $bm (keys %$bond_modes) {
877                             my $id = $bond_modes->{$bm};
878                             if ($id eq $value) {
879                                 $value = $bm;
880                                 last;
881                             }
882                         }
883                         $d->{$id} = $value;
884                     } else {
885                         push @{$f->{options}}, $option;
886                     }
887                 } else {
888                     last;
889                 }
890             }
891             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
892             last SECTION if !defined($line);
893             redo SECTION;
894         } elsif ($line =~ /\w/) {
895             push @$options, [$priority++, $line];
896         }
897     }
898
899
900
901     if (!$ifaces->{lo}) {
902         $ifaces->{lo}->{priority} = 1;
903         $ifaces->{lo}->{method} = 'loopback';
904         $ifaces->{lo}->{type} = 'loopback';
905         $ifaces->{lo}->{autostart} = 1;
906     }
907
908     foreach my $iface (keys %$ifaces) {
909         my $d = $ifaces->{$iface};
910         if ($iface =~ m/^bond\d+$/) {
911             if (!$d->{ovs_type}) {
912                 $d->{type} = 'bond';
913             } elsif ($d->{ovs_type} eq 'OVSBond') {
914                 $d->{type} = $d->{ovs_type};
915                 # translate: ovs_options => bond_mode
916                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
917                 my $lacp = &$extract_ovs_option($d, 'lacp');
918                 if ($lacp && $lacp eq 'active') {
919                     if ($d->{'bond_mode'} eq 'balance-slb') {
920                         $d->{'bond_mode'} = 'lacp-balance-slb';
921                     }
922                 }
923                 # Note: balance-tcp needs lacp
924                 if ($d->{'bond_mode'} eq 'balance-tcp') {
925                     $d->{'bond_mode'} = 'lacp-balance-tcp';
926                 }
927                 my $tag = &$extract_ovs_option($d, 'tag');
928                 $d->{ovs_tag} = $tag if defined($tag);
929             } else {
930                 $d->{type} = 'unknown';
931             }
932         } elsif ($iface =~ m/^vmbr\d+$/) {
933             if (!$d->{ovs_type}) {
934                 $d->{type} = 'bridge';
935
936                 if (!defined ($d->{bridge_fd})) {
937                     $d->{bridge_fd} = 0;
938                 }
939                 if (!defined ($d->{bridge_stp})) {
940                     $d->{bridge_stp} = 'off';
941                 }
942             } elsif ($d->{ovs_type} eq 'OVSBridge') {
943                 $d->{type} = $d->{ovs_type};
944             } else {
945                 $d->{type} = 'unknown';
946             }
947         } elsif ($iface =~ m/^(\S+):\d+$/) {
948             $d->{type} = 'alias';
949             if (defined ($ifaces->{$1})) {
950                 $d->{exists} = $ifaces->{$1}->{exists};
951             } else {
952                 $ifaces->{$1}->{exists} = 0;
953                 $d->{exists} = 0;
954             }
955         } elsif ($iface =~ m/^eth\d+$/) {
956             if (!$d->{ovs_type}) {
957                 $d->{type} = 'eth';
958             } elsif ($d->{ovs_type} eq 'OVSPort') {
959                 $d->{type} = $d->{ovs_type};
960                 my $tag = &$extract_ovs_option($d, 'tag');
961                 $d->{ovs_tag} = $tag if defined($tag);
962             } else {
963                 $d->{type} = 'unknown';
964             }
965         } elsif ($iface =~ m/^lo$/) {
966             $d->{type} = 'loopback';
967         } else {
968             if (!$d->{ovs_type}) {
969                 $d->{type} = 'unknown';
970             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
971                 $d->{type} = $d->{ovs_type};
972                 my $tag = &$extract_ovs_option($d, 'tag');
973                 $d->{ovs_tag} = $tag if defined($tag);
974             }
975         }
976
977         $d->{method} = 'manual' if !$d->{method};
978         $d->{method6} = 'manual' if !$d->{method6};
979     }
980
981     if (my $fd2 = IO::File->new("/proc/net/if_inet6", "r")) {
982         while (defined ($line = <$fd2>)) {
983             if ($line =~ m/^[a-f0-9]{32}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+[a-f0-9]{2}\s+(\S+)$/) {
984                 $ifaces->{$1}->{active} = 1 if defined($ifaces->{$1});
985             }
986         }
987         close ($fd2);
988     }
989
990     return $config;
991 }
992
993 sub __interface_to_string {
994     my ($iface, $d, $family, $first_block) = @_;
995
996     (my $suffix = $family) =~ s/^inet//;
997
998     return '' if !($d && $d->{"method$suffix"});
999
1000     my $raw = '';
1001
1002     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1003     $raw .= "\taddress  " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1004     $raw .= "\tnetmask  " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1005     $raw .= "\tgateway  " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1006     $raw .= "\tbroadcast  " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1007
1008     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1009                  comments => 1, autostart => 1, options => 1,
1010                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1011                  method6 => 1, families => 1, options6 => 1,
1012                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1 };
1013
1014     if (!$first_block) {
1015         # not printing out options
1016     } elsif ($d->{type} eq 'bridge') {
1017
1018         my $ports = $d->{bridge_ports} || 'none';
1019         $raw .= "\tbridge_ports $ports\n";
1020         $done->{bridge_ports} = 1;
1021
1022         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1023         $raw .= "\tbridge_stp $v\n";
1024         $done->{bridge_stp} = 1;
1025
1026         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1027         $raw .= "\tbridge_fd $v\n";
1028         $done->{bridge_fd} = 1;
1029     
1030     } elsif ($d->{type} eq 'bond') {
1031
1032         my $slaves = $d->{slaves} || 'none';
1033         $raw .= "\tslaves $slaves\n";
1034         $done->{slaves} = 1;
1035
1036         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1037         $raw .= "\tbond_miimon $v\n";
1038         $done->{'bond_miimon'} = 1;
1039
1040         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1041         $raw .= "\tbond_mode $v\n";
1042         $done->{'bond_mode'} = 1;
1043
1044         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1045             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1046             $raw .= "\tbond_xmit_hash_policy $d->{'bond_xmit_hash_policy'}\n";
1047         }
1048         $done->{'bond_xmit_hash_policy'} = 1;
1049
1050     } elsif ($d->{type} eq 'OVSBridge') {
1051
1052         $raw .= "\tovs_type $d->{type}\n";
1053         $done->{ovs_type} = 1;
1054
1055         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1056         $done->{ovs_ports} = 1;
1057     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1058              $d->{type} eq 'OVSBond') {
1059
1060         $d->{autostart} = 0; # started by the bridge
1061
1062         if (defined($d->{ovs_tag})) {
1063             &$set_ovs_option($d, tag => $d->{ovs_tag});
1064         }
1065         $done->{ovs_tag} = 1;
1066
1067         if ($d->{type} eq 'OVSBond') {
1068
1069             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1070
1071             $ovs_bond_modes->{$d->{bond_mode}} ||
1072                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1073
1074             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1075                 &$set_ovs_option($d, lacp => 'active');
1076                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1077             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1078                 &$set_ovs_option($d, lacp => 'active');
1079                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1080             } else {
1081                 &$set_ovs_option($d, lacp => undef);
1082                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1083             }
1084             $done->{bond_mode} = 1;
1085
1086             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1087             $done->{ovs_bonds} = 1;
1088         }
1089
1090         $raw .= "\tovs_type $d->{type}\n";
1091         $done->{ovs_type} = 1;
1092
1093         if ($d->{ovs_bridge}) {
1094             $raw = "allow-$d->{ovs_bridge} $iface\n$raw";
1095             $raw .= "\tovs_bridge $d->{ovs_bridge}\n";
1096             $done->{ovs_bridge} = 1;
1097         }
1098     }
1099
1100     if ($first_block) {
1101         # print other settings
1102         foreach my $k (keys %$d) {
1103            next if $done->{$k};
1104            next if !$d->{$k};
1105            $raw .= "\t$k $d->{$k}\n";
1106         }
1107     }
1108
1109     foreach my $option (@{$d->{"options$suffix"}}) {
1110         $raw .= "\t$option\n";
1111     }
1112
1113     # add comments
1114     my $comments = $d->{"comments$suffix"} || '';
1115     foreach my $cl (split(/\n/, $comments)) {
1116         $raw .= "#$cl\n";
1117     }
1118
1119     $raw .= "\n";
1120
1121     return $raw;
1122 }
1123
1124 sub write_etc_network_interfaces {
1125     my ($filename, $fh, $config) = @_;
1126
1127     my $ifaces = $config->{ifaces};
1128     my @options = @{$config->{options}};
1129
1130     my $used_ports = {};
1131
1132     foreach my $iface (keys %$ifaces) {
1133         my $d = $ifaces->{$iface};
1134
1135         my $ports = '';
1136         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1137             $ports .= " $d->{$k}" if $d->{$k};
1138         }
1139
1140         foreach my $p (PVE::Tools::split_list($ports)) {
1141             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1142                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1143             $used_ports->{$p} = $iface;
1144         }
1145     }
1146
1147     # delete unused OVS ports
1148     foreach my $iface (keys %$ifaces) {
1149         my $d = $ifaces->{$iface};
1150         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' || 
1151             $d->{type} eq 'OVSBond') {
1152             my $brname = $used_ports->{$iface};
1153             if (!$brname || !$ifaces->{$brname}) { 
1154                 delete $ifaces->{$iface}; 
1155                 next;
1156             }
1157             my $bd = $ifaces->{$brname};
1158             if ($bd->{type} ne 'OVSBridge') {
1159                 delete $ifaces->{$iface};
1160                 next;
1161             }
1162         }
1163     }
1164
1165     # create OVS bridge ports
1166     foreach my $iface (keys %$ifaces) {
1167         my $d = $ifaces->{$iface};
1168         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1169             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1170                 my $n = $ifaces->{$p};
1171                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1172                     if !$n;
1173                 if ($n->{type} eq 'eth') {
1174                     $n->{type} = 'OVSPort';
1175                     $n->{ovs_bridge} = $iface;              
1176                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1177                     $n->{type} eq 'OVSIntPort') {
1178                     $n->{ovs_bridge} = $iface;
1179                 } else {
1180                     die "interface '$p' is not defined as OVS port/bond\n";
1181                 }
1182             }
1183         }
1184     }
1185
1186     # check OVS bond ports
1187     foreach my $iface (keys %$ifaces) {
1188         my $d = $ifaces->{$iface};
1189         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1190             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1191                 my $n = $ifaces->{$p};
1192                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1193                     if !$n;
1194                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1195                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1196             }
1197         }
1198     }
1199
1200     my $raw = "# network interface settings\n";
1201
1202     my $printed = {};
1203
1204     my $if_type_hash = {
1205         unknown => 0,
1206         loopback => 10,
1207         eth => 20,
1208         bond => 30,
1209         bridge => 40,
1210    };
1211
1212     my $lookup_type_prio = sub {
1213         my $iface = shift;
1214
1215         my $alias = 0;
1216         if ($iface =~ m/^(\S+):\d+$/) {
1217             $iface = $1;
1218             $alias = 1;
1219         }
1220
1221         my $pri;
1222         if ($iface eq 'lo') {
1223             $pri = $if_type_hash->{loopback};
1224         } elsif ($iface =~ m/^eth\d+$/) {
1225             $pri = $if_type_hash->{eth} + $alias;
1226         } elsif ($iface =~ m/^bond\d+$/) {
1227             $pri = $if_type_hash->{bond} + $alias;
1228         } elsif ($iface =~ m/^vmbr\d+$/) {
1229             $pri = $if_type_hash->{bridge} + $alias;
1230         }
1231
1232         return $pri || ($if_type_hash->{unknown} + $alias);
1233     };
1234
1235     foreach my $iface (sort {
1236         my $ref1 = $ifaces->{$a};
1237         my $ref2 = $ifaces->{$b};
1238         my $p1 = &$lookup_type_prio($a);
1239         my $p2 = &$lookup_type_prio($b);
1240
1241         return $p1 <=> $p2 if $p1 != $p2;
1242
1243         $p1 = $ref1->{priority} || 100000;
1244         $p2 = $ref2->{priority} || 100000;
1245
1246         return $p1 <=> $p2 if $p1 != $p2;
1247
1248         return $a cmp $b;
1249                        } keys %$ifaces) {
1250
1251         my $d = $ifaces->{$iface};
1252
1253         next if $printed->{$iface};
1254
1255         if (@options && $options[0]->[0] < $d->{priority}) {
1256             do {
1257                 $raw .= (shift @options)->[1] . "\n";
1258             } while (@options && $options[0]->[0] < $d->{priority});
1259             $raw .= "\n";
1260         }
1261
1262         $printed->{$iface} = 1;
1263         $raw .= "auto $iface\n" if $d->{autostart};
1264         my $i = 0; # some options should be printed only once
1265         $raw .= __interface_to_string($iface, $d, $_, !$i++) foreach @{$d->{families}};
1266     }
1267
1268     $raw .= $_->[1] . "\n" foreach @options;
1269
1270     PVE::Tools::safe_print($filename, $fh, $raw);
1271 }
1272
1273 register_file('interfaces', "/etc/network/interfaces",
1274               \&read_etc_network_interfaces,
1275               \&write_etc_network_interfaces);
1276
1277
1278 sub read_iscsi_initiatorname {
1279     my ($filename, $fd) = @_;
1280
1281     while (defined(my $line = <$fd>)) {
1282         if ($line =~ m/^InitiatorName=(\S+)$/) {
1283             return $1;
1284         }
1285     }
1286
1287     return 'undefined';
1288 }
1289
1290 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",  
1291               \&read_iscsi_initiatorname);
1292
1293 sub read_apt_auth {
1294     my ($filename, $fd) = @_;
1295
1296     local $/;
1297
1298     my $raw = defined($fd) ? <$fd> : '';
1299
1300     $raw =~ s/^\s+//;
1301
1302  
1303     my @tokens = split(/\s+/, $raw);
1304
1305     my $data = {};
1306
1307     my $machine;
1308     while (defined(my $tok = shift @tokens)) {
1309
1310         $machine = shift @tokens if $tok eq 'machine';
1311         next if !$machine;
1312         $data->{$machine} = {} if !$data->{$machine};
1313
1314         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1315         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1316     };
1317
1318     return $data;
1319 }
1320
1321 my $format_apt_auth_data = sub {
1322     my $data = shift;
1323
1324     my $raw = '';
1325
1326     foreach my $machine (sort keys %$data) {
1327         my $d = $data->{$machine};
1328         $raw .= "machine $machine\n";
1329         $raw .= " login $d->{login}\n" if $d->{login};
1330         $raw .= " password $d->{password}\n" if $d->{password};
1331         $raw .= "\n";
1332     }
1333
1334     return $raw;
1335 };
1336
1337 sub write_apt_auth {
1338     my ($filename, $fh, $data) = @_;
1339
1340     my $raw = &$format_apt_auth_data($data);
1341
1342     die "write failed: $!" unless print $fh "$raw\n";
1343    
1344     return $data;
1345 }
1346
1347 sub update_apt_auth {
1348     my ($filename, $fh, $data) = @_;
1349
1350     my $orig = read_apt_auth($filename, $fh);
1351
1352     foreach my $machine (keys %$data) {
1353         $orig->{$machine} = $data->{$machine};
1354     }
1355
1356     return &$format_apt_auth_data($orig);
1357 }
1358
1359 register_file('apt-auth', "/etc/apt/auth.conf",  
1360               \&read_apt_auth, \&write_apt_auth,
1361               \&update_apt_auth, perm => 0640);
1362
1363 1;