src/PVE/ProcFSTools.pm

   1 package PVE::ProcFSTools;
   2
   3 use strict;
   4 use warnings;
   5 use POSIX;
   6 use Time::HiRes qw (gettimeofday);
   7 use IO::File;
   8 use List::Util qw(sum);
   9 use PVE::Tools;
  10 use Cwd qw();
  11
  12 use Socket qw(PF_INET PF_INET6 SOCK_DGRAM IPPROTO_IP);
  13
  14 use constant IFF_UP => 1;
  15 use constant IFNAMSIZ => 16;
  16 use constant SIOCGIFFLAGS => 0x8913;
  17
  18 my $clock_ticks = POSIX::sysconf(&POSIX::_SC_CLK_TCK);
  19
  20 my $cpuinfo;
  21
  22 sub read_cpuinfo {
  23     my $fn = '/proc/cpuinfo';
  24
  25     return $cpuinfo if $cpuinfo;
  26
  27     my $res = {
  28         user_hz => $clock_ticks,
  29         model => 'unknown',
  30         mhz => 0,
  31         cpus => 1,
  32         sockets => 1,
  33         flags => '',
  34     };
  35
  36     my $fh = IO::File->new ($fn, "r");
  37     return $res if !$fh;
  38
  39     my $cpuid = 0;
  40     my $idhash = {};
  41     my $count = 0;
  42     while (defined(my $line = <$fh>)) {
  43         if ($line =~ m/^processor\s*:\s*\d+\s*$/i) {
  44             $count++;
  45         } elsif ($line =~ m/^model\s+name\s*:\s*(.*)\s*$/i) {
  46             $res->{model} = $1 if $res->{model} eq 'unknown';
  47         } elsif ($line =~ m/^cpu\s+MHz\s*:\s*(\d+\.\d+)\s*$/i) {
  48             $res->{mhz} = $1 if !$res->{mhz};
  49         } elsif ($line =~ m/^flags\s*:\s*(.*)$/) {
  50             $res->{flags} = $1 if !length $res->{flags};
  51         } elsif ($line =~ m/^physical id\s*:\s*(\d+)\s*$/i) {
  52             $cpuid = $1;
  53             $idhash->{$1} = 1 if not defined($idhash->{$1});
  54         } elsif ($line =~ m/^cpu cores\s*:\s*(\d+)\s*$/i) {
  55             $idhash->{$cpuid} = $1 if defined($idhash->{$cpuid});
  56         }
  57     }
  58
  59     # Hardware Virtual Machine (Intel VT / AMD-V)
  60     $res->{hvm} = $res->{flags} =~ m/\s(vmx|svm)\s/;
  61
  62     $res->{sockets} = scalar(keys %$idhash) || 1;
  63
  64     $res->{cores} = sum(values %$idhash) || 1;
  65
  66     $res->{cpus} = $count;
  67
  68     $fh->close;
  69
  70     $cpuinfo = $res;
  71
  72     return $res;
  73 }
  74
  75 sub read_proc_uptime {
  76     my $ticks = shift;
  77
  78     my $line = PVE::Tools::file_read_firstline("/proc/uptime");
  79     if ($line && $line =~ m|^(\d+\.\d+)\s+(\d+\.\d+)\s*$|) {
  80         if ($ticks) {
  81             return (int($1*$clock_ticks), int($2*$clock_ticks));
  82         } else {
  83             return (int($1), int($2));
  84         }
  85     }
  86
  87     return (0, 0);
  88 }
  89
  90 sub kernel_version {
  91     my $line = PVE::Tools::file_read_firstline("/proc/version");
  92
  93     if ($line && $line =~ m|^Linux\sversion\s((\d+(?:\.\d+)+)-?(\S+)?)|) {
  94         my ($fullversion, $version_numbers, $extra) = ($1, $2, $3);
  95
  96         # variable names are the one from the Linux kernel Makefile
  97         my ($version, $patchlevel, $sublevel) = split(/\./, $version_numbers);
  98
  99         return wantarray
 100             ? (int($version), int($patchlevel), int($sublevel), $extra, $fullversion)
 101             : $fullversion;
 102     }
 103
 104     return (0, 0, 0, '', '');
 105 }
 106
 107 # Check if the kernel is at least $major.$minor. Return either just a boolean,
 108 # or a boolean and the kernel version's major.minor string from /proc/version
 109 sub check_kernel_release {
 110     my ($major, $minor) = @_;
 111
 112     my ($k_major, $k_minor) = kernel_version();
 113
 114     my $ok;
 115     if (defined($minor)) {
 116         $ok = $k_major > $major || ($k_major == $major && $k_minor >= $minor);
 117     } else {
 118         $ok = $k_major >= $major;
 119     }
 120
 121     return wantarray ? ($ok, "$k_major.$k_minor") : $ok;
 122 }
 123
 124 sub read_loadavg {
 125
 126     my $line = PVE::Tools::file_read_firstline('/proc/loadavg');
 127
 128     if ($line =~ m|^(\d+\.\d+)\s+(\d+\.\d+)\s+(\d+\.\d+)\s+\d+/\d+\s+\d+\s*$|) {
 129         return wantarray ? ($1, $2, $3) : $1;
 130     }
 131
 132     return wantarray ? (0, 0, 0) : 0;
 133 }
 134
 135 sub parse_pressure {
 136     my ($path) = @_;
 137
 138     my $res = {};
 139     my $v = qr/\d+\.\d+/;
 140     my $fh = IO::File->new($path, "r") or return undef;
 141     while (defined (my $line = <$fh>)) {
 142         if ($line =~ /^(some|full)\s+avg10\=($v)\s+avg60\=($v)\s+avg300\=($v)\s+total\=(\d+)/) {
 143             $res->{$1}->{avg10} = $2;
 144             $res->{$1}->{avg60} = $3;
 145             $res->{$1}->{avg300} = $4;
 146             $res->{$1}->{total} = $4;
 147         }
 148     }
 149     $fh->close;
 150     return $res;
 151 }
 152
 153 sub read_pressure {
 154     my $res = {};
 155     foreach my $type (qw(cpu memory io)) {
 156         my $stats = parse_pressure("/proc/pressure/$type");
 157         $res->{$type} = $stats if $stats;
 158     }
 159     return $res;
 160 }
 161
 162 my $last_proc_stat;
 163
 164 sub read_proc_stat {
 165     my $res = { user => 0, nice => 0, system => 0, idle => 0 , sum => 0};
 166
 167     my $cpucount = 0;
 168
 169     if (my $fh = IO::File->new ("/proc/stat", "r")) {
 170         while (defined (my $line = <$fh>)) {
 171             if ($line =~ m|^cpu\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)|) {
 172                 $res->{user} = $1;
 173                 $res->{nice} = $2;
 174                 $res->{system} = $3;
 175                 $res->{idle} = $4;
 176                 $res->{used} = $1+$2+$3;
 177                 $res->{iowait} = $5;
 178                 $res->{irq} = $6;
 179                 $res->{softirq} = $7;
 180                 $res->{steal} = $8;
 181                 $res->{guest} = $9;
 182                 $res->{guest_nice} = $10;
 183             } elsif ($line =~ m|^cpu\d+\s|) {
 184                 $cpucount++;
 185             }
 186         }
 187         $fh->close;
 188     }
 189
 190     $cpucount = 1 if !$cpucount;
 191
 192     my $ctime = gettimeofday; # floating point time in seconds
 193
 194     # the sum of all (non-guest) fields
 195     $res->{total} = $res->{user}
 196         + $res->{nice}
 197         + $res->{system}
 198         + $res->{iowait}
 199         + $res->{irq}
 200         + $res->{softirq}
 201         + $res->{steal}
 202         + $res->{idle};
 203
 204     $res->{ctime} = $ctime;
 205     $res->{cpu} = 0;
 206     $res->{wait} = 0;
 207
 208     $last_proc_stat = $res if !$last_proc_stat;
 209
 210     my $diff = ($ctime - $last_proc_stat->{ctime}) * $clock_ticks * $cpucount;
 211
 212     if ($diff > 1000) { # don't update too often
 213         my $useddiff =  $res->{used} - $last_proc_stat->{used};
 214         $useddiff = $diff if $useddiff > $diff;
 215         $res->{cpu} = $useddiff/$diff;
 216
 217         my $waitdiff =  $res->{iowait} - $last_proc_stat->{iowait};
 218         $waitdiff = $diff if $waitdiff > $diff;
 219         $res->{wait} = $waitdiff/$diff;
 220
 221         $last_proc_stat = $res;
 222     } else {
 223         $res->{cpu} = $last_proc_stat->{cpu};
 224         $res->{wait} = $last_proc_stat->{wait};
 225     }
 226
 227     return $res;
 228 }
 229
 230 sub read_proc_pid_stat {
 231     my $pid = shift;
 232
 233     my $statstr = PVE::Tools::file_read_firstline("/proc/$pid/stat");
 234
 235     if ($statstr && $statstr =~ m/^$pid \(.*\) (\S) (-?\d+) -?\d+ -?\d+ -?\d+ -?\d+ \d+ \d+ \d+ \d+ \d+ (\d+) (\d+) (-?\d+) (-?\d+) -?\d+ -?\d+ -?\d+ 0 (\d+) (\d+) (-?\d+) \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ \d+ -?\d+ -?\d+ \d+ \d+ \d+/) {
 236         return {
 237             status => $1,
 238             ppid => $2,
 239             utime => $3,
 240             stime => $4,
 241             starttime => $7,
 242             vsize => $8,
 243             rss => $9 * 4096,
 244         };
 245     }
 246
 247     return undef;
 248 }
 249
 250 sub check_process_running {
 251     my ($pid, $pstart) = @_;
 252
 253     # note: waitpid only work for child processes, but not
 254     # for processes spanned by other processes.
 255     # kill(0, pid) return succes for zombies.
 256     # So we read the status form /proc/$pid/stat instead
 257
 258     my $info = read_proc_pid_stat($pid);
 259
 260     return $info && (!$pstart || ($info->{starttime} eq $pstart)) && ($info->{status} ne 'Z') ? $info : undef;
 261 }
 262
 263 sub read_proc_starttime {
 264     my $pid = shift;
 265
 266     my $info = read_proc_pid_stat($pid);
 267     return $info ? $info->{starttime} : 0;
 268 }
 269
 270 sub read_meminfo {
 271
 272     my $res = {
 273         memtotal => 0,
 274         memfree => 0,
 275         memused => 0,
 276         memshared => 0,
 277         swaptotal => 0,
 278         swapfree => 0,
 279         swapused => 0,
 280     };
 281
 282     my $fh = IO::File->new ("/proc/meminfo", "r");
 283     return $res if !$fh;
 284
 285     my $d = {};
 286     while (my $line = <$fh>) {
 287         if ($line =~ m/^(\S+):\s+(\d+)\s*kB/i) {
 288             $d->{lc ($1)} = $2 * 1024;
 289         }
 290     }
 291     close($fh);
 292
 293     $res->{memtotal} = $d->{memtotal};
 294     $res->{memfree} =  $d->{memfree} + $d->{buffers} + $d->{cached};
 295     $res->{memused} = $res->{memtotal} - $res->{memfree};
 296
 297     $res->{swaptotal} = $d->{swaptotal};
 298     $res->{swapfree} = $d->{swapfree};
 299     $res->{swapused} = $res->{swaptotal} - $res->{swapfree};
 300
 301     my $spages = PVE::Tools::file_read_firstline("/sys/kernel/mm/ksm/pages_sharing") // 0 ;
 302     $res->{memshared} = int($spages) * 4096;
 303
 304     return $res;
 305 }
 306
 307 # memory usage of current process
 308 sub read_memory_usage {
 309
 310     my $res = { size => 0, resident => 0, shared => 0 };
 311
 312     my $ps = 4096;
 313
 314     my $line = PVE::Tools::file_read_firstline("/proc/$$/statm");
 315
 316     if ($line =~ m/^(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s*/) {
 317         $res->{size} = $1*$ps;
 318         $res->{resident} = $2*$ps;
 319         $res->{shared} = $3*$ps;
 320     }
 321
 322     return $res;
 323 }
 324
 325 sub read_proc_net_dev {
 326
 327     my $res = {};
 328
 329     my $fh = IO::File->new ("/proc/net/dev", "r");
 330     return $res if !$fh;
 331
 332     while (defined (my $line = <$fh>)) {
 333         if ($line =~ m/^\s*(.*):\s*(\d+)\s+\d+\s+\d+\s+\d+\s+\d+\s+\d+\s+\d+\s+\d+\s+(\d+)\s+/) {
 334             $res->{$1} = {
 335                 receive => $2,
 336                 transmit => $3,
 337             };
 338         }
 339     }
 340
 341     close($fh);
 342
 343     return $res;
 344 }
 345
 346 sub write_proc_entry {
 347     my ($filename, $data) = @_;#
 348
 349     my $fh = IO::File->new($filename,  O_WRONLY);
 350     die "unable to open file '$filename' - $!\n" if !$fh;
 351     die "unable to write '$filename' - $!\n" unless print $fh $data;
 352     die "closing file '$filename' failed - $!\n" unless close $fh;
 353     $fh->close();
 354 }
 355
 356 sub read_proc_net_route {
 357     my $filename = "/proc/net/route";
 358
 359     my $res = [];
 360
 361     my $fh = IO::File->new ($filename, "r");
 362     return $res if !$fh;
 363
 364     my $int_to_quad = sub {
 365        return join '.' => map { ($_[0] >> 8*(3-$_)) % 256 } (3, 2, 1, 0);
 366     };
 367
 368     while (defined(my $line = <$fh>)) {
 369        next if $line =~/^Iface\s+Destination/; # skip head
 370        my ($iface, $dest, $gateway, $metric, $mask, $mtu) = (split(/\s+/, $line))[0,1,2,6,7,8];
 371        push @$res, {
 372            dest => &$int_to_quad(hex($dest)),
 373            gateway => &$int_to_quad(hex($gateway)),
 374            mask => &$int_to_quad(hex($mask)),
 375            metric => $metric,
 376            mtu => $mtu,
 377            iface => $iface,
 378        };
 379     }
 380
 381     return $res;
 382 }
 383
 384 sub read_proc_mounts {
 385     return PVE::Tools::file_get_contents("/proc/mounts", 512*1024);
 386 }
 387
 388 # mounts encode spaces (\040), tabs (\011), newlines (\012), backslashes (\\ or \134)
 389 sub decode_mount {
 390     my ($str) = @_;
 391     return $str =~ s/\\(?:040|01[12]|134|\\)/"\"$&\""/geer;
 392 }
 393
 394 sub parse_mounts {
 395     my ($mounts) = @_;
 396
 397     my $mntent = [];
 398     while ($mounts =~ /^\s*([^#].*)$/gm) {
 399         # lines from the file are encoded so we can just split at spaces
 400         my ($what, $dir, $fstype, $opts) = split(/[ \t]/, $1, 4);
 401         my ($freq, $passno) = (0, 0);
 402         # in glibc's parser frequency and pass seem to be optional
 403         $freq = $1 if $opts =~ s/\s+(\d+)$//;
 404         $passno = $1 if $opts =~ s/\s+(\d+)$//;
 405         push @$mntent, [
 406             decode_mount($what),
 407             decode_mount($dir),
 408             decode_mount($fstype),
 409             decode_mount($opts),
 410             $freq,
 411             $passno,
 412         ];
 413     }
 414     return $mntent;
 415 }
 416
 417 sub parse_proc_mounts {
 418     return parse_mounts(read_proc_mounts());
 419 }
 420
 421 sub is_mounted {
 422     my ($mountpoint) = @_;
 423
 424     $mountpoint = Cwd::realpath($mountpoint);
 425
 426     return 0 if !defined($mountpoint); # path does not exist
 427
 428     my $mounts = parse_proc_mounts();
 429     return (grep { $_->[1] eq $mountpoint } @$mounts) ? 1 : 0;
 430 }
 431
 432 sub read_proc_net_ipv6_route {
 433     my $filename = "/proc/net/ipv6_route";
 434
 435     my $res = [];
 436
 437     my $fh = IO::File->new ($filename, "r");
 438     return $res if !$fh;
 439
 440     my $read_v6addr = sub { $_[0] =~ s/....(?!$)/$&:/gr };
 441
 442     # ipv6_route has no header
 443     while (defined(my $line = <$fh>)) {
 444         my ($dest, $prefix, $nexthop, $metric, $iface) = (split(/\s+/, $line))[0,1,4,5,9];
 445         push @$res, {
 446             dest => &$read_v6addr($dest),
 447             prefix => hex("$prefix"),
 448             gateway => &$read_v6addr($nexthop),
 449             metric => hex("$metric"),
 450             iface => $iface
 451         };
 452     }
 453
 454     return $res;
 455 }
 456
 457 sub upid_wait {
 458     my ($upid, $waitfunc, $sleep_intervall) = @_;
 459
 460     my $task = PVE::Tools::upid_decode($upid);
 461
 462     $sleep_intervall = $sleep_intervall ? $sleep_intervall : 1;
 463
 464     my $next_time = time + $sleep_intervall;
 465
 466     while (check_process_running($task->{pid}, $task->{pstart})) {
 467
 468         if (time >= $next_time && $waitfunc && ref($waitfunc) eq 'CODE'){
 469             &$waitfunc($task);
 470             $next_time = time + $sleep_intervall;
 471         }
 472
 473         CORE::sleep(1);
 474     }
 475 }
 476
 477 # struct ifreq { // FOR SIOCGIFFLAGS:
 478 #   char ifrn_name[IFNAMSIZ]
 479 #   short ifru_flags
 480 # };
 481 my $STRUCT_IFREQ_SIOCGIFFLAGS = 'Z' . IFNAMSIZ . 's1';
 482 sub get_active_network_interfaces {
 483     # Use the interface name list from /proc/net/dev
 484     open my $fh, '<', '/proc/net/dev'
 485         or die "failed to open /proc/net/dev: $!\n";
 486     # And filter by IFF_UP flag fetched via a PF_INET6 socket ioctl:
 487     my $sock;
 488     socket($sock, PF_INET6, SOCK_DGRAM, &IPPROTO_IP)
 489     or socket($sock, PF_INET, SOCK_DGRAM, &IPPROTO_IP)
 490     or return [];
 491
 492     my $ifaces = [];
 493     while(defined(my $line = <$fh>)) {
 494         next if $line !~ /^\s*([^:\s]+):/;
 495         my $ifname = $1;
 496         my $ifreq = pack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifname, 0);
 497         if (!defined(ioctl($sock, SIOCGIFFLAGS, $ifreq))) {
 498             warn "failed to get interface flags for: $ifname\n";
 499             next;
 500         }
 501         my ($name, $flags) = unpack($STRUCT_IFREQ_SIOCGIFFLAGS, $ifreq);
 502         push @$ifaces, $ifname if ($flags & IFF_UP);
 503     }
 504     close $fh;
 505     close $sock;
 506     return $ifaces;
 507 }
 508
 509 1;