src/PVE/RESTEnvironment.pm

   1 package PVE::RESTEnvironment;
   2
   3 # NOTE: you can/should provide your own specialice class, and
   4 # use this a bas class (as example see PVE::RPCEnvironment).
   5
   6 # we use this singleton class to pass RPC related environment values
   7
   8 use strict;
   9 use warnings;
  10 use POSIX qw(:sys_wait_h EINTR);
  11 use IO::Handle;
  12 use IO::File;
  13 use IO::Select;
  14 use Fcntl qw(:flock);
  15 use PVE::Exception qw(raise raise_perm_exc);
  16 use PVE::SafeSyslog;
  17 use PVE::Tools;
  18 use PVE::INotify;
  19 use PVE::ProcFSTools;
  20
  21
  22 my $rest_env;
  23
  24 # save $SIG{CHLD} handler implementation.
  25 # simply set $SIG{CHLD} = $worker_reaper;
  26 # and register forked processes with &$register_worker(pid)
  27 # Note: using $SIG{CHLD} = 'IGNORE' or $SIG{CHLD} = sub { wait (); } or ...
  28 # has serious side effects, because perls built in system() and open()
  29 # functions can't get the correct exit status of a child. So we cant use
  30 # that (also see perlipc)
  31
  32 my $WORKER_PIDS;
  33 my $WORKER_FLAG = 0;
  34
  35 my $log_task_result = sub {
  36     my ($upid, $user, $status) = @_;
  37
  38     return if !$rest_env;
  39
  40     my $msg = 'successful';
  41     my $pri = 'info';
  42     if ($status != 0) {
  43         my $ec = $status >> 8;
  44         my $ic = $status & 255;
  45         $msg = $ec ? "failed ($ec)" : "interrupted ($ic)";
  46         $pri = 'err';
  47     }
  48
  49     my $tlist = $rest_env->active_workers($upid);
  50     eval { $rest_env->broadcast_tasklist($tlist); };
  51     syslog('err', $@) if $@;
  52
  53     my $task;
  54     foreach my $t (@$tlist) {
  55         if ($t->{upid} eq $upid) {
  56             $task = $t;
  57             last;
  58         }
  59     }
  60     if ($task && $task->{status}) {
  61         $msg = $task->{status};
  62     }
  63
  64     $rest_env->log_cluster_msg($pri, $user, "end task $upid $msg");
  65 };
  66
  67 my $worker_reaper = sub {
  68     local $!; local $?;
  69     foreach my $pid (keys %$WORKER_PIDS) {
  70         my $waitpid = waitpid ($pid, WNOHANG);
  71         if (defined($waitpid) && ($waitpid == $pid)) {
  72             my $info = $WORKER_PIDS->{$pid};
  73             if ($info && $info->{upid} && $info->{user}) {
  74                 &$log_task_result($info->{upid}, $info->{user}, $?);
  75             }
  76             delete ($WORKER_PIDS->{$pid});
  77         }
  78     }
  79 };
  80
  81 my $register_worker = sub {
  82     my ($pid, $user, $upid) = @_;
  83
  84     return if !$pid;
  85
  86     # do not register if already finished
  87     my $waitpid = waitpid ($pid, WNOHANG);
  88     if (defined($waitpid) && ($waitpid == $pid)) {
  89         delete ($WORKER_PIDS->{$pid});
  90         return;
  91     }
  92
  93     $WORKER_PIDS->{$pid} = {
  94         user => $user,
  95         upid => $upid,
  96     };
  97 };
  98
  99 # initialize environment - must be called once at program startup
 100 sub init {
 101     my ($class, $type, %params) = @_;
 102
 103     $class = ref($class) || $class;
 104
 105     die "already initialized" if $rest_env;
 106
 107     die "unknown environment type"
 108         if !$type || $type !~ m/^(cli|pub|priv|ha)$/;
 109
 110     $SIG{CHLD} = $worker_reaper;
 111
 112     # environment types
 113     # cli  ... command started fron command line
 114     # pub  ... access from public server (apache)
 115     # priv ... access from private server (pvedaemon)
 116     # ha   ... access from HA resource manager agent (rgmanager)
 117
 118     my $self = { type => $type };
 119
 120     bless $self, $class;
 121
 122     foreach my $p (keys %params) {
 123         if ($p eq 'atfork') {
 124             $self->{$p} = $params{$p};
 125         } else {
 126             die "unknown option '$p'";
 127         }
 128     }
 129
 130     $rest_env = $self;
 131
 132     my ($sysname, $nodename) = POSIX::uname();
 133
 134     $nodename =~ s/\..*$//; # strip domain part, if any
 135
 136     $self->{nodename} = $nodename;
 137
 138     return $self;
 139 };
 140
 141 # convenience function for command line tools
 142 sub setup_default_cli_env {
 143     my ($class, $username) = @_;
 144
 145     $class = ref($class) || $class;
 146
 147     $username //= 'root@pam';
 148
 149     PVE::INotify::inotify_init();
 150
 151     my $rpcenv = $class->init('cli');
 152     $rpcenv->init_request();
 153     $rpcenv->set_language($ENV{LANG});
 154     $rpcenv->set_user($username);
 155
 156     die "please run as root\n"
 157         if ($username eq 'root@pam') && ($> != 0);
 158 }
 159
 160 # get the singleton
 161 sub get {
 162
 163     die "REST environment not initialized" if !$rest_env;
 164
 165     return $rest_env;
 166 }
 167
 168 sub set_client_ip {
 169     my ($self, $ip) = @_;
 170
 171     $self->{client_ip} = $ip;
 172 }
 173
 174 sub get_client_ip {
 175     my ($self) = @_;
 176
 177     return $self->{client_ip};
 178 }
 179
 180 sub set_result_attrib {
 181     my ($self, $key, $value) = @_;
 182
 183     $self->{result_attributes}->{$key} = $value;
 184 }
 185
 186 sub get_result_attrib {
 187     my ($self, $key) = @_;
 188
 189     return $self->{result_attributes}->{$key};
 190 }
 191
 192 sub set_language {
 193     my ($self, $lang) = @_;
 194
 195     # fixme: initialize I18N
 196
 197     $self->{language} = $lang;
 198 }
 199
 200 sub get_language {
 201     my ($self) = @_;
 202
 203     return $self->{language};
 204 }
 205
 206 sub set_user {
 207     my ($self, $user) = @_;
 208
 209     $self->{user} = $user;
 210 }
 211
 212 sub get_user {
 213     my ($self, $noerr) = @_;
 214
 215     return $self->{user} if defined($self->{user}) || $noerr;
 216
 217     die "user name not set\n";
 218 }
 219
 220 sub is_worker {
 221     my ($class) = @_;
 222
 223     return $WORKER_FLAG;
 224 }
 225
 226 # read/update list of active workers
 227 # we move all finished tasks to the archive index,
 228 # but keep aktive and most recent task in the active file.
 229 # $nocheck ... consider $new_upid still running (avoid that
 230 # we try to read the reult to early.
 231 sub active_workers  {
 232     my ($self, $new_upid, $nocheck) = @_;
 233
 234     my $lkfn = "/var/log/pve/tasks/.active.lock";
 235
 236     my $timeout = 10;
 237
 238     my $code = sub {
 239
 240         my $tasklist = PVE::INotify::read_file('active');
 241
 242         my @ta;
 243         my $tlist = [];
 244         my $thash = {}; # only list task once
 245
 246         my $check_task = sub {
 247             my ($task, $running) = @_;
 248
 249             if ($running || PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart})) {
 250                 push @$tlist, $task;
 251             } else {
 252                 delete $task->{pid};
 253                 push @ta, $task;
 254             }
 255             delete $task->{pstart};
 256         };
 257
 258         foreach my $task (@$tasklist) {
 259             my $upid = $task->{upid};
 260             next if $thash->{$upid};
 261             $thash->{$upid} = $task;
 262             &$check_task($task);
 263         }
 264
 265         if ($new_upid && !(my $task = $thash->{$new_upid})) {
 266             $task = PVE::Tools::upid_decode($new_upid);
 267             $task->{upid} = $new_upid;
 268             $thash->{$new_upid} = $task;
 269             &$check_task($task, $nocheck);
 270         }
 271
 272
 273         @ta = sort { $b->{starttime} <=> $a->{starttime} } @ta;
 274
 275         my $save = defined($new_upid);
 276
 277         foreach my $task (@ta) {
 278             next if $task->{endtime};
 279             $task->{endtime} = time();
 280             $task->{status} = PVE::Tools::upid_read_status($task->{upid});
 281             $save = 1;
 282         }
 283
 284         my $archive = '';
 285         my @arlist = ();
 286         foreach my $task (@ta) {
 287             if (!$task->{saved}) {
 288                 $archive .= sprintf("%s %08X %s\n", $task->{upid}, $task->{endtime}, $task->{status});
 289                 $save = 1;
 290                 push @arlist, $task;
 291                 $task->{saved} = 1;
 292             }
 293         }
 294
 295         if ($archive) {
 296             my $size = 0;
 297             my $filename = "/var/log/pve/tasks/index";
 298             eval {
 299                 my $fh = IO::File->new($filename, '>>', 0644) ||
 300                     die "unable to open file '$filename' - $!\n";
 301                 PVE::Tools::safe_print($filename, $fh, $archive);
 302                 $size = -s $fh;
 303                 close($fh) ||
 304                     die "unable to close file '$filename' - $!\n";
 305             };
 306             my $err = $@;
 307             if ($err) {
 308                 syslog('err', $err);
 309                 foreach my $task (@arlist) { # mark as not saved
 310                     $task->{saved} = 0;
 311                 }
 312             }
 313             my $maxsize = 50000; # about 1000 entries
 314             if ($size > $maxsize) {
 315                 rename($filename, "$filename.1");
 316             }
 317         }
 318
 319         # we try to reduce the amount of data
 320         # list all running tasks and task and a few others
 321         # try to limit to 25 tasks
 322         my $max = 25 - scalar(@$tlist);
 323         foreach my $task (@ta) {
 324             last if $max <= 0;
 325             push @$tlist, $task;
 326             $max--;
 327         }
 328
 329         PVE::INotify::write_file('active', $tlist) if $save;
 330
 331         return $tlist;
 332     };
 333
 334     my $res = PVE::Tools::lock_file($lkfn, $timeout, $code);
 335     die $@ if $@;
 336
 337     return $res;
 338 }
 339
 340 my $kill_process_group = sub {
 341     my ($pid, $pstart) = @_;
 342
 343     # send kill to process group (negative pid)
 344     my $kpid = -$pid;
 345
 346     # always send signal to all pgrp members
 347     kill(15, $kpid); # send TERM signal
 348
 349     # give max 5 seconds to shut down
 350     for (my $i = 0; $i < 5; $i++) {
 351         return if !PVE::ProcFSTools::check_process_running($pid, $pstart);
 352         sleep (1);
 353     }
 354
 355     # to be sure
 356     kill(9, $kpid);
 357 };
 358
 359 sub check_worker {
 360     my ($self, $upid, $killit) = @_;
 361
 362     my $task = PVE::Tools::upid_decode($upid);
 363
 364     my $running = PVE::ProcFSTools::check_process_running($task->{pid}, $task->{pstart});
 365
 366     return 0 if !$running;
 367
 368     if ($killit) {
 369         &$kill_process_group($task->{pid});
 370         return 0;
 371     }
 372
 373     return 1;
 374 }
 375
 376 # acts almost as tee: writes an output both to STDOUT and a task log,
 377 # we differ as we're worker aware and look also at the childs control pipe,
 378 # so we know if the function could be executed successfully or not.
 379 my $tee_worker = sub {
 380     my ($childfd, $ctrlfd, $taskfh, $cpid) = @_;
 381
 382     eval {
 383         my $int_count = 0;
 384         local $SIG{INT} = local $SIG{QUIT} = local $SIG{TERM} = sub {
 385             # always send signal to all pgrp members
 386             my $kpid = -$cpid;
 387             if ($int_count < 3) {
 388                 kill(15, $kpid); # send TERM signal
 389             } else {
 390                 kill(9, $kpid); # send KILL signal
 391             }
 392             $int_count++;
 393         };
 394         local $SIG{PIPE} = sub { die "broken pipe\n"; };
 395
 396         my $select = new IO::Select;
 397         my $fh = IO::Handle->new_from_fd($childfd, 'r');
 398         $select->add($fh);
 399
 400         my $readbuf = '';
 401         my $count;
 402         while ($select->count) {
 403             my @handles = $select->can_read(1);
 404             if (scalar(@handles)) {
 405                 my $count = sysread ($handles[0], $readbuf, 4096);
 406                 if (!defined ($count)) {
 407                     my $err = $!;
 408                     die "sync pipe read error: $err\n";
 409                 }
 410                 last if $count == 0; # eof
 411
 412                 print $readbuf;
 413                 select->flush();
 414
 415                 print $taskfh $readbuf;
 416                 $taskfh->flush();
 417             } else {
 418                 # some commands daemonize without closing stdout
 419                 last if !PVE::ProcFSTools::check_process_running($cpid);
 420             }
 421         }
 422
 423         # get status (error or OK)
 424         POSIX::read($ctrlfd, $readbuf, 4096);
 425         if ($readbuf =~ m/^TASK OK\n?$/) {
 426             # skip printing to stdout
 427             print $taskfh $readbuf;
 428         } elsif ($readbuf =~ m/^TASK ERROR: (.*)\n?$/) {
 429             print STDERR "$1\n";
 430             print $taskfh "\n$readbuf"; # ensure start on new line for webUI
 431         } else {
 432             die "got unexpected control message: $readbuf\n";
 433         }
 434         $taskfh->flush();
 435     };
 436     my $err = $@;
 437
 438     POSIX::close($childfd);
 439     POSIX::close($ctrlfd);
 440
 441     if ($err) {
 442         $err =~ s/\n/ /mg;
 443         print STDERR "$err\n";
 444         print $taskfh "TASK ERROR: $err\n";
 445     }
 446 };
 447
 448 # start long running workers
 449 # STDIN is redirected to /dev/null
 450 # STDOUT,STDERR are redirected to the filename returned by upid_decode
 451 # NOTE: we simulate running in foreground if ($self->{type} eq 'cli')
 452 sub fork_worker {
 453     my ($self, $dtype, $id, $user, $function, $background) = @_;
 454
 455     $dtype = 'unknown' if !defined ($dtype);
 456     $id = '' if !defined ($id);
 457
 458     $user = 'root@pve' if !defined ($user);
 459
 460     my $sync = ($self->{type} eq 'cli' && !$background) ? 1 : 0;
 461
 462     local $SIG{INT} =
 463         local $SIG{QUIT} =
 464         local $SIG{PIPE} =
 465         local $SIG{TERM} = 'IGNORE';
 466
 467     my $starttime = time ();
 468
 469     my @psync = POSIX::pipe();
 470     my @csync = POSIX::pipe();
 471     my @ctrlfd = POSIX::pipe() if $sync;
 472
 473     my $node = $self->{nodename};
 474
 475     my $cpid = fork();
 476     die "unable to fork worker - $!" if !defined($cpid);
 477
 478     my $workerpuid = $cpid ? $cpid : $$;
 479
 480     my $pstart = PVE::ProcFSTools::read_proc_starttime($workerpuid) ||
 481         die "unable to read process start time";
 482
 483     my $upid = PVE::Tools::upid_encode ({
 484         node => $node, pid => $workerpuid, pstart => $pstart,
 485         starttime => $starttime, type => $dtype, id => $id, user => $user });
 486
 487     my $outfh;
 488
 489     if (!$cpid) { # child
 490
 491         $0 = "task $upid";
 492         $WORKER_FLAG = 1;
 493
 494         $SIG{INT} = $SIG{QUIT} = $SIG{TERM} = sub { die "received interrupt\n"; };
 495
 496         $SIG{CHLD} = $SIG{PIPE} = 'DEFAULT';
 497
 498         # set sess/process group - we want to be able to kill the
 499         # whole process group
 500         POSIX::setsid();
 501
 502         POSIX::close ($psync[0]);
 503         POSIX::close ($ctrlfd[0]) if $sync;
 504         POSIX::close ($csync[1]);
 505
 506         $outfh = $sync ? $psync[1] : undef;
 507         my $resfh = $sync ? $ctrlfd[1] : undef;
 508
 509         eval {
 510             PVE::INotify::inotify_close();
 511
 512             if (my $atfork = $self->{atfork}) {
 513                 &$atfork();
 514             }
 515
 516             # same algorythm as used inside SA
 517             # STDIN = /dev/null
 518             my $fd = fileno (STDIN);
 519
 520             if (!$sync) {
 521                 close STDIN;
 522                 POSIX::close(0) if $fd != 0;
 523
 524                 die "unable to redirect STDIN - $!"
 525                     if !open(STDIN, "</dev/null");
 526
 527                 $outfh = PVE::Tools::upid_open($upid);
 528                 $resfh = fileno($outfh);
 529             }
 530
 531
 532             # redirect STDOUT
 533             $fd = fileno(STDOUT);
 534             close STDOUT;
 535             POSIX::close (1) if $fd != 1;
 536
 537             die "unable to redirect STDOUT - $!"
 538                 if !open(STDOUT, ">&", $outfh);
 539
 540             STDOUT->autoflush (1);
 541
 542             #  redirect STDERR to STDOUT
 543             $fd = fileno (STDERR);
 544             close STDERR;
 545             POSIX::close(2) if $fd != 2;
 546
 547             die "unable to redirect STDERR - $!"
 548                 if !open(STDERR, ">&1");
 549
 550             STDERR->autoflush(1);
 551         };
 552         if (my $err = $@) {
 553             my $msg =  "ERROR: $err";
 554             POSIX::write($psync[1], $msg, length ($msg));
 555             POSIX::close($psync[1]);
 556             POSIX::_exit(1);
 557             kill(-9, $$);
 558         }
 559
 560         # sync with parent (signal that we are ready)
 561         POSIX::write($psync[1], $upid, length ($upid));
 562         POSIX::close($psync[1]) if !$sync; # don't need output pipe if async
 563
 564         eval {
 565             my $readbuf = '';
 566             # sync with parent (wait until parent is ready)
 567             POSIX::read($csync[0], $readbuf, 4096);
 568             die "parent setup error\n" if $readbuf ne 'OK';
 569
 570             if ($self->{type} eq 'ha') {
 571                 print "task started by HA resource agent\n";
 572             }
 573             &$function($upid);
 574         };
 575         my $err = $@;
 576         if ($err) {
 577             chomp $err;
 578             $err =~ s/\n/ /mg;
 579             syslog('err', $err);
 580             my $msg = "TASK ERROR: $err\n";
 581             POSIX::write($resfh, $msg, length($msg));
 582             POSIX::close($resfh) if $sync;
 583             POSIX::_exit(-1);
 584         } else {
 585             my $msg = "TASK OK\n";
 586             POSIX::write($resfh, $msg, length($msg));
 587             POSIX::close($resfh) if $sync;
 588             POSIX::_exit(0);
 589         }
 590         kill(-9, $$);
 591     }
 592
 593     # parent
 594
 595     POSIX::close ($psync[1]);
 596     POSIX::close ($ctrlfd[1]) if $sync;
 597     POSIX::close ($csync[0]);
 598
 599     my $readbuf = '';
 600     # sync with child (wait until child starts)
 601     POSIX::read($psync[0], $readbuf, 4096);
 602
 603     if (!$sync) {
 604         POSIX::close($psync[0]);
 605         &$register_worker($cpid, $user, $upid);
 606     } else {
 607         chomp $readbuf;
 608     }
 609
 610     eval {
 611         die "got no worker upid - start worker failed\n" if !$readbuf;
 612
 613         if ($readbuf =~ m/^ERROR:\s*(.+)$/m) {
 614             die "starting worker failed: $1\n";
 615         }
 616
 617         if ($readbuf ne $upid) {
 618             die "got strange worker upid ('$readbuf' != '$upid') - start worker failed\n";
 619         }
 620
 621         if ($sync) {
 622             $outfh = PVE::Tools::upid_open($upid);
 623         }
 624     };
 625     my $err = $@;
 626
 627     if (!$err) {
 628         my $msg = 'OK';
 629         POSIX::write($csync[1], $msg, length ($msg));
 630         POSIX::close($csync[1]);
 631
 632     } else {
 633         POSIX::close($csync[1]);
 634         kill(-9, $cpid); # make sure it gets killed
 635         die $err;
 636     }
 637
 638     $self->log_cluster_msg('info', $user, "starting task $upid");
 639
 640     my $tlist = $self->active_workers($upid, $sync);
 641     eval { $self->broadcast_tasklist($tlist); };
 642     syslog('err', $@) if $@;
 643
 644     my $res = 0;
 645
 646     if ($sync) {
 647
 648         $tee_worker->($psync[0], $ctrlfd[0], $outfh, $cpid);
 649
 650         &$kill_process_group($cpid, $pstart); # make sure it gets killed
 651
 652         close($outfh);
 653
 654         waitpid($cpid, 0);
 655         $res = $?;
 656         &$log_task_result($upid, $user, $res);
 657     }
 658
 659     return wantarray ? ($upid, $res) : $upid;
 660 }
 661
 662 # Abstract function
 663
 664 sub log_cluster_msg {
 665     my ($self, $pri, $user, $msg) = @_;
 666
 667     syslog($pri, "%s", $msg);
 668
 669     # PVE::Cluster::log_msg($pri, $user, $msg);
 670 }
 671
 672 sub broadcast_tasklist {
 673     my ($self, $tlist) = @_;
 674
 675     # PVE::Cluster::broadcast_tasklist($tlist);
 676 }
 677
 678 sub check_api2_permissions {
 679     my ($self, $perm, $username, $param) = @_;
 680
 681     return 1 if !$username && $perm->{user} eq 'world';
 682
 683     raise_perm_exc("user != null") if !$username;
 684
 685     return 1 if $username eq 'root@pam';
 686
 687     raise_perm_exc('user != root@pam') if !$perm;
 688
 689     return 1 if $perm->{user} && $perm->{user} eq 'all';
 690
 691     ##return $self->exec_api2_perm_check($perm->{check}, $username, $param)
 692     ##if $perm->{check};
 693
 694     raise_perm_exc();
 695 }
 696
 697 # init_request - should be called before each REST/CLI request
 698 sub init_request {
 699     my ($self, %params) = @_;
 700
 701     $self->{result_attributes} = {}
 702
 703     # if you nedd more, implement in subclass
 704 }
 705
 706 1;