8cfac0dbe1db369860a660b97d4ede2d76ddafaf
[pve-common.git] / src / PVE / Network.pm
1 package PVE::Network;
2
3 use strict;
4 use warnings;
5 use PVE::Tools qw(run_command);
6 use PVE::ProcFSTools;
7 use PVE::INotify;
8 use File::Basename;
9 use IO::Socket::IP;
10 use POSIX qw(ECONNREFUSED);
11
12 use Net::IP;
13
14 # host network related utility functions
15
16 our $ipv4_reverse_mask = [
17     '0.0.0.0',
18     '128.0.0.0',
19     '192.0.0.0',
20     '224.0.0.0',
21     '240.0.0.0',
22     '248.0.0.0',
23     '252.0.0.0',
24     '254.0.0.0',
25     '255.0.0.0',
26     '255.128.0.0',
27     '255.192.0.0',
28     '255.224.0.0',
29     '255.240.0.0',
30     '255.248.0.0',
31     '255.252.0.0',
32     '255.254.0.0',
33     '255.255.0.0',
34     '255.255.128.0',
35     '255.255.192.0',
36     '255.255.224.0',
37     '255.255.240.0',
38     '255.255.248.0',
39     '255.255.252.0',
40     '255.255.254.0',
41     '255.255.255.0',
42     '255.255.255.128',
43     '255.255.255.192',
44     '255.255.255.224',
45     '255.255.255.240',
46     '255.255.255.248',
47     '255.255.255.252',
48     '255.255.255.254',
49     '255.255.255.255',
50 ];
51
52 our $ipv4_mask_hash_localnet = {
53     '255.255.0.0' => 16,
54     '255.255.128.0' => 17,
55     '255.255.192.0' => 18,
56     '255.255.224.0' => 19,
57     '255.255.240.0' => 20,
58     '255.255.248.0' => 21,
59     '255.255.252.0' => 22,
60     '255.255.254.0' => 23,
61     '255.255.255.0' => 24,
62     '255.255.255.128' => 25,
63     '255.255.255.192' => 26,
64     '255.255.255.224' => 27,
65     '255.255.255.240' => 28,
66     '255.255.255.248' => 29,
67     '255.255.255.252' => 30,
68 };
69
70 sub setup_tc_rate_limit {
71     my ($iface, $rate, $burst, $debug) = @_;
72
73     system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
74     system("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1");
75     system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
76     system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
77
78     return if !$rate;
79
80     # tbf does not work for unknown reason
81     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
82     # so we use htb instead
83     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
84     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
85                 "htb rate ${rate}bps burst ${burst}b");
86
87     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
88     run_command("/sbin/tc filter add dev $iface parent ffff: " .
89                 "protocol all prio 50 u32 match u32 0 0 " .
90                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
91                 "drop flowid :1");
92
93     if ($debug) {
94         print "DEBUG tc settings\n";
95         system("/sbin/tc qdisc ls dev $iface");
96         system("/sbin/tc class ls dev $iface");
97         system("/sbin/tc filter ls dev $iface parent ffff:");
98     }
99 }
100
101 sub tap_rate_limit {
102     my ($iface, $rate) = @_;
103
104     my $debug = 0;
105     $rate = int($rate*1024*1024);
106     my $burst = 1024*1024;
107
108     setup_tc_rate_limit($iface, $rate, $burst, $debug);
109 }
110
111 my $read_bridge_mtu = sub {
112     my ($bridge) = @_;
113
114     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
115     die "bridge '$bridge' does not exist\n" if !$mtu;
116     # avoid insecure dependency;
117     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
118     $mtu = int($1);
119
120     return $mtu;
121 };
122
123 my $parse_tap_device_name = sub {
124     my ($iface, $noerr) = @_;
125
126     my ($vmid, $devid);
127
128     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
129         $vmid = $1;
130         $devid = $2;
131     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
132         $vmid = $1;
133         $devid = $2;
134     } else {
135         return undef if $noerr;
136         die "can't create firewall bridge for random interface name '$iface'\n";
137     }
138
139     return ($vmid, $devid);
140 };
141
142 my $compute_fwbr_names = sub {
143     my ($vmid, $devid) = @_;
144
145     my $fwbr = "fwbr${vmid}i${devid}";
146     # Note: the firewall use 'fwln+' to filter traffic to VMs
147     my $vethfw = "fwln${vmid}i${devid}";
148     my $vethfwpeer = "fwpr${vmid}p${devid}";
149     my $ovsintport = "fwln${vmid}o${devid}";
150
151     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
152 };
153
154 my $cond_create_bridge = sub {
155     my ($bridge) = @_;
156
157     if (! -d "/sys/class/net/$bridge") {
158         system("/sbin/brctl addbr $bridge") == 0 ||
159             die "can't add bridge '$bridge'\n";
160     }
161 };
162
163 my $bridge_add_interface = sub {
164     my ($bridge, $iface, $tag, $trunks) = @_;
165
166     system("/sbin/brctl addif $bridge $iface") == 0 ||
167         die "can't add interface 'iface' to bridge '$bridge'\n";
168
169    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
170
171    if ($vlan_aware) {
172         if ($tag) {
173             system("/sbin/bridge vlan add dev $iface vid $tag pvid untagged") == 0 ||
174             die "unable to add vlan $tag to interface $iface\n";
175         } else {
176             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
177             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
178         } 
179
180         if ($trunks) {
181             my @trunks_array = split /;/, $trunks;
182             foreach my $trunk (@trunks_array) { 
183                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
184                 die "unable to add vlan $trunk to interface $iface\n";
185             }
186         }
187    }
188 };
189
190 my $ovs_bridge_add_port = sub {
191     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
192
193     $trunks =~ s/;/,/g if $trunks;
194
195     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
196     $cmd .= " tag=$tag" if $tag;
197     $cmd .= " trunks=". join(',', $trunks) if $trunks;
198     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
199
200     $cmd .= " -- set Interface $iface type=internal" if $internal;
201     system($cmd) == 0 ||
202         die "can't add ovs port '$iface'\n";
203 };
204
205 my $activate_interface = sub {
206     my ($iface) = @_;
207
208     system("/sbin/ip link set $iface up") == 0 ||
209         die "can't activate interface '$iface'\n";
210 };
211
212 sub tap_create {
213     my ($iface, $bridge) = @_;
214
215     die "unable to get bridge setting\n" if !$bridge;
216
217     my $bridgemtu = &$read_bridge_mtu($bridge);
218
219     eval { 
220         PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
221     };
222     die "interface activation failed\n" if $@;
223 }
224
225 sub veth_create {
226     my ($veth, $vethpeer, $bridge, $mac) = @_;
227
228     die "unable to get bridge setting\n" if !$bridge;
229
230     my $bridgemtu = &$read_bridge_mtu($bridge);
231
232     # create veth pair
233     if (! -d "/sys/class/net/$veth") {
234         my $cmd = "/sbin/ip link add name $veth type veth peer name $vethpeer mtu $bridgemtu";
235         $cmd .= " addr $mac" if $mac;
236         system($cmd) == 0 || die "can't create interface $veth\n";
237     }
238
239     # up vethpair
240     &$activate_interface($veth);
241     &$activate_interface($vethpeer);
242 }
243
244 sub veth_delete {
245     my ($veth) = @_;
246
247     if (-d "/sys/class/net/$veth") {
248         run_command("/sbin/ip link delete dev $veth", outfunc => sub {}, errfunc => sub {});
249     }
250
251 }
252
253 my $create_firewall_bridge_linux = sub {
254     my ($iface, $bridge, $tag, $trunks) = @_;
255
256     my ($vmid, $devid) = &$parse_tap_device_name($iface);
257     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
258
259     &$cond_create_bridge($fwbr);
260     &$activate_interface($fwbr);
261
262     copy_bridge_config($bridge, $fwbr);
263     veth_create($vethfw, $vethfwpeer, $bridge);
264
265     &$bridge_add_interface($fwbr, $vethfw);
266     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
267
268     &$bridge_add_interface($fwbr, $iface);
269 };
270
271 my $create_firewall_bridge_ovs = sub {
272     my ($iface, $bridge, $tag, $trunks) = @_;
273
274     my ($vmid, $devid) = &$parse_tap_device_name($iface);
275     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
276
277     my $bridgemtu = &$read_bridge_mtu($bridge);
278
279     &$cond_create_bridge($fwbr);
280     &$activate_interface($fwbr);
281
282     &$bridge_add_interface($fwbr, $iface);
283
284     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
285     &$activate_interface($ovsintport);
286
287     # set the same mtu for ovs int port
288     PVE::Tools::run_command("/sbin/ifconfig $ovsintport mtu $bridgemtu");
289     
290     &$bridge_add_interface($fwbr, $ovsintport);
291 };
292
293 my $cleanup_firewall_bridge = sub {
294     my ($iface) = @_;
295
296     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
297     return if !defined($vmid);  
298     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
299
300     # cleanup old port config from any openvswitch bridge
301     if (-d "/sys/class/net/$ovsintport") {
302         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
303     }
304
305     # delete old vethfw interface
306     veth_delete($vethfw);
307
308     # cleanup fwbr bridge
309     if (-d "/sys/class/net/$fwbr") {
310         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
311         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
312     }
313 };
314
315 sub tap_plug {
316     my ($iface, $bridge, $tag, $firewall, $trunks) = @_;
317
318     #cleanup old port config from any openvswitch bridge
319     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
320
321     if (-d "/sys/class/net/$bridge/bridge") {
322         &$cleanup_firewall_bridge($iface); # remove stale devices
323
324         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
325
326         if (!$vlan_aware) {
327             die "vlan aware feature need to be enabled to use trunks" if $trunks;
328             my $newbridge = activate_bridge_vlan($bridge, $tag);
329             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
330             $bridge = $newbridge;
331             $tag = undef;
332         }
333
334         if ($firewall) {
335             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
336         } else {
337             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
338         }
339
340     } else {
341         &$cleanup_firewall_bridge($iface); # remove stale devices
342
343         if ($firewall) {
344             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
345         } else {
346             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
347         }
348     }
349 }
350
351 sub tap_unplug {
352     my ($iface) = @_;
353
354     my $path= "/sys/class/net/$iface/brport/bridge";
355     if (-l $path) {
356         my $bridge = basename(readlink($path));
357         #avoid insecure dependency;
358         ($bridge) = $bridge =~ /(\S+)/;
359
360         system("/sbin/brctl delif $bridge $iface") == 0 ||
361             die "can't del interface '$iface' from bridge '$bridge'\n";
362
363     }
364     
365     &$cleanup_firewall_bridge($iface);
366 }
367
368 sub copy_bridge_config {
369     my ($br0, $br1) = @_;
370
371     return if $br0 eq $br1;
372
373     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay', 
374                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
375
376     foreach my $sysname (@$br_configs) {
377         eval {
378             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
379             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
380             if ($v0 ne $v1) {
381                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
382             }
383         };
384         warn $@ if $@;
385     }
386 }
387
388 sub activate_bridge_vlan_slave {
389     my ($bridgevlan, $iface, $tag) = @_;
390     my $ifacevlan = "${iface}.$tag";
391         
392     # create vlan on $iface is not already exist
393     if (! -d "/sys/class/net/$ifacevlan") {
394         system("/sbin/ip link add link $iface name ${iface}.${tag} type vlan id $tag") == 0 ||
395             die "can't add vlan tag $tag to interface $iface\n";
396     }
397
398     # be sure to have the $ifacevlan up
399     &$activate_interface($ifacevlan);
400
401     # test if $vlaniface is already enslaved in another bridge
402     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
403     if (-l $path) {
404         my $tbridge = basename(readlink($path));
405         if ($tbridge ne $bridgevlan) {
406             die "interface $ifacevlan already exist in bridge $tbridge\n";
407         } else {
408             # Port already attached to bridge: do nothing.
409             return;
410         }
411     }
412
413     # add $ifacevlan to the bridge
414     &$bridge_add_interface($bridgevlan, $ifacevlan);
415 }
416
417 sub activate_bridge_vlan {
418     my ($bridge, $tag_param) = @_;
419
420     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
421
422     return $bridge if !defined($tag_param); # no vlan, simply return
423
424     my $tag = int($tag_param);
425
426     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
427
428     my $bridgevlan = "${bridge}v$tag";
429
430     my @ifaces = ();
431     my $dir = "/sys/class/net/$bridge/brif";
432     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+(\.\d+)?)', sub {
433         push @ifaces, $_[0];
434     });
435
436     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
437
438     # add bridgevlan if it doesn't already exist
439     if (! -d "/sys/class/net/$bridgevlan") {
440         system("/sbin/brctl addbr $bridgevlan") == 0 ||
441             die "can't add bridge $bridgevlan\n";
442     }
443
444     # for each physical interface (eth or bridge) bind them to bridge vlan
445     foreach my $iface (@ifaces) {
446         activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
447     }
448
449     #fixme: set other bridge flags
450
451     # be sure to have the bridge up
452     system("/sbin/ip link set $bridgevlan up") == 0 ||
453         die "can't up bridge $bridgevlan\n";
454    
455     return $bridgevlan;
456 }
457
458 sub tcp_ping {
459     my ($host, $port, $timeout) = @_;
460
461     my $refused = 1;
462
463     $timeout = 3 if !$timeout; # sane default
464     if (!$port) {
465         # Net::Ping defaults to the echo port
466         $port = 7;
467     } else {
468         # Net::Ping's port_number() implies service_check(1)
469         $refused = 0;
470     }
471
472     my ($sock, $result);
473     eval {
474         $result = PVE::Tools::run_with_timeout($timeout, sub {
475             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
476             $result = $refused if $! == ECONNREFUSED;
477         });
478     };
479     if ($sock) {
480         $sock->close();
481         $result = 1;
482     }
483     return $result;
484 }
485
486 sub IP_from_cidr {
487     my ($cidr, $version) = @_;
488
489     return if $cidr !~ m!^(\S+?)/(\S+)$!;
490     my ($ip, $prefix) = ($1, $2);
491
492     my $ipobj = Net::IP->new($ip, $version);
493     return if !$ipobj;
494
495     $version = $ipobj->version();
496
497     my $binmask = Net::IP::ip_get_mask($prefix, $version);
498     return if !$binmask;
499
500     my $masked_binip = $ipobj->binip() & $binmask;
501     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
502     return Net::IP->new("$masked_ip/$prefix");
503 }
504
505 sub is_ip_in_cidr {
506     my ($ip, $cidr, $version) = @_;
507
508     my $cidr_obj = IP_from_cidr($cidr, $version);
509     return undef if !$cidr_obj;
510
511     my $ip_obj = Net::IP->new($ip, $version);
512     return undef if !$ip_obj;
513
514     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
515 }
516
517 1;