src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Tools qw(run_command);
   6 use PVE::ProcFSTools;
   7 use PVE::INotify;
   8 use File::Basename;
   9
  10 # host network related utility functions
  11
  12 our $ipv4_reverse_mask = [
  13     '0.0.0.0',
  14     '128.0.0.0',
  15     '192.0.0.0',
  16     '224.0.0.0',
  17     '240.0.0.0',
  18     '248.0.0.0',
  19     '252.0.0.0',
  20     '254.0.0.0',
  21     '255.0.0.0',
  22     '255.128.0.0',
  23     '255.192.0.0',
  24     '255.224.0.0',
  25     '255.240.0.0',
  26     '255.248.0.0',
  27     '255.252.0.0',
  28     '255.254.0.0',
  29     '255.255.0.0',
  30     '255.255.128.0',
  31     '255.255.192.0',
  32     '255.255.224.0',
  33     '255.255.240.0',
  34     '255.255.248.0',
  35     '255.255.252.0',
  36     '255.255.254.0',
  37     '255.255.255.0',
  38     '255.255.255.128',
  39     '255.255.255.192',
  40     '255.255.255.224',
  41     '255.255.255.240',
  42     '255.255.255.248',
  43     '255.255.255.252',
  44     '255.255.255.254',
  45     '255.255.255.255',
  46 ];
  47
  48 our $ipv4_mask_hash_localnet = {
  49     '255.255.0.0' => 16,
  50     '255.255.128.0' => 17,
  51     '255.255.192.0' => 18,
  52     '255.255.224.0' => 19,
  53     '255.255.240.0' => 20,
  54     '255.255.248.0' => 21,
  55     '255.255.252.0' => 22,
  56     '255.255.254.0' => 23,
  57     '255.255.255.0' => 24,
  58     '255.255.255.128' => 25,
  59     '255.255.255.192' => 26,
  60     '255.255.255.224' => 27,
  61     '255.255.255.240' => 28,
  62     '255.255.255.248' => 29,
  63     '255.255.255.252' => 30,
  64 };
  65
  66 sub setup_tc_rate_limit {
  67     my ($iface, $rate, $burst, $debug) = @_;
  68
  69     system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
  70     system("/sbin/tc filter del dev $iface parent ffff: protocol ip prio 50 estimator 1sec 8sec >/dev/null 2>&1");
  71     system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
  72     system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
  73
  74     return if !$rate;
  75
  76     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
  77
  78     # this does not work wit virtio - don't know why (setting "mtu 64kb" does not help)
  79     #run_command("/sbin/tc filter add dev $iface parent ffff: protocol ip prio 50 u32 match ip src 0.0.0.0/0 police rate ${rate}bps burst ${burst}b drop flowid :1");
  80     # so we use avrate instead
  81     run_command("/sbin/tc filter add dev $iface parent ffff: " .
  82                 "protocol ip prio 50 estimator 1sec 8sec " .
  83                 "u32 match ip src 0.0.0.0/0 police avrate ${rate}bps drop flowid :1");
  84
  85     # tbf does not work for unknown reason
  86     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  87     # so we use htb instead
  88     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  89     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
  90                 "htb rate ${rate}bps burst ${burst}b");
  91
  92     if ($debug) {
  93         print "DEBUG tc settings\n";
  94         system("/sbin/tc qdisc ls dev $iface");
  95         system("/sbin/tc class ls dev $iface");
  96         system("/sbin/tc filter ls dev $iface parent ffff:");
  97     }
  98 }
  99
 100 sub tap_rate_limit {
 101     my ($iface, $rate) = @_;
 102
 103     my $debug = 0;
 104     $rate = int($rate*1024*1024);
 105     my $burst = 1024*1024;
 106
 107     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 108 }
 109
 110 my $read_bridge_mtu = sub {
 111     my ($bridge) = @_;
 112
 113     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 114     die "bridge '$bridge' does not exist\n" if !$mtu;
 115     # avoid insecure dependency;
 116     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 117     $mtu = int($1);
 118
 119     return $mtu;
 120 };
 121
 122 my $parse_tap_device_name = sub {
 123     my ($iface, $noerr) = @_;
 124
 125     my ($vmid, $devid);
 126
 127     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 128         $vmid = $1;
 129         $devid = $2;
 130     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 131         $vmid = $1;
 132         $devid = $2;
 133     } else {
 134         return undef if $noerr;
 135         die "can't create firewall bridge for random interface name '$iface'\n";
 136     }
 137
 138     return ($vmid, $devid);
 139 };
 140
 141 my $compute_fwbr_names = sub {
 142     my ($vmid, $devid) = @_;
 143
 144     my $fwbr = "fwbr${vmid}i${devid}";
 145     # Note: the firewall use 'fwln+' to filter traffic to VMs
 146     my $vethfw = "fwln${vmid}i${devid}";
 147     my $vethfwpeer = "fwpr${vmid}p${devid}";
 148     my $ovsintport = "fwln${vmid}o${devid}";
 149
 150     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 151 };
 152
 153 my $cond_create_bridge = sub {
 154     my ($bridge) = @_;
 155
 156     if (! -d "/sys/class/net/$bridge") {
 157         system("/sbin/brctl addbr $bridge") == 0 ||
 158             die "can't add bridge '$bridge'\n";
 159     }
 160 };
 161
 162 my $bridge_add_interface = sub {
 163     my ($bridge, $iface, $tag) = @_;
 164
 165     system("/sbin/brctl addif $bridge $iface") == 0 ||
 166         die "can't add interface 'iface' to bridge '$bridge'\n";
 167
 168    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 169
 170    if ($vlan_aware) {
 171         if ($tag) {
 172             system("/sbin/bridge vlan add dev $iface vid $tag pvid untagged") == 0 ||
 173             die "unable to add vlan $tag to interface $iface\n";
 174         } else {
 175             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 176             die "unable to add vlan $tag to interface $iface\n";
 177         }
 178    }
 179 };
 180
 181 my $ovs_bridge_add_port = sub {
 182     my ($bridge, $iface, $tag, $internal) = @_;
 183
 184     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 185     $cmd .= " tag=$tag" if $tag;
 186     $cmd .= " -- set Interface $iface type=internal" if $internal;
 187     system($cmd) == 0 ||
 188         die "can't add ovs port '$iface'\n";
 189 };
 190
 191 my $activate_interface = sub {
 192     my ($iface) = @_;
 193
 194     system("/sbin/ip link set $iface up") == 0 ||
 195         die "can't activate interface '$iface'\n";
 196 };
 197
 198 sub tap_create {
 199     my ($iface, $bridge) = @_;
 200
 201     die "unable to get bridge setting\n" if !$bridge;
 202
 203     my $bridgemtu = &$read_bridge_mtu($bridge);
 204
 205     eval {
 206         PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
 207     };
 208     die "interface activation failed\n" if $@;
 209 }
 210
 211 sub veth_create {
 212     my ($veth, $vethpeer, $bridge, $mac) = @_;
 213
 214     die "unable to get bridge setting\n" if !$bridge;
 215
 216     my $bridgemtu = &$read_bridge_mtu($bridge);
 217
 218     # create veth pair
 219     if (! -d "/sys/class/net/$veth") {
 220         my $cmd = "/sbin/ip link add name $veth type veth peer name $vethpeer mtu $bridgemtu";
 221         $cmd .= " addr $mac" if $mac;
 222         system($cmd) == 0 || die "can't create interface $veth\n";
 223     }
 224
 225     # up vethpair
 226     &$activate_interface($veth);
 227     &$activate_interface($vethpeer);
 228 }
 229
 230 sub veth_delete {
 231     my ($veth) = @_;
 232
 233     if (-d "/sys/class/net/$veth") {
 234         run_command("/sbin/ip link delete dev $veth", outfunc => sub {}, errfunc => sub {});
 235     }
 236
 237 }
 238
 239 my $create_firewall_bridge_linux = sub {
 240     my ($iface, $bridge, $tag) = @_;
 241
 242     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 243     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 244
 245     &$cond_create_bridge($fwbr);
 246     &$activate_interface($fwbr);
 247
 248     copy_bridge_config($bridge, $fwbr);
 249     veth_create($vethfw, $vethfwpeer, $bridge);
 250
 251     &$bridge_add_interface($fwbr, $vethfw);
 252     &$bridge_add_interface($bridge, $vethfwpeer, $tag);
 253
 254     &$bridge_add_interface($fwbr, $iface);
 255 };
 256
 257 my $create_firewall_bridge_ovs = sub {
 258     my ($iface, $bridge, $tag) = @_;
 259
 260     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 261     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 262
 263     my $bridgemtu = &$read_bridge_mtu($bridge);
 264
 265     &$cond_create_bridge($fwbr);
 266     &$activate_interface($fwbr);
 267
 268     &$bridge_add_interface($fwbr, $iface);
 269
 270     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1);
 271     &$activate_interface($ovsintport);
 272
 273     # set the same mtu for ovs int port
 274     PVE::Tools::run_command("/sbin/ifconfig $ovsintport mtu $bridgemtu");
 275
 276     &$bridge_add_interface($fwbr, $ovsintport);
 277 };
 278
 279 my $cleanup_firewall_bridge = sub {
 280     my ($iface) = @_;
 281
 282     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 283     return if !defined($vmid);
 284     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 285
 286     # cleanup old port config from any openvswitch bridge
 287     if (-d "/sys/class/net/$ovsintport") {
 288         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 289     }
 290
 291     # delete old vethfw interface
 292     veth_delete($vethfw);
 293
 294     # cleanup fwbr bridge
 295     if (-d "/sys/class/net/$fwbr") {
 296         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
 297         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
 298     }
 299 };
 300
 301 sub tap_plug {
 302     my ($iface, $bridge, $tag, $firewall) = @_;
 303
 304     #cleanup old port config from any openvswitch bridge
 305     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 306
 307     if (-d "/sys/class/net/$bridge/bridge") {
 308         &$cleanup_firewall_bridge($iface); # remove stale devices
 309
 310         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 311
 312         if (!$vlan_aware) {
 313             my $newbridge = activate_bridge_vlan($bridge, $tag);
 314             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 315             $bridge = $newbridge;
 316             $tag = undef;
 317         }
 318
 319         if ($firewall) {
 320             &$create_firewall_bridge_linux($iface, $bridge, $tag);
 321         } else {
 322             &$bridge_add_interface($bridge, $iface, $tag);
 323         }
 324
 325     } else {
 326         &$cleanup_firewall_bridge($iface); # remove stale devices
 327
 328         if ($firewall) {
 329             &$create_firewall_bridge_ovs($iface, $bridge, $tag);
 330         } else {
 331             &$ovs_bridge_add_port($bridge, $iface, $tag);
 332         }
 333     }
 334 }
 335
 336 sub tap_unplug {
 337     my ($iface) = @_;
 338
 339     my $path= "/sys/class/net/$iface/brport/bridge";
 340     if (-l $path) {
 341         my $bridge = basename(readlink($path));
 342         #avoid insecure dependency;
 343         ($bridge) = $bridge =~ /(\S+)/;
 344
 345         system("/sbin/brctl delif $bridge $iface") == 0 ||
 346             die "can't del interface '$iface' from bridge '$bridge'\n";
 347
 348     }
 349
 350     &$cleanup_firewall_bridge($iface);
 351 }
 352
 353 sub copy_bridge_config {
 354     my ($br0, $br1) = @_;
 355
 356     return if $br0 eq $br1;
 357
 358     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 359                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 360
 361     foreach my $sysname (@$br_configs) {
 362         eval {
 363             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 364             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 365             if ($v0 ne $v1) {
 366                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 367             }
 368         };
 369         warn $@ if $@;
 370     }
 371 }
 372
 373 sub activate_bridge_vlan_slave {
 374     my ($bridgevlan, $iface, $tag) = @_;
 375     my $ifacevlan = "${iface}.$tag";
 376
 377     # create vlan on $iface is not already exist
 378     if (! -d "/sys/class/net/$ifacevlan") {
 379         system("/sbin/ip link add link $iface name ${iface}.${tag} type vlan id $tag") == 0 ||
 380             die "can't add vlan tag $tag to interface $iface\n";
 381     }
 382
 383     # be sure to have the $ifacevlan up
 384     &$activate_interface($ifacevlan);
 385
 386     # test if $vlaniface is already enslaved in another bridge
 387     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 388     if (-l $path) {
 389         my $tbridge = basename(readlink($path));
 390         if ($tbridge ne $bridgevlan) {
 391             die "interface $ifacevlan already exist in bridge $tbridge\n";
 392         } else {
 393             # Port already attached to bridge: do nothing.
 394             return;
 395         }
 396     }
 397
 398     # add $ifacevlan to the bridge
 399     &$bridge_add_interface($bridgevlan, $ifacevlan);
 400 }
 401
 402 sub activate_bridge_vlan {
 403     my ($bridge, $tag_param) = @_;
 404
 405     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 406
 407     return $bridge if !defined($tag_param); # no vlan, simply return
 408
 409     my $tag = int($tag_param);
 410
 411     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 412
 413     my $bridgevlan = "${bridge}v$tag";
 414
 415     my @ifaces = ();
 416     my $dir = "/sys/class/net/$bridge/brif";
 417     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+)', sub {
 418         push @ifaces, $_[0];
 419     });
 420
 421     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 422
 423     # add bridgevlan if it doesn't already exist
 424     if (! -d "/sys/class/net/$bridgevlan") {
 425         system("/sbin/brctl addbr $bridgevlan") == 0 ||
 426             die "can't add bridge $bridgevlan\n";
 427     }
 428
 429     # for each physical interface (eth or bridge) bind them to bridge vlan
 430     foreach my $iface (@ifaces) {
 431         activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 432     }
 433
 434     #fixme: set other bridge flags
 435
 436     # be sure to have the bridge up
 437     system("/sbin/ip link set $bridgevlan up") == 0 ||
 438         die "can't up bridge $bridgevlan\n";
 439
 440     return $bridgevlan;
 441 }
 442
 443 1;