src/PVE/PTY.pm

   1 package PVE::PTY;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Fcntl;
   7 use POSIX qw(O_RDWR O_NOCTTY);
   8
   9 # Constants
  10
  11 use constant {
  12     TCGETS     => 0x5401,   # fixed, from asm-generic/ioctls.h
  13     TCSETS     => 0x5402,   # fixed, from asm-generic/ioctls.h
  14     TIOCGWINSZ => 0x5413,   # fixed, from asm-generic/ioctls.h
  15     TIOCSWINSZ => 0x5414,   # fixed, from asm-generic/ioctls.h
  16     TIOCSCTTY  => 0x540E,   # fixed, from asm-generic/ioctls.h
  17     TIOCNOTTY  => 0x5422,   # fixed, from asm-generic/ioctls.h
  18     TIOCGPGRP  => 0x540F,   # fixed, from asm-generic/ioctls.h
  19     TIOCSPGRP  => 0x5410,   # fixed, from asm-generic/ioctls.h
  20
  21     # IOC: dir:2 size:14 type:8 nr:8
  22     # Get pty number: dir=2 size=4 type='T' nr=0x30
  23     TIOCGPTN => 0x80045430,
  24
  25     # Set pty lock: dir=1 size=4 type='T' nr=0x31
  26     TIOCSPTLCK => 0x40045431,
  27
  28     # Send signal: dir=1 size=4 type='T' nr=0x36
  29     TIOCSIG => 0x40045436,
  30
  31     # c_cc indices:
  32     VINTR => 0,
  33     VQUIT => 1,
  34     VERASE => 2,
  35     VKILL => 3,
  36     VEOF => 4,
  37     VTIME => 5,
  38     VMIN => 6,
  39     VSWTC => 7,
  40     VSTART => 8,
  41     VSTOP => 9,
  42     VSUSP => 10,
  43     VEOL => 11,
  44     VREPRINT => 12,
  45     VDISCARD => 13,
  46     VWERASE => 14,
  47     VLNEXT => 15,
  48     VEOL2 => 16,
  49 };
  50
  51 # Utility functions
  52
  53 sub createpty() {
  54     # Open the master file descriptor:
  55     sysopen(my $master, '/dev/ptmx', O_RDWR | O_NOCTTY)
  56         or die "failed to create pty: $!\n";
  57
  58     # Find the tty number
  59     my $ttynum = pack('L', 0);
  60     ioctl($master, TIOCGPTN, $ttynum)
  61         or die "failed to query pty number: $!\n";
  62     $ttynum = unpack('L', $ttynum);
  63
  64     # Get the slave name/path
  65     my $ttyname = "/dev/pts/$ttynum";
  66
  67     # Unlock
  68     my $false = pack('L', 0);
  69     ioctl($master, TIOCSPTLCK, $false)
  70         or die "failed to unlock pty: $!\n";
  71
  72     return ($master, $ttyname);
  73 }
  74
  75 my $openslave = sub {
  76     my ($ttyname) = @_;
  77
  78     # Create a slave file descriptor:
  79     sysopen(my $slave, $ttyname, O_RDWR | O_NOCTTY)
  80         or die "failed to open slave pty handle: $!\n";
  81     return $slave;
  82 };
  83
  84 sub lose_controlling_terminal() {
  85     # Can we open our current terminal?
  86     if (sysopen(my $ttyfd, '/dev/tty', O_RDWR)) {
  87         # Disconnect:
  88         ioctl($ttyfd, TIOCNOTTY, 0)
  89             or die "failed to disconnect controlling tty: $!\n";
  90         close($ttyfd);
  91     }
  92 }
  93
  94 sub termios(%) {
  95     my (%termios) = @_;
  96     my $cc = $termios{cc} // [];
  97     if (@$cc < 19) {
  98         push @$cc, (0) x (19-@$cc);
  99     } elsif (@$cc > 19) {
 100         @$cc = $$cc[0..18];
 101     }
 102
 103     return pack('LLLLCC[19]',
 104         $termios{iflag} || 0,
 105         $termios{oflag} || 0,
 106         $termios{cflag} || 0,
 107         $termios{lflag} || 0,
 108         $termios{line} || 0,
 109         @$cc);
 110 }
 111
 112 my $parse_termios = sub {
 113     my ($blob) = @_;
 114     my ($iflag, $oflag, $cflag, $lflag, $line, @cc) =
 115     unpack('LLLLCC[19]', $blob);
 116     return {
 117         iflag => $iflag,
 118         oflag => $oflag,
 119         cflag => $cflag,
 120         lflag => $lflag,
 121         line => $line,
 122         cc => \@cc
 123     };
 124 };
 125
 126 sub cfmakeraw($) {
 127     my ($termios) = @_;
 128     $termios->{iflag} &=
 129         ~(POSIX::IGNBRK | POSIX::BRKINT | POSIX::PARMRK | POSIX::ISTRIP |
 130           POSIX::INLCR | POSIX::IGNCR | POSIX::ICRNL | POSIX::IXON);
 131     $termios->{oflag} &= ~POSIX::OPOST;
 132     $termios->{lflag} &=
 133         ~(POSIX::ECHO | POSIX::ECHONL | POSIX::ICANON | POSIX::ISIG |
 134           POSIX::IEXTEN);
 135     $termios->{cflag} &= ~(POSIX::CSIZE | POSIX::PARENB);
 136     $termios->{cflag} |= POSIX::CS8;
 137 }
 138
 139 sub tcgetattr($) {
 140     my ($fd) = @_;
 141     my $blob = termios();
 142     ioctl($fd, TCGETS, $blob) or die "failed to get terminal attributes\n";
 143     return $parse_termios->($blob);
 144 }
 145
 146 sub tcsetattr($$) {
 147     my ($fd, $termios) = @_;
 148     my $blob = termios(%$termios);
 149     ioctl($fd, TCSETS, $blob) or die "failed to set terminal attributes\n";
 150 }
 151
 152 # tcgetsize -> (columns, rows)
 153 sub tcgetsize($) {
 154         my ($fd) = @_;
 155         my $struct_winsz = pack('SSSS', 0, 0, 0, 0);
 156         ioctl($fd, TIOCGWINSZ, $struct_winsz)
 157                 or die "failed to get window size: $!\n";
 158         return reverse unpack('SS', $struct_winsz);
 159 }
 160
 161 sub tcsetsize($$$) {
 162     my ($fd, $columns, $rows) = @_;
 163     my $struct_winsz = pack('SSSS', $rows, $columns, 0, 0);
 164     ioctl($fd, TIOCSWINSZ, $struct_winsz)
 165         or die "failed to set window size: $!\n";
 166 }
 167
 168 # Class functions
 169
 170 sub new {
 171     my ($class) = @_;
 172
 173     my ($master, $ttyname) = createpty();
 174
 175     my $self = {
 176         master => $master,
 177         ttyname => $ttyname,
 178     };
 179
 180     return bless $self, $class;
 181 }
 182
 183 # Properties
 184
 185 sub master  { return $_[0]->{master}  }
 186 sub ttyname { return $_[0]->{ttyname} }
 187
 188 # Methods
 189
 190 sub close {
 191     my ($self) = @_;
 192     close($self->{master});
 193 }
 194
 195 sub open_slave {
 196     my ($self) = @_;
 197     return $openslave->($self->{ttyname});
 198 }
 199
 200 sub set_size {
 201     my ($self, $columns, $rows) = @_;
 202     tcsetsize($self->{master}, $columns, $rows);
 203 }
 204
 205 # get_size -> (columns, rows)
 206 sub get_size {
 207     my ($self) = @_;
 208     return tcgetsize($self->{master});
 209 }
 210
 211 sub kill {
 212     my ($self, $signal) = @_;
 213     if (!ioctl($self->{master}, TIOCSIG, $signal)) {
 214         # kill fallback if the ioctl does not work
 215         kill $signal, $self->get_foreground_pid()
 216             or die "failed to send signal: $!\n";
 217     }
 218 }
 219
 220 sub get_foreground_pid {
 221     my ($self) = @_;
 222     my $pid = pack('L', 0);
 223     ioctl($self->{master}, TIOCGPGRP, $pid)
 224         or die "failed to get foreground pid: $!\n";
 225     return unpack('L', $pid);
 226 }
 227
 228 sub has_process {
 229     my ($self) = @_;
 230     return 0 != $self->get_foreground_pid();
 231 }
 232
 233 sub make_controlling_terminal {
 234     my ($self) = @_;
 235
 236     #lose_controlling_terminal();
 237     POSIX::setsid();
 238     my $slave = $self->open_slave();
 239     ioctl($slave, TIOCSCTTY, 0)
 240         or die "failed to change controlling tty: $!\n";
 241     POSIX::dup2(fileno($slave), 0) or die "failed to dup stdin\n";
 242     POSIX::dup2(fileno($slave), 1) or die "failed to dup stdout\n";
 243     POSIX::dup2(fileno($slave), 2) or die "failed to dup stderr\n";
 244     CORE::close($slave) if fileno($slave) > 2;
 245     CORE::close($self->{master});
 246 }
 247
 248 sub getattr {
 249     my ($self) = @_;
 250     return tcgetattr($self->{master});
 251 }
 252
 253 sub setattr {
 254     my ($self, $termios) = @_;
 255     return tcsetattr($self->{master}, $termios);
 256 }
 257
 258 sub send_cc {
 259     my ($self, $ccidx) = @_;
 260     my $attrs = $self->getattr();
 261     my $data = pack('C', $attrs->{cc}->[$ccidx]);
 262     syswrite($self->{master}, $data)
 263     == 1 || die "write failed: $!\n";
 264 }
 265
 266 sub send_eof {
 267     my ($self) = @_;
 268     $self->send_cc(VEOF);
 269 }
 270
 271 sub send_interrupt {
 272     my ($self) = @_;
 273     $self->send_cc(VINTR);
 274 }
 275
 276 1;