be2613298b73358e229ac581638c18e4f5a4ccdb
[pve-common.git] / src / PVE / Network.pm
1 package PVE::Network;
2
3 use strict;
4 use warnings;
5 use PVE::Tools qw(run_command);
6 use PVE::ProcFSTools;
7 use PVE::INotify;
8 use File::Basename;
9 use IO::Socket::IP;
10 use POSIX qw(ECONNREFUSED);
11
12 use Net::IP;
13
14 use Socket qw(IPPROTO_IP);
15
16 use constant IFF_UP => 1;
17 use constant IFNAMSIZ => 16;
18 use constant SIOCGIFFLAGS => 0x8913;
19
20 # host network related utility functions
21
22 our $ipv4_reverse_mask = [
23     '0.0.0.0',
24     '128.0.0.0',
25     '192.0.0.0',
26     '224.0.0.0',
27     '240.0.0.0',
28     '248.0.0.0',
29     '252.0.0.0',
30     '254.0.0.0',
31     '255.0.0.0',
32     '255.128.0.0',
33     '255.192.0.0',
34     '255.224.0.0',
35     '255.240.0.0',
36     '255.248.0.0',
37     '255.252.0.0',
38     '255.254.0.0',
39     '255.255.0.0',
40     '255.255.128.0',
41     '255.255.192.0',
42     '255.255.224.0',
43     '255.255.240.0',
44     '255.255.248.0',
45     '255.255.252.0',
46     '255.255.254.0',
47     '255.255.255.0',
48     '255.255.255.128',
49     '255.255.255.192',
50     '255.255.255.224',
51     '255.255.255.240',
52     '255.255.255.248',
53     '255.255.255.252',
54     '255.255.255.254',
55     '255.255.255.255',
56 ];
57
58 our $ipv4_mask_hash_localnet = {
59     '255.255.0.0' => 16,
60     '255.255.128.0' => 17,
61     '255.255.192.0' => 18,
62     '255.255.224.0' => 19,
63     '255.255.240.0' => 20,
64     '255.255.248.0' => 21,
65     '255.255.252.0' => 22,
66     '255.255.254.0' => 23,
67     '255.255.255.0' => 24,
68     '255.255.255.128' => 25,
69     '255.255.255.192' => 26,
70     '255.255.255.224' => 27,
71     '255.255.255.240' => 28,
72     '255.255.255.248' => 29,
73     '255.255.255.252' => 30,
74 };
75
76 sub setup_tc_rate_limit {
77     my ($iface, $rate, $burst, $debug) = @_;
78
79     # these are allowed / expected to fail, e.g. when there is no previous rate limit to remove
80     eval { run_command("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1"); };
81     eval { run_command("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1"); };
82     eval { run_command("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1"); };
83     eval { run_command("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1"); };
84
85     return if !$rate;
86
87     # tbf does not work for unknown reason
88     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
89     # so we use htb instead
90     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
91     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
92                 "htb rate ${rate}bps burst ${burst}b");
93
94     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
95     run_command("/sbin/tc filter add dev $iface parent ffff: " .
96                 "prio 50 basic " .
97                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
98                 "drop flowid :1");
99
100     if ($debug) {
101         print "DEBUG tc settings\n";
102         system("/sbin/tc qdisc ls dev $iface");
103         system("/sbin/tc class ls dev $iface");
104         system("/sbin/tc filter ls dev $iface parent ffff:");
105     }
106 }
107
108 sub tap_rate_limit {
109     my ($iface, $rate) = @_;
110
111     my $debug = 0;
112     $rate = int($rate*1024*1024) if $rate;
113     my $burst = 1024*1024;
114
115     setup_tc_rate_limit($iface, $rate, $burst, $debug);
116 }
117
118 my $read_bridge_mtu = sub {
119     my ($bridge) = @_;
120
121     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
122     die "bridge '$bridge' does not exist\n" if !$mtu;
123     # avoid insecure dependency;
124     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
125     $mtu = int($1);
126
127     return $mtu;
128 };
129
130 my $parse_tap_device_name = sub {
131     my ($iface, $noerr) = @_;
132
133     my ($vmid, $devid);
134
135     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
136         $vmid = $1;
137         $devid = $2;
138     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
139         $vmid = $1;
140         $devid = $2;
141     } else {
142         return undef if $noerr;
143         die "can't create firewall bridge for random interface name '$iface'\n";
144     }
145
146     return ($vmid, $devid);
147 };
148
149 my $compute_fwbr_names = sub {
150     my ($vmid, $devid) = @_;
151
152     my $fwbr = "fwbr${vmid}i${devid}";
153     # Note: the firewall use 'fwln+' to filter traffic to VMs
154     my $vethfw = "fwln${vmid}i${devid}";
155     my $vethfwpeer = "fwpr${vmid}p${devid}";
156     my $ovsintport = "fwln${vmid}o${devid}";
157
158     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
159 };
160
161 my $cond_create_bridge = sub {
162     my ($bridge) = @_;
163
164     if (! -d "/sys/class/net/$bridge") {
165         system("/sbin/brctl addbr $bridge") == 0 ||
166             die "can't add bridge '$bridge'\n";
167     }
168 };
169
170 my $bridge_add_interface = sub {
171     my ($bridge, $iface, $tag, $trunks) = @_;
172
173     system("/sbin/brctl addif $bridge $iface") == 0 ||
174         die "can't add interface 'iface' to bridge '$bridge'\n";
175
176    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
177
178    if ($vlan_aware) {
179         if ($tag) {
180             system("/sbin/bridge vlan add dev $iface vid $tag pvid untagged") == 0 ||
181             die "unable to add vlan $tag to interface $iface\n";
182         } else {
183             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
184             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
185         } 
186
187         if ($trunks) {
188             my @trunks_array = split /;/, $trunks;
189             foreach my $trunk (@trunks_array) { 
190                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
191                 die "unable to add vlan $trunk to interface $iface\n";
192             }
193         }
194    }
195 };
196
197 my $ovs_bridge_add_port = sub {
198     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
199
200     $trunks =~ s/;/,/g if $trunks;
201
202     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
203     $cmd .= " tag=$tag" if $tag;
204     $cmd .= " trunks=". join(',', $trunks) if $trunks;
205     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
206
207     $cmd .= " -- set Interface $iface type=internal" if $internal;
208     system($cmd) == 0 ||
209         die "can't add ovs port '$iface'\n";
210 };
211
212 my $activate_interface = sub {
213     my ($iface) = @_;
214
215     system("/sbin/ip link set $iface up") == 0 ||
216         die "can't activate interface '$iface'\n";
217 };
218
219 sub tap_create {
220     my ($iface, $bridge) = @_;
221
222     die "unable to get bridge setting\n" if !$bridge;
223
224     my $bridgemtu = &$read_bridge_mtu($bridge);
225
226     eval { 
227         PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
228     };
229     die "interface activation failed\n" if $@;
230 }
231
232 sub veth_create {
233     my ($veth, $vethpeer, $bridge, $mac) = @_;
234
235     die "unable to get bridge setting\n" if !$bridge;
236
237     my $bridgemtu = &$read_bridge_mtu($bridge);
238
239     # create veth pair
240     if (! -d "/sys/class/net/$veth") {
241         my $cmd = "/sbin/ip link add name $veth type veth peer name $vethpeer mtu $bridgemtu";
242         $cmd .= " addr $mac" if $mac;
243         system($cmd) == 0 || die "can't create interface $veth\n";
244     }
245
246     # up vethpair
247     &$activate_interface($veth);
248     &$activate_interface($vethpeer);
249 }
250
251 sub veth_delete {
252     my ($veth) = @_;
253
254     if (-d "/sys/class/net/$veth") {
255         run_command("/sbin/ip link delete dev $veth", outfunc => sub {}, errfunc => sub {});
256     }
257
258 }
259
260 my $create_firewall_bridge_linux = sub {
261     my ($iface, $bridge, $tag, $trunks) = @_;
262
263     my ($vmid, $devid) = &$parse_tap_device_name($iface);
264     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
265
266     &$cond_create_bridge($fwbr);
267     &$activate_interface($fwbr);
268
269     copy_bridge_config($bridge, $fwbr);
270     veth_create($vethfw, $vethfwpeer, $bridge);
271
272     &$bridge_add_interface($fwbr, $vethfw);
273     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
274
275     &$bridge_add_interface($fwbr, $iface);
276 };
277
278 my $create_firewall_bridge_ovs = sub {
279     my ($iface, $bridge, $tag, $trunks) = @_;
280
281     my ($vmid, $devid) = &$parse_tap_device_name($iface);
282     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
283
284     my $bridgemtu = &$read_bridge_mtu($bridge);
285
286     &$cond_create_bridge($fwbr);
287     &$activate_interface($fwbr);
288
289     &$bridge_add_interface($fwbr, $iface);
290
291     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
292     &$activate_interface($ovsintport);
293
294     # set the same mtu for ovs int port
295     PVE::Tools::run_command("/sbin/ifconfig $ovsintport mtu $bridgemtu");
296     
297     &$bridge_add_interface($fwbr, $ovsintport);
298 };
299
300 my $cleanup_firewall_bridge = sub {
301     my ($iface) = @_;
302
303     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
304     return if !defined($vmid);  
305     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
306
307     # cleanup old port config from any openvswitch bridge
308     if (-d "/sys/class/net/$ovsintport") {
309         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
310     }
311
312     # delete old vethfw interface
313     veth_delete($vethfw);
314
315     # cleanup fwbr bridge
316     if (-d "/sys/class/net/$fwbr") {
317         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
318         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
319     }
320 };
321
322 sub tap_plug {
323     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
324
325     #cleanup old port config from any openvswitch bridge
326     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
327
328     if (-d "/sys/class/net/$bridge/bridge") {
329         &$cleanup_firewall_bridge($iface); # remove stale devices
330
331         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
332
333         if (!$vlan_aware) {
334             die "vlan aware feature need to be enabled to use trunks" if $trunks;
335             my $newbridge = activate_bridge_vlan($bridge, $tag);
336             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
337             $bridge = $newbridge;
338             $tag = undef;
339         }
340
341         if ($firewall) {
342             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
343         } else {
344             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
345         }
346
347     } else {
348         &$cleanup_firewall_bridge($iface); # remove stale devices
349
350         if ($firewall) {
351             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
352         } else {
353             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
354         }
355     }
356
357     tap_rate_limit($iface, $rate);
358 }
359
360 sub tap_unplug {
361     my ($iface) = @_;
362
363     my $path= "/sys/class/net/$iface/brport/bridge";
364     if (-l $path) {
365         my $bridge = basename(readlink($path));
366         #avoid insecure dependency;
367         ($bridge) = $bridge =~ /(\S+)/;
368
369         system("/sbin/brctl delif $bridge $iface") == 0 ||
370             die "can't del interface '$iface' from bridge '$bridge'\n";
371
372     }
373     
374     &$cleanup_firewall_bridge($iface);
375     #cleanup old port config from any openvswitch bridge
376     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
377 }
378
379 sub copy_bridge_config {
380     my ($br0, $br1) = @_;
381
382     return if $br0 eq $br1;
383
384     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay', 
385                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
386
387     foreach my $sysname (@$br_configs) {
388         eval {
389             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
390             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
391             if ($v0 ne $v1) {
392                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
393             }
394         };
395         warn $@ if $@;
396     }
397 }
398
399 sub activate_bridge_vlan_slave {
400     my ($bridgevlan, $iface, $tag) = @_;
401     my $ifacevlan = "${iface}.$tag";
402         
403     # create vlan on $iface is not already exist
404     if (! -d "/sys/class/net/$ifacevlan") {
405         system("/sbin/ip link add link $iface name ${iface}.${tag} type vlan id $tag") == 0 ||
406             die "can't add vlan tag $tag to interface $iface\n";
407     }
408
409     # be sure to have the $ifacevlan up
410     &$activate_interface($ifacevlan);
411
412     # test if $vlaniface is already enslaved in another bridge
413     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
414     if (-l $path) {
415         my $tbridge = basename(readlink($path));
416         if ($tbridge ne $bridgevlan) {
417             die "interface $ifacevlan already exist in bridge $tbridge\n";
418         } else {
419             # Port already attached to bridge: do nothing.
420             return;
421         }
422     }
423
424     # add $ifacevlan to the bridge
425     &$bridge_add_interface($bridgevlan, $ifacevlan);
426 }
427
428 sub activate_bridge_vlan {
429     my ($bridge, $tag_param) = @_;
430
431     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
432
433     return $bridge if !defined($tag_param); # no vlan, simply return
434
435     my $tag = int($tag_param);
436
437     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
438
439     my $bridgevlan = "${bridge}v$tag";
440
441     my @ifaces = ();
442     my $dir = "/sys/class/net/$bridge/brif";
443     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+(\.\d+)?)', sub {
444         push @ifaces, $_[0];
445     });
446
447     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
448
449     # add bridgevlan if it doesn't already exist
450     if (! -d "/sys/class/net/$bridgevlan") {
451         system("/sbin/brctl addbr $bridgevlan") == 0 ||
452             die "can't add bridge $bridgevlan\n";
453     }
454
455     # for each physical interface (eth or bridge) bind them to bridge vlan
456     foreach my $iface (@ifaces) {
457         activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
458     }
459
460     #fixme: set other bridge flags
461
462     # be sure to have the bridge up
463     system("/sbin/ip link set $bridgevlan up") == 0 ||
464         die "can't up bridge $bridgevlan\n";
465    
466     return $bridgevlan;
467 }
468
469 sub tcp_ping {
470     my ($host, $port, $timeout) = @_;
471
472     my $refused = 1;
473
474     $timeout = 3 if !$timeout; # sane default
475     if (!$port) {
476         # Net::Ping defaults to the echo port
477         $port = 7;
478     } else {
479         # Net::Ping's port_number() implies service_check(1)
480         $refused = 0;
481     }
482
483     my ($sock, $result);
484     eval {
485         $result = PVE::Tools::run_with_timeout($timeout, sub {
486             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
487             $result = $refused if $! == ECONNREFUSED;
488         });
489     };
490     if ($sock) {
491         $sock->close();
492         $result = 1;
493     }
494     return $result;
495 }
496
497 sub IP_from_cidr {
498     my ($cidr, $version) = @_;
499
500     return if $cidr !~ m!^(\S+?)/(\S+)$!;
501     my ($ip, $prefix) = ($1, $2);
502
503     my $ipobj = Net::IP->new($ip, $version);
504     return if !$ipobj;
505
506     $version = $ipobj->version();
507
508     my $binmask = Net::IP::ip_get_mask($prefix, $version);
509     return if !$binmask;
510
511     my $masked_binip = $ipobj->binip() & $binmask;
512     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
513     return Net::IP->new("$masked_ip/$prefix");
514 }
515
516 sub is_ip_in_cidr {
517     my ($ip, $cidr, $version) = @_;
518
519     my $cidr_obj = IP_from_cidr($cidr, $version);
520     return undef if !$cidr_obj;
521
522     my $ip_obj = Net::IP->new($ip, $version);
523     return undef if !$ip_obj;
524
525     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
526 }
527
528 # struct ifreq { // FOR SIOCGIFFLAGS:
529 #   char ifrn_name[IFNAMSIZ]
530 #   short ifru_flags
531 # };
532 my $STRUCT_IFREQ_SIOCGIFFLAGS = 'Z' . IFNAMSIZ . 's1';
533 sub get_active_interfaces {
534     # Use the interface name list from /proc/net/dev
535     open my $fh, '<', '/proc/net/dev'
536         or die "failed to open /proc/net/dev: $!\n";
537     # And filter by IFF_UP flag fetched via a PF_INET6 socket ioctl:
538     my $sock;
539     socket($sock, PF_INET6, SOCK_DGRAM, &IPPROTO_IP)
540     or socket($sock, PF_INET, SOCK_DGRAM, &IPPROTO_IP)
541     or return [];
542
543     my $ifaces = [];
544     while(defined(my $line = <$fh>)) {
545         next if $line !~ /^\s*([^:\s]+):/;
546         my $ifname = $1;
547         my $ifreq = pack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifname, 0);
548         if (!defined(ioctl($sock, SIOCGIFFLAGS, $ifreq))) {
549             warn "failed to get interface flags for: $ifname\n";
550             next;
551         }
552         my ($name, $flags) = unpack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifreq);
553         push @$ifaces, $ifname if ($flags & IFF_UP);
554     }
555     close $fh;
556     close $sock;
557     return $ifaces;
558 }
559
560 1;