src/PVE/Network.pm

   1 package PVE::Network;
   2
   3 use strict;
   4 use warnings;
   5 use PVE::Tools qw(run_command);
   6 use PVE::ProcFSTools;
   7 use PVE::INotify;
   8 use File::Basename;
   9 use IO::Socket::IP;
  10 use POSIX qw(ECONNREFUSED);
  11
  12 use Net::IP;
  13
  14 use Socket qw(IPPROTO_IP);
  15
  16 use constant IFF_UP => 1;
  17 use constant IFNAMSIZ => 16;
  18 use constant SIOCGIFFLAGS => 0x8913;
  19
  20 # host network related utility functions
  21
  22 our $ipv4_reverse_mask = [
  23     '0.0.0.0',
  24     '128.0.0.0',
  25     '192.0.0.0',
  26     '224.0.0.0',
  27     '240.0.0.0',
  28     '248.0.0.0',
  29     '252.0.0.0',
  30     '254.0.0.0',
  31     '255.0.0.0',
  32     '255.128.0.0',
  33     '255.192.0.0',
  34     '255.224.0.0',
  35     '255.240.0.0',
  36     '255.248.0.0',
  37     '255.252.0.0',
  38     '255.254.0.0',
  39     '255.255.0.0',
  40     '255.255.128.0',
  41     '255.255.192.0',
  42     '255.255.224.0',
  43     '255.255.240.0',
  44     '255.255.248.0',
  45     '255.255.252.0',
  46     '255.255.254.0',
  47     '255.255.255.0',
  48     '255.255.255.128',
  49     '255.255.255.192',
  50     '255.255.255.224',
  51     '255.255.255.240',
  52     '255.255.255.248',
  53     '255.255.255.252',
  54     '255.255.255.254',
  55     '255.255.255.255',
  56 ];
  57
  58 our $ipv4_mask_hash_localnet = {
  59     '255.255.0.0' => 16,
  60     '255.255.128.0' => 17,
  61     '255.255.192.0' => 18,
  62     '255.255.224.0' => 19,
  63     '255.255.240.0' => 20,
  64     '255.255.248.0' => 21,
  65     '255.255.252.0' => 22,
  66     '255.255.254.0' => 23,
  67     '255.255.255.0' => 24,
  68     '255.255.255.128' => 25,
  69     '255.255.255.192' => 26,
  70     '255.255.255.224' => 27,
  71     '255.255.255.240' => 28,
  72     '255.255.255.248' => 29,
  73     '255.255.255.252' => 30,
  74 };
  75
  76 sub setup_tc_rate_limit {
  77     my ($iface, $rate, $burst, $debug) = @_;
  78
  79     system("/sbin/tc class del dev $iface parent 1: classid 1:1 >/dev/null 2>&1");
  80     system("/sbin/tc filter del dev $iface parent ffff: protocol all pref 50 u32 >/dev/null 2>&1");
  81     system("/sbin/tc qdisc del dev $iface ingress >/dev/null 2>&1");
  82     system("/sbin/tc qdisc del dev $iface root >/dev/null 2>&1");
  83
  84     return if !$rate;
  85
  86     # tbf does not work for unknown reason
  87     #$TC qdisc add dev $DEV root tbf rate $RATE latency 100ms burst $BURST
  88     # so we use htb instead
  89     run_command("/sbin/tc qdisc add dev $iface root handle 1: htb default 1");
  90     run_command("/sbin/tc class add dev $iface parent 1: classid 1:1 " .
  91                 "htb rate ${rate}bps burst ${burst}b");
  92
  93     run_command("/sbin/tc qdisc add dev $iface handle ffff: ingress");
  94     run_command("/sbin/tc filter add dev $iface parent ffff: " .
  95                 "prio 50 basic " .
  96                 "police rate ${rate}bps burst ${burst}b mtu 64kb " .
  97                 "drop flowid :1");
  98
  99     if ($debug) {
 100         print "DEBUG tc settings\n";
 101         system("/sbin/tc qdisc ls dev $iface");
 102         system("/sbin/tc class ls dev $iface");
 103         system("/sbin/tc filter ls dev $iface parent ffff:");
 104     }
 105 }
 106
 107 sub tap_rate_limit {
 108     my ($iface, $rate) = @_;
 109
 110     my $debug = 0;
 111     $rate = int($rate*1024*1024) if $rate;
 112     my $burst = 1024*1024;
 113
 114     setup_tc_rate_limit($iface, $rate, $burst, $debug);
 115 }
 116
 117 my $read_bridge_mtu = sub {
 118     my ($bridge) = @_;
 119
 120     my $mtu = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/mtu");
 121     die "bridge '$bridge' does not exist\n" if !$mtu;
 122     # avoid insecure dependency;
 123     die "unable to parse mtu value" if $mtu !~ /^(\d+)$/;
 124     $mtu = int($1);
 125
 126     return $mtu;
 127 };
 128
 129 my $parse_tap_device_name = sub {
 130     my ($iface, $noerr) = @_;
 131
 132     my ($vmid, $devid);
 133
 134     if ($iface =~ m/^tap(\d+)i(\d+)$/) {
 135         $vmid = $1;
 136         $devid = $2;
 137     } elsif ($iface =~ m/^veth(\d+)i(\d+)$/) {
 138         $vmid = $1;
 139         $devid = $2;
 140     } else {
 141         return undef if $noerr;
 142         die "can't create firewall bridge for random interface name '$iface'\n";
 143     }
 144
 145     return ($vmid, $devid);
 146 };
 147
 148 my $compute_fwbr_names = sub {
 149     my ($vmid, $devid) = @_;
 150
 151     my $fwbr = "fwbr${vmid}i${devid}";
 152     # Note: the firewall use 'fwln+' to filter traffic to VMs
 153     my $vethfw = "fwln${vmid}i${devid}";
 154     my $vethfwpeer = "fwpr${vmid}p${devid}";
 155     my $ovsintport = "fwln${vmid}o${devid}";
 156
 157     return ($fwbr, $vethfw, $vethfwpeer, $ovsintport);
 158 };
 159
 160 my $cond_create_bridge = sub {
 161     my ($bridge) = @_;
 162
 163     if (! -d "/sys/class/net/$bridge") {
 164         system("/sbin/brctl addbr $bridge") == 0 ||
 165             die "can't add bridge '$bridge'\n";
 166     }
 167 };
 168
 169 my $bridge_add_interface = sub {
 170     my ($bridge, $iface, $tag, $trunks) = @_;
 171
 172     system("/sbin/brctl addif $bridge $iface") == 0 ||
 173         die "can't add interface 'iface' to bridge '$bridge'\n";
 174
 175    my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 176
 177    if ($vlan_aware) {
 178         if ($tag) {
 179             system("/sbin/bridge vlan add dev $iface vid $tag pvid untagged") == 0 ||
 180             die "unable to add vlan $tag to interface $iface\n";
 181         } else {
 182             system("/sbin/bridge vlan add dev $iface vid 2-4094") == 0 ||
 183             die "unable to add default vlan tags to interface $iface\n" if !$trunks;
 184         }
 185
 186         if ($trunks) {
 187             my @trunks_array = split /;/, $trunks;
 188             foreach my $trunk (@trunks_array) {
 189                 system("/sbin/bridge vlan add dev $iface vid $trunk") == 0 ||
 190                 die "unable to add vlan $trunk to interface $iface\n";
 191             }
 192         }
 193    }
 194 };
 195
 196 my $ovs_bridge_add_port = sub {
 197     my ($bridge, $iface, $tag, $internal, $trunks) = @_;
 198
 199     $trunks =~ s/;/,/g if $trunks;
 200
 201     my $cmd = "/usr/bin/ovs-vsctl add-port $bridge $iface";
 202     $cmd .= " tag=$tag" if $tag;
 203     $cmd .= " trunks=". join(',', $trunks) if $trunks;
 204     $cmd .= " vlan_mode=native-untagged" if $tag && $trunks;
 205
 206     $cmd .= " -- set Interface $iface type=internal" if $internal;
 207     system($cmd) == 0 ||
 208         die "can't add ovs port '$iface'\n";
 209 };
 210
 211 my $activate_interface = sub {
 212     my ($iface) = @_;
 213
 214     system("/sbin/ip link set $iface up") == 0 ||
 215         die "can't activate interface '$iface'\n";
 216 };
 217
 218 sub tap_create {
 219     my ($iface, $bridge) = @_;
 220
 221     die "unable to get bridge setting\n" if !$bridge;
 222
 223     my $bridgemtu = &$read_bridge_mtu($bridge);
 224
 225     eval {
 226         PVE::Tools::run_command("/sbin/ifconfig $iface 0.0.0.0 promisc up mtu $bridgemtu");
 227     };
 228     die "interface activation failed\n" if $@;
 229 }
 230
 231 sub veth_create {
 232     my ($veth, $vethpeer, $bridge, $mac) = @_;
 233
 234     die "unable to get bridge setting\n" if !$bridge;
 235
 236     my $bridgemtu = &$read_bridge_mtu($bridge);
 237
 238     # create veth pair
 239     if (! -d "/sys/class/net/$veth") {
 240         my $cmd = "/sbin/ip link add name $veth type veth peer name $vethpeer mtu $bridgemtu";
 241         $cmd .= " addr $mac" if $mac;
 242         system($cmd) == 0 || die "can't create interface $veth\n";
 243     }
 244
 245     # up vethpair
 246     &$activate_interface($veth);
 247     &$activate_interface($vethpeer);
 248 }
 249
 250 sub veth_delete {
 251     my ($veth) = @_;
 252
 253     if (-d "/sys/class/net/$veth") {
 254         run_command("/sbin/ip link delete dev $veth", outfunc => sub {}, errfunc => sub {});
 255     }
 256
 257 }
 258
 259 my $create_firewall_bridge_linux = sub {
 260     my ($iface, $bridge, $tag, $trunks) = @_;
 261
 262     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 263     my ($fwbr, $vethfw, $vethfwpeer) = &$compute_fwbr_names($vmid, $devid);
 264
 265     &$cond_create_bridge($fwbr);
 266     &$activate_interface($fwbr);
 267
 268     copy_bridge_config($bridge, $fwbr);
 269     veth_create($vethfw, $vethfwpeer, $bridge);
 270
 271     &$bridge_add_interface($fwbr, $vethfw);
 272     &$bridge_add_interface($bridge, $vethfwpeer, $tag, $trunks);
 273
 274     &$bridge_add_interface($fwbr, $iface);
 275 };
 276
 277 my $create_firewall_bridge_ovs = sub {
 278     my ($iface, $bridge, $tag, $trunks) = @_;
 279
 280     my ($vmid, $devid) = &$parse_tap_device_name($iface);
 281     my ($fwbr, undef, undef, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 282
 283     my $bridgemtu = &$read_bridge_mtu($bridge);
 284
 285     &$cond_create_bridge($fwbr);
 286     &$activate_interface($fwbr);
 287
 288     &$bridge_add_interface($fwbr, $iface);
 289
 290     &$ovs_bridge_add_port($bridge, $ovsintport, $tag, 1, $trunks);
 291     &$activate_interface($ovsintport);
 292
 293     # set the same mtu for ovs int port
 294     PVE::Tools::run_command("/sbin/ifconfig $ovsintport mtu $bridgemtu");
 295
 296     &$bridge_add_interface($fwbr, $ovsintport);
 297 };
 298
 299 my $cleanup_firewall_bridge = sub {
 300     my ($iface) = @_;
 301
 302     my ($vmid, $devid) = &$parse_tap_device_name($iface, 1);
 303     return if !defined($vmid);
 304     my ($fwbr, $vethfw, $vethfwpeer, $ovsintport) = &$compute_fwbr_names($vmid, $devid);
 305
 306     # cleanup old port config from any openvswitch bridge
 307     if (-d "/sys/class/net/$ovsintport") {
 308         run_command("/usr/bin/ovs-vsctl del-port $ovsintport", outfunc => sub {}, errfunc => sub {});
 309     }
 310
 311     # delete old vethfw interface
 312     veth_delete($vethfw);
 313
 314     # cleanup fwbr bridge
 315     if (-d "/sys/class/net/$fwbr") {
 316         run_command("/sbin/ip link set dev $fwbr down", outfunc => sub {}, errfunc => sub {});
 317         run_command("/sbin/brctl delbr $fwbr", outfunc => sub {}, errfunc => sub {});
 318     }
 319 };
 320
 321 sub tap_plug {
 322     my ($iface, $bridge, $tag, $firewall, $trunks, $rate) = @_;
 323
 324     #cleanup old port config from any openvswitch bridge
 325     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 326
 327     if (-d "/sys/class/net/$bridge/bridge") {
 328         &$cleanup_firewall_bridge($iface); # remove stale devices
 329
 330         my $vlan_aware = PVE::Tools::file_read_firstline("/sys/class/net/$bridge/bridge/vlan_filtering");
 331
 332         if (!$vlan_aware) {
 333             die "vlan aware feature need to be enabled to use trunks" if $trunks;
 334             my $newbridge = activate_bridge_vlan($bridge, $tag);
 335             copy_bridge_config($bridge, $newbridge) if $bridge ne $newbridge;
 336             $bridge = $newbridge;
 337             $tag = undef;
 338         }
 339
 340         if ($firewall) {
 341             &$create_firewall_bridge_linux($iface, $bridge, $tag, $trunks);
 342         } else {
 343             &$bridge_add_interface($bridge, $iface, $tag, $trunks);
 344         }
 345
 346     } else {
 347         &$cleanup_firewall_bridge($iface); # remove stale devices
 348
 349         if ($firewall) {
 350             &$create_firewall_bridge_ovs($iface, $bridge, $tag, $trunks);
 351         } else {
 352             &$ovs_bridge_add_port($bridge, $iface, $tag, undef, $trunks);
 353         }
 354     }
 355
 356     tap_rate_limit($iface, $rate);
 357 }
 358
 359 sub tap_unplug {
 360     my ($iface) = @_;
 361
 362     my $path= "/sys/class/net/$iface/brport/bridge";
 363     if (-l $path) {
 364         my $bridge = basename(readlink($path));
 365         #avoid insecure dependency;
 366         ($bridge) = $bridge =~ /(\S+)/;
 367
 368         system("/sbin/brctl delif $bridge $iface") == 0 ||
 369             die "can't del interface '$iface' from bridge '$bridge'\n";
 370
 371     }
 372
 373     &$cleanup_firewall_bridge($iface);
 374     #cleanup old port config from any openvswitch bridge
 375     eval {run_command("/usr/bin/ovs-vsctl del-port $iface", outfunc => sub {}, errfunc => sub {}) };
 376 }
 377
 378 sub copy_bridge_config {
 379     my ($br0, $br1) = @_;
 380
 381     return if $br0 eq $br1;
 382
 383     my $br_configs = [ 'ageing_time', 'stp_state', 'priority', 'forward_delay',
 384                        'hello_time', 'max_age', 'multicast_snooping', 'multicast_querier'];
 385
 386     foreach my $sysname (@$br_configs) {
 387         eval {
 388             my $v0 = PVE::Tools::file_read_firstline("/sys/class/net/$br0/bridge/$sysname");
 389             my $v1 = PVE::Tools::file_read_firstline("/sys/class/net/$br1/bridge/$sysname");
 390             if ($v0 ne $v1) {
 391                  PVE::ProcFSTools::write_proc_entry("/sys/class/net/$br1/bridge/$sysname", $v0);
 392             }
 393         };
 394         warn $@ if $@;
 395     }
 396 }
 397
 398 sub activate_bridge_vlan_slave {
 399     my ($bridgevlan, $iface, $tag) = @_;
 400     my $ifacevlan = "${iface}.$tag";
 401
 402     # create vlan on $iface is not already exist
 403     if (! -d "/sys/class/net/$ifacevlan") {
 404         system("/sbin/ip link add link $iface name ${iface}.${tag} type vlan id $tag") == 0 ||
 405             die "can't add vlan tag $tag to interface $iface\n";
 406     }
 407
 408     # be sure to have the $ifacevlan up
 409     &$activate_interface($ifacevlan);
 410
 411     # test if $vlaniface is already enslaved in another bridge
 412     my $path= "/sys/class/net/$ifacevlan/brport/bridge";
 413     if (-l $path) {
 414         my $tbridge = basename(readlink($path));
 415         if ($tbridge ne $bridgevlan) {
 416             die "interface $ifacevlan already exist in bridge $tbridge\n";
 417         } else {
 418             # Port already attached to bridge: do nothing.
 419             return;
 420         }
 421     }
 422
 423     # add $ifacevlan to the bridge
 424     &$bridge_add_interface($bridgevlan, $ifacevlan);
 425 }
 426
 427 sub activate_bridge_vlan {
 428     my ($bridge, $tag_param) = @_;
 429
 430     die "bridge '$bridge' is not active\n" if ! -d "/sys/class/net/$bridge";
 431
 432     return $bridge if !defined($tag_param); # no vlan, simply return
 433
 434     my $tag = int($tag_param);
 435
 436     die "got strange vlan tag '$tag_param'\n" if $tag < 1 || $tag > 4094;
 437
 438     my $bridgevlan = "${bridge}v$tag";
 439
 440     my @ifaces = ();
 441     my $dir = "/sys/class/net/$bridge/brif";
 442     PVE::Tools::dir_glob_foreach($dir, '((eth|bond)\d+(\.\d+)?)', sub {
 443         push @ifaces, $_[0];
 444     });
 445
 446     die "no physical interface on bridge '$bridge'\n" if scalar(@ifaces) == 0;
 447
 448     # add bridgevlan if it doesn't already exist
 449     if (! -d "/sys/class/net/$bridgevlan") {
 450         system("/sbin/brctl addbr $bridgevlan") == 0 ||
 451             die "can't add bridge $bridgevlan\n";
 452     }
 453
 454     # for each physical interface (eth or bridge) bind them to bridge vlan
 455     foreach my $iface (@ifaces) {
 456         activate_bridge_vlan_slave($bridgevlan, $iface, $tag);
 457     }
 458
 459     #fixme: set other bridge flags
 460
 461     # be sure to have the bridge up
 462     system("/sbin/ip link set $bridgevlan up") == 0 ||
 463         die "can't up bridge $bridgevlan\n";
 464
 465     return $bridgevlan;
 466 }
 467
 468 sub tcp_ping {
 469     my ($host, $port, $timeout) = @_;
 470
 471     my $refused = 1;
 472
 473     $timeout = 3 if !$timeout; # sane default
 474     if (!$port) {
 475         # Net::Ping defaults to the echo port
 476         $port = 7;
 477     } else {
 478         # Net::Ping's port_number() implies service_check(1)
 479         $refused = 0;
 480     }
 481
 482     my ($sock, $result);
 483     eval {
 484         $result = PVE::Tools::run_with_timeout($timeout, sub {
 485             $sock = IO::Socket::IP->new(PeerHost => $host, PeerPort => $port, Type => SOCK_STREAM);
 486             $result = $refused if $! == ECONNREFUSED;
 487         });
 488     };
 489     if ($sock) {
 490         $sock->close();
 491         $result = 1;
 492     }
 493     return $result;
 494 }
 495
 496 sub IP_from_cidr {
 497     my ($cidr, $version) = @_;
 498
 499     return if $cidr !~ m!^(\S+?)/(\S+)$!;
 500     my ($ip, $prefix) = ($1, $2);
 501
 502     my $ipobj = Net::IP->new($ip, $version);
 503     return if !$ipobj;
 504
 505     $version = $ipobj->version();
 506
 507     my $binmask = Net::IP::ip_get_mask($prefix, $version);
 508     return if !$binmask;
 509
 510     my $masked_binip = $ipobj->binip() & $binmask;
 511     my $masked_ip = Net::IP::ip_bintoip($masked_binip, $version);
 512     return Net::IP->new("$masked_ip/$prefix");
 513 }
 514
 515 sub is_ip_in_cidr {
 516     my ($ip, $cidr, $version) = @_;
 517
 518     my $cidr_obj = IP_from_cidr($cidr, $version);
 519     return undef if !$cidr_obj;
 520
 521     my $ip_obj = Net::IP->new($ip, $version);
 522     return undef if !$ip_obj;
 523
 524     return $cidr_obj->overlaps($ip_obj) == $Net::IP::IP_B_IN_A_OVERLAP;
 525 }
 526
 527 # struct ifreq { // FOR SIOCGIFFLAGS:
 528 #   char ifrn_name[IFNAMSIZ]
 529 #   short ifru_flags
 530 # };
 531 my $STRUCT_IFREQ_SIOCGIFFLAGS = 'Z' . IFNAMSIZ . 's1';
 532 sub get_active_interfaces {
 533     # Use the interface name list from /proc/net/dev
 534     open my $fh, '<', '/proc/net/dev'
 535         or die "failed to open /proc/net/dev: $!\n";
 536     # And filter by IFF_UP flag fetched via a PF_INET6 socket ioctl:
 537     my $sock;
 538     socket($sock, PF_INET6, SOCK_DGRAM, &IPPROTO_IP)
 539     or socket($sock, PF_INET, SOCK_DGRAM, &IPPROTO_IP)
 540     or return [];
 541
 542     my $ifaces = [];
 543     while(defined(my $line = <$fh>)) {
 544         next if $line !~ /^\s*([^:\s]+):/;
 545         my $ifname = $1;
 546         my $ifreq = pack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifname, 0);
 547         if (!defined(ioctl($sock, SIOCGIFFLAGS, $ifreq))) {
 548             warn "failed to get interface flags for: $ifname\n";
 549             next;
 550         }
 551         my ($name, $flags) = unpack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifreq);
 552         push @$ifaces, $ifname if ($flags & IFF_UP);
 553     }
 554     close $fh;
 555     close $sock;
 556     return $ifaces;
 557 }
 558
 559 1;