src/PVE/INotify.pm

   1 package PVE::INotify;
   2
   3 # todo: maybe we do not need update_file() ?
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::File;
  10 use IO::Dir;
  11 use File::stat;
  12 use File::Basename;
  13 use Fcntl qw(:DEFAULT :flock);
  14 use PVE::SafeSyslog;
  15 use PVE::Exception qw(raise_param_exc);
  16 use PVE::Network;
  17 use PVE::Tools;
  18 use PVE::ProcFSTools;
  19 use PVE::JSONSchema;
  20 use Clone qw(clone);
  21 use Linux::Inotify2;
  22 use base 'Exporter';
  23 use JSON;
  24 use Digest::SHA;
  25 use Encode qw(encode decode);
  26
  27 our @EXPORT_OK = qw(read_file write_file register_file);
  28
  29 my $ccache;
  30 my $ccachemap;
  31 my $ccacheregex;
  32 my $inotify;
  33 my $inotify_pid = 0;
  34 my $versions;
  35 my $shadowfiles = {
  36     '/etc/network/interfaces' => '/etc/network/interfaces.new',
  37 };
  38
  39 # to enable cached operation, you need to call 'inotify_init'
  40 # inotify handles are a limited resource, so use with care (only
  41 # enable the cache if you really need it)
  42
  43 # Note: please close the inotify handle after you fork
  44
  45 sub ccache_default_writer {
  46     my ($filename, $data) = @_;
  47
  48     die "undefined config writer for '$filename' :ERROR";
  49 }
  50
  51 sub ccache_default_parser {
  52     my ($filename, $srcfd) = @_;
  53
  54     die "undefined config reader for '$filename' :ERROR";
  55 }
  56
  57 sub ccache_compute_diff {
  58     my ($filename, $shadow) = @_;
  59
  60     my $diff = '';
  61
  62     my $cmd = ['/usr/bin/diff', '-b', '-N', '-u', $filename, $shadow];
  63     PVE::Tools::run_command($cmd, noerr => 1, outfunc => sub {
  64         my ($line) = @_;
  65         $diff .= decode('UTF-8', $line) . "\n";
  66     });
  67
  68     $diff = undef if !$diff;
  69
  70     return $diff;
  71 }
  72
  73 sub ccache_info {
  74     my ($filename) = @_;
  75
  76     foreach my $uid (keys %$ccacheregex) {
  77         my $ccinfo = $ccacheregex->{$uid};
  78         my $dir = $ccinfo->{dir};
  79         my $regex = $ccinfo->{regex};
  80         if ($filename =~ m|^$dir/+$regex$|) {
  81             if (!$ccache->{$filename}) {
  82                 my $cp = {};
  83                 while (my ($k, $v) = each %$ccinfo) {
  84                     $cp->{$k} = $v;
  85                 }
  86                 $ccache->{$filename} = $cp;
  87             }
  88             return ($ccache->{$filename}, $filename);
  89         }
  90     }
  91
  92     $filename = $ccachemap->{$filename} if defined ($ccachemap->{$filename});
  93
  94     die "file '$filename' not added :ERROR" if !defined ($ccache->{$filename});
  95
  96     return ($ccache->{$filename}, $filename);
  97 }
  98
  99 sub write_file {
 100     my ($fileid, $data, $full) = @_;
 101
 102     my ($ccinfo, $filename) = ccache_info($fileid);
 103
 104     my $writer = $ccinfo->{writer};
 105
 106     my $realname = $filename;
 107
 108     my $shadow;
 109     if ($shadow = $shadowfiles->{$filename}) {
 110         $realname = $shadow;
 111     }
 112
 113     my $perm = $ccinfo->{perm} || 0644;
 114
 115     my $tmpname = "$realname.tmp.$$";
 116
 117     my $res;
 118     eval {
 119         my $fh = IO::File->new($tmpname, O_WRONLY|O_CREAT, $perm);
 120         die "unable to open file '$tmpname' - $!\n" if !$fh;
 121
 122         $res = &$writer($filename, $fh, $data);
 123
 124         die "closing file '$tmpname' failed - $!\n" unless close $fh;
 125     };
 126     my $err = $@;
 127
 128     $ccinfo->{version} = undef;
 129
 130     if ($err) {
 131         unlink $tmpname;
 132         die $err;
 133     }
 134
 135     if (!rename($tmpname, $realname)) {
 136         my $msg = "close (rename) atomic file '$filename' failed: $!\n";
 137         unlink $tmpname;
 138         die $msg;
 139     }
 140
 141     my $diff;
 142     if ($shadow && $full) {
 143         $diff = ccache_compute_diff ($filename, $shadow);
 144     }
 145
 146     if ($full) {
 147         return { data => $res, changes => $diff };
 148     }
 149
 150     return $res;
 151 }
 152
 153 sub update_file {
 154     my ($fileid, $data, @args) = @_;
 155
 156     my ($ccinfo, $filename) = ccache_info($fileid);
 157
 158     my $update = $ccinfo->{update};
 159
 160     die "unable to update/merge data" if !$update;
 161
 162     my $lkfn = "$filename.lock";
 163
 164     my $timeout = 10;
 165
 166     my $fd;
 167
 168     my $code = sub {
 169
 170         $fd = IO::File->new ($filename, "r");
 171
 172         my $new = &$update($filename, $fd, $data, @args);
 173
 174         if (defined($new)) {
 175             PVE::Tools::file_set_contents($filename, $new, $ccinfo->{perm});
 176         } else {
 177             unlink $filename;
 178         }
 179     };
 180
 181     PVE::Tools::lock_file($lkfn, $timeout, $code);
 182     my $err = $@;
 183
 184     close($fd) if defined($fd);
 185
 186     die $err if $err;
 187
 188     return undef;
 189 }
 190
 191 sub discard_changes {
 192     my ($fileid, $full) = @_;
 193
 194     my ($ccinfo, $filename) = ccache_info($fileid);
 195
 196     if (my $copy = $shadowfiles->{$filename}) {
 197         unlink $copy;
 198     }
 199
 200     return read_file ($filename, $full);
 201 }
 202
 203 sub poll_changes {
 204     my ($filename) = @_;
 205
 206     poll() if $inotify; # read new inotify events
 207
 208     $versions->{$filename} = 0 if !defined ($versions->{$filename});
 209
 210     return $versions->{$filename};
 211 }
 212
 213 sub read_file {
 214     my ($fileid, $full) = @_;
 215
 216     my $parser;
 217
 218     my ($ccinfo, $filename) = ccache_info($fileid);
 219
 220     $parser = $ccinfo->{parser};
 221
 222     my $fd;
 223     my $shadow;
 224
 225     my $cver = poll_changes($filename);
 226
 227     if (my $copy = $shadowfiles->{$filename}) {
 228         if ($fd = IO::File->new ($copy, "r")) {
 229             $shadow = $copy;
 230         } else {
 231             $fd = IO::File->new ($filename, "r");
 232         }
 233     } else {
 234         $fd = IO::File->new ($filename, "r");
 235     }
 236
 237     my $acp = $ccinfo->{always_call_parser};
 238
 239     if (!$fd) {
 240         $ccinfo->{version} = undef;
 241         $ccinfo->{data} = undef;
 242         $ccinfo->{diff} = undef;
 243         return undef if !$acp;
 244     }
 245
 246     my $noclone = $ccinfo->{noclone};
 247
 248     # file unchanged?
 249     if (!$ccinfo->{nocache} &&
 250         $inotify && $cver &&
 251         defined ($ccinfo->{data}) &&
 252         defined ($ccinfo->{version}) &&
 253         ($ccinfo->{readonce} ||
 254          ($ccinfo->{version} == $cver))) {
 255
 256         my $ret;
 257         if (!$noclone && ref ($ccinfo->{data})) {
 258             $ret->{data} = clone ($ccinfo->{data});
 259         } else {
 260             $ret->{data} = $ccinfo->{data};
 261         }
 262         $ret->{changes} = $ccinfo->{diff};
 263
 264         return $full ? $ret : $ret->{data};
 265     }
 266
 267     my $diff;
 268
 269     if ($shadow) {
 270         $diff = ccache_compute_diff ($filename, $shadow);
 271     }
 272
 273     my $res = &$parser($filename, $fd);
 274
 275     if (!$ccinfo->{nocache}) {
 276         $ccinfo->{version} = $cver;
 277     }
 278
 279     # we cache data with references, so we always need to
 280     # clone this data. Else the original data may get
 281     # modified.
 282     $ccinfo->{data} = $res;
 283
 284     # also store diff
 285     $ccinfo->{diff} = $diff;
 286
 287     my $ret;
 288     if (!$noclone && ref ($ccinfo->{data})) {
 289         $ret->{data} = clone ($ccinfo->{data});
 290     } else {
 291         $ret->{data} = $ccinfo->{data};
 292     }
 293     $ret->{changes} = $ccinfo->{diff};
 294
 295     return $full ? $ret : $ret->{data};
 296 }
 297
 298 sub parse_ccache_options {
 299     my ($ccinfo, %options) = @_;
 300
 301     foreach my $opt (keys %options) {
 302         my $v = $options{$opt};
 303         if ($opt eq 'readonce') {
 304             $ccinfo->{$opt} = $v;
 305         } elsif ($opt eq 'nocache') {
 306             $ccinfo->{$opt} = $v;
 307         } elsif ($opt eq 'shadow') {
 308             $ccinfo->{$opt} = $v;
 309         } elsif ($opt eq 'perm') {
 310             $ccinfo->{$opt} = $v;
 311         } elsif ($opt eq 'noclone') {
 312             # noclone flag for large read-only data chunks like aplinfo
 313             $ccinfo->{$opt} = $v;
 314         } elsif ($opt eq 'always_call_parser') {
 315             # when set, we call parser even when the file does not exist.
 316             # this allows the parser to return some default
 317             $ccinfo->{$opt} = $v;
 318         } else {
 319             die "internal error - unsupported option '$opt'";
 320         }
 321     }
 322 }
 323
 324 sub register_file {
 325     my ($id, $filename, $parser, $writer, $update, %options) = @_;
 326
 327     die "can't register file '$filename' after inotify_init" if $inotify;
 328
 329     die "file '$filename' already added :ERROR" if defined ($ccache->{$filename});
 330     die "ID '$id' already used :ERROR" if defined ($ccachemap->{$id});
 331
 332     my $ccinfo = {};
 333
 334     $ccinfo->{id} = $id;
 335     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 336     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 337     $ccinfo->{update} = $update;
 338
 339     parse_ccache_options($ccinfo, %options);
 340
 341     if ($options{shadow}) {
 342         $shadowfiles->{$filename} = $options{shadow};
 343     }
 344
 345     $ccachemap->{$id} = $filename;
 346     $ccache->{$filename} = $ccinfo;
 347 }
 348
 349 sub register_regex {
 350     my ($dir, $regex, $parser, $writer, $update, %options) = @_;
 351
 352     die "can't register regex after inotify_init" if $inotify;
 353
 354     my $uid = "$dir/$regex";
 355     die "regular expression '$uid' already added :ERROR" if defined ($ccacheregex->{$uid});
 356
 357     my $ccinfo = {};
 358
 359     $ccinfo->{dir} = $dir;
 360     $ccinfo->{regex} = $regex;
 361     $ccinfo->{parser} = $parser || \&ccache_default_parser;
 362     $ccinfo->{writer} = $writer || \&ccache_default_writer;
 363     $ccinfo->{update} = $update;
 364
 365     parse_ccache_options($ccinfo, %options);
 366
 367     $ccacheregex->{$uid} = $ccinfo;
 368 }
 369
 370 sub poll {
 371     return if !$inotify;
 372
 373     if ($inotify_pid != $$) {
 374         syslog ('err', "got inotify poll request in wrong process - disabling inotify");
 375         $inotify = undef;
 376     } else {
 377         1 while $inotify && $inotify->poll;
 378     }
 379 }
 380
 381 sub flushcache {
 382     foreach my $filename (keys %$ccache) {
 383         $ccache->{$filename}->{version} = undef;
 384         $ccache->{$filename}->{data} = undef;
 385         $ccache->{$filename}->{diff} = undef;
 386     }
 387 }
 388
 389 sub inotify_close {
 390     $inotify = undef;
 391 }
 392
 393 sub inotify_init {
 394
 395     die "only one inotify instance allowed" if $inotify;
 396
 397     $inotify =  Linux::Inotify2->new()
 398         || die "Unable to create new inotify object: $!";
 399
 400     $inotify->blocking (0);
 401
 402     $versions = {};
 403
 404     my $dirhash = {};
 405     foreach my $fn (keys %$ccache) {
 406         my $dir = dirname ($fn);
 407         my $base = basename ($fn);
 408
 409         $dirhash->{$dir}->{$base} = $fn;
 410
 411         if (my $sf = $shadowfiles->{$fn}) {
 412             $base = basename ($sf);
 413             $dir = dirname ($sf);
 414             $dirhash->{$dir}->{$base} = $fn; # change version of original file!
 415         }
 416     }
 417
 418     foreach my $uid (keys %$ccacheregex) {
 419         my $ccinfo = $ccacheregex->{$uid};
 420         $dirhash->{$ccinfo->{dir}}->{_regex} = 1;
 421     }
 422
 423     $inotify_pid = $$;
 424
 425     foreach my $dir (keys %$dirhash) {
 426
 427         my $evlist = IN_MODIFY|IN_ATTRIB|IN_MOVED_FROM|IN_MOVED_TO|IN_DELETE|IN_CREATE;
 428         $inotify->watch ($dir, $evlist, sub {
 429             my $e = shift;
 430             my $name = $e->name;
 431
 432             if ($inotify_pid != $$) {
 433                 syslog ('err', "got inotify event in wrong process");
 434             }
 435
 436             if ($e->IN_ISDIR || !$name) {
 437                 return;
 438             }
 439
 440             if ($e->IN_Q_OVERFLOW) {
 441                 syslog ('info', "got inotify overflow - flushing cache");
 442                 flushcache();
 443                 return;
 444             }
 445
 446             if ($e->IN_UNMOUNT) {
 447                 syslog ('err', "got 'unmount' event on '$name' - disabling inotify");
 448                 $inotify = undef;
 449             }
 450             if ($e->IN_IGNORED) {
 451                 syslog ('err', "got 'ignored' event on '$name' - disabling inotify");
 452                 $inotify = undef;
 453             }
 454
 455             if ($dirhash->{$dir}->{_regex}) {
 456                 foreach my $uid (keys %$ccacheregex) {
 457                     my $ccinfo = $ccacheregex->{$uid};
 458                     next if $dir ne $ccinfo->{dir};
 459                     my $regex = $ccinfo->{regex};
 460                     if ($regex && ($name =~ m|^$regex$|)) {
 461
 462                         my $fn = "$dir/$name";
 463                         $versions->{$fn}++;
 464                         #print "VERSION:$fn:$versions->{$fn}\n";
 465                     }
 466                 }
 467             } elsif (my $fn = $dirhash->{$dir}->{$name}) {
 468
 469                 $versions->{$fn}++;
 470                 #print "VERSION:$fn:$versions->{$fn}\n";
 471             }
 472         });
 473     }
 474
 475     foreach my $dir (keys %$dirhash) {
 476         foreach my $name (keys %{$dirhash->{$dir}}) {
 477             if ($name eq '_regex') {
 478                 foreach my $uid (keys %$ccacheregex) {
 479                     my $ccinfo = $ccacheregex->{$uid};
 480                     next if $dir ne $ccinfo->{dir};
 481                     my $re = $ccinfo->{regex};
 482                     if (my $fd = IO::Dir->new ($dir)) {
 483                         while (defined(my $de = $fd->read)) {
 484                             if ($de =~ m/^$re$/) {
 485                                 my $fn = "$dir/$de";
 486                                 $versions->{$fn}++; # init with version
 487                                 #print "init:$fn:$versions->{$fn}\n";
 488                             }
 489                         }
 490                     }
 491                 }
 492             } else {
 493                 my $fn = $dirhash->{$dir}->{$name};
 494                 $versions->{$fn}++; # init with version
 495                 #print "init:$fn:$versions->{$fn}\n";
 496             }
 497         }
 498     }
 499 }
 500
 501 my $cached_nodename;
 502
 503 sub nodename {
 504
 505     return $cached_nodename if $cached_nodename;
 506
 507     my ($sysname, $nodename) = POSIX::uname();
 508
 509     $nodename =~ s/\..*$//; # strip domain part, if any
 510
 511     die "unable to read node name\n" if !$nodename;
 512
 513     $cached_nodename = $nodename;
 514
 515     return $cached_nodename;
 516 }
 517
 518 sub read_etc_hostname {
 519     my ($filename, $fd) = @_;
 520
 521     my $hostname = <$fd>;
 522
 523     chomp $hostname;
 524
 525     $hostname =~ s/\..*$//; # strip domain part, if any
 526
 527     return $hostname;
 528 }
 529
 530 sub write_etc_hostname {
 531     my ($filename, $fh, $hostname) = @_;
 532
 533     die "write failed: $!" unless print $fh "$hostname\n";
 534
 535     return $hostname;
 536 }
 537
 538 register_file('hostname', "/etc/hostname",
 539               \&read_etc_hostname,
 540               \&write_etc_hostname);
 541
 542 sub read_etc_hosts {
 543     my ($filename, $fh) = @_;
 544
 545     my $raw = '';
 546     my $data = '';
 547
 548     while (my $line = <$fh>) {
 549         $raw .= $line;
 550         if ($line =~ m/^\s*#/) {
 551             $line = decode('UTF-8', $line);
 552         }
 553         $data .= $line;
 554     }
 555
 556     return {
 557         digest => Digest::SHA::sha1_hex($raw),
 558         data => $data,
 559     }
 560 }
 561
 562 sub write_etc_hosts {
 563     my ($filename, $fh, $hosts, @args) = @_;
 564
 565     # check validity of ips/names
 566     for my $line (split("\n", $hosts)) {
 567         next if $line =~ m/^\s*#/; # comments
 568         next if $line =~ m/^\s*$/; # whitespace/empty lines
 569
 570         my ($ip, @names) = split(/\s+/, $line);
 571
 572         raise_param_exc({ 'data' => "Invalid IP '$ip'" })
 573             if $ip !~ m/^$PVE::Tools::IPRE$/;
 574
 575         for my $name (@names) {
 576             raise_param_exc({ 'data' => "Invalid Hostname '$name'" })
 577                 if $name !~ m/^[.\-a-zA-Z0-9]+$/;
 578         }
 579     }
 580
 581     die "write failed: $!" if !print $fh encode('UTF-8', $hosts);
 582
 583     return $hosts;
 584 }
 585
 586 register_file('etchosts', "/etc/hosts",
 587               \&read_etc_hosts,
 588               \&write_etc_hosts);
 589
 590 sub read_etc_resolv_conf {
 591     my ($filename, $fh) = @_;
 592
 593     my $res = {};
 594
 595     my $nscount = 0;
 596     while (my $line = <$fh>) {
 597         chomp $line;
 598         if ($line =~ m/^(search|domain)\s+(\S+)\s*/) {
 599             $res->{search} = $2;
 600         } elsif ($line =~ m/^\s*nameserver\s+($PVE::Tools::IPRE)\s*/) {
 601             $nscount++;
 602             if ($nscount <= 3) {
 603                 $res->{"dns$nscount"} = $1;
 604             }
 605         }
 606     }
 607
 608     return $res;
 609 }
 610
 611 sub update_etc_resolv_conf {
 612     my ($filename, $fh, $resolv, @args) = @_;
 613
 614     my $data = "";
 615
 616     $data = "search $resolv->{search}\n"
 617         if $resolv->{search};
 618
 619     my $written = {};
 620     foreach my $k ("dns1", "dns2", "dns3") {
 621         my $ns = $resolv->{$k};
 622         if ($ns && $ns ne '0.0.0.0' && !$written->{$ns}) {
 623             $written->{$ns} = 1;
 624             $data .= "nameserver $ns\n";
 625         }
 626     }
 627
 628     while (my $line = <$fh>) {
 629         next if $line =~ m/^(search|domain|nameserver)\s+/;
 630         $data .= $line
 631     }
 632
 633     return $data;
 634 }
 635
 636 register_file('resolvconf', "/etc/resolv.conf",
 637               \&read_etc_resolv_conf, undef,
 638               \&update_etc_resolv_conf);
 639
 640 sub read_etc_timezone {
 641     my ($filename, $fd) = @_;
 642
 643     my $timezone = <$fd>;
 644
 645     chomp $timezone;
 646
 647     return $timezone;
 648 }
 649
 650 sub write_etc_timezone {
 651     my ($filename, $fh, $timezone) = @_;
 652
 653     my $tzinfo = "/usr/share/zoneinfo/$timezone";
 654
 655     raise_param_exc({ 'timezone' => "No such timezone" })
 656         if (! -f $tzinfo);
 657
 658     ($timezone) = $timezone =~ m/^(.*)$/; # untaint
 659
 660     print $fh "$timezone\n";
 661
 662     unlink ("/etc/localtime");
 663     symlink ("/usr/share/zoneinfo/$timezone", "/etc/localtime");
 664
 665 }
 666
 667 register_file('timezone', "/etc/timezone",
 668               \&read_etc_timezone,
 669               \&write_etc_timezone);
 670
 671 sub read_active_workers {
 672     my ($filename, $fh) = @_;
 673
 674     return [] if !$fh;
 675
 676     my $res = [];
 677     while (defined (my $line = <$fh>)) {
 678         if ($line =~ m/^(\S+)\s(0|1)(\s([0-9A-Za-z]{8})(\s(\s*\S.*))?)?$/) {
 679             my $upid = $1;
 680             my $saved = $2;
 681             my $endtime = $4;
 682             my $status = $6;
 683             if ((my $task = PVE::Tools::upid_decode($upid, 1))) {
 684                 $task->{upid} = $upid;
 685                 $task->{saved} = $saved;
 686                 $task->{endtime} = hex($endtime) if $endtime;
 687                 $task->{status} = $status if $status;
 688                 push @$res, $task;
 689             }
 690         } else {
 691             warn "unable to parse line: $line";
 692         }
 693     }
 694
 695     return $res;
 696
 697 }
 698
 699 sub write_active_workers {
 700     my ($filename, $fh, $tasklist) = @_;
 701
 702     my $raw = '';
 703     foreach my $task (@$tasklist) {
 704         my $upid = $task->{upid};
 705         my $saved = $task->{saved} ? 1 : 0;
 706         if ($task->{endtime}) {
 707             if ($task->{status}) {
 708                 $raw .= sprintf("%s %s %08X %s\n", $upid, $saved, $task->{endtime}, $task->{status});
 709             } else {
 710                 $raw .= sprintf("%s %s %08X\n", $upid, $saved, $task->{endtime});
 711             }
 712         } else {
 713             $raw .= "$upid $saved\n";
 714         }
 715     }
 716
 717     PVE::Tools::safe_print($filename, $fh, $raw) if $raw;
 718 }
 719
 720 register_file('active', "/var/log/pve/tasks/active",
 721               \&read_active_workers,
 722               \&write_active_workers);
 723
 724
 725 our $bond_modes = { 'balance-rr' => 0,
 726                    'active-backup' => 1,
 727                    'balance-xor' => 2,
 728                    'broadcast' => 3,
 729                    '802.3ad' => 4,
 730                    'balance-tlb' => 5,
 731                    'balance-alb' => 6,
 732                };
 733
 734 my $ovs_bond_modes = {
 735     'active-backup' => 1,
 736     'balance-slb' => 1,
 737     'lacp-balance-slb' => 1,
 738     'lacp-balance-tcp' => 1,
 739 };
 740
 741 #sub get_bond_modes {
 742 #    return $bond_modes;
 743 #}
 744
 745 my $parse_ovs_option = sub {
 746     my ($data) = @_;
 747
 748     my $opts = {};
 749     foreach my $kv (split (/\s+/, $data || '')) {
 750         my ($k, $v) = split('=', $kv, 2);
 751         $opts->{$k} = $v if $k && $v;
 752     }
 753     return $opts;
 754 };
 755
 756 my $set_ovs_option = sub {
 757     my ($d, %params) = @_;
 758
 759     my $opts = &$parse_ovs_option($d->{ovs_options});
 760
 761     foreach my $k (keys %params) {
 762         my $v = $params{$k};
 763         if ($v) {
 764             $opts->{$k} = $v;
 765         } else {
 766             delete $opts->{$k};
 767         }
 768     }
 769
 770     my $res = [];
 771     foreach my $k (keys %$opts) {
 772         push @$res, "$k=$opts->{$k}";
 773     }
 774
 775     if (my $new = join(' ', @$res)) {
 776         $d->{ovs_options} = $new;
 777         return $d->{ovs_options};
 778     } else {
 779         delete $d->{ovs_options};
 780         return undef;
 781     }
 782 };
 783
 784 my $extract_ovs_option = sub {
 785     my ($d, $name) = @_;
 786
 787     my $opts = &$parse_ovs_option($d->{ovs_options});
 788
 789     my $v = delete $opts->{$name};
 790
 791     my $res = [];
 792     foreach my $k (keys %$opts) {
 793         push @$res, "$k=$opts->{$k}";
 794     }
 795
 796     if (my $new = join(' ', @$res)) {
 797         $d->{ovs_options} = $new;
 798     } else {
 799         delete $d->{ovs_options};
 800     }
 801
 802     return $v;
 803 };
 804
 805 my $check_mtu = sub {
 806     my ($ifaces, $parent, $child) = @_;
 807
 808     die "check mtu - missing parent interface\n" if !$parent;
 809     die "check mtu - missing child interface\n" if !$child;
 810
 811     my $cmtu = $ifaces->{$child}->{mtu};
 812     return if !$cmtu;
 813
 814     my $parentdata = $ifaces->{$parent};
 815     my $pmtu = $parentdata->{mtu};
 816     $pmtu = $cmtu if $parentdata->{type} eq 'bond' && !$pmtu;
 817     $pmtu = 1500 if !$pmtu;
 818
 819     die "interface '$parent' - mtu $pmtu is lower than '$child' - mtu $cmtu\n"
 820         if $pmtu < $cmtu;
 821 };
 822
 823 # config => {
 824 #   ifaces => {
 825 #     $ifname => {
 826 #       <optional> exists => BOOL,
 827 #       <optional> active => BOOL,
 828 #       <optional> autostart => BOOL,
 829 #       <auto> priority => INT,
 830 #
 831 #       type => "eth" | "bridge" | "bond" | "loopback" | "OVS*" | ... ,
 832 #
 833 #       families => ["inet", "inet6", ...],
 834 #
 835 #       method => "manual" | "static" | "dhcp" | ... ,
 836 #       address => IP,
 837 #       netmask => SUBNET,
 838 #       broadcast => IP,
 839 #       gateway => IP,
 840 #       comments => [ "..." ],
 841 #
 842 #       method6 => "manual" | "static" | "dhcp" | ... ,
 843 #       address6 => IP,
 844 #       netmask6 => SUBNET,
 845 #       gateway6 => IP,
 846 #       comments6 => [ "..." ],
 847 #
 848 #       <known options>, # like bridge_ports, ovs_*
 849 #
 850 #       # extra/unknown options stored by-family:
 851 #       options => { <inet options>... }
 852 #       options6 => { <inet6 options>... }
 853 #     }
 854 #   },
 855 #   options => [
 856 #     # mappings end up here as well, as we don't need to understand them
 857 #     [priority,line]
 858 #   ]
 859 # }
 860 sub read_etc_network_interfaces {
 861     my ($filename, $fh) = @_;
 862     my $proc_net_dev = IO::File->new('/proc/net/dev', 'r');
 863     my $active = PVE::ProcFSTools::get_active_network_interfaces();
 864     return __read_etc_network_interfaces($fh, $proc_net_dev, $active);
 865 }
 866
 867 sub __read_etc_network_interfaces {
 868     my ($fh, $proc_net_dev, $active_ifaces) = @_;
 869
 870     my $config = {};
 871     my $ifaces = $config->{ifaces} = {};
 872     my $options = $config->{options} = [];
 873
 874     my $options_alternatives = {
 875         'ovs_mtu'     => 'mtu',
 876         'bond-slaves' => 'slaves',
 877         'bond_slaves' => 'slaves',
 878         'bond-xmit-hash-policy' => 'bond_xmit_hash_policy',
 879         'bond-mode' => 'bond_mode',
 880         'bond-miimon' =>'bond_miimon',
 881         'bridge-vlan-aware' => 'bridge_vlan_aware',
 882         'bridge-fd' => 'bridge_fd',
 883         'bridge-stp' => 'bridge_stp',
 884         'bridge-ports' => 'bridge_ports',
 885         'bridge-vids' => 'bridge_vids'
 886     };
 887
 888     my $line;
 889
 890     if ($proc_net_dev) {
 891         while (defined ($line = <$proc_net_dev>)) {
 892             if ($line =~ m/^\s*($PVE::Network::PHYSICAL_NIC_RE):.*/) {
 893                 $ifaces->{$1}->{exists} = 1;
 894             }
 895         }
 896         close($proc_net_dev);
 897     }
 898
 899     # we try to keep order inside the file
 900     my $priority = 2; # 1 is reserved for lo
 901
 902     SECTION: while (defined ($line = <$fh>)) {
 903         chomp ($line);
 904         next if $line =~ m/^\s*#/;
 905         next if $line =~ m/^\s*(allow-hotplug)\s+(.*)$/;
 906
 907         if ($line =~ m/^\s*(auto|allow-ovs)\s+(.*)$/) {
 908             my @aa = split (/\s+/, $2);
 909
 910             foreach my $a (@aa) {
 911                 $ifaces->{$a}->{autostart} = 1;
 912             }
 913
 914         } elsif ($line =~ m/^\s*iface\s+(\S+)\s+(inet6?)\s+(\S+)\s*$/) {
 915             my $i = $1;
 916             my $family = $2;
 917             my $f = { method => $3 }; # by family, merged to $d with a $suffix
 918             (my $suffix = $family) =~ s/^inet//;
 919
 920             my $d = $ifaces->{$i} ||= {};
 921             $d->{priority} = $priority++ if !$d->{priority};
 922             push @{$d->{families}}, $family;
 923
 924             while (defined ($line = <$fh>)) {
 925                 chomp $line;
 926                 if ($line =~ m/^\s*#(.*?)\s*$/) {
 927                     $f->{comments} = '' if !$f->{comments};
 928                     my $comment = decode('UTF-8', $1);
 929                     $f->{comments} .= "$comment\n";
 930                 } elsif ($line =~ m/^\s*(?:iface\s
 931                                           |mapping\s
 932                                           |auto\s
 933                                           |allow-
 934                                           |source\s
 935                                           |source-directory\s
 936                                         )/x) {
 937                     last;
 938                 } elsif ($line =~ m/^\s*((\S+)\s+(.+))$/) {
 939                     my $option = $1;
 940                     my ($id, $value) = ($2, $3);
 941
 942                     $id = $options_alternatives->{$id} if $options_alternatives->{$id};
 943
 944                     my $simple_options = {
 945                         'mtu' => 1,
 946                         'ovs_type' => 1,
 947                         'ovs_options' => 1,
 948                         'ovs_bridge' => 1,
 949                         'ovs_bonds' => 1,
 950                         'ovs_ports' => 1,
 951                         'bridge_fd' => 1,
 952                         'bridge_vids' => 1,
 953                         'bridge-access' => 1,
 954                         'bridge-learning' => 1,
 955                         'bridge-arp-nd-suppress' => 1,
 956                         'bridge-unicast-flood' => 1,
 957                         'bridge-multicast-flood' => 1,
 958                         'bond_miimon' => 1,
 959                         'bond_xmit_hash_policy' => 1,
 960                         'bond-primary' => 1,
 961                         'uplink-id' => 1,
 962                         'vlan-protocol' => 1,
 963                         'vxlan-id' => 1,
 964                         'vxlan-svcnodeip' => 1,
 965                         'vxlan-physdev' => 1,
 966                         'vxlan-local-tunnelip' => 1 };
 967
 968                     if (($id eq 'address') || ($id eq 'netmask') || ($id eq 'broadcast') || ($id eq 'gateway')) {
 969                         $f->{$id} = $value;
 970                     } elsif ($simple_options->{$id}) {
 971                         $d->{$id} = $value;
 972                     } elsif ($id eq 'slaves' || $id eq 'bridge_ports') {
 973                         my $devs = {};
 974                         foreach my $p (split (/\s+/, $value)) {
 975                             next if $p eq 'none';
 976                             $devs->{$p} = 1;
 977                         }
 978                         my $str = join (' ', sort keys %{$devs});
 979                         if ($d->{$id}) {
 980                             $d->{$id} .= ' ' . $str if $str;
 981                         } else {
 982                             $d->{$id} = $str || '';
 983                         }
 984                     } elsif ($id eq 'bridge_stp') {
 985                         if ($value =~ m/^\s*(on|yes)\s*$/i) {
 986                             $d->{$id} = 'on';
 987                         } else {
 988                             $d->{$id} = 'off';
 989                         }
 990                     } elsif ($id eq 'bridge_vlan_aware') {
 991                         $d->{$id} = 1;
 992                     } elsif ($id eq 'bond_mode') {
 993                         # always use names
 994                         foreach my $bm (keys %$bond_modes) {
 995                             my $id = $bond_modes->{$bm};
 996                             if ($id eq $value) {
 997                                 $value = $bm;
 998                                 last;
 999                             }
1000                         }
1001                         $d->{$id} = $value;
1002                     } elsif ($id eq 'vxlan-remoteip') {
1003                         push @{$d->{$id}}, $value;
1004                     } else {
1005                         push @{$f->{options}}, $option;
1006                     }
1007                 } else {
1008                     last;
1009                 }
1010             }
1011             $d->{"$_$suffix"} = $f->{$_} foreach (keys %$f);
1012             last SECTION if !defined($line);
1013             redo SECTION;
1014         } elsif ($line =~ /\w/) {
1015             push @$options, [$priority++, $line];
1016         }
1017     }
1018
1019     foreach my $ifname (@$active_ifaces) {
1020         if (my $iface = $ifaces->{$ifname}) {
1021             $iface->{active} = 1;
1022         }
1023     }
1024
1025     if (!$ifaces->{lo}) {
1026         $ifaces->{lo}->{priority} = 1;
1027         $ifaces->{lo}->{method} = 'loopback';
1028         $ifaces->{lo}->{type} = 'loopback';
1029         $ifaces->{lo}->{autostart} = 1;
1030     }
1031
1032     foreach my $iface (keys %$ifaces) {
1033         my $d = $ifaces->{$iface};
1034         if ($iface =~ m/^bond\d+$/) {
1035             if (!$d->{ovs_type}) {
1036                 $d->{type} = 'bond';
1037             } elsif ($d->{ovs_type} eq 'OVSBond') {
1038                 $d->{type} = $d->{ovs_type};
1039                 # translate: ovs_options => bond_mode
1040                 $d->{'bond_mode'} = &$extract_ovs_option($d, 'bond_mode');
1041                 my $lacp = &$extract_ovs_option($d, 'lacp');
1042                 if ($lacp && $lacp eq 'active') {
1043                     if ($d->{'bond_mode'} eq 'balance-slb') {
1044                         $d->{'bond_mode'} = 'lacp-balance-slb';
1045                     }
1046                 }
1047                 # Note: balance-tcp needs lacp
1048                 if ($d->{'bond_mode'} eq 'balance-tcp') {
1049                     $d->{'bond_mode'} = 'lacp-balance-tcp';
1050                 }
1051                 my $tag = &$extract_ovs_option($d, 'tag');
1052                 $d->{ovs_tag} = $tag if defined($tag);
1053             } else {
1054                 $d->{type} = 'unknown';
1055             }
1056         } elsif ($iface =~ m/^vmbr\d+$/) {
1057             if (!$d->{ovs_type}) {
1058                 $d->{type} = 'bridge';
1059
1060                 if (!defined ($d->{bridge_fd})) {
1061                     $d->{bridge_fd} = 0;
1062                 }
1063                 if (!defined ($d->{bridge_stp})) {
1064                     $d->{bridge_stp} = 'off';
1065                 }
1066             } elsif ($d->{ovs_type} eq 'OVSBridge') {
1067                 $d->{type} = $d->{ovs_type};
1068             } else {
1069                 $d->{type} = 'unknown';
1070             }
1071         } elsif ($iface =~ m/^(\S+):\d+$/) {
1072             $d->{type} = 'alias';
1073             if (defined ($ifaces->{$1})) {
1074                 $d->{exists} = $ifaces->{$1}->{exists};
1075             } else {
1076                 $ifaces->{$1}->{exists} = 0;
1077                 $d->{exists} = 0;
1078             }
1079         } elsif ($iface =~ m/^(\S+)\.\d+$/) {
1080             $d->{type} = 'vlan';
1081             if (defined ($ifaces->{$1})) {
1082                 $d->{exists} = $ifaces->{$1}->{exists};
1083             } else {
1084                 $ifaces->{$1}->{exists} = 0;
1085                 $d->{exists} = 0;
1086             }
1087         } elsif ($iface =~ m/^$PVE::Network::PHYSICAL_NIC_RE$/) {
1088             if (!$d->{ovs_type}) {
1089                 $d->{type} = 'eth';
1090             } elsif ($d->{ovs_type} eq 'OVSPort') {
1091                 $d->{type} = $d->{ovs_type};
1092                 my $tag = &$extract_ovs_option($d, 'tag');
1093                 $d->{ovs_tag} = $tag if defined($tag);
1094             } else {
1095                 $d->{type} = 'unknown';
1096             }
1097         } elsif ($iface =~ m/^lo$/) {
1098             $d->{type} = 'loopback';
1099         } else {
1100             if ($d->{'vxlan-id'}) {
1101                 $d->{type} = 'vxlan';
1102             } elsif (!$d->{ovs_type}) {
1103                 $d->{type} = 'unknown';
1104             } elsif ($d->{ovs_type} eq 'OVSIntPort') {
1105                 $d->{type} = $d->{ovs_type};
1106                 my $tag = &$extract_ovs_option($d, 'tag');
1107                 $d->{ovs_tag} = $tag if defined($tag);
1108             }
1109         }
1110
1111         # map address and netmask to cidr
1112         if ($d->{address}) {
1113             if ($d->{netmask} && $d->{netmask} =~ m/^\d+$/) { # e.g. netmask 20
1114                 $d->{cidr} = $d->{address} . "/" . $d->{netmask};
1115             } elsif ($d->{netmask} &&
1116                      (my $cidr = PVE::JSONSchema::get_netmask_bits($d->{netmask}))) { # e.g. netmask 255.255.255.0
1117                 $d->{cidr} = $d->{address} . "/" . $cidr;
1118             } elsif ($d->{address} =~ m!^(.*)/(\d+)$!) {
1119                 $d->{cidr} = $d->{address};
1120                 $d->{address} = $1;
1121                 $d->{netmask} = $2;
1122             } else {
1123                 $d->{cidr} = $d->{address};
1124             }
1125         }
1126
1127         # map address6 and netmask6 to cidr6
1128         if ($d->{address6}) {
1129             $d->{cidr6} = $d->{address6};
1130             if ($d->{netmask6}) {
1131                 $d->{cidr6} .= "/" . $d->{netmask6};
1132             } elsif ($d->{address6} =~ m!^(.*)/(\d+)$!) {
1133                 $d->{address6} = $1;
1134                 $d->{netmask6} = $2;
1135             }
1136         }
1137
1138         $d->{method} = 'manual' if !$d->{method};
1139         $d->{method6} = 'manual' if !$d->{method6};
1140
1141         $d->{families} ||= ['inet'];
1142     }
1143
1144     # OVS bridges create "allow-$BRIDGE $IFACE" lines which we need to remove
1145     # from the {options} hash for them to be removed correctly.
1146     @$options = grep {defined($_)} map {
1147         my ($pri, $line) = @$_;
1148         if ($line =~ /^allow-ovs\s+(.*)$/) {
1149             undef;
1150         } elsif ($line =~ /^allow-(\S+)\s+(.*)$/) {
1151             my $bridge = $1;
1152             my @ports = split(/\s+/, $2);
1153             if (defined(my $br = $ifaces->{$bridge})) {
1154                 # if this port is part of a bridge, remove it
1155                 my %in_ovs_ports = map {$_=>1} split(/\s+/, $br->{ovs_ports});
1156                 @ports = grep { not $in_ovs_ports{$_} } @ports;
1157             }
1158             # create the allow line for the remaining ports, or delete if empty
1159             if (@ports) {
1160                 [$pri, "allow-$bridge " . join(' ', @ports)];
1161             } else {
1162                 undef;
1163             }
1164         } else {
1165             # don't modify other lines
1166             $_;
1167         }
1168     } @$options;
1169
1170     return $config;
1171 }
1172
1173 sub __interface_to_string {
1174     my ($iface, $d, $family, $first_block, $ifupdown2) = @_;
1175
1176     (my $suffix = $family) =~ s/^inet//;
1177
1178     return '' if !($d && $d->{"method$suffix"});
1179
1180     my $raw = '';
1181
1182     $raw .= "iface $iface $family " . $d->{"method$suffix"} . "\n";
1183     $raw .= "\taddress  " . $d->{"address$suffix"} . "\n" if $d->{"address$suffix"};
1184     $raw .= "\tnetmask  " . $d->{"netmask$suffix"} . "\n" if $d->{"netmask$suffix"};
1185     $raw .= "\tgateway  " . $d->{"gateway$suffix"} . "\n" if $d->{"gateway$suffix"};
1186     $raw .= "\tbroadcast  " . $d->{"broadcast$suffix"} . "\n" if $d->{"broadcast$suffix"};
1187
1188     my $done = { type => 1, priority => 1, method => 1, active => 1, exists => 1,
1189                  comments => 1, autostart => 1, options => 1,
1190                  address => 1, netmask => 1, gateway => 1, broadcast => 1,
1191                  method6 => 1, families => 1, options6 => 1,
1192                  address6 => 1, netmask6 => 1, gateway6 => 1, broadcast6 => 1, 'uplink-id' => 1 };
1193
1194     if (!$first_block) {
1195         # not printing out options
1196     } elsif ($d->{type} eq 'bridge') {
1197
1198         $d->{bridge_ports} =~ s/[;,\s]+/ /g;
1199         my $ports = $d->{bridge_ports} || 'none';
1200         $raw .= "\tbridge-ports $ports\n";
1201         $done->{bridge_ports} = 1;
1202
1203         my $v = defined($d->{bridge_stp}) ? $d->{bridge_stp} : 'off';
1204         $raw .= "\tbridge-stp $v\n";
1205         $done->{bridge_stp} = 1;
1206
1207         $v = defined($d->{bridge_fd}) ? $d->{bridge_fd} : 0;
1208         $raw .= "\tbridge-fd $v\n";
1209         $done->{bridge_fd} = 1;
1210
1211         if( defined($d->{bridge_vlan_aware})) {
1212             $raw .= "\tbridge-vlan-aware yes\n";
1213             $v = defined($d->{bridge_vids}) ? $d->{bridge_vids} : "2-4094";
1214             $raw .= "\tbridge-vids $v\n";
1215         }
1216         $done->{bridge_vlan_aware} = 1;
1217         $done->{bridge_vids} = 1;
1218
1219         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1220         $done->{mtu} = 1;
1221
1222     } elsif ($d->{type} eq 'bond') {
1223
1224         $d->{slaves} =~ s/[;,\s]+/ /g;
1225         my $slaves = $d->{slaves} || 'none';
1226         $raw .= "\tbond-slaves $slaves\n";
1227         $done->{slaves} = 1;
1228
1229         my $v = defined ($d->{'bond_miimon'}) ? $d->{'bond_miimon'} : 100;
1230         $raw .= "\tbond-miimon $v\n";
1231         $done->{'bond_miimon'} = 1;
1232
1233         $v = defined ($d->{'bond_mode'}) ? $d->{'bond_mode'} : 'balance-rr';
1234         $raw .= "\tbond-mode $v\n";
1235         $done->{'bond_mode'} = 1;
1236
1237         if ($d->{'bond_mode'} && $d->{'bond_xmit_hash_policy'} &&
1238             ($d->{'bond_mode'} eq 'balance-xor' || $d->{'bond_mode'} eq '802.3ad')) {
1239             $raw .= "\tbond-xmit-hash-policy $d->{'bond_xmit_hash_policy'}\n";
1240         }
1241         $done->{'bond_xmit_hash_policy'} = 1;
1242
1243         if ($d->{'bond_mode'} && $d->{'bond_mode'} eq 'active-backup' && $d->{'bond-primary'}) {
1244             $raw .= "\tbond-primary $d->{'bond-primary'}\n";
1245         }
1246         $done->{'bond-primary'} = 1;
1247
1248         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1249         $done->{mtu} = 1;
1250
1251     } elsif ($d->{type} eq 'vlan') {
1252         die "$iface: wrong vlan-protocol $d->{'vlan-protocol'}\n"
1253             if $d->{'vlan-protocol'} && $d->{'vlan-protocol'} ne '802.1ad' && $d->{'vlan-protocol'} ne '802.1q';
1254
1255     } elsif ($d->{type} eq 'vxlan') {
1256
1257         foreach my $k (qw(vxlan-id vxlan-svcnodeip vxlan-physdev vxlan-local-tunnelip)) {
1258             $raw .= "\t$k $d->{$k}\n" if defined $d->{$k};
1259             $done->{$k} = 1;
1260         }
1261
1262         if ($d->{'vxlan-remoteip'}) {
1263             foreach my $remoteip (@{$d->{'vxlan-remoteip'}}) {
1264                 $raw .= "\tvxlan-remoteip $remoteip\n";
1265             }
1266             $done->{'vxlan-remoteip'} = 1;
1267         }
1268
1269         $raw .= "\tmtu $d->{mtu}\n" if $d->{mtu};
1270         $done->{mtu} = 1;
1271
1272     } elsif ($d->{type} eq 'OVSBridge') {
1273
1274         $raw .= "\tovs_type $d->{type}\n";
1275         $done->{ovs_type} = 1;
1276
1277         $raw .= "\tovs_ports $d->{ovs_ports}\n" if $d->{ovs_ports};
1278         $done->{ovs_ports} = 1;
1279
1280         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1281         $done->{mtu} = 1;
1282
1283     } elsif ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1284              $d->{type} eq 'OVSBond') {
1285
1286         $d->{autostart} = 0; # started by the bridge
1287
1288         if (defined($d->{ovs_tag})) {
1289             &$set_ovs_option($d, tag => $d->{ovs_tag});
1290         }
1291         $done->{ovs_tag} = 1;
1292
1293         if ($d->{type} eq 'OVSBond') {
1294
1295             $d->{bond_mode} = 'active-backup' if !$d->{bond_mode};
1296
1297             $ovs_bond_modes->{$d->{bond_mode}} ||
1298                 die "OVS does not support bond mode '$d->{bond_mode}\n";
1299
1300             if ($d->{bond_mode} eq 'lacp-balance-slb') {
1301                 &$set_ovs_option($d, lacp => 'active');
1302                 &$set_ovs_option($d, bond_mode => 'balance-slb');
1303             } elsif ($d->{bond_mode} eq 'lacp-balance-tcp') {
1304                 &$set_ovs_option($d, lacp => 'active');
1305                 &$set_ovs_option($d, bond_mode => 'balance-tcp');
1306             } else {
1307                 &$set_ovs_option($d, lacp => undef);
1308                 &$set_ovs_option($d, bond_mode => $d->{bond_mode});
1309             }
1310             $done->{bond_mode} = 1;
1311
1312             $raw .= "\tovs_bonds $d->{ovs_bonds}\n" if $d->{ovs_bonds};
1313             $done->{ovs_bonds} = 1;
1314         }
1315
1316         $raw .= "\tovs_type $d->{type}\n";
1317         $done->{ovs_type} = 1;
1318
1319         if (my $bridge = $d->{ovs_bridge}) {
1320             $raw = "allow-$bridge $iface\n$raw";
1321             $raw .= "\tovs_bridge $bridge\n";
1322             $done->{ovs_bridge} = 1;
1323         }
1324
1325         $raw .= "\tovs_mtu $d->{mtu}\n" if $d->{mtu};
1326         $done->{mtu} = 1;
1327     }
1328
1329     if ($first_block) {
1330         # print other settings
1331         foreach my $k (sort keys %$d) {
1332            next if $done->{$k};
1333            next if !$d->{$k};
1334            $raw .= "\t$k $d->{$k}\n";
1335         }
1336     }
1337
1338     foreach my $option (@{$d->{"options$suffix"}}) {
1339         $raw .= "\t$option\n";
1340     }
1341
1342     # add comments
1343     my $comments = $d->{"comments$suffix"} || '';
1344     foreach my $cl (split(/\n/, $comments)) {
1345         $raw .= "#$cl\n";
1346     }
1347
1348     $raw .= "\n";
1349
1350     return $raw;
1351 }
1352
1353
1354 sub write_etc_network_interfaces {
1355     my ($filename, $fh, $config) = @_;
1356     my $ifupdown2 = -e '/usr/share/ifupdown2';
1357     my $raw = __write_etc_network_interfaces($config, $ifupdown2);
1358     PVE::Tools::safe_print($filename, $fh, encode('UTF-8', $raw));
1359 }
1360 sub __write_etc_network_interfaces {
1361     my ($config, $ifupdown2) = @_;
1362
1363     my $ifaces = $config->{ifaces};
1364     my @options = @{$config->{options}};
1365
1366     my $used_ports = {};
1367
1368     foreach my $iface (keys %$ifaces) {
1369         my $d = $ifaces->{$iface};
1370
1371         delete $d->{cidr};
1372         delete $d->{cidr6};
1373
1374         my $ports = '';
1375         foreach my $k (qw(bridge_ports ovs_ports slaves ovs_bonds)) {
1376             $ports .= " $d->{$k}" if $d->{$k};
1377         }
1378
1379         foreach my $p (PVE::Tools::split_list($ports)) {
1380             die "port '$p' is already used on interface '$used_ports->{$p}'\n"
1381                 if $used_ports->{$p} && $used_ports->{$p} ne $iface;
1382             $used_ports->{$p} = $iface;
1383         }
1384     }
1385
1386     # delete unused OVS ports
1387     foreach my $iface (keys %$ifaces) {
1388         my $d = $ifaces->{$iface};
1389         if ($d->{type} eq 'OVSPort' || $d->{type} eq 'OVSIntPort' ||
1390             $d->{type} eq 'OVSBond') {
1391             my $brname = $used_ports->{$iface};
1392             if (!$brname || !$ifaces->{$brname}) {
1393                 if ($iface =~ /^$PVE::Network::PHYSICAL_NIC_RE/) {
1394                     $ifaces->{$iface} = { type => 'eth',
1395                                           exists => 1,
1396                                           method => 'manual',
1397                                           families => ['inet'] };
1398                 } else {
1399                     delete $ifaces->{$iface};
1400                 }
1401                 next;
1402             }
1403             my $bd = $ifaces->{$brname};
1404             if ($bd->{type} ne 'OVSBridge') {
1405                 delete $ifaces->{$iface};
1406                 next;
1407             }
1408         }
1409     }
1410
1411     # create OVS bridge ports
1412     foreach my $iface (keys %$ifaces) {
1413         my $d = $ifaces->{$iface};
1414         if ($d->{type} eq 'OVSBridge' && $d->{ovs_ports}) {
1415             foreach my $p (split (/\s+/, $d->{ovs_ports})) {
1416                 my $n = $ifaces->{$p};
1417                 die "OVS bridge '$iface' - unable to find port '$p'\n"
1418                     if !$n;
1419                 $n->{autostart} = 0;
1420                 if ($n->{type} eq 'eth') {
1421                     $n->{type} = 'OVSPort';
1422                     $n->{ovs_bridge} = $iface;
1423                 } elsif ($n->{type} eq 'OVSBond' || $n->{type} eq 'OVSPort' ||
1424                     $n->{type} eq 'OVSIntPort') {
1425                     $n->{ovs_bridge} = $iface;
1426                 } else {
1427                     die "interface '$p' is not defined as OVS port/bond\n";
1428                 }
1429
1430                 &$check_mtu($ifaces, $iface, $p);
1431             }
1432         }
1433     }
1434
1435     # check OVS bond ports
1436     foreach my $iface (keys %$ifaces) {
1437         my $d = $ifaces->{$iface};
1438         if ($d->{type} eq 'OVSBond' && $d->{ovs_bonds}) {
1439             foreach my $p (split (/\s+/, $d->{ovs_bonds})) {
1440                 my $n = $ifaces->{$p};
1441                 die "OVS bond '$iface' - unable to find slave '$p'\n"
1442                     if !$n;
1443                 die "OVS bond '$iface' - wrong interface type on slave '$p' " .
1444                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1445                 &$check_mtu($ifaces, $iface, $p);
1446             }
1447         }
1448     }
1449
1450     # check bond
1451     foreach my $iface (keys %$ifaces) {
1452         my $d = $ifaces->{$iface};
1453         if ($d->{type} eq 'bond' && $d->{slaves}) {
1454             my $bond_primary_is_slave = undef;
1455             foreach my $p (split (/\s+/, $d->{slaves})) {
1456                 my $n = $ifaces->{$p};
1457
1458                 die "bond '$iface' - unable to find slave '$p'\n"
1459                     if !$n;
1460                 die "bond '$iface' - wrong interface type on slave '$p' " .
1461                     "('$n->{type}' != 'eth')\n" if $n->{type} ne 'eth';
1462                 &$check_mtu($ifaces, $iface, $p);
1463                 $bond_primary_is_slave = 1 if $d->{'bond-primary'} && $d->{'bond-primary'} eq $p;
1464             }
1465             die "bond '$iface' - bond-primary interface is not a slave" if $d->{'bond-primary'} && !$bond_primary_is_slave;
1466         }
1467     }
1468
1469     # check vxlan
1470     my $vxlans = {};
1471     foreach my $iface (keys %$ifaces) {
1472         my $d = $ifaces->{$iface};
1473
1474         if ($d->{type} eq 'vxlan' && $d->{'vxlan-id'}) {
1475             my $vxlanid = $d->{'vxlan-id'};
1476             die "iface $iface - duplicate vxlan-id $vxlanid already used in $vxlans->{$vxlanid}\n" if $vxlans->{$vxlanid};
1477             $vxlans->{$vxlanid} = $iface;
1478         }
1479
1480         my $ips = 0;
1481         ++$ips if defined $d->{'vxlan-svcnodeip'};
1482         ++$ips if defined $d->{'vxlan-remoteip'};
1483         ++$ips if defined $d->{'vxlan-local-tunnelip'};
1484         if ($ips > 1) {
1485             die "iface $iface - vxlan-svcnodeip, vxlan-remoteip and vxlan-localtunnelip are mutually exclusive\n";
1486         }
1487
1488         if (defined($d->{'vxlan-svcnodeip'}) != defined($d->{'vxlan-physdev'})) {
1489             die "iface $iface - vxlan-svcnodeip and vxlan-physdev must be define together\n";
1490         }
1491         #fixme : check if vxlan mtu is lower than 50bytes than physical interface where tunnel is going out
1492     }
1493
1494     # check vlan
1495     foreach my $iface (keys %$ifaces) {
1496         my $d = $ifaces->{$iface};
1497         if ($d->{type} eq 'vlan' && $iface =~ m/^(\S+)\.\d+$/) {
1498             my $p = $1;
1499             my $n = $ifaces->{$p};
1500
1501             die "vlan '$iface' - unable to find parent '$p'\n"
1502                 if !$n;
1503
1504             if ($n->{type} ne 'eth' && $n->{type} ne 'bridge' && $n->{type} ne 'bond' && $n->{type} ne 'vlan') {
1505                 die "vlan '$iface' - wrong interface type on parent '$p' " .
1506                     "('$n->{type}' != 'eth|bond|bridge|vlan' )\n";
1507             }
1508
1509             &$check_mtu($ifaces, $p, $iface);
1510
1511         }
1512     }
1513
1514     # check uplink
1515     my $uplinks = {};
1516     foreach my $iface (keys %$ifaces) {
1517         my $d = $ifaces->{$iface};
1518         if (my $uplinkid = $d->{'uplink-id'}) {
1519             die "iface '$iface' - uplink-id $uplinkid is only allowed on physical and linux bond interfaces\n"
1520                 if $d->{type} ne 'eth' && $d->{type} ne 'bond';
1521
1522             die "iface '$iface' - uplink-id $uplinkid is already assigned on '$uplinks->{$uplinkid}'\n"
1523                 if $uplinks->{$uplinkid};
1524
1525             $uplinks->{$uplinkid} = $iface;
1526         }
1527     }
1528
1529     # check bridgeport option
1530     my $bridgeports = {};
1531     my $bridges = {};
1532     foreach my $iface (keys %$ifaces) {
1533         my $d = $ifaces->{$iface};
1534         if ($d->{type} eq 'bridge') {
1535             foreach my $p (split (/\s+/, $d->{bridge_ports})) {
1536                 $p =~ s/\.\d+$//;
1537                 my $n = $ifaces->{$p};
1538                 die "bridge '$iface' - unable to find bridge port '$p'\n"
1539                     if !$n;
1540                 die "iface $p - ip address can't be set on interface if bridged in $iface\n"
1541                     if ($n->{method} eq 'static' && $n->{address} ne '0.0.0.0') ||
1542                         ($n->{method6} eq 'static' && $n->{address} ne "\:\:");
1543
1544                 &$check_mtu($ifaces, $iface, $p);
1545                 $bridgeports->{$p} = $iface;
1546             }
1547             $bridges->{$iface} = $d;
1548         }
1549     }
1550
1551     foreach my $iface (keys %$ifaces) {
1552         my $d = $ifaces->{$iface};
1553
1554         foreach my $k (qw(bridge-learning bridge-arp-nd-suppress bridge-unicast-flood bridge-multicast-flood bridge-access)) {
1555             die "iface $iface - $k: bridge port specific options can be used only on interfaces attached to a bridge\n"
1556                 if $d->{$k} && !$bridgeports->{$iface};
1557         }
1558
1559         if ($d->{'bridge-access'} && !$bridges->{$bridgeports->{$iface}}->{bridge_vlan_aware}) {
1560             die "iface $iface - bridge-access option can be only used if interface is in a vlan aware bridge\n";
1561         }
1562     }
1563
1564     my $raw = <<'NETWORKDOC';
1565 # network interface settings; autogenerated
1566 # Please do NOT modify this file directly, unless you know what
1567 # you're doing.
1568 #
1569 # If you want to manage parts of the network configuration manually,
1570 # please utilize the 'source' or 'source-directory' directives to do
1571 # so.
1572 # PVE will preserve these directives, but will NOT read its network
1573 # configuration from sourced files, so do not attempt to move any of
1574 # the PVE managed interfaces into external files!
1575
1576 NETWORKDOC
1577
1578     my $printed = {};
1579
1580     my $if_type_hash = {
1581         loopback => 100000,
1582         eth => 200000,
1583         OVSPort => 200000,
1584         OVSIntPort => 200000,
1585         bond => 300000,
1586         bridge => 400000,
1587         OVSBridge => 400000,
1588         vxlan => 500000,
1589    };
1590
1591     my $lookup_type_prio = sub {
1592         my ($iface, $ifaces) = @_;
1593
1594         my ($rootiface, @rest) = split(/[.:]/, $iface);
1595         my $childlevel = scalar(@rest);
1596         my $n = $ifaces->{$rootiface};
1597
1598         my $pri = $if_type_hash->{$n->{type}} + $childlevel
1599             if $n->{type} && $n->{type} ne 'unknown';
1600
1601         return $pri;
1602     };
1603
1604     foreach my $iface (sort {
1605         my $ref1 = $ifaces->{$a};
1606         my $ref2 = $ifaces->{$b};
1607         my $tp1 = &$lookup_type_prio($a, $ifaces);
1608         my $tp2 = &$lookup_type_prio($b, $ifaces);
1609
1610         # Only recognized types are in relation to each other. If one type
1611         # is unknown then only consider the interfaces' priority attributes.
1612         $tp1 = $tp2 = 0 if !defined($tp1) || !defined($tp2);
1613
1614         my $p1 = $tp1 + ($ref1->{priority} // 50000);
1615         my $p2 = $tp2 + ($ref2->{priority} // 50000);
1616
1617         return $p1 <=> $p2 if $p1 != $p2;
1618
1619         return $a cmp $b;
1620     } keys %$ifaces) {
1621         next if $printed->{$iface};
1622         my $d = $ifaces->{$iface};
1623         my $pri = $d->{priority} // 0;
1624         if (@options && $options[0]->[0] < $pri) {
1625             do {
1626                 $raw .= (shift @options)->[1] . "\n";
1627             } while (@options && $options[0]->[0] < $pri);
1628             $raw .= "\n";
1629         }
1630
1631         $printed->{$iface} = 1;
1632         if ($d->{autostart}) {
1633             if ($d->{type} eq 'OVSBridge') {
1634                 # cannot use 'auto' for OVS, would add race with systemd ifup@.service
1635                 $raw .= "allow-ovs $iface\n";
1636             } else {
1637                 $raw .= "auto $iface\n";
1638             }
1639         }
1640
1641         my $i = 0; # some options should be printed only once
1642         $raw .= __interface_to_string($iface, $d, $_, !$i++, $ifupdown2) foreach @{$d->{families}};
1643     }
1644
1645     $raw .= $_->[1] . "\n" foreach @options;
1646     return $raw;
1647 }
1648
1649 register_file('interfaces', "/etc/network/interfaces",
1650               \&read_etc_network_interfaces,
1651               \&write_etc_network_interfaces);
1652
1653
1654 sub read_iscsi_initiatorname {
1655     my ($filename, $fd) = @_;
1656
1657     while (defined(my $line = <$fd>)) {
1658         if ($line =~ m/^InitiatorName=(\S+)$/) {
1659             return $1;
1660         }
1661     }
1662
1663     return 'undefined';
1664 }
1665
1666 register_file('initiatorname', "/etc/iscsi/initiatorname.iscsi",
1667               \&read_iscsi_initiatorname);
1668
1669 sub read_apt_auth {
1670     my ($filename, $fd) = @_;
1671
1672     local $/;
1673
1674     my $raw = defined($fd) ? <$fd> : '';
1675
1676     $raw =~ s/^\s+//;
1677
1678
1679     my @tokens = split(/\s+/, $raw);
1680
1681     my $data = {};
1682
1683     my $machine;
1684     while (defined(my $tok = shift @tokens)) {
1685
1686         $machine = shift @tokens if $tok eq 'machine';
1687         next if !$machine;
1688         $data->{$machine} = {} if !$data->{$machine};
1689
1690         $data->{$machine}->{login} = shift @tokens if $tok eq 'login';
1691         $data->{$machine}->{password} = shift @tokens if $tok eq 'password';
1692     };
1693
1694     return $data;
1695 }
1696
1697 my $format_apt_auth_data = sub {
1698     my $data = shift;
1699
1700     my $raw = '';
1701
1702     foreach my $machine (sort keys %$data) {
1703         my $d = $data->{$machine};
1704         $raw .= "machine $machine\n";
1705         $raw .= " login $d->{login}\n" if $d->{login};
1706         $raw .= " password $d->{password}\n" if $d->{password};
1707         $raw .= "\n";
1708     }
1709
1710     return $raw;
1711 };
1712
1713 sub write_apt_auth {
1714     my ($filename, $fh, $data) = @_;
1715
1716     my $raw = &$format_apt_auth_data($data);
1717
1718     die "write failed: $!" unless print $fh "$raw\n";
1719
1720     return $data;
1721 }
1722
1723 sub update_apt_auth {
1724     my ($filename, $fh, $data) = @_;
1725
1726     my $orig = read_apt_auth($filename, $fh);
1727
1728     foreach my $machine (keys %$data) {
1729         $orig->{$machine} = $data->{$machine};
1730     }
1731
1732     return &$format_apt_auth_data($orig);
1733 }
1734
1735 register_file('apt-auth', "/etc/apt/auth.conf",
1736               \&read_apt_auth, \&write_apt_auth,
1737               \&update_apt_auth, perm => 0640);
1738
1739 1;