src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5
   6 use PVE::INotify;
   7 use PVE::ProcFSTools;
   8 use PVE::Tools qw(run_command lock_file);
   9
  10 use File::Basename;
  11 use IO::Socket::IP;
  12 use Net::IP;
  13 use POSIX qw(ECONNREFUSED);
  14 use Socket qw(NI_NUMERICHOST NI_NUMERICSERV);
  15
  16 # host network related utility functions
  17
  18 our $PHYSICAL_NIC_RE = qr/(?:eth\d+|en[^:.]+|ib\d+)/;
  19
  20 our $ipv4_reverse_mask = [
  21     '0.0.0.0',
  22     '128.0.0.0',
  23     '192.0.0.0',
  24     '224.0.0.0',
  25     '240.0.0.0',
  26     '248.0.0.0',
  27     '252.0.0.0',
  28     '254.0.0.0',
  29     '255.0.0.0',
  30     '255.128.0.0',
  31     '255.192.0.0',
  32     '255.224.0.0',
  33     '255.240.0.0',
  34     '255.248.0.0',
  35     '255.252.0.0',
  36     '255.254.0.0',
  37     '255.255.0.0',
  38     '255.255.128.0',
  39     '255.255.192.0',
  40     '255.255.224.0',
  41     '255.255.240.0',
  42     '255.255.248.0',
  43     '255.255.252.0',
  44     '255.255.254.0',
  45     '255.255.255.0',
  46     '255.255.255.128',
  47     '255.255.255.192',
  48     '255.255.255.224',
  49     '255.255.255.240',
  50     '255.255.255.248',
  51     '255.255.255.252',
  52     '255.255.255.254',
  53     '255.255.255.255',
  54 ];
  55
  56 our $ipv4_mask_hash_localnet = {
  57     '255.0.0.0' => 8,
  58     '255.128.0.0' => 9,
  59     '255.192.0.0' => 10,
  60     '255.224.0.0' => 11,
  61     '255.240.0.0' => 12,
  62     '255.248.0.0' => 13,
  63     '255.252.0.0' => 14,
  64     '255.254.0.0' => 15,
  65     '255.255.0.0' => 16,
  66     '255.255.128.0' => 17,
  67     '255.255.192.0' => 18,
  68     '255.255.224.0' => 19,
  69     '255.255.240.0' => 20,
  70     '255.255.248.0' => 21,
  71     '255.255.252.0' => 22,
  72     '255.255.254.0' => 23,
  73     '255.255.255.0' => 24,
  74     '255.255.255.128' => 25,
  75     '255.255.255.192' => 26,
  76     '255.255.255.224' => 27,
  77     '255.255.255.240' => 28,
  78     '255.255.255.248' => 29,
  79     '255.255.255.252' => 30,
  80     '255.255.255.254' => 31,
  81     '255.255.255.255' => 32,
  82 };
  83
  84 sub setup_tc_rate_limit {
  85     my ($iface, $rate, $burst, $debug) = @_;
  86
  87     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
  88     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
  89     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
  90     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
  91     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
  92
  93     return if !$rate;
  94
  95     # tbf does not work for unknown reason
  96     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  97     # so we use htb instead
  98     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  99     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
 100                 "htb rate ${rate}bps burst ${burst}b");
 101
 102     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
 103     run_command("/sbin/tc filter add dev $iface parent ffff: " .
 104                 "prio 50 basic " .
 105                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
 106                 "drop");
 107
 108     if ($debug) {
 109         print "DEBUG tc settings\n";
 110         system("/sbin/tc qdisc ls dev $iface");
 111         system("/sbin/tc class ls dev $iface");
 112         system("/sbin/tc filter ls dev $iface parent ffff:");
 113     }
 114 }
 115
 116 sub tap_rate_limit {
 117     my ($iface, $rate) = @_;
 118
 119     my $debug = 0;
 120     $rate = int($rate*1024*1024) if $rate;
 121     my $burst = 1024*1024;
 122
 123     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 124 }
 125
 126 my $read_bridge_mtu = sub {
 127     my ($bridge) = @_;
 128
 129     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 130     die "bridge '$bridge' does not exist\n" if !$mtu;
 131     # avoid insecure dependency;
 132     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 133     $mtu = int($1);
 134
 135     return $mtu;
 136 };
 137
 138 my $parse_tap_device_name = sub {
 139     my ($iface, $noerr) = @_;
 140
 141     my ($vmid, $devid);
 142
 143     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 144         $vmid = $1;
 145         $devid = $2;
 146     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 147         $vmid = $1;
 148         $devid = $2;
 149     } else {
 150         return undef if $noerr;
 151         die "can't create firewall bridge for random interface name '$iface'\n";
 152     }
 153
 154     return ($vmid, $devid);
 155 };
 156
 157 my $compute_fwbr_names = sub {
 158     my ($vmid, $devid) = @_;
 159
 160     my $fwbr = "fwbr${vmid}i${devid}";
 161     # Note: the firewall use 'fwln+' to filter traffic to VMs
 162     my $vethfw = "fwln${vmid}i${devid}";
 163     my $vethfwpeer = "fwpr${vmid}p${devid}";
 164     my $ovsintport = "fwln${vmid}o${devid}";
 165
 166     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 167 };
 168
 169 sub iface_delete($) {
 170     my ($iface) = @_;
 171     run_command(['/sbin/ip', 'link', 'delete', 'dev', $iface], noerr => 1)
 172         == 0 or die "failed to delete interface '$iface'\n";
 173 }
 174
 175 sub iface_create($$@) {
 176     my ($iface, $type, @args) = @_;
 177     run_command(['/sbin/ip', 'link', 'add', $iface, 'type', $type, @args], noerr => 1)
 178         == 0 or die "failed to create interface '$iface'\n";
 179 }
 180
 181 sub iface_set($@) {
 182     my ($iface, @opts) = @_;
 183     run_command(['/sbin/ip', 'link', 'set', $iface, @opts], noerr => 1)
 184         == 0 or die "failed to set interface options for '$iface' (".join(' ', @opts).")\n";
 185 }
 186
 187 # helper for nicer error messages:
 188 sub iface_set_master($$) {
 189     my ($iface, $master) = @_;
 190     if (defined($master)) {
 191         eval { iface_set($iface, 'master', $master) };
 192         die "can't enslave '$iface' to '$master'\n" if $@;
 193     } else {
 194         eval { iface_set($iface, 'nomaster') };
 195         die "can't unenslave '$iface'\n" if $@;
 196     }
 197 }
 198
 199 my $cond_create_bridge = sub {
 200     my ($bridge) = @_;
 201
 202     if (! -d "/sys/class/net/$bridge") {
 203         iface_create($bridge, 'bridge');
 204         disable_ipv6($bridge);
 205     }
 206 };
 207
 208 sub disable_ipv6 {
 209     my ($iface) = @_;
 210     return if !-d '/proc/sys/net/ipv6'; # ipv6 might be completely disabled
 211     my $file = "/proc/sys/net/ipv6/conf/$iface/disable_ipv6";
 212     open(my $fh, '>', $file) or die "failed to open $file for writing: $!\n";
 213     print {$fh} "1\n" or die "failed to disable link-local ipv6 for $iface\n";
 214     close($fh);
 215 }
 216
 217 my $bridge_add_interface = sub {
 218     my ($bridge, $iface, $tag, $trunks) = @_;
 219
 220     # drop link local address (it can't be used when on a bridge anyway)
 221     disable_ipv6($iface);
 222     iface_set_master($iface, $bridge);
 223
 224    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 225
 226    if ($vlan_aware) {
 227         if ($tag) {
 228             system({'/sbin/bridge'} 'bridge', 'vlan', 'del', 'dev', $iface, 'vid', '1-4094') == 0
 229                 or die "failed to remove default vlan tags of $iface\n";
 230             system({'/sbin/bridge'} 'bridge', 'vlan', 'add', 'dev', $iface, 'vid', $tag, 'pvid', 'untagged') == 0
 231                 or die "unable to add vlan $tag to interface $iface\n";
 232
 233             warn "Caution: Setting VLAN ID 1 on a VLAN aware bridge may be dangerous\n" if $tag == 1;
 234         } else {
 235             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 236             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
 237         }
 238
 239         if ($trunks) {
 240             my @trunks_array = split /;/, $trunks;
 241             foreach my $trunk (@trunks_array) {
 242                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
 243                 die "unable to add vlan $trunk to interface $iface\n";
 244             }
 245         }
 246    }
 247 };
 248
 249 my $ovs_bridge_add_port = sub {
 250     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 251
 252     $trunks =~ s/;/,/g if $trunks;
 253
 254     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 255     $cmd .= " tag=$tag" if $tag;
 256     $cmd .= " trunks=". join(',', $trunks) if $trunks;
 257     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
 258
 259     $cmd .= " -- set Interface $iface type=internal" if $internal;
 260     system($cmd) == 0 ||
 261         die "can't add ovs port '$iface'\n";
 262     disable_ipv6($iface);
 263 };
 264
 265 my $activate_interface = sub {
 266     my ($iface) = @_;
 267
 268     system("/sbin/ip link set $iface up") == 0 ||
 269         die "can't activate interface '$iface'\n";
 270 };
 271
 272 sub tap_create {
 273     my ($iface, $bridge) = @_;
 274
 275     die "unable to get bridge setting\n" if !$bridge;
 276
 277     my $bridgemtu = &$read_bridge_mtu($bridge);
 278
 279     eval {
 280         disable_ipv6($iface);
 281         PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $iface, 'up', 'promisc', 'on', 'mtu', $bridgemtu]);
 282     };
 283     die "interface activation failed\n" if $@;
 284 }
 285
 286 sub veth_create {
 287     my ($veth, $vethpeer, $bridge, $mac) = @_;
 288
 289     die "unable to get bridge setting\n" if !$bridge;
 290
 291     my $bridgemtu = &$read_bridge_mtu($bridge);
 292
 293     # create veth pair
 294     if (! -d "/sys/class/net/$veth") {
 295         my $cmd = "/sbin/ip link add name $veth mtu $bridgemtu type veth peer name $vethpeer mtu $bridgemtu";
 296         $cmd .= " addr $mac" if $mac;
 297         system($cmd) == 0 || die "can't create interface $veth\n";
 298     }
 299
 300     # up vethpair
 301     disable_ipv6($veth);
 302     disable_ipv6($vethpeer);
 303     &$activate_interface($veth);
 304     &$activate_interface($vethpeer);
 305 }
 306
 307 sub veth_delete {
 308     my ($veth) = @_;
 309
 310     if (-d "/sys/class/net/$veth") {
 311         iface_delete($veth);
 312     }
 313     eval { tap_unplug($veth) };
 314 }
 315
 316 my $create_firewall_bridge_linux = sub {
 317     my ($iface, $bridge, $tag, $trunks) = @_;
 318
 319     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 320     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 321
 322     &$cond_create_bridge($fwbr);
 323     &$activate_interface($fwbr);
 324
 325     copy_bridge_config($bridge, $fwbr);
 326     veth_create($vethfw, $vethfwpeer, $bridge);
 327
 328     &$bridge_add_interface($fwbr, $vethfw);
 329     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 330
 331     &$bridge_add_interface($fwbr, $iface);
 332 };
 333
 334 my $create_firewall_bridge_ovs = sub {
 335     my ($iface, $bridge, $tag, $trunks) = @_;
 336
 337     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 338     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 339
 340     my $bridgemtu = &$read_bridge_mtu($bridge);
 341
 342     &$cond_create_bridge($fwbr);
 343     &$activate_interface($fwbr);
 344
 345     &$bridge_add_interface($fwbr, $iface);
 346
 347     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 348     &$activate_interface($ovsintport);
 349
 350     # set the same mtu for ovs int port
 351     PVE::Tools::run_command(['/sbin/ip', 'link', 'set', $ovsintport, 'mtu', $bridgemtu]);
 352
 353     &$bridge_add_interface($fwbr, $ovsintport);
 354 };
 355
 356 my $cleanup_firewall_bridge = sub {
 357     my ($iface) = @_;
 358
 359     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 360     return if !defined($vmid);
 361     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 362
 363     # cleanup old port config from any openvswitch bridge
 364     if (-d "/sys/class/net/$ovsintport") {
 365         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 366     }
 367
 368     # delete old vethfw interface
 369     veth_delete($vethfw);
 370
 371     # cleanup fwbr bridge
 372     if (-d "/sys/class/net/$fwbr") {
 373         iface_delete($fwbr);
 374     }
 375 };
 376
 377 sub tap_plug {
 378     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 379
 380     #cleanup old port config from any openvswitch bridge
 381     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 382
 383     if (-d "/sys/class/net/$bridge/bridge") {
 384         &$cleanup_firewall_bridge($iface); # remove stale devices
 385
 386         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 387
 388         if (!$vlan_aware) {
 389             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 390             my $newbridge = activate_bridge_vlan($bridge, $tag);
 391             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 392             $bridge = $newbridge;
 393             $tag = undef;
 394         }
 395
 396         if ($firewall) {
 397             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 398         } else {
 399             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 400         }
 401
 402     } else {
 403         &$cleanup_firewall_bridge($iface); # remove stale devices
 404
 405         if ($firewall) {
 406             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 407         } else {
 408             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 409         }
 410     }
 411
 412     tap_rate_limit($iface, $rate);
 413 }
 414
 415 sub tap_unplug {
 416     my ($iface) = @_;
 417
 418     my $path= "/sys/class/net/$iface/brport/bridge";
 419     if (-l $path) {
 420         my $bridge = basename(readlink($path));
 421         #avoid insecure dependency;
 422         ($bridge) = $bridge =~ /(\S+)/;
 423
 424         iface_set_master($iface, undef);
 425     }
 426
 427     &$cleanup_firewall_bridge($iface);
 428     #cleanup old port config from any openvswitch bridge
 429     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 430 }
 431
 432 sub copy_bridge_config {
 433     my ($br0, $br1) = @_;
 434
 435     return if $br0 eq $br1;
 436
 437     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 438                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 439
 440     foreach my $sysname (@$br_configs) {
 441         eval {
 442             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 443             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 444             if ($v0 ne $v1) {
 445                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 446             }
 447         };
 448         warn $@ if $@;
 449     }
 450 }
 451
 452 sub activate_bridge_vlan_slave {
 453     my ($bridgevlan, $iface, $tag) = @_;
 454     my $ifacevlan = "${iface}.$tag";
 455
 456     # create vlan on $iface is not already exist
 457     if (! -d "/sys/class/net/$ifacevlan") {
 458         system("/sbin/ip link add link $iface name $ifacevlan type vlan id $tag") == 0 ||
 459             die "can't add vlan tag $tag to interface $iface\n";
 460
 461         # remove ipv6 link-local address before activation
 462         disable_ipv6($ifacevlan);
 463     }
 464
 465     # be sure to have the $ifacevlan up
 466     &$activate_interface($ifacevlan);
 467
 468     # test if $vlaniface is already enslaved in another bridge
 469     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 470     if (-l $path) {
 471         my $tbridge = basename(readlink($path));
 472         if ($tbridge ne $bridgevlan) {
 473             die "interface $ifacevlan already exist in bridge $tbridge\n";
 474         } else {
 475             # Port already attached to bridge: do nothing.
 476             return;
 477         }
 478     }
 479
 480     # add $ifacevlan to the bridge
 481     &$bridge_add_interface($bridgevlan, $ifacevlan);
 482 }
 483
 484 sub activate_bridge_vlan {
 485     my ($bridge, $tag_param) = @_;
 486
 487     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 488
 489     return $bridge if !defined($tag_param); # no vlan, simply return
 490
 491     my $tag = int($tag_param);
 492
 493     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 494
 495     my $bridgevlan = "${bridge}v$tag";
 496
 497     my @ifaces = ();
 498     my $dir = "/sys/class/net/$bridge/brif";
 499     PVE::Tools::dir_glob_foreach($dir, '(((eth|bond)\d+|en[^.]+)(\.\d+)?)', sub {
 500         push @ifaces, $_[0];
 501     });
 502
 503     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 504
 505     lock_network(sub {
 506         # add bridgevlan if it doesn't already exist
 507         if (! -d "/sys/class/net/$bridgevlan") {
 508             iface_create($bridgevlan, 'bridge');
 509         }
 510
 511         # for each physical interface (eth or bridge) bind them to bridge vlan
 512         foreach my $iface (@ifaces) {
 513             activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 514         }
 515
 516         #fixme: set other bridge flags
 517
 518         # remove ipv6 link-local address before activation
 519         disable_ipv6($bridgevlan);
 520         # be sure to have the bridge up
 521         &$activate_interface($bridgevlan);
 522     });
 523     return $bridgevlan;
 524 }
 525
 526 sub tcp_ping {
 527     my ($host, $port, $timeout) = @_;
 528
 529     my $refused = 1;
 530
 531     $timeout = 3 if !$timeout; # sane default
 532     if (!$port) {
 533         # Net::Ping defaults to the echo port
 534         $port = 7;
 535     } else {
 536         # Net::Ping's port_number() implies service_check(1)
 537         $refused = 0;
 538     }
 539
 540     my ($sock, $result);
 541     eval {
 542         $result = PVE::Tools::run_with_timeout($timeout, sub {
 543             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 544             $result = $refused if $! == ECONNREFUSED;
 545         });
 546     };
 547     if ($sock) {
 548         $sock->close();
 549         $result = 1;
 550     }
 551     return $result;
 552 }
 553
 554 sub IP_from_cidr {
 555     my ($cidr, $version) = @_;
 556
 557     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 558     my ($ip, $prefix) = ($1, $2);
 559
 560     my $ipobj = Net::IP->new($ip, $version);
 561     return if !$ipobj;
 562
 563     $version = $ipobj->version();
 564
 565     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 566     return if !$binmask;
 567
 568     my $masked_binip = $ipobj->binip() & $binmask;
 569     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 570     return Net::IP->new("$masked_ip/$prefix");
 571 }
 572
 573 sub is_ip_in_cidr {
 574     my ($ip, $cidr, $version) = @_;
 575
 576     my $cidr_obj = IP_from_cidr($cidr, $version);
 577     return undef if !$cidr_obj;
 578
 579     my $ip_obj = Net::IP->new($ip, $version);
 580     return undef if !$ip_obj;
 581
 582     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 583 }
 584
 585
 586 sub get_local_ip_from_cidr {
 587     my ($cidr) = @_;
 588
 589     my $IPs = [];
 590     run_command(['/sbin/ip', 'address', 'show', 'to', $cidr, 'up'], outfunc => sub {
 591         if ($_[0] =~ m!^\s*inet(?:6)?\s+($PVE::Tools::IPRE)(?:/\d+|\s+peer\s+)!) {
 592             push @$IPs, $1;
 593         }
 594     });
 595
 596     return $IPs;
 597 }
 598
 599 sub addr_to_ip {
 600     my ($addr) = @_;
 601     my ($err, $host, $port) = Socket::getnameinfo($addr, NI_NUMERICHOST | NI_NUMERICSERV);
 602     die "failed to get numerical host address: $err\n" if $err;
 603     return ($host, $port) if wantarray;
 604     return $host;
 605 }
 606
 607 sub get_ip_from_hostname {
 608     my ($hostname, $noerr) = @_;
 609
 610     my @res = eval { PVE::Tools::getaddrinfo_all($hostname) };
 611     if ($@) {
 612         die "hostname lookup '$hostname' failed - $@" if !$noerr;
 613         return undef;
 614     }
 615
 616     my ($ip, $family);
 617     for my $ai (@res) {
 618         $family = $ai->{family};
 619         my $tmpip = addr_to_ip($ai->{addr});
 620         if ($tmpip !~ m/^127\.|^::1$/) {
 621             $ip = $tmpip;
 622             last;
 623         }
 624     }
 625     if (!defined($ip) ) {
 626         die "hostname lookup '$hostname' failed - got local IP address '$ip'\n" if !$noerr;
 627         return undef;
 628     }
 629
 630     return wantarray ? ($ip, $family) : $ip;
 631 }
 632
 633 sub lock_network {
 634     my ($code, @param) = @_;
 635     my $res = lock_file('/var/lock/pve-network.lck', 10, $code, @param);
 636     die $@ if $@;
 637     return $res;
 638 }
 639
 640 1;